Merge "Revert "AGI: Only defer frames when in an interception routine.""
[asterisk/asterisk.git] / autoconf / ast_ext_lib.m4
1 # Helper function to setup variables for a package.
2 # $1 -> the package name. Used in configure.ac and also as a prefix
3 #       for the variables ($1_DIR, $1_INCLUDE, $1_LIB) in makeopts
4 # $3 -> option name, used in --with-$3 or --without-$3 when calling configure.
5 # $2 and $4 are just text describing the package (short and long form)
6
7 # AST_EXT_LIB_SETUP([package], [short description], [configure option name], [long description])
8
9 AC_DEFUN([AST_EXT_LIB_SETUP],
10 [
11     $1_DESCRIP="$2"
12     $1_OPTION="$3"
13     PBX_$1=0
14     AC_ARG_WITH([$3], AS_HELP_STRING([--with-$3=PATH],[use $2 files in PATH$4]),
15     [
16         case ${withval} in
17         n|no)
18         USE_$1=no
19         # -1 is a magic value used by menuselect to know that the package
20         # was disabled, other than 'not found'
21         PBX_$1=-1
22         ;;
23         y|ye|yes)
24         ac_mandatory_list="${ac_mandatory_list} $1"
25         ;;
26         *)
27         $1_DIR="${withval}"
28         ac_mandatory_list="${ac_mandatory_list} $1"
29         ;;
30         esac
31     ])
32     AH_TEMPLATE(m4_bpatsubst([[HAVE_$1]], [(.*)]), [Define to 1 if you have the $2 library.])
33     AC_SUBST([$1_LIB])
34     AC_SUBST([$1_INCLUDE])
35     AC_SUBST([$1_DIR])
36     AC_SUBST([PBX_$1])
37 ])
38
39 # AST_OPTION_ONLY([option name], [option variable], [option description], [default value])
40 AC_DEFUN([AST_OPTION_ONLY],
41 [
42 AC_ARG_WITH([$1], AC_HELP_STRING([--with-$1=PATH], [use $3 in PATH]),
43         [
44         case ${withval} in
45         n|no)
46                 unset $2
47                 ;;
48         *)
49                 if test "x${withval}" = "x"; then
50                         m4_ifval($4, [$2="$4"], [:])
51                 else
52                         $2="${withval}"
53                 fi
54                 ;;
55         esac
56         ],
57         [m4_ifval($4, [$2="$4"], [:])])
58 AC_SUBST($2)
59 ])
60
61 # Setup required dependent package
62 # AST_EXT_LIB_SETUP_DEPENDENT([dependent package symbol name], [dependent package friendly name], [master package symbol name], [master package name])
63
64 AC_DEFUN([AST_EXT_LIB_SETUP_DEPENDENT],
65 [
66 $1_DESCRIP="$2"
67 m4_ifval([$4], [$1_OPTION=$4])
68 m4_ifval([$3], [
69 for i in ${ac_mandatory_list}; do
70    if test "x$3" = "x$i"; then
71       ac_mandatory_list="${ac_mandatory_list} $1"
72       break
73    fi
74 done
75 $1_DIR=${$3_DIR}
76 ])
77 PBX_$1=0
78 AH_TEMPLATE(m4_bpatsubst([[HAVE_$1]], [(.*)]), [Define to 1 if you have the $2 library.])
79 AC_SUBST([$1_LIB])
80 AC_SUBST([$1_INCLUDE])
81 AC_SUBST([$1_DIR])
82 AC_SUBST([PBX_$1])
83 ])
84
85 # Setup optional dependent package
86 # AST_EXT_LIB_SETUP_OPTIONAL([optional package symbol name], [optional package friendly name], [master package symbol name], [master package name])
87
88 AC_DEFUN([AST_EXT_LIB_SETUP_OPTIONAL],
89 [
90 $1_DESCRIP="$2"
91 m4_ifval([$4], [$1_OPTION=$4])
92 m4_ifval([$3], [$1_DIR=${$3_DIR}
93 ])
94 PBX_$1=0
95 AH_TEMPLATE(m4_bpatsubst([[HAVE_$1]], [(.*)]), [Define to 1 if $3 has the $2 feature.])
96 AC_SUBST([$1_LIB])
97 AC_SUBST([$1_INCLUDE])
98 AC_SUBST([$1_DIR])
99 AC_SUBST([PBX_$1])
100 ])
101
102 # Check for existence of a given package ($1), either looking up a function
103 # in a library, or, if no function is supplied, only check for the
104 # existence of the header files.
105
106 # AST_EXT_LIB_CHECK([package], [library], [function], [header],
107 #        [extra libs], [extra cflags], [version])
108 AC_DEFUN([AST_EXT_LIB_CHECK],
109 [
110 if test "x${PBX_$1}" != "x1" -a "${USE_$1}" != "no"; then
111    pbxlibdir=""
112    # if --with-$1=DIR has been specified, use it.
113    if test "x${$1_DIR}" != "x"; then
114       if test -d ${$1_DIR}/lib; then
115          pbxlibdir="-L${$1_DIR}/lib"
116       else
117          pbxlibdir="-L${$1_DIR}"
118       fi
119    fi
120    pbxfuncname="$3"
121    if test "x${pbxfuncname}" = "x" ; then   # empty lib, assume only headers
122       AST_$1_FOUND=yes
123    else
124       ast_ext_lib_check_save_CFLAGS="${CFLAGS}"
125       CFLAGS="${CFLAGS} $6"
126       AC_CHECK_LIB([$2], [${pbxfuncname}], [AST_$1_FOUND=yes], [AST_$1_FOUND=no], [${pbxlibdir} $5])
127       CFLAGS="${ast_ext_lib_check_save_CFLAGS}"
128    fi
129
130    # now check for the header.
131    if test "${AST_$1_FOUND}" = "yes"; then
132       $1_LIB="${pbxlibdir} -l$2 $5"
133       # if --with-$1=DIR has been specified, use it.
134       if test "x${$1_DIR}" != "x"; then
135          $1_INCLUDE="-I${$1_DIR}/include"
136       fi
137       $1_INCLUDE="${$1_INCLUDE} $6"
138       if test "x$4" = "x" ; then        # no header, assume found
139          $1_HEADER_FOUND="1"
140       else                              # check for the header
141          ast_ext_lib_check_saved_CPPFLAGS="${CPPFLAGS}"
142          CPPFLAGS="${CPPFLAGS} ${$1_INCLUDE}"
143          AC_CHECK_HEADER([$4], [$1_HEADER_FOUND=1], [$1_HEADER_FOUND=0])
144          CPPFLAGS="${ast_ext_lib_check_saved_CPPFLAGS}"
145       fi
146       if test "x${$1_HEADER_FOUND}" = "x0" ; then
147          $1_LIB=""
148          $1_INCLUDE=""
149       else
150          if test "x${pbxfuncname}" = "x" ; then         # only checking headers -> no library
151             $1_LIB=""
152          fi
153          PBX_$1=1
154          cat >>confdefs.h <<_ACEOF
155 [@%:@define] HAVE_$1 1
156 _ACEOF
157          m4_ifval([$7], [
158          cat >>confdefs.h <<_ACEOF
159 [@%:@define] HAVE_$1_VERSION $7
160 _ACEOF
161             ])
162       fi
163    fi
164 fi
165 m4_ifval([$7], [AH_TEMPLATE(m4_bpatsubst([[HAVE_$1_VERSION]], [(.*)]), [Define to the version of the $2 library.])])
166 ])