Merged revisions 214436 via svnmerge from
[asterisk/asterisk.git] / autoconf / ast_ext_lib.m4
1 # Helper function to setup variables for a package.
2 # $1 -> the package name. Used in configure.ac and also as a prefix
3 #       for the variables ($1_DIR, $1_INCLUDE, $1_LIB) in makeopts
4 # $3 -> option name, used in --with-$3 or --without-$3 when calling configure.
5 # $2 and $4 are just text describing the package (short and long form)
6
7 # AST_EXT_LIB_SETUP([package], [short description], [configure option name], [long description])
8
9 AC_DEFUN([AST_EXT_LIB_SETUP],
10 [
11     $1_DESCRIP="$2"
12     $1_OPTION="$3"
13     PBX_$1=0
14     AC_ARG_WITH([$3], AC_HELP_STRING([--with-$3=PATH],[use $2 files in PATH$4]),
15     [
16         case ${withval} in
17         n|no)
18         USE_$1=no
19         # -1 is a magic value used by menuselect to know that the package
20         # was disabled, other than 'not found'
21         PBX_$1=-1
22         ;;
23         y|ye|yes)
24         ac_mandatory_list="${ac_mandatory_list} $1"
25         ;;
26         *)
27         $1_DIR="${withval}"
28         ac_mandatory_list="${ac_mandatory_list} $1"
29         ;;
30         esac
31     ])
32     AH_TEMPLATE(m4_bpatsubst([[HAVE_$1]], [(.*)]), [Define to 1 if you have the $2 library.])
33     AH_TEMPLATE(m4_bpatsubst([[HAVE_$1_VERSION]], [(.*)]), [Define to the version of the $2 library.])
34     AC_SUBST([$1_LIB])
35     AC_SUBST([$1_INCLUDE])
36     AC_SUBST([$1_DIR])
37     AC_SUBST([PBX_$1])
38 ])
39
40 # AST_EXT_LIB_SETUP_DEPENDENT([package symbol name], [package friendly name], [master package symbol name], [master package option name])
41
42 AC_DEFUN([AST_EXT_LIB_SETUP_DEPENDENT],
43 [
44 $1_DESCRIP="$2"
45 m4_ifval([$4], [$1_OPTION=$4])
46 m4_ifval([$3], [
47 for i in ${ac_mandatory_list}; do
48    if test "x$3" = "x$i"; then
49       ac_mandatory_list="${ac_mandatory_list} $1"
50       break
51    fi
52 done
53 ])
54 PBX_$1=0
55 AH_TEMPLATE(m4_bpatsubst([[HAVE_$1]], [(.*)]), [Define to 1 if you have the $2 library.])
56 AC_SUBST([$1_LIB])
57 AC_SUBST([$1_INCLUDE])
58 AC_SUBST([$1_DIR])
59 AC_SUBST([PBX_$1])
60 ])
61
62 # Check for existence of a given package ($1), either looking up a function
63 # in a library, or, if no function is supplied, only check for the
64 # existence of the header files.
65
66 # AST_EXT_LIB_CHECK([package], [library], [function], [header],
67 #        [extra libs], [extra cflags], [version])
68 AC_DEFUN([AST_EXT_LIB_CHECK],
69 [
70 if test "x${PBX_$1}" != "x1" -a "${USE_$1}" != "no"; then
71    pbxlibdir=""
72    # if --with-$1=DIR has been specified, use it.
73    if test "x${$1_DIR}" != "x"; then
74       if test -d ${$1_DIR}/lib; then
75          pbxlibdir="-L${$1_DIR}/lib"
76       else
77          pbxlibdir="-L${$1_DIR}"
78       fi
79    fi
80    pbxfuncname="$3"
81    if test "x${pbxfuncname}" = "x" ; then   # empty lib, assume only headers
82       AST_$1_FOUND=yes
83    else
84       AC_CHECK_LIB([$2], [${pbxfuncname}], [AST_$1_FOUND=yes], [AST_$1_FOUND=no], ${pbxlibdir} $5)
85    fi
86
87    # now check for the header.
88    if test "${AST_$1_FOUND}" = "yes"; then
89       $1_LIB="${pbxlibdir} -l$2 $5"
90       # if --with-$1=DIR has been specified, use it.
91       if test "x${$1_DIR}" != "x"; then
92          $1_INCLUDE="-I${$1_DIR}/include"
93       fi
94       $1_INCLUDE="${$1_INCLUDE} $6"
95       if test "x$4" = "x" ; then        # no header, assume found
96          $1_HEADER_FOUND="1"
97       else                              # check for the header
98          saved_cppflags="${CPPFLAGS}"
99          CPPFLAGS="${CPPFLAGS} ${$1_INCLUDE}"
100          AC_CHECK_HEADER([$4], [$1_HEADER_FOUND=1], [$1_HEADER_FOUND=0])
101          CPPFLAGS="${saved_cppflags}"
102       fi
103       if test "x${$1_HEADER_FOUND}" = "x0" ; then
104          $1_LIB=""
105          $1_INCLUDE=""
106       else
107          if test "x${pbxfuncname}" = "x" ; then         # only checking headers -> no library
108             $1_LIB=""
109          fi
110          PBX_$1=1
111          cat >>confdefs.h <<_ACEOF
112 [@%:@define] HAVE_$1 1
113 [@%:@define] HAVE_$1_VERSION $7
114 _ACEOF
115       fi
116    fi
117 fi
118 ])