Merged revisions 78166 via svnmerge from
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <stdlib.h>
292                          #include <netdb.h>],
293                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
294         AC_MSG_RESULT(yes)
295         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
296         AC_MSG_RESULT(no)
297 )
298
299 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
300 AC_LINK_IFELSE(
301         AC_LANG_PROGRAM([#include <stdlib.h>
302                          #include <netdb.h>],
303                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
304         AC_MSG_RESULT(yes)
305         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
306         AC_MSG_RESULT(no)
307 )
308
309 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
310
311 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
312 AC_LINK_IFELSE(
313 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
314 AC_MSG_RESULT(yes)
315 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
316 AC_MSG_RESULT(no)
317 )
318
319 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
320 AC_LINK_IFELSE(
321 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
322 AC_MSG_RESULT(yes)
323 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
324 AC_MSG_RESULT(no)
325 )
326
327 if test "${cross_compiling}" = "no";
328 then
329   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
330 fi
331
332 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
333 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
334
335 AC_MSG_CHECKING(for compiler atomic operations)
336 AC_LINK_IFELSE(
337 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
338 AC_MSG_RESULT(yes)
339 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
340 AC_MSG_RESULT(no)
341 )
342
343 AST_GCC_ATTRIBUTE(pure)
344 AST_GCC_ATTRIBUTE(malloc)
345 AST_GCC_ATTRIBUTE(const)
346 AST_GCC_ATTRIBUTE(unused)
347 AST_GCC_ATTRIBUTE(always_inline)
348 AST_GCC_ATTRIBUTE(deprecated)
349
350 AC_MSG_CHECKING(for -ffunction-sections support)
351 saved_CFLAGS="${CFLAGS}"
352 CFLAGS="${CFLAGS} -ffunction-sections"
353 AC_COMPILE_IFELSE(
354         AC_LANG_PROGRAM([], [int x = 1;]),
355         AC_MSG_RESULT(yes)
356         [saved_LDFLAGS="${LDFLAGS}"]
357         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
358         AC_MSG_CHECKING(for --gc-sections support)
359         AC_LINK_IFELSE(
360                 AC_LANG_PROGRAM([], [int x = 1;]),
361                 AC_MSG_RESULT(yes)
362                 [GC_CFLAGS="-ffunction-sections"]
363                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
364                 AC_MSG_RESULT(no)
365         )
366         [LDFLAGS="${saved_LDFLAGS}"],
367         AC_MSG_RESULT(no)
368 )
369 CFLAGS="${saved_CFLAGS}"
370 AC_SUBST(GC_CFLAGS)
371 AC_SUBST(GC_LDFLAGS)
372
373 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
374 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
375         AC_MSG_RESULT(yes)
376         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
377 else
378         AC_MSG_RESULT(no)
379         AST_DECLARATION_AFTER_STATEMENT=
380 fi
381 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
382
383
384 AC_MSG_CHECKING(for sysinfo)
385 AC_LINK_IFELSE(
386         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
387                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
388         AC_MSG_RESULT(yes)
389         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
390         AC_MSG_RESULT(no)
391 )
392
393 AC_MSG_CHECKING(for res_ninit)
394 AC_LINK_IFELSE(
395         AC_LANG_PROGRAM([#include <resolv.h>],
396                         [int foo = res_ninit(NULL);]),
397         AC_MSG_RESULT(yes)
398         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
399         AC_MSG_CHECKING(for res_ndestroy)
400         AC_LINK_IFELSE(
401                 AC_LANG_PROGRAM([#include <resolv.h>],
402                                 [int foo = res_ndestroy(NULL);]),
403                 AC_MSG_RESULT(yes)
404                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
405                 AC_MSG_RESULT(no)
406         ),
407         AC_MSG_RESULT(no)
408 )
409
410 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
411
412 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
413
414 AC_CHECK_HEADER([libkern/OSAtomic.h],
415                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
416
417 AC_CHECK_SIZEOF(int)
418
419 # do the package library checks now
420
421 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
422
423 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
424
425 if test "x${host_os}" = "xlinux-gnu" ; then
426   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
427 fi
428
429 # BSD might not have exp2, and/or log2
430 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
431 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
432 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
433 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
434 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
435 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
436 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
437 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
438
439 GSM_INTERNAL="yes"
440 AC_SUBST(GSM_INTERNAL)
441 GSM_SYSTEM="yes"
442 if test "${USE_GSM}" != "no"; then
443    if test "${GSM_DIR}" = "internal"; then
444       GSM_SYSTEM="no"
445    elif test "${GSM_DIR}" != ""; then
446       GSM_INTERNAL="no"
447    fi
448    if test "${GSM_SYSTEM}" = "yes"; then
449       gsmlibdir=""
450       if test "x${GSM_DIR}" != "x"; then
451          if test -d ${GSM_DIR}/lib; then
452             gsmlibdir="-L${GSM_DIR}/lib"
453          else
454             gsmlibdir="-L${GSM_DIR}"
455          fi
456       fi
457       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
458       [Define to indicate the GSM library]), [], ${gsmlibdir})
459       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
460          if test "x${GSM_DIR}" != "x" ; then
461             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
462             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
463          else
464             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
465             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
466          fi
467          if test "${GSM_HEADER_FOUND}" = "0" ; then
468             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
469                if test "x${GSM_MANDATORY}" = "xyes" ; then
470                   AC_MSG_NOTICE([***])
471                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
472                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
473                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
474                   exit 1
475                fi
476             fi
477          fi
478          GSM_OK=0
479          if test "${GSM_HEADER_FOUND}" = "1" ; then
480             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
481             GSM_OK=1
482          else
483             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
484                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
485                GSM_OK=1
486             fi
487          fi
488          if test "${GSM_OK}" = "1" ; then
489             GSM_LIB="-lgsm"
490             if test "x${GSM_DIR}" != "x"; then
491                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
492                GSM_INCLUDE="-I${GSM_DIR}/include"
493             fi
494             PBX_GSM=1
495             GSM_INTERNAL="no"
496          fi
497       fi
498    fi
499    if test "${GSM_INTERNAL}" = "yes"; then
500       PBX_GSM=1
501       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
502    fi
503 fi
504
505 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
506
507 if test "${PBX_IKSEMEL}" = 1; then
508    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
509 fi
510
511 if test "${USE_IMAP_TK}" != "no"; then
512    if test "${IMAP_TK_DIR}" = "system" ; then
513       AC_MSG_NOTICE([Checking for system c-client library...])
514    elif test "${IMAP_TK_DIR}" = ""; then
515       IMAP_TK_DIR=`pwd`"/../imap-2004g"
516       if test  -n "${IMAP_TK_MANDATORY}"; then
517          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
518          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
519          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
520          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
521       fi
522    fi
523    if test "${IMAP_TK_DIR}" != "system" ; then
524       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
525    fi
526    saved_cppflags="${CPPFLAGS}"
527    saved_libs="${LIBS}"
528    if test "${IMAP_TK_DIR}" = "system" ; then
529       imap_ldflags=""
530       imap_libs="-lc-client"
531       imap_include="-DUSE_SYSTEM_IMAP"
532    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
533       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
534       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
535       imap_include="-I${IMAP_TK_DIR}/c-client"
536    fi
537    CPPFLAGS="${CPPFLAGS} ${imap_include}"
538    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
539    AC_LINK_IFELSE(
540         AC_LANG_PROGRAM(
541                 [#ifdef USE_SYSTEM_IMAP
542                 #include <imap/c-client.h>
543                 #else
544                 #include "c-client.h"
545                 #endif
546                 void mm_searched (MAILSTREAM *stream,unsigned long number)
547                 {
548                 }
549                 void mm_exists (MAILSTREAM *stream,unsigned long number)
550                 {
551                 }
552                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
553                 {
554                 }
555                 void mm_flags (MAILSTREAM *stream,unsigned long number)
556                 {
557                 }
558                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
559                 {
560                 }
561                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
562                 {
563                 }
564                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
565                 {
566                 }
567                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
568                 {
569                 }
570                 void mm_log (char *string,long errflg)
571                 {
572                 }
573                 void mm_dlog (char *string)
574                 {
575                 }
576                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
577                 {
578                 }
579                 void mm_critical (MAILSTREAM *stream)
580                 {
581                 }
582                 void mm_nocritical (MAILSTREAM *stream)
583                 {
584                 }
585                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
586                 {
587                 }
588                 void mm_fatal (char *string)
589                 {
590                 }],
591                 [
592                 MAILSTREAM *foo = mail_open(NULL, "", 0);
593                 ]
594         ),
595         [ac_cv_imap_tk="yes"],
596         [ac_cv_imap_tk="no"]
597    )
598    if test "${ac_cv_imap_tk}" = "yes"; then
599    AC_LINK_IFELSE(
600       AC_LANG_PROGRAM(
601          [#ifdef USE_SYSTEM_IMAP
602          #include <imap/c-client.h>
603          #else
604          #include "c-client.h"
605          #endif
606          void mm_searched (MAILSTREAM *stream,unsigned long number)
607          {
608          }
609          void mm_exists (MAILSTREAM *stream,unsigned long number)
610          {
611          }
612          void mm_expunged (MAILSTREAM *stream,unsigned long number)
613          {
614          }
615          void mm_flags (MAILSTREAM *stream,unsigned long number)
616          {
617          }
618          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
619          {
620          }
621          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
622          {
623          }
624          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
625          {
626          }
627          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
628          {
629          }
630          void mm_log (char *string,long errflg)
631          {
632          }
633          void mm_dlog (char *string)
634          {
635          }
636          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
637          {
638          }
639          void mm_critical (MAILSTREAM *stream)
640          {
641          }
642          void mm_nocritical (MAILSTREAM *stream)
643          {
644          }
645          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
646          {
647          }
648          void mm_fatal (char *string)
649          {
650          }],
651          [
652          long check = mail_expunge_full(NULL, "", 0);
653          ]
654       ),
655       [ac_cv_imap_tk2006="yes"],
656       [ac_cv_imap_tk2006="no"]
657   )
658   fi
659    CPPFLAGS="${saved_cppflags}"
660    LIBS="${saved_libs}"
661    if test "${ac_cv_imap_tk}" = "yes"; then
662       AC_MSG_RESULT(yes) 
663       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
664       IMAP_TK_INCLUDE="${imap_include}"
665       PBX_IMAP_TK=1
666       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
667       if test "${ac_cv_imap_tk2006}" = "yes"; then
668          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
669       fi
670    else
671       AC_MSG_RESULT(no) 
672    fi
673 fi
674
675 # Needed by unixodbc
676 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
677
678 AC_LANG_PUSH(C++)
679
680 if test "${USE_KDE}" != "no"; then
681    AC_MSG_CHECKING(for crashHandler in -lkdecore)
682    saved_libs="${LIBS}"
683    saved_cppflags="${CPPFLAGS}"
684    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
685    if test -d ${KDE_DIR}/lib; then
686       kdelibdir="${KDE_DIR}/lib"
687    else
688       kdelibdir="${KDE_DIR}"
689    fi
690    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
691
692    AC_LINK_IFELSE(
693         [AC_LANG_PROGRAM(
694                         [#include "kcrash.h"],
695                         [KCrash::defaultCrashHandler(1);])
696         ],
697         [ac_cv_lib_kde_crash="yes"],
698         [ac_cv_lib_kde_crash="no"])
699                 
700    LIBS="${saved_libs}"
701    CPPFLAGS="${saved_cppflags}"
702         
703    if test "${ac_cv_lib_kde_crash}" = "yes"; then
704       AC_MSG_RESULT(yes) 
705       KDE_LIB="-lkdecore -lkdeui"
706       if test "${KDE_DIR}" != ""; then
707          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
708          KDE_INCLUDE="-I${KDE_DIR}/include"
709       fi
710       PBX_KDE=1
711       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
712    else
713       AC_MSG_RESULT(no) 
714    fi
715 fi
716 if test "${PBX_KDE}" = 1; then
717    AC_PATH_TOOL(KDEINIT, kdeinit, No)
718    if test ! x"${KDEINIT}" = xNo; then
719       KDEDIR=$(${DIRNAME} ${KDEINIT})
720       KDEDIR=$(${DIRNAME} ${KDEDIR})
721    fi
722    AC_SUBST([KDEDIR])
723 fi
724
725 AC_LANG_POP
726
727 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
728
729 if test "${PBX_MISDN}" = 1; then
730    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
731    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
732    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
733 fi
734
735 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
736
737 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
738
739 NETSNMP_CONFIG=No
740 if test "${USE_NETSNMP}" != "no"; then  
741    if test "x${NETSNMP_DIR}" != "x"; then
742       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
743       if test x"${NETSNMP_CONFIG}" = xNo; then
744          AC_MSG_NOTICE([***])
745          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
746          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
747          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
748          AC_MSG_NOTICE([*** including --without-netsnmp])
749          exit 1
750       fi
751    else
752       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
753    fi
754 fi
755 if test x"${NETSNMP_CONFIG}" != xNo; then
756    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
757    
758    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
759    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
760
761    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
762       NETSNMP_LIB="${NETSNMP_libs}"
763       PBX_NETSNMP=1
764    fi
765 fi
766
767 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
768
769 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
770
771 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
772
773 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
774
775 # possible places for oss definitions
776 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
777 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
778 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
779
780 PG_CONFIG=No
781 if test "${USE_PGSQL}" != "no"; then    
782    if test "x${PGSQL_DIR}" != "x"; then
783       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
784       if test x"${PG_CONFIG}" = xNo; then
785          AC_MSG_NOTICE([***])
786          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
787          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
788          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
789          AC_MSG_NOTICE([*** including --without-postgres])
790          exit 1
791       fi
792    else
793       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
794    fi
795 fi
796 if test "${PG_CONFIG}" != No; then
797    PGSQL_libdir=`${PG_CONFIG} --libdir`
798    PGSQL_includedir=`${PG_CONFIG} --includedir`
799    if test "x$?" != "x0" ; then
800       if test -n "${PGSQL_MANDATORY}" ; then
801          AC_MSG_NOTICE([***])
802          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
803          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
804          AC_MSG_NOTICE([*** including --without-postgres])
805          exit 1
806           fi
807    else 
808       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
809       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
810
811       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
812          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
813          PGSQL_INCLUDE="-I${PGSQL_includedir}"
814          PBX_PGSQL=1
815       elif test -n "${PGSQL_MANDATORY}";
816       then
817          AC_MSG_NOTICE([***])
818          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
819          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
820          AC_MSG_NOTICE([*** including --without-postgres])
821          exit 1
822       fi
823    fi
824 fi
825
826 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
827
828 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
829
830 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
831
832 if test "${USE_PWLIB}" != "no"; then
833         if test -n "${PWLIB_DIR}"; then
834                 PWLIBDIR="${PWLIB_DIR}"
835         fi
836         AST_CHECK_PWLIB()
837         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
838                 
839         if test "${HAS_PWLIB:-unset}" != "unset"; then
840                 AST_CHECK_OPENH323_PLATFORM()
841
842                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
843
844                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
845                         [Define if your system has the PWLib libraries.],
846                         [#include "ptlib.h"],
847                         [BOOL q = PTime::IsDaylightSavings();])
848         fi
849 fi
850
851 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
852         if test -n "${OPENH323_DIR}"; then
853                 OPENH323DIR="${OPENH323_DIR}"
854         fi
855         AST_CHECK_OPENH323()
856         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
857         AST_CHECK_OPENH323_BUILD()
858         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
859         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
860                 [Define if your system has the OpenH323 libraries.],
861                 [#include "ptlib.h"
862                 #include "h323.h"
863                 #include "h323ep.h"],
864                 [H323EndPoint ep = H323EndPoint();],
865                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
866 fi
867
868 AC_LANG_PUSH(C++)
869
870 if test "${USE_QT}" != "no"; then
871    AC_MSG_CHECKING(for QDate in -lqt)
872    saved_libs="${LIBS}"
873    saved_cppflags="${CPPFLAGS}"
874    if test "x${QT_DIR}" != "x"; then
875       LIBS="${LIBS} -L${QT_DIR}/lib"
876       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
877    fi
878    LIBS="${LIBS} -lqt"
879    qtlib="qt"
880    AC_LINK_IFELSE(
881         [
882                 AC_LANG_PROGRAM(
883                 [#include <qt3/qdatetime.h>],
884                 [QDate date();])
885         ],
886         [ac_cv_lib_qt_qt_date="yes"],
887         [ac_cv_lib_qt_qt_date="no"])
888    LIBS="${saved_libs}"
889    CPPFLAGS="${saved_cppflags}"
890         
891    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
892       saved_libs="${LIBS}"
893       saved_cppflags="${CPPFLAGS}"
894       if test "x${QT_DIR}" != "x"; then
895          LIBS="${LIBS} -L${QT_DIR}/lib"
896          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
897       fi
898       LIBS="${LIBS} -lqt-mt"
899       qtlib="qt-mt"     
900       AC_LINK_IFELSE(
901                 [
902                         AC_LANG_PROGRAM(
903                         [#include <qt3/qdatetime.h>],
904                         [QDate date();])
905                 ],
906                 [ac_cv_lib_qt_qt_date="yes"],
907                 [ac_cv_lib_qt_qt_date="no"])
908       LIBS="${saved_libs}"
909       CPPFLAGS="${saved_cppflags}"
910    fi   
911
912    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
913       AC_MSG_RESULT(yes) 
914    else
915       AC_MSG_RESULT(no) 
916    fi
917         
918    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
919       QT_LIB="-l${qtlib}"
920       if test "${QT_DIR}" != ""; then
921          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
922          QT_INCLUDE="-I${QT_DIR}/include"
923       fi
924       PBX_QT=1
925       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
926       AC_PATH_TOOL(QTMOC, moc, No)
927    fi
928 fi
929
930 AC_LANG_POP
931
932 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
933
934 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
935
936 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
937
938 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
939
940 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
941
942 if test "$PBX_CRYPTO" = "1";
943 then
944     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
945 fi
946
947 if test "$PBX_OPENSSL" = "1";
948 then
949     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
950 fi
951
952 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
953 if test "${PBX_FREETDS}" != "0";
954 then
955     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
956         *0.64*)
957                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
958         ;;
959     *0.63*)
960         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
961         ;;
962     *0.62*)
963         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
964         ;;
965     *)
966         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
967         ;;
968     esac
969 fi
970
971 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
972
973 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
974
975 if test "${host_os}" != "linux-gnu" ; then
976   tonezone_extra="-lm"
977 fi
978
979 # new tonezone, version 1.4.0
980 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
981 # other case, old tonezone (0.80)
982 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
983
984 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
985
986 AC_LANG_PUSH(C++)
987
988 if test "${USE_VPB}" != "no"; then
989    AC_MSG_CHECKING(for vpb_open in -lvpb)
990    saved_libs="${LIBS}"
991    saved_cppflags="${CPPFLAGS}"
992    if test "x${VPB_DIR}" != "x"; then
993       if test -d ${VPB_DIR}/lib; then
994          vpblibdir=${VPB_DIR}/lib
995       else
996          vpblibdir=${VPB_DIR}
997       fi
998       LIBS="${LIBS} -L${vpblibdir}"
999       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1000    fi
1001    LIBS="${LIBS} -lvpb -lpthread"
1002    AC_LINK_IFELSE(
1003         [
1004         AC_LANG_PROGRAM(
1005         [#include <vpbapi.h>],
1006         [int q = vpb_open(0,0);])
1007         ],
1008         [       AC_MSG_RESULT(yes) 
1009                 ac_cv_lib_vpb_vpb_open="yes" 
1010         ],
1011         [       AC_MSG_RESULT(no) 
1012                 ac_cv_lib_vpb_vpb_open="no" 
1013         ]
1014         )
1015    LIBS="${saved_libs}"
1016    CPPFLAGS="${saved_cppflags}"
1017    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1018         VPB_LIB="-lvpb"
1019         if test "${VPB_DIR}" != ""; then
1020            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1021            VPB_INCLUDE="-I${VPB_DIR}/include"
1022         fi
1023         PBX_VPB=1
1024         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1025    fi
1026 fi
1027
1028 AC_LANG_POP
1029
1030 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1031
1032 # Check for various zaptel features and locations.
1033 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1034 # will be used in the system headers to determine the location
1035 # of the zaptel.h header.
1036
1037 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1038 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1039
1040 # Check for VLDTMF support
1041 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1042
1043 # Check for transcode support
1044 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1045
1046 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1047 case "${host_os}" in
1048     freebsd*)
1049         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1050         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1051         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1052
1053         # other case, old tonezone (0.80)
1054         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1055         ;;
1056 esac
1057
1058 EDITLINE_LIB=""
1059 if test "x$TERMCAP_LIB" != "x" ; then
1060   EDITLINE_LIB="$TERMCAP_LIB"
1061 elif test "x$TINFO_LIB" != "x" ; then
1062   EDITLINE_LIB="$TINFO_LIB"
1063 elif test "x$CURSES_LIB" != "x" ; then
1064   EDITLINE_LIB="$CURSES_LIB"
1065 elif test "x$NCURSES_LIB" != "x" ; then
1066   EDITLINE_LIB="$NCURSES_LIB"
1067 else
1068   AC_MSG_ERROR(*** termcap support not found)
1069 fi
1070 AC_SUBST(EDITLINE_LIB)
1071
1072 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1073 AC_SUBST(PBX_H323)
1074
1075 AC_CHECK_HEADER([linux/compiler.h],
1076                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1077
1078 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1079                                    #include <linux/version.h>
1080                                    #ifdef HAVE_LINUX_COMPILER_H
1081                                    #include <linux/compiler.h>
1082                                    #endif
1083                                    ])
1084 AC_SUBST(PBX_IXJUSER)
1085
1086 PBX_GTK=0
1087 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1088 if test ! "x${GTKCONFIG}" = xNo; then
1089    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1090    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1091    PBX_GTK=1
1092    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1093 fi
1094 AC_SUBST(PBX_GTK)
1095 AC_SUBST(GTK_INCLUDE)
1096 AC_SUBST(GTK_LIB)
1097
1098 PBX_GTK2=0
1099 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1100 if test ! "x${PKGCONFIG}" = xNo; then
1101    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1102    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1103    PBX_GTK2=1
1104    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1105 fi
1106 AC_SUBST(PBX_GTK2)
1107 AC_SUBST(GTK2_INCLUDE)
1108 AC_SUBST(GTK2_LIB)
1109
1110 if test "${USE_CURL}" != "no"; then
1111    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1112    if test ! x"${CURL_CONFIG}" = xNo; then
1113    # check for version
1114       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1115          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1116          CURL_LIB=$(${CURL_CONFIG} --libs)
1117
1118          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1119          saved_cppflags="${CPPFLAGS}"
1120          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1121          AC_COMPILE_IFELSE(
1122             [AC_LANG_PROGRAM(
1123                 [#include <curl/curl.h>],
1124                     [curl_version();])
1125             ],[
1126                 AC_MSG_RESULT(yes)
1127                 ac_cv_curl_h="yes"
1128             ],[
1129                 AC_MSG_RESULT(no)
1130                 ac_cv_curl_h="no"
1131             ]
1132          )
1133          CPPFLAGS="${saved_cppflags}"
1134          if test "${ac_cv_curl_h}" = "yes"; then
1135              PBX_CURL=1
1136              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1137          fi
1138       fi
1139    fi
1140 fi
1141
1142 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1143 AST_CHECK_MANDATORY
1144
1145 AC_OUTPUT
1146
1147 if test "x${silent}" != "xyes" ; then
1148 echo
1149 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1150 echo "            .\$7\$7..          .7\$\$7:.    "
1151 echo "          .\$\$:.                 ,\$7.7   "
1152 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1153 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1154 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1155 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1156 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1157 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1158 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1159 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1160 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1161 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1162 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1163 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1164 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1165 echo " \$\$\$\$\$                        \$\$\$       "
1166 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1167 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1168 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1169 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1170 echo
1171 fi
1172
1173 AC_MSG_NOTICE(Package configured for: )
1174 AC_MSG_NOTICE( OS type  : $host_os)
1175 AC_MSG_NOTICE( Host CPU : $host_cpu)
1176 if test "${cross_compiling}" = "yes"; then
1177    AC_MSG_NOTICE( Cross Compilation = YES)
1178 fi