c64d37e6e1dfedec1fc6af8e5c858e2d5e813e8b
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2
3 AC_PREREQ(2.60)
4
5 m4_define([PBX_VERSION],
6           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
7                        [\([0-9.]*\)\(\w\|\W\)*],
8                        [\1]))
9 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
10
11 # cross-compile macros
12 AC_CANONICAL_BUILD
13 AC_CANONICAL_HOST
14
15 # check existence of the package
16 AC_CONFIG_SRCDIR([main/asterisk.c])
17
18 # specify output header file
19 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
20
21 AC_COPYRIGHT("Asterisk")
22 AC_REVISION($Revision$)
23
24 case "${host_os}" in
25      freebsd*)
26      ac_default_prefix=/usr/local
27      ;;
28      *)
29      ac_default_prefix=/usr
30      if test ${sysconfdir} = '${prefix}/etc'; then
31         sysconfdir=/etc
32      fi
33      if test ${mandir} = '${prefix}/man'; then
34         mandir=/usr/share/man
35      fi
36      ;;
37 esac
38
39 if test ${localstatedir} = '${prefix}/var'; then
40      localstatedir=/var
41 fi
42
43 BUILD_PLATFORM=${build}
44 BUILD_CPU=${build_cpu}
45 BUILD_VENDOR=${build_vendor}
46 BUILD_OS=${build_os}
47
48 AC_SUBST(BUILD_PLATFORM)
49 AC_SUBST(BUILD_CPU)
50 AC_SUBST(BUILD_VENDOR)
51 AC_SUBST(BUILD_OS)
52
53 HOST_PLATFORM=${host}
54 HOST_CPU=${host_cpu}
55 HOST_VENDOR=${host_vendor}
56 HOST_OS=${host_os}
57
58 AC_SUBST(HOST_PLATFORM)
59 AC_SUBST(HOST_CPU)
60 AC_SUBST(HOST_VENDOR)
61 AC_SUBST(HOST_OS)
62
63 case "${host_os}" in
64      freebsd*)
65      OSARCH=FreeBSD
66      ;;
67      netbsd*)
68      OSARCH=NetBSD
69      ;;
70      openbsd*)
71      OSARCH=OpenBSD
72      ;;
73      solaris*)
74      OSARCH=SunOS
75      ;;
76      *)
77      OSARCH=${HOST_OS}
78      ;;
79 esac
80
81 AC_SUBST(OSARCH)
82
83 #  check for uname
84 AC_PATH_TOOL([UNAME], [uname], No)
85 if test ! x"${UNAME}" = xNo; then
86    PBX_OSREV=$(${UNAME} -r)
87 fi
88 AC_SUBST(PBX_OSREV)
89
90 # This needs to be before any macros that use the C compiler
91 AC_GNU_SOURCE
92
93 AH_TOP(
94 #ifndef ASTERISK_AUTOCONFIG_H
95 #define ASTERISK_AUTOCONFIG_H
96
97 #include "asterisk/buildopts.h"
98
99 #ifndef _REENTRANT
100 #define _REENTRANT
101 #endif
102 )
103
104 AH_BOTTOM(
105 #endif
106 )
107
108 # cross-compile checks
109 if test "${cross_compiling}" = "yes"; 
110 then
111    AC_CHECK_TOOL(CC, gcc, :)
112    AC_CHECK_TOOL(CXX, g++, :)
113    AC_CHECK_TOOL(LD, ld, :)
114    AC_CHECK_TOOL(RANLIB, ranlib, :)
115    AC_CHECK_TOOL(AR, ar, :)
116 fi
117
118 # Checks for programs.
119 AC_PROG_CC
120 AC_PROG_CXX
121 AC_PROG_CPP
122 AC_PROG_CXXCPP
123 AC_PROG_AWK
124 AC_PROG_INSTALL
125 AC_PROG_LN_S
126 AC_PROG_RANLIB
127 AST_CHECK_GNU_MAKE
128
129 # http://www.mail-archive.com/bug-make@gnu.org/msg02871.html
130 echo 'define A' > testMakefile
131 echo '12345: $(1:.idl=.hh) $(1:.idl=S.h) $(1:.idl=C.h) $(1:.idl=SK.cc) $(1:.idl=DynSK.cc)' >> testMakefile
132 echo 'endef' >> testMakefile
133 echo '$(eval $(call A,01234567890123456789012345678901.idl))' >> testMakefile
134 echo '01234567890123456789012345678901.hh:' >> testMakefile
135 echo '01234567890123456789012345678901S.h:' >> testMakefile
136 echo '01234567890123456789012345678901C.h:' >> testMakefile
137 echo '01234567890123456789012345678901SK.cc:' >> testMakefile
138 echo '01234567890123456789012345678901DynSK.cc:' >> testMakefile
139 $GNU_MAKE -r -f testMakefile 2>&1 > /dev/null
140 if test "$?" != "0" ; then
141   rm -f testMakefile
142   AC_MSG_NOTICE(********** ERROR **********)
143   AC_MSG_NOTICE(Your version of GNU Make contains a bug that will cause the Asterisk build)
144   AC_MSG_NOTICE(system to not function properly.  This bug is known to be fixed in version)
145   AC_MSG_NOTICE(3.81 as well as distributions of 3.80 that contain backported bug fixes.  You)
146   AC_MSG_NOTICE(must update GNU make to build Asterisk.)
147   AC_MSG_NOTICE(***************************)
148   exit 1
149 fi
150 rm -f testMakefile
151
152 AC_PATH_PROG([GREP], [grep], :)
153 AC_PATH_PROG([AR], [ar], :)
154 AC_PATH_PROG([FIND], [find], :)
155 AC_PATH_PROG([COMPRESS], [compress], :)
156 AC_PATH_PROG([BASENAME], [basename], :)
157 AC_PATH_PROG([ID], [id], :)
158 AC_PATH_PROG([DIRNAME], [dirname], :)
159 AC_PATH_PROG([SHELL], [sh], :)
160 AC_PATH_PROG([LN], [ln], :)
161 AC_PATH_PROG([DOT], [dot], :)
162
163 AC_LANG(C)
164
165 AC_ARG_ENABLE(dev-mode,
166         [  --enable-dev-mode    Turn on developer mode],
167         [case "${enableval}" in
168               y|ye|yes) AST_DEVMODE=yes ;;
169               n|no)  AST_DEVMODE=no ;;
170               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
171         esac])
172 AC_SUBST(AST_DEVMODE)
173
174 # package option names should be in alphabetical order
175 # by the --with option name, to make things easier for the users :-)
176
177 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
178 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
179 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
180 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
181 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
182 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
183 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
184 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
185 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
186 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
187 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
188 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
189 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
190 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
191 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
192 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
193 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
194 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
195 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
196 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
197 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
198 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
199 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
200 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
201 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
202 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
203 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
204 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
205 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
206 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
207 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL], [ssl])
208 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
209 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
210 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
211 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
212 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
213 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
214 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
215 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
216
217 # check for basic system features and functionality before
218 # checking for package libraries
219
220 AC_FUNC_ALLOCA
221 AC_HEADER_DIRENT
222 AC_HEADER_STDC
223 AC_HEADER_SYS_WAIT
224 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
225
226 AC_SYS_LARGEFILE
227
228 # Checks for typedefs, structures, and compiler characteristics.
229 AC_HEADER_STDBOOL
230 AC_C_CONST
231 AC_TYPE_UID_T
232 AC_C_INLINE
233 AC_TYPE_MODE_T
234 AC_TYPE_OFF_T
235 AC_TYPE_PID_T
236 AC_TYPE_SIZE_T
237 AC_CHECK_MEMBERS([struct stat.st_blksize])
238 AC_HEADER_TIME
239 AC_STRUCT_TM
240 AC_C_VOLATILE
241 AC_CHECK_TYPES([ptrdiff_t])
242
243 # Checks for library functions.
244 AC_FUNC_CHOWN
245 AC_FUNC_CLOSEDIR_VOID
246 AC_FUNC_ERROR_AT_LINE
247 AST_FUNC_FORK
248 AC_FUNC_FSEEKO
249 AC_PROG_GCC_TRADITIONAL
250 # XXX: these are commented out until we determine whether it matters if our malloc()
251 # acts exactly like glibc's or not
252 # AC_FUNC_MALLOC
253 # AC_FUNC_REALLOC
254 AC_FUNC_MEMCMP
255 AC_FUNC_MKTIME
256 AC_FUNC_MMAP
257 AC_FUNC_SELECT_ARGTYPES
258 AC_FUNC_SETVBUF_REVERSED
259 AC_TYPE_SIGNAL
260 AC_FUNC_STAT
261 AC_FUNC_STRCOLL
262 AC_FUNC_STRFTIME
263 AC_FUNC_STRNLEN
264 AC_FUNC_STRTOD
265 AC_FUNC_UTIME_NULL
266 AC_FUNC_VPRINTF
267 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
268
269 AC_MSG_CHECKING(for compiler atomic operations)
270 AC_LINK_IFELSE(
271 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
272 AC_MSG_RESULT(yes)
273 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
274 AC_MSG_RESULT(no)
275 )
276
277 AST_GCC_ATTRIBUTE(pure)
278 AST_GCC_ATTRIBUTE(malloc)
279 AST_GCC_ATTRIBUTE(const)
280 AST_GCC_ATTRIBUTE(unused)
281 AST_GCC_ATTRIBUTE(always_inline)
282
283 AC_MSG_CHECKING(for -ffunction-sections support)
284 saved_CFLAGS="${CFLAGS}"
285 CFLAGS="${CFLAGS} -ffunction-sections"
286 AC_COMPILE_IFELSE(
287         AC_LANG_PROGRAM([], [int x = 1;]),
288         AC_MSG_RESULT(yes)
289         [saved_LDFLAGS="${LDFLAGS}"]
290         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
291         AC_MSG_CHECKING(for --gc-sections support)
292         AC_LINK_IFELSE(
293                 AC_LANG_PROGRAM([], [int x = 1;]),
294                 AC_MSG_RESULT(yes)
295                 [GC_CFLAGS="-ffunction-sections"]
296                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
297                 AC_MSG_RESULT(no)
298         )
299         [LDFLAGS="${saved_LDFLAGS}"],
300         AC_MSG_RESULT(no)
301 )
302 CFLAGS="${saved_CFLAGS}"
303 AC_SUBST(GC_CFLAGS)
304 AC_SUBST(GC_LDFLAGS)
305
306 AC_MSG_CHECKING(for res_ninit)
307 AC_LINK_IFELSE(
308         AC_LANG_PROGRAM([#include <resolv.h>],
309                         [int foo = res_ninit(NULL);]),
310         AC_MSG_RESULT(yes)
311         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
312         AC_MSG_RESULT(no)
313 )
314
315 AC_MSG_CHECKING(for RTLD_NOLOAD)
316 AC_LINK_IFELSE(
317         AC_LANG_PROGRAM([#include <dlfcn.h>],
318                         [int foo = RTLD_NOLOAD;]),
319         AC_MSG_RESULT(yes)
320         AC_DEFINE([HAVE_RTLD_NOLOAD], 1, [Define to 1 if your system has a dynamic linker that supports RTLD_NOLOAD.]),
321         AC_MSG_RESULT(no)
322 )
323
324 AC_CHECK_HEADER([libkern/OSAtomic.h],
325                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
326
327 AC_CHECK_SIZEOF(int)
328
329 # do the package library checks now
330
331 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
332
333 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
334
335 if test "x${host_os}" = "xlinux-gnu" ; then
336   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
337 fi
338
339 GSM_INTERNAL="yes"
340 AC_SUBST(GSM_INTERNAL)
341 GSM_SYSTEM="yes"
342 if test "${USE_GSM}" != "no"; then
343    if test "${GSM_DIR}" = "internal"; then
344       GSM_SYSTEM="no"
345    elif test "${GSM_DIR}" != ""; then
346       GSM_INTERNAL="no"
347    fi
348    if test "${GSM_SYSTEM}" = "yes"; then
349       gsmlibdir=""
350       if test "x${GSM_DIR}" != "x"; then
351          if test -d ${GSM_DIR}/lib; then
352             gsmlibdir="-L${GSM_DIR}/lib"
353          else
354             gsmlibdir="-L${GSM_DIR}"
355          fi
356       fi
357       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
358       [Define to indicate the GSM library]), [], ${gsmlibdir})
359       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
360          GSM_LIB="-lgsm"
361          if test "x${GSM_DIR}" != "x"; then
362             GSM_LIB="${gsmlibdir} ${GSM_LIB}"
363             GSM_INCLUDE="-I${GSM_DIR}/include"
364          fi
365          PBX_GSM=1
366          GSM_INTERNAL="no"
367       fi
368    fi
369    if test "${GSM_INTERNAL}" = "yes"; then
370       PBX_GSM=1
371    fi
372 fi
373
374 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
375
376 if test "${PBX_IKSEMEL}" = 1; then
377    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye])
378    if test "${PBX_GNUTLS}" = 1; then
379       IKSEMEL_LIB="${IKSEMEL_LIB} -lgnutls -lz -lgcrypt -lnsl -lgpg-error"
380    fi
381 fi
382
383 if test "${USE_IMAP_TK}" != "no"; then
384    if test "${IMAP_TK_DIR}" = ""; then
385       IMAP_TK_DIR=`pwd`"/../imap-2004g"
386    fi
387    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
388    saved_cppflags="${CPPFLAGS}"
389    saved_libs="${LIBS}"
390    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
391       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
392    fi
393    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
394    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
395    AC_LINK_IFELSE(
396         AC_LANG_PROGRAM(
397                 [#include "c-client.h"
398                 void mm_searched (MAILSTREAM *stream,unsigned long number)
399                 {
400                 }
401                 void mm_exists (MAILSTREAM *stream,unsigned long number)
402                 {
403                 }
404                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
405                 {
406                 }
407                 void mm_flags (MAILSTREAM *stream,unsigned long number)
408                 {
409                 }
410                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
411                 {
412                 }
413                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
414                 {
415                 }
416                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
417                 {
418                 }
419                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
420                 {
421                 }
422                 void mm_log (char *string,long errflg)
423                 {
424                 }
425                 void mm_dlog (char *string)
426                 {
427                 }
428                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
429                 {
430                 }
431                 void mm_critical (MAILSTREAM *stream)
432                 {
433                 }
434                 void mm_nocritical (MAILSTREAM *stream)
435                 {
436                 }
437                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
438                 {
439                 }
440                 void mm_fatal (char *string)
441                 {
442                 }],
443                 [
444                 MAILSTREAM *foo = mail_open(NULL, "", 0);
445                 ]
446         ),
447         [ac_cv_imap_tk="yes"],
448         [ac_cv_imap_tk="no"]
449    )
450    if test "${ac_cv_imap_tk}" = "yes"; then
451    AC_LINK_IFELSE(
452       AC_LANG_PROGRAM(
453          [#include "c-client.h"
454          void mm_searched (MAILSTREAM *stream,unsigned long number)
455          {
456          }
457          void mm_exists (MAILSTREAM *stream,unsigned long number)
458          {
459          }
460          void mm_expunged (MAILSTREAM *stream,unsigned long number)
461          {
462          }
463          void mm_flags (MAILSTREAM *stream,unsigned long number)
464          {
465          }
466          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
467          {
468          }
469          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
470          {
471          }
472          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
473          {
474          }
475          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
476          {
477          }
478          void mm_log (char *string,long errflg)
479          {
480          }
481          void mm_dlog (char *string)
482          {
483          }
484          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
485          {
486          }
487          void mm_critical (MAILSTREAM *stream)
488          {
489          }
490          void mm_nocritical (MAILSTREAM *stream)
491          {
492          }
493          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
494          {
495          }
496          void mm_fatal (char *string)
497          {
498          }],
499          [
500          long check = mail_expunge_full(NULL, "", 0);
501          ]
502       ),
503       [ac_cv_imap_tk2006="yes"],
504       [ac_cv_imap_tk2006="no"]
505   )
506   fi
507    CPPFLAGS="${saved_cppflags}"
508    LIBS="${saved_libs}"
509    if test "${ac_cv_imap_tk}" = "yes"; then
510       AC_MSG_RESULT(yes) 
511       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
512       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
513       PBX_IMAP_TK=1
514       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
515       if test "${ac_cv_imap_tk2006}" = "yes"; then
516          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
517       fi
518    elif test ! -z "${IMAP_TK_MANDATORY}"; then
519       AC_MSG_RESULT(no) 
520       AC_MSG_NOTICE(***)
521       AC_MSG_NOTICE(*** The UW IMAP Toolkit installation on this system appears to be broken.)
522       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
523       AC_MSG_NOTICE(*** including --without-imap.)
524       exit 1
525    else
526       AC_MSG_RESULT(no) 
527    fi
528 fi
529
530 AC_LANG_PUSH(C++)
531
532 if test "${USE_KDE}" != "no"; then
533    AC_MSG_CHECKING(for crashHandler in -lkdecore)
534    saved_libs="${LIBS}"
535    saved_cppflags="${CPPFLAGS}"
536    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
537    if test -d ${KDE_DIR}/lib; then
538       kdelibdir="${KDE_DIR}/lib"
539    else
540       kdelibdir="${KDE_DIR}"
541    fi
542    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
543
544    AC_LINK_IFELSE(
545         [AC_LANG_PROGRAM(
546                         [#include "kcrash.h"],
547                         [KCrash::defaultCrashHandler(1);])
548         ],
549         [ac_cv_lib_kde_crash="yes"],
550         [ac_cv_lib_kde_crash="no"])
551                 
552    LIBS="${saved_libs}"
553    CPPFLAGS="${saved_cppflags}"
554         
555    if test "${ac_cv_lib_kde_crash}" = "yes"; then
556       AC_MSG_RESULT(yes) 
557       KDE_LIB="-lkdecore -lkdeui"
558       if test "${KDE_DIR}" != ""; then
559          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
560          KDE_INCLUDE="-I${KDE_DIR}/include"
561       fi
562       PBX_KDE=1
563       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
564    elif test ! -z "${KDE_MANDATORY}"; then
565       AC_MSG_RESULT(no) 
566       AC_MSG_NOTICE(***)
567       AC_MSG_NOTICE(*** The KDE installation on this system appears to be broken.)
568       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
569       AC_MSG_NOTICE(*** including --without-kde.)
570       exit 1
571    else
572       AC_MSG_RESULT(no) 
573    fi
574 fi
575 if test "${PBX_KDE}" = 1; then
576    AC_PATH_TOOL(KDEINIT, kdeinit, No)
577    if test ! x"${KDEINIT}" = xNo; then
578       KDEDIR=$(${DIRNAME} ${KDEINIT})
579       KDEDIR=$(${DIRNAME} ${KDEDIR})
580    fi
581    AC_SUBST([KDEDIR])
582 fi
583
584 AC_LANG_POP
585
586 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
587
588 if test "${PBX_MISDN}" = 1; then
589    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
590    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
591 fi
592
593 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
594
595 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
596
597 NETSNMP_CONFIG=No
598 if test "${USE_NETSNMP}" != "no"; then  
599    if test "x${NETSNMP_DIR}" != "x"; then
600       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
601       if test x"${NETSNMP_CONFIG}" = xNo; then
602          AC_MSG_NOTICE(***)
603          AC_MSG_NOTICE(*** net-snmp-config was not found in the path you specified:)
604          AC_MSG_NOTICE(*** ${NETSNMP_DIR}/bin)
605          AC_MSG_NOTICE(*** Either correct the installation, or run configure)
606          AC_MSG_NOTICE(*** including --without-netsnmp)
607          exit 1
608       fi
609    else
610       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
611    fi
612 fi
613 if test x"${NETSNMP_CONFIG}" != xNo; then
614    NETSNMP_libs=`net-snmp-config --agent-libs`
615    
616    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
617    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
618
619    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
620       NETSNMP_LIB="${NETSNMP_libs}"
621       PBX_NETSNMP=1
622    elif test ! -z "${NETSNMP_MANDATORY}";
623    then
624       AC_MSG_NOTICE(***)
625       AC_MSG_NOTICE(*** The Net-SNMP installation on this system appears to be broken.)
626       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
627       AC_MSG_NOTICE(*** including --without-netsnmp)
628       exit 1
629    fi
630 elif test ! -z "${NETSNMP_MANDATORY}";
631 then
632    AC_MSG_NOTICE(***)
633    AC_MSG_NOTICE(*** The Net-SNMP installation on this system appears to be broken.)
634    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
635    AC_MSG_NOTICE(*** including --without-netsnmp)
636    exit 1
637 fi
638
639 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
640
641 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [-lltdl])
642
643 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
644
645 AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
646
647 PBX_OSS=0
648 AC_CHECK_HEADER([linux/soundcard.h],
649                 [
650                 PBX_OSS=1
651                 AC_DEFINE_UNQUOTED([HAVE_OSS], 1, [Define to indicate the Open Sound System library])
652                 ])
653 if test "$PBX_OSS" = "0"; then
654    AC_CHECK_HEADER([sys/soundcard.h],
655                    [
656                    PBX_OSS=1
657                    AC_DEFINE_UNQUOTED([HAVE_OSS], 1, [Define to indicate the Open Sound System library])
658                    ])
659 fi
660 if test "$PBX_OSS" = "0"; then
661    AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
662 fi
663
664 PG_CONFIG=No
665 if test "${USE_PGSQL}" != "no"; then    
666    if test "x${PGSQL_DIR}" != "x"; then
667       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
668       if test x"${PG_CONFIG}" = xNo; then
669          AC_MSG_NOTICE(***)
670          AC_MSG_NOTICE(*** pg_config was not found in the path you specified:)
671          AC_MSG_NOTICE(*** ${PGSQL_DIR}/bin)
672          AC_MSG_NOTICE(*** Either correct the installation, or run configure)
673          AC_MSG_NOTICE(*** including --without-postgres)
674          exit 1
675       fi
676    else
677       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
678    fi
679 fi
680 if test "${PG_CONFIG}" != No; then
681    PGSQL_libdir=`pg_config --libdir`
682    PGSQL_includedir=`pg_config --includedir`
683    
684    AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
685    [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
686
687    if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
688       PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz -lcrypt"
689       PGSQL_INCLUDE="-I${PGSQL_includedir}"
690       PBX_PGSQL=1
691    elif test ! -z "${PGSQL_MANDATORY}";
692    then
693       AC_MSG_NOTICE(***)
694       AC_MSG_NOTICE(*** The PostgreSQL installation on this system appears to be broken.)
695       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
696       AC_MSG_NOTICE(*** including --without-postgres)
697       exit 1
698    fi
699 elif test ! -z "${PGSQL_MANDATORY}";
700 then
701    AC_MSG_NOTICE(***)
702    AC_MSG_NOTICE(*** The PostgreSQL installation on this system appears to be broken.)
703    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
704    AC_MSG_NOTICE(*** including --without-postgres)
705    exit 1
706 fi
707
708 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
709
710 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
711
712 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
713
714 if test "${USE_PWLIB}" != "no"; then
715         if test ! -z "${PWLIB_DIR}"; then
716                 PWLIBDIR="${PWLIB_DIR}"
717         fi
718         AST_CHECK_PWLIB()
719         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
720                 
721         if test "${HAS_PWLIB:-unset}" != "unset"; then
722                 AST_CHECK_OPENH323_PLATFORM()
723
724                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
725
726                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
727                         [Define if your system has the PWLib libraries.],
728                         [#include "ptlib.h"],
729                         [BOOL q = PTime::IsDaylightSavings();])
730         fi
731 fi
732
733 if test "${USE_PWLIB}" != "no" -a "x${ac_cv_lib_PWLIB}" != "xyes" -a ! -z "${PWLIB_MANDATORY}"; then
734    AC_MSG_NOTICE(***)
735    AC_MSG_NOTICE(*** The PWLIB installation on this system appears to be broken.)
736    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
737    AC_MSG_NOTICE(*** including --without-pwlib)
738    exit 1
739 fi
740
741 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
742         if test ! -z "${OPENH323_DIR}"; then
743                 OPENH323DIR="${OPENH323_DIR}"
744         fi
745         AST_CHECK_OPENH323()
746         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
747         AST_CHECK_OPENH323_BUILD()
748         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
749         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
750                 [Define if your system has the OpenH323 libraries.],
751                 [#include "ptlib.h"
752                 #include "h323.h"
753                 #include "h323ep.h"],
754                 [H323EndPoint ep = H323EndPoint();],
755                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
756 fi
757 if test "${USE_OPENH323}" != "no" -a "x${ac_cv_lib_OPENH323}" != "xyes" -a ! -z "${OPENH323_MANDATORY}"; then
758    AC_MSG_NOTICE(***)
759    AC_MSG_NOTICE(*** The PWLIB installation on this system appears to be broken.)
760    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
761    AC_MSG_NOTICE(*** including --without-pwlib)
762    exit 1
763 fi
764
765
766 AC_LANG_PUSH(C++)
767
768 if test "${USE_QT}" != "no"; then
769    AC_MSG_CHECKING(for QDate in -lqt)
770    saved_libs="${LIBS}"
771    saved_cppflags="${CPPFLAGS}"
772    if test "x${QT_DIR}" != "x"; then
773       LIBS="${LIBS} -L${QT_DIR}/lib"
774       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
775    fi
776    LIBS="${LIBS} -lqt"
777    qtlib="qt"
778    AC_LINK_IFELSE(
779         [
780                 AC_LANG_PROGRAM(
781                 [#include <qt3/qdatetime.h>],
782                 [QDate date();])
783         ],
784         [ac_cv_lib_qt_qt_date="yes"],
785         [ac_cv_lib_qt_qt_date="no"])
786    LIBS="${saved_libs}"
787    CPPFLAGS="${saved_cppflags}"
788         
789    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
790       saved_libs="${LIBS}"
791       saved_cppflags="${CPPFLAGS}"
792       if test "x${QT_DIR}" != "x"; then
793          LIBS="${LIBS} -L${QT_DIR}/lib"
794          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
795       fi
796       LIBS="${LIBS} -lqt-mt"
797       qtlib="qt-mt"     
798       AC_LINK_IFELSE(
799                 [
800                         AC_LANG_PROGRAM(
801                         [#include <qt3/qdatetime.h>],
802                         [QDate date();])
803                 ],
804                 [ac_cv_lib_qt_qt_date="yes"],
805                 [ac_cv_lib_qt_qt_date="no"])
806       LIBS="${saved_libs}"
807       CPPFLAGS="${saved_cppflags}"
808    fi   
809
810    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
811       AC_MSG_RESULT(yes) 
812    else
813       AC_MSG_RESULT(no) 
814    fi
815         
816    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
817       QT_LIB="-l${qtlib}"
818       if test "${QT_DIR}" != ""; then
819          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
820          QT_INCLUDE="-I${QT_DIR}/include"
821       fi
822       PBX_QT=1
823       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
824       AC_PATH_TOOL(QTMOC, moc, No)
825    elif test ! -z "${QT_MANDATORY}"; 
826    then
827       AC_MSG_NOTICE(***)
828       AC_MSG_NOTICE(*** The Qt installation on this system appears to be broken.)
829       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
830       AC_MSG_NOTICE(*** including --without-qt.)
831       exit 1
832    fi
833 fi
834
835 AC_LANG_POP
836
837 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
838
839 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
840
841 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
842
843 AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
844
845 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
846 if test "${PBX_FREETDS}" != "0";
847 then
848     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr/include}/tdsver.h` in
849         *0.64*)
850                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
851         ;;
852     *0.63*)
853         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
854         ;;
855     *0.62*)
856         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
857         ;;
858     *)
859         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
860         ;;
861     esac
862 fi
863
864 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
865
866 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
867
868 if test "${host_os}" != "linux-gnu" ; then
869   tonezone_extra="-lm"
870 fi
871
872 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}])
873
874 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
875
876 AC_LANG_PUSH(C++)
877
878 if test "${USE_VPB}" != "no"; then
879    AC_MSG_CHECKING(for vpb_open in -lvpb)
880    saved_libs="${LIBS}"
881    saved_cppflags="${CPPFLAGS}"
882    if test "x${VPB_DIR}" != "x"; then
883       if test -d ${VPB_DIR}/lib; then
884          vpblibdir=${VPB_DIR}/lib
885       else
886          vpblibdir=${VPB_DIR}
887       fi
888       LIBS="${LIBS} -L${vpblibdir}"
889       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
890    fi
891    LIBS="${LIBS} -lvpb -lpthread"
892    AC_LINK_IFELSE(
893         [
894         AC_LANG_PROGRAM(
895         [#include <vpbapi.h>],
896         [int q = vpb_open(0,0);])
897         ],
898         [       AC_MSG_RESULT(yes) 
899                 ac_cv_lib_vpb_vpb_open="yes" 
900         ],
901         [       AC_MSG_RESULT(no) 
902                 ac_cv_lib_vpb_vpb_open="no" 
903         ]
904         )
905    LIBS="${saved_libs}"
906    CPPFLAGS="${saved_cppflags}"
907    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
908         VPB_LIB="-lvpb"
909         if test "${VPB_DIR}" != ""; then
910            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
911            VPB_INCLUDE="-I${VPB_DIR}/include"
912         fi
913         PBX_VPB=1
914         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
915    elif test ! -z "${VPB_MANDATORY}"; then
916       AC_MSG_NOTICE(***)
917       AC_MSG_NOTICE(*** The VoiceTronix (vpb) installation on this system appears to be broken.)
918       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
919       AC_MSG_NOTICE(*** including --without-vpb.)
920       exit 1
921    fi
922 fi
923
924 AC_LANG_POP
925
926 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
927
928 if test "${USE_ZAPTEL}" != "no"; then
929    AC_MSG_CHECKING(for ZT_TONE_DTMF_BASE in zaptel.h)
930    saved_cppflags="${CPPFLAGS}"
931    if test "x${ZAPTEL_DIR}" != "x"; then
932       CPPFLAGS="${CPPFLAGS} -I${ZAPTEL_DIR}/include"
933    fi
934    AC_COMPILE_IFELSE(
935         [
936         AC_LANG_PROGRAM(
937         [#include <zaptel/zaptel.h>],
938         [int foo = ZT_TONE_DTMF_BASE;])
939         ],
940         [       AC_MSG_RESULT(yes) 
941                 ac_cv_zaptel_h="yes" 
942         ],
943         [       AC_MSG_RESULT(no) 
944                 ac_cv_zaptel_h="no" 
945         ]
946         )
947    CPPFLAGS="${saved_cppflags}"
948    if test "${ac_cv_zaptel_h}" = "yes"; then
949         if test "${ZAPTEL_DIR}" != ""; then
950            ZAPTEL_INCLUDE="-I${ZAPTEL_DIR}/include"
951         fi
952         PBX_ZAPTEL=1
953         AC_DEFINE([HAVE_ZAPTEL], 1, [Define if your system has the Zaptel headers.])
954    elif test ! -z "${ZAPTEL_MANDATORY}"; 
955    then
956       AC_MSG_NOTICE(***)
957       AC_MSG_NOTICE(*** The Zaptel installation on this system appears to be broken.)
958       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
959       AC_MSG_NOTICE(*** including --without-zaptel.)
960       exit 1
961    fi
962 fi
963
964 EDITLINE_LIB=""
965 if test "x$TERMCAP_LIB" != "x" ; then
966   EDITLINE_LIB="$TERMCAP_LIB"
967 elif test "x$TINFO_LIB" != "x" ; then
968   EDITLINE_LIB="$TINFO_LIB"
969 elif test "x$CURSES_LIB" != "x" ; then
970   EDITLINE_LIB="$CURSES_LIB"
971 elif test "x$NCURSES_LIB" != "x" ; then
972   EDITLINE_LIB="$NCURSES_LIB"
973 else
974   AC_MSG_ERROR(*** termcap support not found)
975 fi
976 AC_SUBST(EDITLINE_LIB)
977
978 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
979 AC_SUBST(PBX_H323)
980
981 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
982                                    #include <linux/version.h>
983                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
984                                    #include <linux/compiler.h>
985                                    #endif
986                                    ])
987 AC_SUBST(PBX_IXJUSER)
988
989 PBX_GTK=0
990 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
991 if test ! "x${GTKCONFIG}" = xNo; then
992    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
993    GTK_LIB=$(${GTKCONFIG} --libs gthread)
994    PBX_GTK=1
995    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
996 fi
997 AC_SUBST(PBX_GTK)
998 AC_SUBST(GTK_INCLUDE)
999 AC_SUBST(GTK_LIB)
1000
1001 if test "${USE_CURL}" != "no"; then
1002    AC_PATH_TOOL([CURL], [curl-config], No)
1003    if test ! x"${CURL}" = xNo; then
1004    # check for version
1005       if test "${host_os}" = "SunOS"; then
1006             if [[ 0x`curl-config --vernum` -ge 0x70907 ]]; then
1007                 CURL_INCLUDE=$(${CURL} --cflags)
1008                 CURL_LIB=$(${CURL} --libs)
1009                 PBX_CURL=1
1010                 AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1011             fi
1012          else
1013             if [[[ 0x`curl-config --vernum` -ge 0x70907 ]]]; then
1014                 CURL_INCLUDE=$(${CURL} --cflags)
1015                 CURL_LIB=$(${CURL} --libs)
1016                 PBX_CURL=1
1017                 AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1018             fi
1019         fi
1020     fi
1021 fi
1022
1023 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1024 AC_OUTPUT
1025
1026 if test "x${silent}" != "xyes" ; then
1027 echo
1028 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1029 echo "            .\$7\$7..          .7\$\$7:.    "
1030 echo "          .\$\$:.                 ,\$7.7   "
1031 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1032 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1033 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1034 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1035 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1036 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1037 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1038 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1039 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1040 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1041 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1042 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1043 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1044 echo " \$\$\$\$\$                        \$\$\$       "
1045 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1046 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1047 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1048 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1049 echo
1050 fi
1051
1052 AC_MSG_NOTICE(Package configured for: )
1053 AC_MSG_NOTICE( OS type  : $host_os)
1054 AC_MSG_NOTICE( Host CPU : $host_cpu)
1055 if test "${cross_compiling}" = "yes"; then
1056    AC_MSG_NOTICE( Cross Compilation = YES)
1057 fi