da256c74bc8918353ee39f3f5abfdd4a0c8a29a3
[asterisk/asterisk.git] / autoconf / ast_ext_tool_check.m4
1 # Check for a package using $2-config. Similar to AST_EXT_LIB_CHECK,
2 # but use $2-config to determine cflags and libraries to use.
3 # $3 and $4 can be used to replace --cflags and --libs in the request
4
5 # AST_EXT_TOOL_CHECK([package], [tool name], [--cflags], [--libs], [includes], [expression])
6 AC_DEFUN([AST_EXT_TOOL_CHECK],
7 [
8         if test "x${PBX_$1}" != "x1" -a "${USE_$1}" != "no"; then
9                 PBX_$1=0
10                 AC_PATH_TOOL(CONFIG_$1, $2, No, [${$1_DIR}/bin:$PATH])
11                 if test ! "x${CONFIG_$1}" = xNo; then
12                         if test x"$3" = x ; then A=--cflags ; else A="$3" ; fi
13                         $1_INCLUDE=$(${CONFIG_$1} $A)
14                         $1_INCLUDE=$(echo ${$1_INCLUDE} | $SED -e "s|-I|-I${$1_DIR}|g")
15
16                         if test x"$4" = x ; then A=--libs ; else A="$4" ; fi
17                         $1_LIB=$(${CONFIG_$1} $A)
18                         $1_LIB=$(echo ${$1_LIB} | $SED -e "s|-L|-L${$1_DIR}|g")
19
20                         if test x"$5" != x ; then
21                                 saved_cppflags="${CPPFLAGS}"
22                                 CPPFLAGS="${CPPFLAGS} ${$1_INCLUDE}"
23
24                                 saved_libs="${LIBS}"
25                                 LIBS=${$1_LIB}
26
27                                 AC_LINK_IFELSE(
28                                         [ AC_LANG_PROGRAM( [ $5 ], [ $6; ])],
29                                         [ PBX_$1=1 AC_DEFINE([HAVE_$1], 1,
30                                                 [Define if your system has the $1 headers.])],
31                                         []
32                                 )
33                                 CPPFLAGS="${saved_cppflags}"
34                                 LIBS="${saved_libs}"
35                         else
36                                 PBX_$1=1
37                                 AC_DEFINE([HAVE_$1], 1, [Define if your system has the $1 libraries.])
38                         fi
39                 fi
40         fi
41 ])