logger.conf.sample: add missing comment mark
[asterisk/asterisk.git] / autoconf / ast_ext_tool_check.m4
1 # Check for a package using $2-config. Similar to AST_EXT_LIB_CHECK,
2 # but use $2-config to determine cflags and libraries to use.
3 # $3 and $4 can be used to replace --cflags and --libs in the request
4
5 # AST_EXT_TOOL_CHECK([package], [tool name], [--cflags], [--libs], [includes], [expression])
6 AC_DEFUN([AST_EXT_TOOL_CHECK],
7 [
8         AC_REQUIRE([AST_PROG_SED])dnl
9         if test "x${PBX_$1}" != "x1" -a "${USE_$1}" != "no"; then
10                 PBX_$1=0
11                 AC_PATH_TOOL(CONFIG_$1, $2, No, [${$1_DIR}/bin:$PATH])
12                 if test ! "x${CONFIG_$1}" = xNo; then
13                         $1_INCLUDE=$(${CONFIG_$1} m4_default([$3],[--cflags]))
14                         $1_INCLUDE=$(echo ${$1_INCLUDE} | $SED -e "s|-I|-I${$1_DIR}|g" -e "s|-std=c99||g")
15
16                         $1_LIB=$(${CONFIG_$1} m4_default([$4],[--libs]))
17                         $1_LIB=$(echo ${$1_LIB} | $SED -e "s|-L|-L${$1_DIR}|g")
18
19                         m4_ifval([$5], [
20                                 saved_cppflags="${CPPFLAGS}"
21                                 CPPFLAGS="${CPPFLAGS} ${$1_INCLUDE}"
22
23                                 saved_libs="${LIBS}"
24                                 LIBS=${$1_LIB}
25
26                                 AC_LINK_IFELSE(
27                                         [ AC_LANG_PROGRAM( [ $5 ], [ $6; ])],
28                                         [ PBX_$1=1 AC_DEFINE([HAVE_$1], 1,
29                                                 [Define if your system has the $1 libraries.])],
30                                         []
31                                 )
32                                 CPPFLAGS="${saved_cppflags}"
33                                 LIBS="${saved_libs}"
34                         ], [
35                                 PBX_$1=1
36                                 AC_DEFINE([HAVE_$1], 1, [Define if your system has the $1 libraries.])
37                         ])
38                 fi
39         fi
40 ])