Merged revisions 151240 via svnmerge from
[asterisk/asterisk.git] / autoconf / ast_ext_tool_check.m4
1 # Check for a package using $2-config. Similar to AST_EXT_LIB_CHECK,
2 # but use $2-config to determine cflags and libraries to use.
3 # $3 and $4 can be used to replace --cflags and --libs in the request
4
5 # AST_EXT_TOOL_CHECK([package], [tool name], [--cflags], [--libs], [includes], [expression])
6 AC_DEFUN([AST_EXT_TOOL_CHECK],
7 [
8     if test "x${PBX_$1}" != "x1" -a "${USE_$1}" != "no"; then
9         PBX_$1=0
10         AC_CHECK_TOOL(CONFIG_$1, $2-config, No)
11         if test ! "x${CONFIG_$1}" = xNo; then
12             if test x"$3" = x ; then A=--cflags ; else A="$3" ; fi
13             $1_INCLUDE=$(${CONFIG_$1} $A)
14             if test x"$4" = x ; then A=--libs ; else A="$4" ; fi
15             $1_LIB=$(${CONFIG_$1} $A)
16             if test x"$5" != x ; then
17                 saved_cppflags="${CPPFLAGS}"
18                 if test "x${$1_DIR}" != "x"; then
19                     $1_INCLUDE="-I${$1_DIR}/include"
20                 fi
21                 CPPFLAGS="${CPPFLAGS} ${$1_INCLUDE}"
22
23                 saved_ldflags="${LDFLAGS}"
24                 LDFLAGS="${$1_LIB}"
25
26                 AC_LINK_IFELSE(
27                     [ AC_LANG_PROGRAM( [ $5 ],
28                                        [ $6; ]
29                                        )],
30                     [   PBX_$1=1
31                         AC_DEFINE([HAVE_$1], 1, [Define if your system has the $1 headers.])
32                     ],
33                     []
34                 )
35                 CPPFLAGS="${saved_cppflags}"
36                 LDFLAGS="${saved_ldflags}"
37             else
38                 PBX_$1=1
39                 AC_DEFINE([HAVE_$1], 1, [Define if your system has the $1 libraries.])
40             fi
41         fi
42     fi
43 ])