Add missing file from previous commit.
[asterisk/asterisk.git] / autoconf / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   May-09-2006
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro #defines HAVE_CURL if a working libcurl setup is
17 # found, and sets @CURL_LIB@ and @CURL_INCLUDE@ to the necessary
18 # values.  Other useful defines are LIBCURL_FEATURE_xxx where xxx are
19 # the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # CURL_LIB="-lcurl" CURL_INCLUDE="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available,
36 # or use curl_version_info to figure it out at runtime.
37
38 AC_DEFUN([AST_LIBCURL_CHECK_CONFIG],
39 [
40   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
41   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
42   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
43   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
44   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
45   AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
46   AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
47   AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
48
49   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
54   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
55   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
56   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
57   AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
58   AC_SUBST(PBX_CURL)
59
60   AC_ARG_WITH(libcurl,
61      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
62      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
63
64   if test "$_libcurl_with" != "no" ; then
65
66      AC_PROG_AWK
67
68      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
69
70      _libcurl_try_link=yes
71
72      if test -d "$_libcurl_with" ; then
73         CURL_INCLUDE="-I$withval/include"
74         _libcurl_ldflags="-L$withval/lib"
75         AC_PATH_PROG([_libcurl_config],[curl-config],["$withval/bin"],
76                      ["$withval/bin"])
77      else
78         AC_PATH_PROG([_libcurl_config],[curl-config])
79      fi
80
81      if test x$_libcurl_config != "x" ; then
82         AC_CACHE_CHECK([for the version of libcurl],
83            [libcurl_cv_lib_curl_version],
84            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
85
86         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
87         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
88
89         if test $_libcurl_wanted -gt 0 ; then
90            AC_CACHE_CHECK([for libcurl >= version $2],
91               [libcurl_cv_lib_version_ok],
92               [
93               if test $_libcurl_version -ge $_libcurl_wanted ; then
94                  libcurl_cv_lib_version_ok=yes
95               else
96                  libcurl_cv_lib_version_ok=no
97               fi
98               ])
99         fi
100
101         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
102            if test x"$CURL_INCLUDE" = "x" ; then
103               CURL_INCLUDE=`$_libcurl_config --cflags`
104            fi
105            if test x"$CURL_LIB" = "x" ; then
106               CURL_LIB=`$_libcurl_config --libs`
107
108               # This is so silly, but Apple actually has a bug in their
109               # curl-config script.  Fixed in Tiger, but there are still
110               # lots of Panther installs around.
111               case "${host}" in
112                  powerpc-apple-darwin7*)
113                     CURL_LIB=`echo $CURL_LIB | sed -e 's|-arch i386||g'`
114                  ;;
115               esac
116            fi
117
118            # All curl-config scripts support --feature
119            _libcurl_features=`$_libcurl_config --feature`
120
121            # Is it modern enough to have --protocols? (7.12.4)
122            if test $_libcurl_version -ge 461828 ; then
123               _libcurl_protocols=`$_libcurl_config --protocols`
124            fi
125         else
126            _libcurl_try_link=no
127         fi
128
129         unset _libcurl_wanted
130      fi
131
132      if test $_libcurl_try_link = yes ; then
133
134         # we didn't find curl-config, so let's see if the user-supplied
135         # link line (or failing that, "-lcurl") is enough.
136         CURL_LIB=${CURL_LIB-"$_libcurl_ldflags -lcurl"}
137
138         AC_CACHE_CHECK([whether libcurl is usable],
139            [libcurl_cv_lib_curl_usable],
140            [
141            _libcurl_save_cppflags=$CPPFLAGS
142            CPPFLAGS="$CURL_INCLUDE $CPPFLAGS"
143            _libcurl_save_libs=$LIBS
144            LIBS="$CURL_LIB $LIBS"
145
146            AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <curl/curl.h>],[
147 /* Try and use a few common options to force a failure if we are
148    missing symbols or can't link. */
149 int x;
150 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
151 x=CURL_ERROR_SIZE;
152 x=CURLOPT_WRITEFUNCTION;
153 x=CURLOPT_FILE;
154 x=CURLOPT_ERRORBUFFER;
155 x=CURLOPT_STDERR;
156 x=CURLOPT_VERBOSE;
157 ])],libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
158
159            CPPFLAGS=$_libcurl_save_cppflags
160            LIBS=$_libcurl_save_libs
161            unset _libcurl_save_cppflags
162            unset _libcurl_save_libs
163            ])
164
165         if test $libcurl_cv_lib_curl_usable = yes ; then
166
167            # Does curl_free() exist in this version of libcurl?
168            # If not, fake it with free()
169
170            _libcurl_save_cppflags=$CPPFLAGS
171            CPPFLAGS="$CPPFLAGS $CURL_INCLUDE"
172            _libcurl_save_libs=$LIBS
173            LIBS="$LIBS $CURL_LIB"
174
175            AC_CHECK_FUNC(curl_free,,
176               AC_DEFINE(curl_free,free,
177                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
178
179            CPPFLAGS=$_libcurl_save_cppflags
180            LIBS=$_libcurl_save_libs
181            unset _libcurl_save_cppflags
182            unset _libcurl_save_libs
183
184            AC_DEFINE(HAVE_CURL,1,
185              [Define to 1 if you have a functional curl library.])
186            AC_SUBST(CURL_INCLUDE)
187            AC_SUBST(CURL_LIB)
188            PBX_CURL=1
189
190            for _libcurl_feature in $_libcurl_features ; do
191               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
192               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
193            done
194
195            if test "x$_libcurl_protocols" = "x" ; then
196
197               # We don't have --protocols, so just assume that all
198               # protocols are available
199               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT"
200
201               if test x$libcurl_feature_SSL = xyes ; then
202                  _libcurl_protocols="$_libcurl_protocols HTTPS"
203
204                  # FTPS wasn't standards-compliant until version
205                  # 7.11.0
206                  if test $_libcurl_version -ge 461568; then
207                     _libcurl_protocols="$_libcurl_protocols FTPS"
208                  fi
209               fi
210            fi
211
212            for _libcurl_protocol in $_libcurl_protocols ; do
213               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
214               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
215            done
216         else
217            unset CURL_LIB
218            unset CURL_INCLUDE
219            PBX_CURL=0
220         fi
221      fi
222
223      unset _libcurl_try_link
224      unset _libcurl_version_parse
225      unset _libcurl_config
226      unset _libcurl_feature
227      unset _libcurl_features
228      unset _libcurl_protocol
229      unset _libcurl_protocols
230      unset _libcurl_version
231      unset _libcurl_ldflags
232   fi
233
234   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
235      # This is the IF-NO path
236      ifelse([$4],,:,[$4])
237   else
238      # This is the IF-YES path
239      ifelse([$3],,:,[$3])
240   fi
241
242   unset _libcurl_with
243 ])dnl
244