Might as well go crazy here too and make the autoservice list read/write.
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121    AC_CHECK_TOOL(AR, ar, :)
122 fi
123
124 # Checks for programs.
125 AC_PROG_CC
126 AC_PROG_CXX
127 AC_PROG_CPP
128 AC_PROG_CXXCPP
129 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
130 # the developers regenerating the configure script don't have to install libtool.
131 AST_PROG_LD     # note, does not work on FreeBSD
132 AC_PROG_AWK
133 AC_PROG_INSTALL
134 AC_PROG_LN_S
135 AC_PROG_RANLIB
136 AST_CHECK_GNU_MAKE
137
138 GNU_LD=0
139 if test "x$with_gnu_ld" = "xyes" ; then
140    GNU_LD=1
141 fi
142 AC_SUBST(GNU_LD)
143
144 AC_PATH_PROG([GREP], [grep], :)
145 AC_PATH_PROG([AR], [ar], :)
146 AC_PATH_PROG([FIND], [find], :)
147 AC_PATH_PROG([COMPRESS], [compress], :)
148 AC_PATH_PROG([BASENAME], [basename], :)
149 AC_PATH_PROG([ID], [id], :)
150 AC_PATH_PROG([DIRNAME], [dirname], :)
151 AC_PATH_PROG([SHELL], [sh], :)
152 AC_PATH_PROG([LN], [ln], :)
153 AC_PATH_PROG([DOT], [dot], :)
154 AC_PATH_PROG([STRIP], [strip], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 if test "${WGET}" != ":" ; then
157   DOWNLOAD=${WGET}
158 else
159   AC_PATH_PROG([FETCH], [fetch], [:])
160   DOWNLOAD=${FETCH}
161 fi
162 AC_SUBST(DOWNLOAD)
163
164 ACX_PTHREAD
165
166 AC_LANG(C)
167
168 AC_ARG_ENABLE(dev-mode,
169         [  --enable-dev-mode    Turn on developer mode],
170         [case "${enableval}" in
171               y|ye|yes) AST_DEVMODE=yes ;;
172               n|no)  AST_DEVMODE=no ;;
173               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
174         esac])
175 AC_SUBST(AST_DEVMODE)
176
177 # package option names should be in alphabetical order
178 # by the --with option name, to make things easier for the users :-)
179
180 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
181
182 # BKTR is used for backtrace support on platforms that do not
183 # have it natively.
184 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
185 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
186 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
187 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
188 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
189 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
190 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
191 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
192 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
193 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
194 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
195 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
196 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
197 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
198 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
199 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
200 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
201 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
202 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
203 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
204 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
205 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
206 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
207 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
208 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
209 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
210 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
211 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
212 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
213 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
214 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL], [ssl])
215 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
216 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
217 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
218 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
219 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
220 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
221 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
222 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
223 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
224 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
225
226 # check for basic system features and functionality before
227 # checking for package libraries
228
229 AC_FUNC_ALLOCA
230 AC_HEADER_DIRENT
231 AC_HEADER_STDC
232 AC_HEADER_SYS_WAIT
233 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
234
235 AC_SYS_LARGEFILE
236
237 # Checks for typedefs, structures, and compiler characteristics.
238 AC_HEADER_STDBOOL
239 AC_C_CONST
240 AC_TYPE_UID_T
241 AC_C_INLINE
242 AC_TYPE_MODE_T
243 AC_TYPE_OFF_T
244 AC_TYPE_PID_T
245 AC_TYPE_SIZE_T
246 AC_CHECK_MEMBERS([struct stat.st_blksize])
247 AC_HEADER_TIME
248 AC_STRUCT_TM
249 AC_C_VOLATILE
250 AC_CHECK_TYPES([ptrdiff_t])
251
252 # Checks for library functions.
253 AC_FUNC_CHOWN
254 AC_FUNC_CLOSEDIR_VOID
255 AC_FUNC_ERROR_AT_LINE
256 AST_FUNC_FORK
257 AC_FUNC_FSEEKO
258 AC_PROG_GCC_TRADITIONAL
259 # XXX: these are commented out until we determine whether it matters if our malloc()
260 # acts exactly like glibc's or not
261 # AC_FUNC_MALLOC
262 # AC_FUNC_REALLOC
263 AC_FUNC_MEMCMP
264 AC_FUNC_MKTIME
265 AC_FUNC_MMAP
266 AC_FUNC_SELECT_ARGTYPES
267 AC_FUNC_SETVBUF_REVERSED
268 AC_TYPE_SIGNAL
269 AC_FUNC_STAT
270 AC_FUNC_STRCOLL
271 AC_FUNC_STRFTIME
272 AC_FUNC_STRNLEN
273 AC_FUNC_STRTOD
274 AC_FUNC_UTIME_NULL
275 AC_FUNC_VPRINTF
276 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
277
278 # https support (in main/http.c) uses funopen on BSD systems,
279 # fopencookie on linux
280 AC_CHECK_FUNCS([funopen fopencookie])
281
282 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
283 AC_CHECK_FUNCS([gethostbyname_r])
284
285 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
286 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
287
288 AC_MSG_CHECKING(for compiler atomic operations)
289 AC_LINK_IFELSE(
290 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
291 AC_MSG_RESULT(yes)
292 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
293 AC_MSG_RESULT(no)
294 )
295
296 AST_GCC_ATTRIBUTE(pure)
297 AST_GCC_ATTRIBUTE(malloc)
298 AST_GCC_ATTRIBUTE(const)
299 AST_GCC_ATTRIBUTE(unused)
300 AST_GCC_ATTRIBUTE(always_inline)
301
302 AC_MSG_CHECKING(for -ffunction-sections support)
303 saved_CFLAGS="${CFLAGS}"
304 CFLAGS="${CFLAGS} -ffunction-sections"
305 AC_COMPILE_IFELSE(
306         AC_LANG_PROGRAM([], [int x = 1;]),
307         AC_MSG_RESULT(yes)
308         [saved_LDFLAGS="${LDFLAGS}"]
309         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
310         AC_MSG_CHECKING(for --gc-sections support)
311         AC_LINK_IFELSE(
312                 AC_LANG_PROGRAM([], [int x = 1;]),
313                 AC_MSG_RESULT(yes)
314                 [GC_CFLAGS="-ffunction-sections"]
315                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
316                 AC_MSG_RESULT(no)
317         )
318         [LDFLAGS="${saved_LDFLAGS}"],
319         AC_MSG_RESULT(no)
320 )
321 CFLAGS="${saved_CFLAGS}"
322 AC_SUBST(GC_CFLAGS)
323 AC_SUBST(GC_LDFLAGS)
324
325 AC_MSG_CHECKING(for res_ninit)
326 AC_LINK_IFELSE(
327         AC_LANG_PROGRAM([#include <resolv.h>],
328                         [int foo = res_ninit(NULL);]),
329         AC_MSG_RESULT(yes)
330         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
331         AC_MSG_RESULT(no)
332 )
333
334 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
335
336 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
337
338 AC_CHECK_HEADER([libkern/OSAtomic.h],
339                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
340
341 AC_CHECK_SIZEOF(int)
342
343 # do the package library checks now
344
345 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
346
347 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
348
349 if test "x${host_os}" = "xlinux-gnu" ; then
350   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
351 fi
352
353 GSM_INTERNAL="yes"
354 AC_SUBST(GSM_INTERNAL)
355 GSM_SYSTEM="yes"
356 if test "${USE_GSM}" != "no"; then
357    if test "${GSM_DIR}" = "internal"; then
358       GSM_SYSTEM="no"
359    elif test "${GSM_DIR}" != ""; then
360       GSM_INTERNAL="no"
361    fi
362    if test "${GSM_SYSTEM}" = "yes"; then
363       gsmlibdir=""
364       if test "x${GSM_DIR}" != "x"; then
365          if test -d ${GSM_DIR}/lib; then
366             gsmlibdir="-L${GSM_DIR}/lib"
367          else
368             gsmlibdir="-L${GSM_DIR}"
369          fi
370       fi
371       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
372       [Define to indicate the GSM library]), [], ${gsmlibdir})
373       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
374          GSM_LIB="-lgsm"
375          if test "x${GSM_DIR}" != "x"; then
376             GSM_LIB="${gsmlibdir} ${GSM_LIB}"
377             GSM_INCLUDE="-I${GSM_DIR}/include"
378          fi
379          PBX_GSM=1
380          GSM_INTERNAL="no"
381       fi
382    fi
383    if test "${GSM_INTERNAL}" = "yes"; then
384       PBX_GSM=1
385    fi
386 fi
387
388 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
389
390 if test "${PBX_IKSEMEL}" = 1; then
391    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye])
392    if test "${PBX_GNUTLS}" = 1; then
393       IKSEMEL_LIB="${IKSEMEL_LIB} -lgnutls -lz -lgcrypt -lgpg-error"
394    fi
395 fi
396
397 if test "${USE_IMAP_TK}" != "no"; then
398    if test "${IMAP_TK_DIR}" = ""; then
399       IMAP_TK_DIR=`pwd`"/../imap-2004g"
400    fi
401    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
402    saved_cppflags="${CPPFLAGS}"
403    saved_libs="${LIBS}"
404    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
405       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
406    fi
407    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
408    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
409    AC_LINK_IFELSE(
410         AC_LANG_PROGRAM(
411                 [#include "c-client.h"
412                 void mm_searched (MAILSTREAM *stream,unsigned long number)
413                 {
414                 }
415                 void mm_exists (MAILSTREAM *stream,unsigned long number)
416                 {
417                 }
418                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
419                 {
420                 }
421                 void mm_flags (MAILSTREAM *stream,unsigned long number)
422                 {
423                 }
424                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
425                 {
426                 }
427                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
428                 {
429                 }
430                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
431                 {
432                 }
433                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
434                 {
435                 }
436                 void mm_log (char *string,long errflg)
437                 {
438                 }
439                 void mm_dlog (char *string)
440                 {
441                 }
442                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
443                 {
444                 }
445                 void mm_critical (MAILSTREAM *stream)
446                 {
447                 }
448                 void mm_nocritical (MAILSTREAM *stream)
449                 {
450                 }
451                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
452                 {
453                 }
454                 void mm_fatal (char *string)
455                 {
456                 }],
457                 [
458                 MAILSTREAM *foo = mail_open(NULL, "", 0);
459                 ]
460         ),
461         [ac_cv_imap_tk="yes"],
462         [ac_cv_imap_tk="no"]
463    )
464    if test "${ac_cv_imap_tk}" = "yes"; then
465    AC_LINK_IFELSE(
466       AC_LANG_PROGRAM(
467          [#include "c-client.h"
468          void mm_searched (MAILSTREAM *stream,unsigned long number)
469          {
470          }
471          void mm_exists (MAILSTREAM *stream,unsigned long number)
472          {
473          }
474          void mm_expunged (MAILSTREAM *stream,unsigned long number)
475          {
476          }
477          void mm_flags (MAILSTREAM *stream,unsigned long number)
478          {
479          }
480          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
481          {
482          }
483          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
484          {
485          }
486          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
487          {
488          }
489          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
490          {
491          }
492          void mm_log (char *string,long errflg)
493          {
494          }
495          void mm_dlog (char *string)
496          {
497          }
498          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
499          {
500          }
501          void mm_critical (MAILSTREAM *stream)
502          {
503          }
504          void mm_nocritical (MAILSTREAM *stream)
505          {
506          }
507          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
508          {
509          }
510          void mm_fatal (char *string)
511          {
512          }],
513          [
514          long check = mail_expunge_full(NULL, "", 0);
515          ]
516       ),
517       [ac_cv_imap_tk2006="yes"],
518       [ac_cv_imap_tk2006="no"]
519   )
520   fi
521    CPPFLAGS="${saved_cppflags}"
522    LIBS="${saved_libs}"
523    if test "${ac_cv_imap_tk}" = "yes"; then
524       AC_MSG_RESULT(yes) 
525       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
526       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
527       PBX_IMAP_TK=1
528       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
529       if test "${ac_cv_imap_tk2006}" = "yes"; then
530          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
531       fi
532    else
533       AC_MSG_RESULT(no) 
534    fi
535 fi
536
537 AC_LANG_PUSH(C++)
538
539 if test "${USE_KDE}" != "no"; then
540    AC_MSG_CHECKING(for crashHandler in -lkdecore)
541    saved_libs="${LIBS}"
542    saved_cppflags="${CPPFLAGS}"
543    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
544    if test -d ${KDE_DIR}/lib; then
545       kdelibdir="${KDE_DIR}/lib"
546    else
547       kdelibdir="${KDE_DIR}"
548    fi
549    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
550
551    AC_LINK_IFELSE(
552         [AC_LANG_PROGRAM(
553                         [#include "kcrash.h"],
554                         [KCrash::defaultCrashHandler(1);])
555         ],
556         [ac_cv_lib_kde_crash="yes"],
557         [ac_cv_lib_kde_crash="no"])
558                 
559    LIBS="${saved_libs}"
560    CPPFLAGS="${saved_cppflags}"
561         
562    if test "${ac_cv_lib_kde_crash}" = "yes"; then
563       AC_MSG_RESULT(yes) 
564       KDE_LIB="-lkdecore -lkdeui"
565       if test "${KDE_DIR}" != ""; then
566          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
567          KDE_INCLUDE="-I${KDE_DIR}/include"
568       fi
569       PBX_KDE=1
570       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
571    else
572       AC_MSG_RESULT(no) 
573    fi
574 fi
575 if test "${PBX_KDE}" = 1; then
576    AC_PATH_TOOL(KDEINIT, kdeinit, No)
577    if test ! x"${KDEINIT}" = xNo; then
578       KDEDIR=$(${DIRNAME} ${KDEINIT})
579       KDEDIR=$(${DIRNAME} ${KDEDIR})
580    fi
581    AC_SUBST([KDEDIR])
582 fi
583
584 AC_LANG_POP
585
586 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
587
588 if test "${PBX_MISDN}" = 1; then
589    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
590    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
591 fi
592
593 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
594
595 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
596
597 NETSNMP_CONFIG=No
598 if test "${USE_NETSNMP}" != "no"; then  
599    if test "x${NETSNMP_DIR}" != "x"; then
600       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
601       if test x"${NETSNMP_CONFIG}" = xNo; then
602          AC_MSG_NOTICE([***])
603          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
604          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
605          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
606          AC_MSG_NOTICE([*** including --without-netsnmp])
607          exit 1
608       fi
609    else
610       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
611    fi
612 fi
613 if test x"${NETSNMP_CONFIG}" != xNo; then
614    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
615    
616    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
617    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
618
619    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
620       NETSNMP_LIB="${NETSNMP_libs}"
621       PBX_NETSNMP=1
622    fi
623 fi
624
625 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
626
627 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [-lltdl])
628
629 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
630
631 AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
632
633 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
634
635 # possible places for oss definitions
636 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
637 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
638 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
639
640 PG_CONFIG=No
641 if test "${USE_PGSQL}" != "no"; then    
642    if test "x${PGSQL_DIR}" != "x"; then
643       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
644       if test x"${PG_CONFIG}" = xNo; then
645          AC_MSG_NOTICE([***])
646          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
647          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
648          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
649          AC_MSG_NOTICE([*** including --without-postgres])
650          exit 1
651       fi
652    else
653       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
654    fi
655 fi
656 if test "${PG_CONFIG}" != No; then
657    PGSQL_libdir=`${PG_CONFIG} --libdir`
658    PGSQL_includedir=`${PG_CONFIG} --includedir`
659    
660    AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
661    [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
662
663    if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
664       PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
665       PGSQL_INCLUDE="-I${PGSQL_includedir}"
666       PBX_PGSQL=1
667    fi
668 fi
669
670 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
671
672 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
673
674 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
675
676 if test "${USE_PWLIB}" != "no"; then
677         if test ! -z "${PWLIB_DIR}"; then
678                 PWLIBDIR="${PWLIB_DIR}"
679         fi
680         AST_CHECK_PWLIB()
681         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
682                 
683         if test "${HAS_PWLIB:-unset}" != "unset"; then
684                 AST_CHECK_OPENH323_PLATFORM()
685
686                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
687
688                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
689                         [Define if your system has the PWLib libraries.],
690                         [#include "ptlib.h"],
691                         [BOOL q = PTime::IsDaylightSavings();])
692         fi
693 fi
694
695 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
696         if test ! -z "${OPENH323_DIR}"; then
697                 OPENH323DIR="${OPENH323_DIR}"
698         fi
699         AST_CHECK_OPENH323()
700         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
701         AST_CHECK_OPENH323_BUILD()
702         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
703         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
704                 [Define if your system has the OpenH323 libraries.],
705                 [#include "ptlib.h"
706                 #include "h323.h"
707                 #include "h323ep.h"],
708                 [H323EndPoint ep = H323EndPoint();],
709                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
710 fi
711
712 AC_LANG_PUSH(C++)
713
714 if test "${USE_QT}" != "no"; then
715    AC_MSG_CHECKING(for QDate in -lqt)
716    saved_libs="${LIBS}"
717    saved_cppflags="${CPPFLAGS}"
718    if test "x${QT_DIR}" != "x"; then
719       LIBS="${LIBS} -L${QT_DIR}/lib"
720       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
721    fi
722    LIBS="${LIBS} -lqt"
723    qtlib="qt"
724    AC_LINK_IFELSE(
725         [
726                 AC_LANG_PROGRAM(
727                 [#include <qt3/qdatetime.h>],
728                 [QDate date();])
729         ],
730         [ac_cv_lib_qt_qt_date="yes"],
731         [ac_cv_lib_qt_qt_date="no"])
732    LIBS="${saved_libs}"
733    CPPFLAGS="${saved_cppflags}"
734         
735    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
736       saved_libs="${LIBS}"
737       saved_cppflags="${CPPFLAGS}"
738       if test "x${QT_DIR}" != "x"; then
739          LIBS="${LIBS} -L${QT_DIR}/lib"
740          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
741       fi
742       LIBS="${LIBS} -lqt-mt"
743       qtlib="qt-mt"     
744       AC_LINK_IFELSE(
745                 [
746                         AC_LANG_PROGRAM(
747                         [#include <qt3/qdatetime.h>],
748                         [QDate date();])
749                 ],
750                 [ac_cv_lib_qt_qt_date="yes"],
751                 [ac_cv_lib_qt_qt_date="no"])
752       LIBS="${saved_libs}"
753       CPPFLAGS="${saved_cppflags}"
754    fi   
755
756    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
757       AC_MSG_RESULT(yes) 
758    else
759       AC_MSG_RESULT(no) 
760    fi
761         
762    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
763       QT_LIB="-l${qtlib}"
764       if test "${QT_DIR}" != ""; then
765          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
766          QT_INCLUDE="-I${QT_DIR}/include"
767       fi
768       PBX_QT=1
769       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
770       AC_PATH_TOOL(QTMOC, moc, No)
771    fi
772 fi
773
774 AC_LANG_POP
775
776 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
777
778 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
779
780 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
781
782 AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
783
784 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
785 if test "${PBX_FREETDS}" != "0";
786 then
787     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr/include}/tdsver.h` in
788         *0.64*)
789                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
790         ;;
791     *0.63*)
792         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
793         ;;
794     *0.62*)
795         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
796         ;;
797     *)
798         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
799         ;;
800     esac
801 fi
802
803 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
804
805 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
806
807 if test "${host_os}" != "linux-gnu" ; then
808   tonezone_extra="-lm"
809 fi
810
811 # new tonezone, version 1.4.0
812 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
813 # other case, old tonezone (0.80)
814 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
815
816 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
817
818 AC_LANG_PUSH(C++)
819
820 if test "${USE_VPB}" != "no"; then
821    AC_MSG_CHECKING(for vpb_open in -lvpb)
822    saved_libs="${LIBS}"
823    saved_cppflags="${CPPFLAGS}"
824    if test "x${VPB_DIR}" != "x"; then
825       if test -d ${VPB_DIR}/lib; then
826          vpblibdir=${VPB_DIR}/lib
827       else
828          vpblibdir=${VPB_DIR}
829       fi
830       LIBS="${LIBS} -L${vpblibdir}"
831       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
832    fi
833    LIBS="${LIBS} -lvpb -lpthread"
834    AC_LINK_IFELSE(
835         [
836         AC_LANG_PROGRAM(
837         [#include <vpbapi.h>],
838         [int q = vpb_open(0,0);])
839         ],
840         [       AC_MSG_RESULT(yes) 
841                 ac_cv_lib_vpb_vpb_open="yes" 
842         ],
843         [       AC_MSG_RESULT(no) 
844                 ac_cv_lib_vpb_vpb_open="no" 
845         ]
846         )
847    LIBS="${saved_libs}"
848    CPPFLAGS="${saved_cppflags}"
849    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
850         VPB_LIB="-lvpb"
851         if test "${VPB_DIR}" != ""; then
852            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
853            VPB_INCLUDE="-I${VPB_DIR}/include"
854         fi
855         PBX_VPB=1
856         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
857    fi
858 fi
859
860 AC_LANG_POP
861
862 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
863
864 # Check for various zaptel features and locations.
865 # The version number, which goes into HAVE_ZAPTEL_VERSION,
866 # will be used in the system headers to determine the location
867 # of the zaptel.h header.
868
869 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
870 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
871
872 # Check for VLDTMF support
873 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h])
874
875 # Check for transcode support
876 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_TRANSCODE], [zaptel/zaptel.h])
877
878 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
879 case "${host_os}" in
880     freebsd*)
881         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
882         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
883         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
884
885         # other case, old tonezone (0.80)
886         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
887         ;;
888 esac
889
890 EDITLINE_LIB=""
891 if test "x$TERMCAP_LIB" != "x" ; then
892   EDITLINE_LIB="$TERMCAP_LIB"
893 elif test "x$TINFO_LIB" != "x" ; then
894   EDITLINE_LIB="$TINFO_LIB"
895 elif test "x$CURSES_LIB" != "x" ; then
896   EDITLINE_LIB="$CURSES_LIB"
897 elif test "x$NCURSES_LIB" != "x" ; then
898   EDITLINE_LIB="$NCURSES_LIB"
899 else
900   AC_MSG_ERROR(*** termcap support not found)
901 fi
902 AC_SUBST(EDITLINE_LIB)
903
904 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
905 AC_SUBST(PBX_H323)
906
907 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
908                                    #include <linux/version.h>
909                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
910                                    #include <linux/compiler.h>
911                                    #endif
912                                    ])
913 AC_SUBST(PBX_IXJUSER)
914
915 PBX_GTK=0
916 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
917 if test ! "x${GTKCONFIG}" = xNo; then
918    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
919    GTK_LIB=$(${GTKCONFIG} --libs gthread)
920    PBX_GTK=1
921    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
922 fi
923 AC_SUBST(PBX_GTK)
924 AC_SUBST(GTK_INCLUDE)
925 AC_SUBST(GTK_LIB)
926
927 if test "${USE_CURL}" != "no"; then
928    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
929    if test ! x"${CURL_CONFIG}" = xNo; then
930    # check for version
931       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
932          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
933          CURL_LIB=$(${CURL_CONFIG} --libs)
934          PBX_CURL=1
935          AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
936       fi
937    fi
938 fi
939
940 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
941 AST_CHECK_MANDATORY
942
943 AC_OUTPUT
944
945 if test "x${silent}" != "xyes" ; then
946 echo
947 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
948 echo "            .\$7\$7..          .7\$\$7:.    "
949 echo "          .\$\$:.                 ,\$7.7   "
950 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
951 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
952 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
953 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
954 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
955 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
956 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
957 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
958 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
959 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
960 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
961 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
962 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
963 echo " \$\$\$\$\$                        \$\$\$       "
964 echo "  \$\$\$\$7.                       \$\$  (TM)     "
965 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
966 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
967 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
968 echo
969 fi
970
971 AC_MSG_NOTICE(Package configured for: )
972 AC_MSG_NOTICE( OS type  : $host_os)
973 AC_MSG_NOTICE( Host CPU : $host_cpu)
974 if test "${cross_compiling}" = "yes"; then
975    AC_MSG_NOTICE( Cross Compilation = YES)
976 fi