Remove a bunch of trailing whitespace in preparation for reformatting/cleanup.
[asterisk/asterisk.git] / configs / asterisk.adsi
1 ;
2 ; Asterisk default ADSI script
3 ;
4 ;
5 ; Begin with the preamble requirements
6 ;
7 DESCRIPTION "Asterisk PBX"              ; Name of vendor
8 VERSION 0x00                                            ; Version of stuff
9 ;SECURITY "_AST"                                        ; Security code
10 SECURITY 0X9BDBF7AC                             ; Security code
11 FDN 0x0000000F                                          ; Descriptor number
12
13 ;
14 ; Flags
15 ;
16 FLAG "nocallwaiting"
17
18 ;
19 ; Predefined strings
20 ;
21 DISPLAY "titles" IS "** Asterisk PBX **"
22 DISPLAY "talkingto" IS "Call active." JUSTIFY LEFT
23 DISPLAY "callname" IS "$Call1p" JUSTIFY LEFT
24 DISPLAY "callnum" IS "$Call1s" JUSTIFY LEFT
25 DISPLAY "incoming" IS "Incoming call!" JUSTIFY LEFT
26 DISPLAY "ringing" IS "Calling... " JUSTIFY LEFT
27 DISPLAY "callended" IS "Call ended." JUSTIFY LEFT
28 DISPLAY "missedcall" IS "Missed call." JUSTIFY LEFT
29 DISPLAY "busy" IS "Busy." JUSTIFY LEFT
30 DISPLAY "reorder" IS "Reorder." JUSTIFY LEFT
31 DISPLAY "cwdisabled" IS "Callwait disabled"
32 DISPLAY "empty" IS "asdf"
33
34 ;
35 ; Begin soft key definitions
36 ;
37 KEY "callfwd" IS "CallFwd" OR "Call Forward"
38 OFFHOOK
39 VOICEMODE
40 WAITDIALTONE
41 SENDDTMF "*60"
42 GOTO "offHook"
43 ENDKEY
44
45 KEY "vmail_OH" IS "VMail" OR "Voicemail"
46 OFFHOOK
47 VOICEMODE
48 WAITDIALTONE
49 SENDDTMF "8500"
50 ENDKEY
51
52 KEY "vmail" IS "VMail" OR "Voicemail"
53 SENDDTMF "8500"
54 ENDKEY
55
56 KEY "backspace" IS "BackSpc" OR "Backspace"
57 BACKSPACE
58 ENDKEY
59
60 KEY "cwdisable" IS "CWDsble" OR "Disable Call Wait"
61 SENDDTMF "*70"
62 SETFLAG "nocallwaiting"
63 SHOWDISPLAY "cwdisabled" AT 4
64 TIMERCLEAR
65 TIMERSTART 1
66 ENDKEY
67
68 KEY "cidblock" IS "CIDBlk" OR "Block Callerid"
69 SENDDTMF "*67"
70 SETFLAG "nocallwaiting"
71 ENDKEY
72
73 ;
74 ; Begin main subroutine
75 ;
76
77 SUB "main" IS
78 IFEVENT NEARANSWER THEN
79 CLEAR
80 SHOWDISPLAY "titles" AT 1 NOUPDATE
81 SHOWDISPLAY "talkingto" AT 2 NOUPDATE
82 SHOWDISPLAY "callname" AT 3
83 SHOWDISPLAY "callnum" AT 4
84 GOTO "stableCall"
85 ENDIF
86 IFEVENT OFFHOOK THEN
87 CLEAR
88 CLEARFLAG "nocallwaiting"
89 CLEARDISPLAY 
90 SHOWDISPLAY "titles" AT 1
91 SHOWKEYS "vmail" 
92 SHOWKEYS "cidblock" 
93 SHOWKEYS "cwdisable" UNLESS "nocallwaiting"
94 GOTO "offHook"
95 ENDIF
96 IFEVENT IDLE THEN
97 CLEAR
98 SHOWDISPLAY "titles" AT 1
99 SHOWKEYS "vmail_OH"
100 ENDIF
101 IFEVENT CALLERID THEN
102 CLEAR
103 ;               SHOWDISPLAY "titles" AT 1 NOUPDATE
104 ;               SHOWDISPLAY "incoming" AT 2 NOUPDATE
105 SHOWDISPLAY "callname" AT 3 NOUPDATE
106 SHOWDISPLAY "callnum" AT 4
107 ENDIF
108 IFEVENT RING THEN
109 CLEAR
110 SHOWDISPLAY "titles" AT 1 NOUPDATE
111 SHOWDISPLAY "incoming" AT 2
112 ENDIF
113 IFEVENT ENDOFRING THEN
114 SHOWDISPLAY "missedcall" AT 2
115 CLEAR
116 SHOWDISPLAY "titles" AT 1
117 SHOWKEYS "vmail_OH"
118 ENDIF
119 IFEVENT TIMER THEN
120 CLEAR   
121 SHOWDISPLAY "empty" AT 4
122 ENDIF           
123 ENDSUB
124
125 SUB "offHook" IS
126 IFEVENT FARRING THEN
127 CLEAR
128 SHOWDISPLAY "titles" AT 1 NOUPDATE
129 SHOWDISPLAY "ringing" AT 2 NOUPDATE
130 SHOWDISPLAY "callname" at 3 NOUPDATE
131 SHOWDISPLAY "callnum" at 4
132 ENDIF
133 IFEVENT FARANSWER THEN
134 CLEAR
135 SHOWDISPLAY "talkingto" AT 2
136 GOTO "stableCall"
137 ENDIF
138 IFEVENT BUSY THEN
139 CLEAR
140 SHOWDISPLAY "titles" AT 1 NOUPDATE
141 SHOWDISPLAY "busy" AT 2 NOUPDATE
142 SHOWDISPLAY "callname" at 3 NOUPDATE
143 SHOWDISPLAY "callnum" at 4
144 ENDIF
145 IFEVENT REORDER THEN
146 CLEAR
147 SHOWDISPLAY "titles" AT 1 NOUPDATE
148 SHOWDISPLAY "reorder" AT 2 NOUPDATE
149 SHOWDISPLAY "callname" at 3 NOUPDATE
150 SHOWDISPLAY "callnum" at 4
151 ENDIF
152 ENDSUB
153
154 SUB "stableCall" IS
155 IFEVENT REORDER THEN
156 SHOWDISPLAY "callended" AT 2
157 ENDIF
158 ENDSUB
159