Add missing file from previous commit.
[asterisk/asterisk.git] / autoconf / ast_ext_tool_check.m4
1 # Check for a package using $2-config. Similar to AST_EXT_LIB_CHECK,
2 # but use $2-config to determine cflags and libraries to use.
3 # $3 and $4 can be used to replace --cflags and --libs in the request
4
5 # AST_EXT_TOOL_CHECK([package], [tool name], [--cflags], [--libs], [includes], [expression])
6 AC_DEFUN([AST_EXT_TOOL_CHECK],
7 [
8         AC_REQUIRE([AST_PROG_SED])dnl
9         if test "x${PBX_$1}" != "x1" -a "${USE_$1}" != "no"; then
10                 PBX_$1=0
11                 AC_PATH_TOOL(CONFIG_$1, $2, No, [${$1_DIR}/bin:$PATH])
12                 if test ! "x${CONFIG_$1}" = xNo; then
13                         if test x"$3" = x ; then A=--cflags ; else A="$3" ; fi
14                         $1_INCLUDE=$(${CONFIG_$1} $A)
15                         $1_INCLUDE=$(echo ${$1_INCLUDE} | $SED -e "s|-I|-I${$1_DIR}|g")
16
17                         if test x"$4" = x ; then A=--libs ; else A="$4" ; fi
18                         $1_LIB=$(${CONFIG_$1} $A)
19                         $1_LIB=$(echo ${$1_LIB} | $SED -e "s|-L|-L${$1_DIR}|g")
20
21                         if test x"$5" != x ; then
22                                 saved_cppflags="${CPPFLAGS}"
23                                 CPPFLAGS="${CPPFLAGS} ${$1_INCLUDE}"
24
25                                 saved_libs="${LIBS}"
26                                 LIBS=${$1_LIB}
27
28                                 AC_LINK_IFELSE(
29                                         [ AC_LANG_PROGRAM( [ $5 ], [ $6; ])],
30                                         [ PBX_$1=1 AC_DEFINE([HAVE_$1], 1,
31                                                 [Define if your system has the $1 headers.])],
32                                         []
33                                 )
34                                 CPPFLAGS="${saved_cppflags}"
35                                 LIBS="${saved_libs}"
36                         else
37                                 PBX_$1=1
38                                 AC_DEFINE([HAVE_$1], 1, [Define if your system has the $1 libraries.])
39                         fi
40                 fi
41         fi
42 ])