res_pjsip: SIP/SDP origin (o=) contained square brackets on IP6 transports.
[asterisk/asterisk.git] / autoconf / libcurl.m4
1 #***************************************************************************
2 #                                  _   _ ____  _
3 #  Project                     ___| | | |  _ \| |
4 #                             / __| | | | |_) | |
5 #                            | (__| |_| |  _ <| |___
6 #                             \___|\___/|_| \_\_____|
7 #
8 # Copyright (C) 2006, David Shaw <dshaw@jabberwocky.com>
9 #
10 # This software is licensed as described in the file COPYING, which
11 # you should have received as part of this distribution. The terms
12 # are also available at https://curl.haxx.se/docs/copyright.html.
13 #
14 # You may opt to use, copy, modify, merge, publish, distribute and/or sell
15 # copies of the Software, and permit persons to whom the Software is
16 # furnished to do so, under the terms of the COPYING file.
17 #
18 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19 # KIND, either express or implied.
20 #
21 ###########################################################################
22 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
23 #                       [ACTION-IF-YES], [ACTION-IF-NO])
24 # ----------------------------------------------------------
25 #      David Shaw <dshaw@jabberwocky.com>   May-09-2006
26 #
27 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
28 # specify whether to default to --with-libcurl or --without-libcurl.
29 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
30 # minimum version of libcurl to accept.  Pass the version as a regular
31 # version number like 7.10.1. If not supplied, any version is
32 # accepted.  ACTION-IF-YES is a list of shell commands to run if
33 # libcurl was successfully found and passed the various tests.
34 # ACTION-IF-NO is a list of shell commands that are run otherwise.
35 # Note that using --without-libcurl does run ACTION-IF-NO.
36 #
37 # This macro #defines HAVE_CURL if a working libcurl setup is
38 # found, and sets @CURL_LIB@ and @CURL_INCLUDE@ to the necessary
39 # values.  Other useful defines are LIBCURL_FEATURE_xxx where xxx are
40 # the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
41 # where yyy are the various protocols supported by libcurl.  Both xxx
42 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
43 # the macro for the complete list of possible defines.  Shell
44 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
45 # defined to 'yes' for those features and protocols that were found.
46 # Note that xxx and yyy keep the same capitalization as in the
47 # curl-config list (e.g. it's "HTTP" and not "http").
48 #
49 # Users may override the detected values by doing something like:
50 # CURL_LIB="-lcurl" CURL_INCLUDE="-I/usr/myinclude" ./configure
51 #
52 # For the sake of sanity, this macro assumes that any libcurl that is
53 # found is after version 7.7.2, the first version that included the
54 # curl-config script.  Note that it is very important for people
55 # packaging binary versions of libcurl to include this script!
56 # Without curl-config, we can only guess what protocols are available,
57 # or use curl_version_info to figure it out at runtime.
58
59 AC_DEFUN([AST_LIBCURL_CHECK_CONFIG],
60 [
61   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
62   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
63   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
64   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
65   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
66   AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
67   AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
68   AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
69
70   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
71   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
72   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
73   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
74   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
75   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
76   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
77   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
78   AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
79   AH_TEMPLATE([LIBCURL_PROTOCOL_RTSP],[Defined if libcurl supports RTSP])
80   AH_TEMPLATE([LIBCURL_PROTOCOL_POP3],[Defined if libcurl supports POP3])
81   AH_TEMPLATE([LIBCURL_PROTOCOL_IMAP],[Defined if libcurl supports IMAP])
82   AH_TEMPLATE([LIBCURL_PROTOCOL_SMTP],[Defined if libcurl supports SMTP])
83   AC_SUBST(PBX_CURL)
84
85   AC_ARG_WITH(libcurl,
86      AS_HELP_STRING([--with-libcurl=PREFIX],[look for the curl library in PREFIX/lib and headers in PREFIX/include]),
87      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
88
89   if test "$_libcurl_with" != "no" ; then
90
91      AC_PROG_AWK
92
93      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
94
95      _libcurl_try_link=yes
96
97      if test -d "$_libcurl_with" ; then
98         CURL_INCLUDE="-I$withval/include"
99         _libcurl_ldflags="-L$withval/lib"
100         AC_PATH_PROG([_libcurl_config],[curl-config],[],
101                      ["$withval/bin"])
102      else
103         AC_PATH_PROG([_libcurl_config],[curl-config],[],[$PATH])
104      fi
105
106      if test x$_libcurl_config != "x" ; then
107         AC_CACHE_CHECK([for the version of libcurl],
108            [libcurl_cv_lib_curl_version],
109            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
110
111         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
112         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
113
114         if test $_libcurl_wanted -gt 0 ; then
115            AC_CACHE_CHECK([for libcurl >= version $2],
116               [libcurl_cv_lib_version_ok],
117               [
118               if test $_libcurl_version -ge $_libcurl_wanted ; then
119                  libcurl_cv_lib_version_ok=yes
120               else
121                  libcurl_cv_lib_version_ok=no
122               fi
123               ])
124         fi
125
126         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
127            if test x"$CURL_INCLUDE" = "x" ; then
128               CURL_INCLUDE=`$_libcurl_config --cflags`
129            fi
130            if test x"$CURL_LIB" = "x" ; then
131               CURL_LIB=`$_libcurl_config --libs`
132
133               # This is so silly, but Apple actually has a bug in their
134               # curl-config script.  Fixed in Tiger, but there are still
135               # lots of Panther installs around.
136               case "${host}" in
137                  powerpc-apple-darwin7*)
138                     CURL_LIB=`echo $CURL_LIB | sed -e 's|-arch i386||g'`
139                  ;;
140               esac
141            fi
142
143            # All curl-config scripts support --feature
144            _libcurl_features=`$_libcurl_config --feature`
145
146            # Is it modern enough to have --protocols? (7.12.4)
147            if test $_libcurl_version -ge 461828 ; then
148               _libcurl_protocols=`$_libcurl_config --protocols`
149            fi
150         else
151            _libcurl_try_link=no
152         fi
153
154         unset _libcurl_wanted
155      fi
156
157      if test $_libcurl_try_link = yes ; then
158
159         # we didn't find curl-config, so let's see if the user-supplied
160         # link line (or failing that, "-lcurl") is enough.
161         CURL_LIB=${CURL_LIB-"$_libcurl_ldflags -lcurl"}
162
163         AC_CACHE_CHECK([whether libcurl is usable],
164            [libcurl_cv_lib_curl_usable],
165            [
166            _libcurl_save_cppflags=$CPPFLAGS
167            CPPFLAGS="$CURL_INCLUDE $CPPFLAGS"
168            _libcurl_save_libs=$LIBS
169            LIBS="$CURL_LIB $LIBS"
170
171            AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
172 /* Try and use a few common options to force a failure if we are
173    missing symbols or can't link. */
174 int x;
175 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
176 x=CURL_ERROR_SIZE;
177 x=CURLOPT_WRITEFUNCTION;
178 x=CURLOPT_WRITEDATA;
179 x=CURLOPT_ERRORBUFFER;
180 x=CURLOPT_STDERR;
181 x=CURLOPT_VERBOSE;
182 if (x) {;}
183 ]])],libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
184
185            CPPFLAGS=$_libcurl_save_cppflags
186            LIBS=$_libcurl_save_libs
187            unset _libcurl_save_cppflags
188            unset _libcurl_save_libs
189            ])
190
191         if test $libcurl_cv_lib_curl_usable = yes ; then
192
193            # Does curl_free() exist in this version of libcurl?
194            # If not, fake it with free()
195
196            _libcurl_save_cppflags=$CPPFLAGS
197            CPPFLAGS="$CPPFLAGS $CURL_INCLUDE"
198            _libcurl_save_libs=$LIBS
199            LIBS="$LIBS $CURL_LIB"
200
201            AC_CHECK_FUNC(curl_free,,
202               AC_DEFINE(curl_free,free,
203                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
204
205            CPPFLAGS=$_libcurl_save_cppflags
206            LIBS=$_libcurl_save_libs
207            unset _libcurl_save_cppflags
208            unset _libcurl_save_libs
209
210            AC_DEFINE(HAVE_CURL,1,
211              [Define to 1 if you have a functional curl library.])
212            AC_SUBST(CURL_INCLUDE)
213            AC_SUBST(CURL_LIB)
214            PBX_CURL=1
215
216            for _libcurl_feature in $_libcurl_features ; do
217               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
218               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
219            done
220
221            if test "x$_libcurl_protocols" = "x" ; then
222
223               # We don't have --protocols, so just assume that all
224               # protocols are available
225               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT TFTP"
226
227               if test x$libcurl_feature_SSL = xyes ; then
228                  _libcurl_protocols="$_libcurl_protocols HTTPS"
229
230                  # FTPS wasn't standards-compliant until version
231                  # 7.11.0 (0x070b00 == 461568)
232                  if test $_libcurl_version -ge 461568; then
233                     _libcurl_protocols="$_libcurl_protocols FTPS"
234                  fi
235               fi
236
237               # RTSP, IMAP, POP3 and SMTP were added in
238               # 7.20.0 (0x071400 == 463872)
239               if test $_libcurl_version -ge 463872; then
240                  _libcurl_protocols="$_libcurl_protocols RTSP IMAP POP3 SMTP"
241               fi
242            fi
243
244            for _libcurl_protocol in $_libcurl_protocols ; do
245               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
246               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
247            done
248         else
249            unset CURL_LIB
250            unset CURL_INCLUDE
251            PBX_CURL=0
252         fi
253      fi
254
255      unset _libcurl_try_link
256      unset _libcurl_version_parse
257      unset _libcurl_config
258      unset _libcurl_feature
259      unset _libcurl_features
260      unset _libcurl_protocol
261      unset _libcurl_protocols
262      unset _libcurl_version
263      unset _libcurl_ldflags
264   fi
265
266   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
267      # This is the IF-NO path
268      ifelse([$4],,:,[$4])
269   else
270      # This is the IF-YES path
271      ifelse([$3],,:,[$3])
272   fi
273
274   unset _libcurl_with
275 ])dnl