Minor header inclusion tweak for new usage of stat()
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_CHECK_FUNCS([gethostbyname_r])
288
289 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
290 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
291
292 AC_MSG_CHECKING(for compiler atomic operations)
293 AC_LINK_IFELSE(
294 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
295 AC_MSG_RESULT(yes)
296 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
297 AC_MSG_RESULT(no)
298 )
299
300 AST_GCC_ATTRIBUTE(pure)
301 AST_GCC_ATTRIBUTE(malloc)
302 AST_GCC_ATTRIBUTE(const)
303 AST_GCC_ATTRIBUTE(unused)
304 AST_GCC_ATTRIBUTE(always_inline)
305
306 AC_MSG_CHECKING(for -ffunction-sections support)
307 saved_CFLAGS="${CFLAGS}"
308 CFLAGS="${CFLAGS} -ffunction-sections"
309 AC_COMPILE_IFELSE(
310         AC_LANG_PROGRAM([], [int x = 1;]),
311         AC_MSG_RESULT(yes)
312         [saved_LDFLAGS="${LDFLAGS}"]
313         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
314         AC_MSG_CHECKING(for --gc-sections support)
315         AC_LINK_IFELSE(
316                 AC_LANG_PROGRAM([], [int x = 1;]),
317                 AC_MSG_RESULT(yes)
318                 [GC_CFLAGS="-ffunction-sections"]
319                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
320                 AC_MSG_RESULT(no)
321         )
322         [LDFLAGS="${saved_LDFLAGS}"],
323         AC_MSG_RESULT(no)
324 )
325 CFLAGS="${saved_CFLAGS}"
326 AC_SUBST(GC_CFLAGS)
327 AC_SUBST(GC_LDFLAGS)
328
329 AC_MSG_CHECKING(for sysinfo)
330 AC_LINK_IFELSE(
331         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
332                         [struct sysinfo sys_info;]),
333         AC_MSG_RESULT(yes)
334         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
335         AC_MSG_RESULT(no)
336 )
337
338 AC_MSG_CHECKING(for res_ninit)
339 AC_LINK_IFELSE(
340         AC_LANG_PROGRAM([#include <resolv.h>],
341                         [int foo = res_ninit(NULL);]),
342         AC_MSG_RESULT(yes)
343         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
344         AC_MSG_RESULT(no)
345 )
346
347 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
348
349 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
350
351 AC_CHECK_HEADER([libkern/OSAtomic.h],
352                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
353
354 AC_CHECK_SIZEOF(int)
355
356 # do the package library checks now
357
358 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
359
360 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
361
362 if test "x${host_os}" = "xlinux-gnu" ; then
363   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
364 fi
365
366 GSM_INTERNAL="yes"
367 AC_SUBST(GSM_INTERNAL)
368 GSM_SYSTEM="yes"
369 if test "${USE_GSM}" != "no"; then
370    if test "${GSM_DIR}" = "internal"; then
371       GSM_SYSTEM="no"
372    elif test "${GSM_DIR}" != ""; then
373       GSM_INTERNAL="no"
374    fi
375    if test "${GSM_SYSTEM}" = "yes"; then
376       gsmlibdir=""
377       if test "x${GSM_DIR}" != "x"; then
378          if test -d ${GSM_DIR}/lib; then
379             gsmlibdir="-L${GSM_DIR}/lib"
380          else
381             gsmlibdir="-L${GSM_DIR}"
382          fi
383       fi
384       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
385       [Define to indicate the GSM library]), [], ${gsmlibdir})
386       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
387          if test "x${GSM_DIR}" != "x" ; then
388             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
389             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
390          else
391             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
392             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
393          fi
394          if test "${GSM_HEADER_FOUND}" = "0" ; then
395             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
396                if test "x${GSM_MANDATORY}" = "xyes" ; then
397                   AC_MSG_NOTICE([***])
398                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
399                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
400                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
401                   exit 1
402                fi
403             fi
404          fi
405          GSM_OK=0
406          if test "${GSM_HEADER_FOUND}" = "1" ; then
407             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
408             GSM_OK=1
409          else
410             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
411                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
412                GSM_OK=1
413             fi
414          fi
415          if test "${GSM_OK}" = "1" ; then
416             GSM_LIB="-lgsm"
417             if test "x${GSM_DIR}" != "x"; then
418                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
419                GSM_INCLUDE="-I${GSM_DIR}/include"
420             fi
421             PBX_GSM=1
422             GSM_INTERNAL="no"
423          fi
424       fi
425    fi
426    if test "${GSM_INTERNAL}" = "yes"; then
427       PBX_GSM=1
428       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
429    fi
430 fi
431
432 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
433
434 if test "${PBX_IKSEMEL}" = 1; then
435    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
436 fi
437
438 if test "${USE_IMAP_TK}" != "no"; then
439    if test "${IMAP_TK_DIR}" = ""; then
440       IMAP_TK_DIR=`pwd`"/../imap-2004g"
441       if test  -n "${IMAP_TK_MANDATORY}"; then
442          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
443          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
444          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
445          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
446       fi
447    fi
448    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
449    saved_cppflags="${CPPFLAGS}"
450    saved_libs="${LIBS}"
451    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
452       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
453    fi
454    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
455    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
456    AC_LINK_IFELSE(
457         AC_LANG_PROGRAM(
458                 [#include "c-client.h"
459                 void mm_searched (MAILSTREAM *stream,unsigned long number)
460                 {
461                 }
462                 void mm_exists (MAILSTREAM *stream,unsigned long number)
463                 {
464                 }
465                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
466                 {
467                 }
468                 void mm_flags (MAILSTREAM *stream,unsigned long number)
469                 {
470                 }
471                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
472                 {
473                 }
474                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
475                 {
476                 }
477                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
478                 {
479                 }
480                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
481                 {
482                 }
483                 void mm_log (char *string,long errflg)
484                 {
485                 }
486                 void mm_dlog (char *string)
487                 {
488                 }
489                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
490                 {
491                 }
492                 void mm_critical (MAILSTREAM *stream)
493                 {
494                 }
495                 void mm_nocritical (MAILSTREAM *stream)
496                 {
497                 }
498                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
499                 {
500                 }
501                 void mm_fatal (char *string)
502                 {
503                 }],
504                 [
505                 MAILSTREAM *foo = mail_open(NULL, "", 0);
506                 ]
507         ),
508         [ac_cv_imap_tk="yes"],
509         [ac_cv_imap_tk="no"]
510    )
511    if test "${ac_cv_imap_tk}" = "yes"; then
512    AC_LINK_IFELSE(
513       AC_LANG_PROGRAM(
514          [#include "c-client.h"
515          void mm_searched (MAILSTREAM *stream,unsigned long number)
516          {
517          }
518          void mm_exists (MAILSTREAM *stream,unsigned long number)
519          {
520          }
521          void mm_expunged (MAILSTREAM *stream,unsigned long number)
522          {
523          }
524          void mm_flags (MAILSTREAM *stream,unsigned long number)
525          {
526          }
527          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
528          {
529          }
530          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
531          {
532          }
533          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
534          {
535          }
536          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
537          {
538          }
539          void mm_log (char *string,long errflg)
540          {
541          }
542          void mm_dlog (char *string)
543          {
544          }
545          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
546          {
547          }
548          void mm_critical (MAILSTREAM *stream)
549          {
550          }
551          void mm_nocritical (MAILSTREAM *stream)
552          {
553          }
554          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
555          {
556          }
557          void mm_fatal (char *string)
558          {
559          }],
560          [
561          long check = mail_expunge_full(NULL, "", 0);
562          ]
563       ),
564       [ac_cv_imap_tk2006="yes"],
565       [ac_cv_imap_tk2006="no"]
566   )
567   fi
568    CPPFLAGS="${saved_cppflags}"
569    LIBS="${saved_libs}"
570    if test "${ac_cv_imap_tk}" = "yes"; then
571       AC_MSG_RESULT(yes) 
572       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
573       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
574       PBX_IMAP_TK=1
575       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
576       if test "${ac_cv_imap_tk2006}" = "yes"; then
577          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
578       fi
579    else
580       AC_MSG_RESULT(no) 
581    fi
582 fi
583
584 # Needed by unixodbc
585 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
586
587 AC_LANG_PUSH(C++)
588
589 if test "${USE_KDE}" != "no"; then
590    AC_MSG_CHECKING(for crashHandler in -lkdecore)
591    saved_libs="${LIBS}"
592    saved_cppflags="${CPPFLAGS}"
593    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
594    if test -d ${KDE_DIR}/lib; then
595       kdelibdir="${KDE_DIR}/lib"
596    else
597       kdelibdir="${KDE_DIR}"
598    fi
599    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
600
601    AC_LINK_IFELSE(
602         [AC_LANG_PROGRAM(
603                         [#include "kcrash.h"],
604                         [KCrash::defaultCrashHandler(1);])
605         ],
606         [ac_cv_lib_kde_crash="yes"],
607         [ac_cv_lib_kde_crash="no"])
608                 
609    LIBS="${saved_libs}"
610    CPPFLAGS="${saved_cppflags}"
611         
612    if test "${ac_cv_lib_kde_crash}" = "yes"; then
613       AC_MSG_RESULT(yes) 
614       KDE_LIB="-lkdecore -lkdeui"
615       if test "${KDE_DIR}" != ""; then
616          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
617          KDE_INCLUDE="-I${KDE_DIR}/include"
618       fi
619       PBX_KDE=1
620       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
621    else
622       AC_MSG_RESULT(no) 
623    fi
624 fi
625 if test "${PBX_KDE}" = 1; then
626    AC_PATH_TOOL(KDEINIT, kdeinit, No)
627    if test ! x"${KDEINIT}" = xNo; then
628       KDEDIR=$(${DIRNAME} ${KDEINIT})
629       KDEDIR=$(${DIRNAME} ${KDEDIR})
630    fi
631    AC_SUBST([KDEDIR])
632 fi
633
634 AC_LANG_POP
635
636 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
637
638 if test "${PBX_MISDN}" = 1; then
639    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
640    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
641    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
642 fi
643
644 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
645
646 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
647
648 NETSNMP_CONFIG=No
649 if test "${USE_NETSNMP}" != "no"; then  
650    if test "x${NETSNMP_DIR}" != "x"; then
651       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
652       if test x"${NETSNMP_CONFIG}" = xNo; then
653          AC_MSG_NOTICE([***])
654          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
655          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
656          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
657          AC_MSG_NOTICE([*** including --without-netsnmp])
658          exit 1
659       fi
660    else
661       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
662    fi
663 fi
664 if test x"${NETSNMP_CONFIG}" != xNo; then
665    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
666    
667    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
668    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
669
670    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
671       NETSNMP_LIB="${NETSNMP_libs}"
672       PBX_NETSNMP=1
673    fi
674 fi
675
676 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
677
678 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
679
680 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
681
682 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
683
684 # possible places for oss definitions
685 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
686 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
687 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
688
689 PG_CONFIG=No
690 if test "${USE_PGSQL}" != "no"; then    
691    if test "x${PGSQL_DIR}" != "x"; then
692       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
693       if test x"${PG_CONFIG}" = xNo; then
694          AC_MSG_NOTICE([***])
695          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
696          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
697          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
698          AC_MSG_NOTICE([*** including --without-postgres])
699          exit 1
700       fi
701    else
702       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
703    fi
704 fi
705 if test "${PG_CONFIG}" != No; then
706    PGSQL_libdir=`${PG_CONFIG} --libdir`
707    PGSQL_includedir=`${PG_CONFIG} --includedir`
708    if test "x$?" != "x0" ; then
709       if test -n "${PGSQL_MANDATORY}" ; then
710          AC_MSG_NOTICE([***])
711          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
712          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
713          AC_MSG_NOTICE([*** including --without-postgres])
714          exit 1
715           fi
716    else 
717       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
718       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
719
720       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
721          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
722          PGSQL_INCLUDE="-I${PGSQL_includedir}"
723          PBX_PGSQL=1
724       elif test -n "${PGSQL_MANDATORY}";
725       then
726          AC_MSG_NOTICE([***])
727          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
728          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
729          AC_MSG_NOTICE([*** including --without-postgres])
730          exit 1
731       fi
732    fi
733 fi
734
735 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
736
737 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
738
739 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
740
741 if test "${USE_PWLIB}" != "no"; then
742         if test -n "${PWLIB_DIR}"; then
743                 PWLIBDIR="${PWLIB_DIR}"
744         fi
745         AST_CHECK_PWLIB()
746         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
747                 
748         if test "${HAS_PWLIB:-unset}" != "unset"; then
749                 AST_CHECK_OPENH323_PLATFORM()
750
751                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
752
753                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
754                         [Define if your system has the PWLib libraries.],
755                         [#include "ptlib.h"],
756                         [BOOL q = PTime::IsDaylightSavings();])
757         fi
758 fi
759
760 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
761         if test -n "${OPENH323_DIR}"; then
762                 OPENH323DIR="${OPENH323_DIR}"
763         fi
764         AST_CHECK_OPENH323()
765         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
766         AST_CHECK_OPENH323_BUILD()
767         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
768         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
769                 [Define if your system has the OpenH323 libraries.],
770                 [#include "ptlib.h"
771                 #include "h323.h"
772                 #include "h323ep.h"],
773                 [H323EndPoint ep = H323EndPoint();],
774                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
775 fi
776
777 AC_LANG_PUSH(C++)
778
779 if test "${USE_QT}" != "no"; then
780    AC_MSG_CHECKING(for QDate in -lqt)
781    saved_libs="${LIBS}"
782    saved_cppflags="${CPPFLAGS}"
783    if test "x${QT_DIR}" != "x"; then
784       LIBS="${LIBS} -L${QT_DIR}/lib"
785       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
786    fi
787    LIBS="${LIBS} -lqt"
788    qtlib="qt"
789    AC_LINK_IFELSE(
790         [
791                 AC_LANG_PROGRAM(
792                 [#include <qt3/qdatetime.h>],
793                 [QDate date();])
794         ],
795         [ac_cv_lib_qt_qt_date="yes"],
796         [ac_cv_lib_qt_qt_date="no"])
797    LIBS="${saved_libs}"
798    CPPFLAGS="${saved_cppflags}"
799         
800    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
801       saved_libs="${LIBS}"
802       saved_cppflags="${CPPFLAGS}"
803       if test "x${QT_DIR}" != "x"; then
804          LIBS="${LIBS} -L${QT_DIR}/lib"
805          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
806       fi
807       LIBS="${LIBS} -lqt-mt"
808       qtlib="qt-mt"     
809       AC_LINK_IFELSE(
810                 [
811                         AC_LANG_PROGRAM(
812                         [#include <qt3/qdatetime.h>],
813                         [QDate date();])
814                 ],
815                 [ac_cv_lib_qt_qt_date="yes"],
816                 [ac_cv_lib_qt_qt_date="no"])
817       LIBS="${saved_libs}"
818       CPPFLAGS="${saved_cppflags}"
819    fi   
820
821    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
822       AC_MSG_RESULT(yes) 
823    else
824       AC_MSG_RESULT(no) 
825    fi
826         
827    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
828       QT_LIB="-l${qtlib}"
829       if test "${QT_DIR}" != ""; then
830          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
831          QT_INCLUDE="-I${QT_DIR}/include"
832       fi
833       PBX_QT=1
834       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
835       AC_PATH_TOOL(QTMOC, moc, No)
836    fi
837 fi
838
839 AC_LANG_POP
840
841 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
842
843 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
844
845 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
846
847 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
848
849 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
850
851 if test "$PBX_CRYPTO" = "1";
852 then
853     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
854 fi
855
856 if test "$PBX_OPENSSL" = "1";
857 then
858     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
859 fi
860
861 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
862 if test "${PBX_FREETDS}" != "0";
863 then
864     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
865         *0.64*)
866                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
867         ;;
868     *0.63*)
869         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
870         ;;
871     *0.62*)
872         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
873         ;;
874     *)
875         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
876         ;;
877     esac
878 fi
879
880 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
881
882 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
883
884 if test "${host_os}" != "linux-gnu" ; then
885   tonezone_extra="-lm"
886 fi
887
888 # new tonezone, version 1.4.0
889 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
890 # other case, old tonezone (0.80)
891 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
892
893 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
894
895 AC_LANG_PUSH(C++)
896
897 if test "${USE_VPB}" != "no"; then
898    AC_MSG_CHECKING(for vpb_open in -lvpb)
899    saved_libs="${LIBS}"
900    saved_cppflags="${CPPFLAGS}"
901    if test "x${VPB_DIR}" != "x"; then
902       if test -d ${VPB_DIR}/lib; then
903          vpblibdir=${VPB_DIR}/lib
904       else
905          vpblibdir=${VPB_DIR}
906       fi
907       LIBS="${LIBS} -L${vpblibdir}"
908       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
909    fi
910    LIBS="${LIBS} -lvpb -lpthread"
911    AC_LINK_IFELSE(
912         [
913         AC_LANG_PROGRAM(
914         [#include <vpbapi.h>],
915         [int q = vpb_open(0,0);])
916         ],
917         [       AC_MSG_RESULT(yes) 
918                 ac_cv_lib_vpb_vpb_open="yes" 
919         ],
920         [       AC_MSG_RESULT(no) 
921                 ac_cv_lib_vpb_vpb_open="no" 
922         ]
923         )
924    LIBS="${saved_libs}"
925    CPPFLAGS="${saved_cppflags}"
926    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
927         VPB_LIB="-lvpb"
928         if test "${VPB_DIR}" != ""; then
929            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
930            VPB_INCLUDE="-I${VPB_DIR}/include"
931         fi
932         PBX_VPB=1
933         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
934    fi
935 fi
936
937 AC_LANG_POP
938
939 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
940
941 # Check for various zaptel features and locations.
942 # The version number, which goes into HAVE_ZAPTEL_VERSION,
943 # will be used in the system headers to determine the location
944 # of the zaptel.h header.
945
946 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
947 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
948
949 # Check for VLDTMF support
950 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
951
952 # Check for transcode support
953 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
954
955 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
956 case "${host_os}" in
957     freebsd*)
958         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
959         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
960         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
961
962         # other case, old tonezone (0.80)
963         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
964         ;;
965 esac
966
967 EDITLINE_LIB=""
968 if test "x$TERMCAP_LIB" != "x" ; then
969   EDITLINE_LIB="$TERMCAP_LIB"
970 elif test "x$TINFO_LIB" != "x" ; then
971   EDITLINE_LIB="$TINFO_LIB"
972 elif test "x$CURSES_LIB" != "x" ; then
973   EDITLINE_LIB="$CURSES_LIB"
974 elif test "x$NCURSES_LIB" != "x" ; then
975   EDITLINE_LIB="$NCURSES_LIB"
976 else
977   AC_MSG_ERROR(*** termcap support not found)
978 fi
979 AC_SUBST(EDITLINE_LIB)
980
981 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
982 AC_SUBST(PBX_H323)
983
984 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
985                                    #include <linux/version.h>
986                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
987                                    #include <linux/compiler.h>
988                                    #endif
989                                    ])
990 AC_SUBST(PBX_IXJUSER)
991
992 PBX_GTK=0
993 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
994 if test ! "x${GTKCONFIG}" = xNo; then
995    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
996    GTK_LIB=$(${GTKCONFIG} --libs gthread)
997    PBX_GTK=1
998    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
999 fi
1000 AC_SUBST(PBX_GTK)
1001 AC_SUBST(GTK_INCLUDE)
1002 AC_SUBST(GTK_LIB)
1003
1004 PBX_GTK2=0
1005 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1006 if test ! "x${PKGCONFIG}" = xNo; then
1007    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags)
1008    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1009    PBX_GTK2=1
1010    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1011 fi
1012 AC_SUBST(PBX_GTK2)
1013 AC_SUBST(GTK2_INCLUDE)
1014 AC_SUBST(GTK2_LIB)
1015
1016 if test "${USE_CURL}" != "no"; then
1017    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1018    if test ! x"${CURL_CONFIG}" = xNo; then
1019    # check for version
1020       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1021          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1022          CURL_LIB=$(${CURL_CONFIG} --libs)
1023
1024          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1025          saved_cppflags="${CPPFLAGS}"
1026          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1027          AC_COMPILE_IFELSE(
1028             [AC_LANG_PROGRAM(
1029                 [#include <curl/curl.h>],
1030                     [curl_version();])
1031             ],[
1032                 AC_MSG_RESULT(yes)
1033                 ac_cv_curl_h="yes"
1034             ],[
1035                 AC_MSG_RESULT(no)
1036                 ac_cv_curl_h="no"
1037             ]
1038          )
1039          CPPFLAGS="${saved_cppflags}"
1040          if test "${ac_cv_curl_h}" = "yes"; then
1041              PBX_CURL=1
1042              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1043          fi
1044       fi
1045    fi
1046 fi
1047
1048 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1049 AST_CHECK_MANDATORY
1050
1051 AC_OUTPUT
1052
1053 if test "x${silent}" != "xyes" ; then
1054 echo
1055 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1056 echo "            .\$7\$7..          .7\$\$7:.    "
1057 echo "          .\$\$:.                 ,\$7.7   "
1058 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1059 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1060 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1061 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1062 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1063 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1064 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1065 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1066 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1067 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1068 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1069 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1070 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1071 echo " \$\$\$\$\$                        \$\$\$       "
1072 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1073 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1074 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1075 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1076 echo
1077 fi
1078
1079 AC_MSG_NOTICE(Package configured for: )
1080 AC_MSG_NOTICE( OS type  : $host_os)
1081 AC_MSG_NOTICE( Host CPU : $host_cpu)
1082 if test "${cross_compiling}" = "yes"; then
1083    AC_MSG_NOTICE( Cross Compilation = YES)
1084 fi