cb6bc26b6235e2cd4323447bc7bb2d7640f6d7ec
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <netdb.h>],
292                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
293         AC_MSG_RESULT(yes)
294         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
295         AC_MSG_RESULT(no)
296 )
297
298 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
299 AC_LINK_IFELSE(
300         AC_LANG_PROGRAM([#include <netdb.h>],
301                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
302         AC_MSG_RESULT(yes)
303         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
304         AC_MSG_RESULT(no)
305 )
306
307 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
308
309 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
310 AC_LINK_IFELSE(
311 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
312 AC_MSG_RESULT(yes)
313 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
314 AC_MSG_RESULT(no)
315 )
316
317 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
318 AC_LINK_IFELSE(
319 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
320 AC_MSG_RESULT(yes)
321 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
322 AC_MSG_RESULT(no)
323 )
324
325 if test "${cross_compiling}" = "no";
326 then
327   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
328 fi
329
330 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
331 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
332
333 AC_MSG_CHECKING(for compiler atomic operations)
334 AC_LINK_IFELSE(
335 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
336 AC_MSG_RESULT(yes)
337 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
338 AC_MSG_RESULT(no)
339 )
340
341 AST_GCC_ATTRIBUTE(pure)
342 AST_GCC_ATTRIBUTE(malloc)
343 AST_GCC_ATTRIBUTE(const)
344 AST_GCC_ATTRIBUTE(unused)
345 AST_GCC_ATTRIBUTE(always_inline)
346 AST_GCC_ATTRIBUTE(deprecated)
347
348 AC_MSG_CHECKING(for -ffunction-sections support)
349 saved_CFLAGS="${CFLAGS}"
350 CFLAGS="${CFLAGS} -ffunction-sections"
351 AC_COMPILE_IFELSE(
352         AC_LANG_PROGRAM([], [int x = 1;]),
353         AC_MSG_RESULT(yes)
354         [saved_LDFLAGS="${LDFLAGS}"]
355         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
356         AC_MSG_CHECKING(for --gc-sections support)
357         AC_LINK_IFELSE(
358                 AC_LANG_PROGRAM([], [int x = 1;]),
359                 AC_MSG_RESULT(yes)
360                 [GC_CFLAGS="-ffunction-sections"]
361                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
362                 AC_MSG_RESULT(no)
363         )
364         [LDFLAGS="${saved_LDFLAGS}"],
365         AC_MSG_RESULT(no)
366 )
367 CFLAGS="${saved_CFLAGS}"
368 AC_SUBST(GC_CFLAGS)
369 AC_SUBST(GC_LDFLAGS)
370
371 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
372 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
373         AC_MSG_RESULT(yes)
374         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
375 else
376         AC_MSG_RESULT(no)
377         AST_DECLARATION_AFTER_STATEMENT=
378 fi
379 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
380
381
382 AC_MSG_CHECKING(for sysinfo)
383 AC_LINK_IFELSE(
384         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
385                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
386         AC_MSG_RESULT(yes)
387         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
388         AC_MSG_RESULT(no)
389 )
390
391 AC_MSG_CHECKING(for res_ninit)
392 AC_LINK_IFELSE(
393         AC_LANG_PROGRAM([#include <resolv.h>],
394                         [int foo = res_ninit(NULL);]),
395         AC_MSG_RESULT(yes)
396         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
397         AC_MSG_CHECKING(for res_ndestroy)
398         AC_LINK_IFELSE(
399                 AC_LANG_PROGRAM([#include <resolv.h>],
400                                 [int foo = res_ndestroy(NULL);]),
401                 AC_MSG_RESULT(yes)
402                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
403                 AC_MSG_RESULT(no)
404         ),
405         AC_MSG_RESULT(no)
406 )
407
408 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
409
410 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
411
412 AC_CHECK_HEADER([libkern/OSAtomic.h],
413                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
414
415 AC_CHECK_SIZEOF(int)
416
417 # do the package library checks now
418
419 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
420
421 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
422
423 if test "x${host_os}" = "xlinux-gnu" ; then
424   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
425 fi
426
427 # BSD might not have exp2, and/or log2
428 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
429 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
430 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
431 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
432 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
433 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
434 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
435 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
436
437 GSM_INTERNAL="yes"
438 AC_SUBST(GSM_INTERNAL)
439 GSM_SYSTEM="yes"
440 if test "${USE_GSM}" != "no"; then
441    if test "${GSM_DIR}" = "internal"; then
442       GSM_SYSTEM="no"
443    elif test "${GSM_DIR}" != ""; then
444       GSM_INTERNAL="no"
445    fi
446    if test "${GSM_SYSTEM}" = "yes"; then
447       gsmlibdir=""
448       if test "x${GSM_DIR}" != "x"; then
449          if test -d ${GSM_DIR}/lib; then
450             gsmlibdir="-L${GSM_DIR}/lib"
451          else
452             gsmlibdir="-L${GSM_DIR}"
453          fi
454       fi
455       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
456       [Define to indicate the GSM library]), [], ${gsmlibdir})
457       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
458          if test "x${GSM_DIR}" != "x" ; then
459             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
460             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
461          else
462             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
463             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
464          fi
465          if test "${GSM_HEADER_FOUND}" = "0" ; then
466             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
467                if test "x${GSM_MANDATORY}" = "xyes" ; then
468                   AC_MSG_NOTICE([***])
469                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
470                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
471                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
472                   exit 1
473                fi
474             fi
475          fi
476          GSM_OK=0
477          if test "${GSM_HEADER_FOUND}" = "1" ; then
478             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
479             GSM_OK=1
480          else
481             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
482                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
483                GSM_OK=1
484             fi
485          fi
486          if test "${GSM_OK}" = "1" ; then
487             GSM_LIB="-lgsm"
488             if test "x${GSM_DIR}" != "x"; then
489                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
490                GSM_INCLUDE="-I${GSM_DIR}/include"
491             fi
492             PBX_GSM=1
493             GSM_INTERNAL="no"
494          fi
495       fi
496    fi
497    if test "${GSM_INTERNAL}" = "yes"; then
498       PBX_GSM=1
499       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
500    fi
501 fi
502
503 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
504
505 if test "${PBX_IKSEMEL}" = 1; then
506    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
507 fi
508
509 if test "${USE_IMAP_TK}" != "no"; then
510    if test "${IMAP_TK_DIR}" = "system" ; then
511       AC_MSG_NOTICE([Checking for system c-client library...])
512    elif test "${IMAP_TK_DIR}" = ""; then
513       IMAP_TK_DIR=`pwd`"/../imap-2004g"
514       if test  -n "${IMAP_TK_MANDATORY}"; then
515          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
516          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
517          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
518          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
519       fi
520    fi
521    if test "${IMAP_TK_DIR}" != "system" ; then
522       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
523    fi
524    saved_cppflags="${CPPFLAGS}"
525    saved_libs="${LIBS}"
526    if test "${IMAP_TK_DIR}" = "system" ; then
527       imap_ldflags=""
528       imap_libs="-lc-client"
529       imap_include="-DUSE_SYSTEM_IMAP"
530    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
531       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
532       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
533       imap_include="-I${IMAP_TK_DIR}/c-client"
534    fi
535    CPPFLAGS="${CPPFLAGS} ${imap_include}"
536    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
537    AC_LINK_IFELSE(
538         AC_LANG_PROGRAM(
539                 [#ifdef USE_SYSTEM_IMAP
540                 #include <imap/c-client.h>
541                 #else
542                 #include "c-client.h"
543                 #endif
544                 void mm_searched (MAILSTREAM *stream,unsigned long number)
545                 {
546                 }
547                 void mm_exists (MAILSTREAM *stream,unsigned long number)
548                 {
549                 }
550                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
551                 {
552                 }
553                 void mm_flags (MAILSTREAM *stream,unsigned long number)
554                 {
555                 }
556                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
557                 {
558                 }
559                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
560                 {
561                 }
562                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
563                 {
564                 }
565                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
566                 {
567                 }
568                 void mm_log (char *string,long errflg)
569                 {
570                 }
571                 void mm_dlog (char *string)
572                 {
573                 }
574                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
575                 {
576                 }
577                 void mm_critical (MAILSTREAM *stream)
578                 {
579                 }
580                 void mm_nocritical (MAILSTREAM *stream)
581                 {
582                 }
583                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
584                 {
585                 }
586                 void mm_fatal (char *string)
587                 {
588                 }],
589                 [
590                 MAILSTREAM *foo = mail_open(NULL, "", 0);
591                 ]
592         ),
593         [ac_cv_imap_tk="yes"],
594         [ac_cv_imap_tk="no"]
595    )
596    if test "${ac_cv_imap_tk}" = "yes"; then
597    AC_LINK_IFELSE(
598       AC_LANG_PROGRAM(
599          [#ifdef USE_SYSTEM_IMAP
600          #include <imap/c-client.h>
601          #else
602          #include "c-client.h"
603          #endif
604          void mm_searched (MAILSTREAM *stream,unsigned long number)
605          {
606          }
607          void mm_exists (MAILSTREAM *stream,unsigned long number)
608          {
609          }
610          void mm_expunged (MAILSTREAM *stream,unsigned long number)
611          {
612          }
613          void mm_flags (MAILSTREAM *stream,unsigned long number)
614          {
615          }
616          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
617          {
618          }
619          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
620          {
621          }
622          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
623          {
624          }
625          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
626          {
627          }
628          void mm_log (char *string,long errflg)
629          {
630          }
631          void mm_dlog (char *string)
632          {
633          }
634          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
635          {
636          }
637          void mm_critical (MAILSTREAM *stream)
638          {
639          }
640          void mm_nocritical (MAILSTREAM *stream)
641          {
642          }
643          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
644          {
645          }
646          void mm_fatal (char *string)
647          {
648          }],
649          [
650          long check = mail_expunge_full(NULL, "", 0);
651          ]
652       ),
653       [ac_cv_imap_tk2006="yes"],
654       [ac_cv_imap_tk2006="no"]
655   )
656   fi
657    CPPFLAGS="${saved_cppflags}"
658    LIBS="${saved_libs}"
659    if test "${ac_cv_imap_tk}" = "yes"; then
660       AC_MSG_RESULT(yes) 
661       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
662       IMAP_TK_INCLUDE="${imap_include}"
663       PBX_IMAP_TK=1
664       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
665       if test "${ac_cv_imap_tk2006}" = "yes"; then
666          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
667       fi
668    else
669       AC_MSG_RESULT(no) 
670    fi
671 fi
672
673 # Needed by unixodbc
674 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
675
676 AC_LANG_PUSH(C++)
677
678 if test "${USE_KDE}" != "no"; then
679    AC_MSG_CHECKING(for crashHandler in -lkdecore)
680    saved_libs="${LIBS}"
681    saved_cppflags="${CPPFLAGS}"
682    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
683    if test -d ${KDE_DIR}/lib; then
684       kdelibdir="${KDE_DIR}/lib"
685    else
686       kdelibdir="${KDE_DIR}"
687    fi
688    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
689
690    AC_LINK_IFELSE(
691         [AC_LANG_PROGRAM(
692                         [#include "kcrash.h"],
693                         [KCrash::defaultCrashHandler(1);])
694         ],
695         [ac_cv_lib_kde_crash="yes"],
696         [ac_cv_lib_kde_crash="no"])
697                 
698    LIBS="${saved_libs}"
699    CPPFLAGS="${saved_cppflags}"
700         
701    if test "${ac_cv_lib_kde_crash}" = "yes"; then
702       AC_MSG_RESULT(yes) 
703       KDE_LIB="-lkdecore -lkdeui"
704       if test "${KDE_DIR}" != ""; then
705          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
706          KDE_INCLUDE="-I${KDE_DIR}/include"
707       fi
708       PBX_KDE=1
709       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
710    else
711       AC_MSG_RESULT(no) 
712    fi
713 fi
714 if test "${PBX_KDE}" = 1; then
715    AC_PATH_TOOL(KDEINIT, kdeinit, No)
716    if test ! x"${KDEINIT}" = xNo; then
717       KDEDIR=$(${DIRNAME} ${KDEINIT})
718       KDEDIR=$(${DIRNAME} ${KDEDIR})
719    fi
720    AC_SUBST([KDEDIR])
721 fi
722
723 AC_LANG_POP
724
725 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
726
727 if test "${PBX_MISDN}" = 1; then
728    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
729    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
730    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
731 fi
732
733 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
734
735 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
736
737 NETSNMP_CONFIG=No
738 if test "${USE_NETSNMP}" != "no"; then  
739    if test "x${NETSNMP_DIR}" != "x"; then
740       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
741       if test x"${NETSNMP_CONFIG}" = xNo; then
742          AC_MSG_NOTICE([***])
743          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
744          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
745          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
746          AC_MSG_NOTICE([*** including --without-netsnmp])
747          exit 1
748       fi
749    else
750       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
751    fi
752 fi
753 if test x"${NETSNMP_CONFIG}" != xNo; then
754    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
755    
756    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
757    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
758
759    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
760       NETSNMP_LIB="${NETSNMP_libs}"
761       PBX_NETSNMP=1
762    fi
763 fi
764
765 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
766
767 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
768
769 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
770
771 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
772
773 # possible places for oss definitions
774 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
775 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
776 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
777
778 PG_CONFIG=No
779 if test "${USE_PGSQL}" != "no"; then    
780    if test "x${PGSQL_DIR}" != "x"; then
781       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
782       if test x"${PG_CONFIG}" = xNo; then
783          AC_MSG_NOTICE([***])
784          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
785          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
786          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
787          AC_MSG_NOTICE([*** including --without-postgres])
788          exit 1
789       fi
790    else
791       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
792    fi
793 fi
794 if test "${PG_CONFIG}" != No; then
795    PGSQL_libdir=`${PG_CONFIG} --libdir`
796    PGSQL_includedir=`${PG_CONFIG} --includedir`
797    if test "x$?" != "x0" ; then
798       if test -n "${PGSQL_MANDATORY}" ; then
799          AC_MSG_NOTICE([***])
800          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
801          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
802          AC_MSG_NOTICE([*** including --without-postgres])
803          exit 1
804           fi
805    else 
806       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
807       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
808
809       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
810          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
811          PGSQL_INCLUDE="-I${PGSQL_includedir}"
812          PBX_PGSQL=1
813       elif test -n "${PGSQL_MANDATORY}";
814       then
815          AC_MSG_NOTICE([***])
816          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
817          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
818          AC_MSG_NOTICE([*** including --without-postgres])
819          exit 1
820       fi
821    fi
822 fi
823
824 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
825
826 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
827
828 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
829
830 if test "${USE_PWLIB}" != "no"; then
831         if test -n "${PWLIB_DIR}"; then
832                 PWLIBDIR="${PWLIB_DIR}"
833         fi
834         AST_CHECK_PWLIB()
835         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
836                 
837         if test "${HAS_PWLIB:-unset}" != "unset"; then
838                 AST_CHECK_OPENH323_PLATFORM()
839
840                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
841
842                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
843                         [Define if your system has the PWLib libraries.],
844                         [#include "ptlib.h"],
845                         [BOOL q = PTime::IsDaylightSavings();])
846         fi
847 fi
848
849 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
850         if test -n "${OPENH323_DIR}"; then
851                 OPENH323DIR="${OPENH323_DIR}"
852         fi
853         AST_CHECK_OPENH323()
854         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
855         AST_CHECK_OPENH323_BUILD()
856         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
857         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
858                 [Define if your system has the OpenH323 libraries.],
859                 [#include "ptlib.h"
860                 #include "h323.h"
861                 #include "h323ep.h"],
862                 [H323EndPoint ep = H323EndPoint();],
863                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
864 fi
865
866 AC_LANG_PUSH(C++)
867
868 if test "${USE_QT}" != "no"; then
869    AC_MSG_CHECKING(for QDate in -lqt)
870    saved_libs="${LIBS}"
871    saved_cppflags="${CPPFLAGS}"
872    if test "x${QT_DIR}" != "x"; then
873       LIBS="${LIBS} -L${QT_DIR}/lib"
874       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
875    fi
876    LIBS="${LIBS} -lqt"
877    qtlib="qt"
878    AC_LINK_IFELSE(
879         [
880                 AC_LANG_PROGRAM(
881                 [#include <qt3/qdatetime.h>],
882                 [QDate date();])
883         ],
884         [ac_cv_lib_qt_qt_date="yes"],
885         [ac_cv_lib_qt_qt_date="no"])
886    LIBS="${saved_libs}"
887    CPPFLAGS="${saved_cppflags}"
888         
889    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
890       saved_libs="${LIBS}"
891       saved_cppflags="${CPPFLAGS}"
892       if test "x${QT_DIR}" != "x"; then
893          LIBS="${LIBS} -L${QT_DIR}/lib"
894          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
895       fi
896       LIBS="${LIBS} -lqt-mt"
897       qtlib="qt-mt"     
898       AC_LINK_IFELSE(
899                 [
900                         AC_LANG_PROGRAM(
901                         [#include <qt3/qdatetime.h>],
902                         [QDate date();])
903                 ],
904                 [ac_cv_lib_qt_qt_date="yes"],
905                 [ac_cv_lib_qt_qt_date="no"])
906       LIBS="${saved_libs}"
907       CPPFLAGS="${saved_cppflags}"
908    fi   
909
910    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
911       AC_MSG_RESULT(yes) 
912    else
913       AC_MSG_RESULT(no) 
914    fi
915         
916    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
917       QT_LIB="-l${qtlib}"
918       if test "${QT_DIR}" != ""; then
919          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
920          QT_INCLUDE="-I${QT_DIR}/include"
921       fi
922       PBX_QT=1
923       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
924       AC_PATH_TOOL(QTMOC, moc, No)
925    fi
926 fi
927
928 AC_LANG_POP
929
930 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
931
932 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
933
934 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
935
936 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
937
938 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
939
940 if test "$PBX_CRYPTO" = "1";
941 then
942     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
943 fi
944
945 if test "$PBX_OPENSSL" = "1";
946 then
947     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
948 fi
949
950 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
951 if test "${PBX_FREETDS}" != "0";
952 then
953     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
954         *0.64*)
955                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
956         ;;
957     *0.63*)
958         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
959         ;;
960     *0.62*)
961         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
962         ;;
963     *)
964         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
965         ;;
966     esac
967 fi
968
969 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
970
971 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
972
973 if test "${host_os}" != "linux-gnu" ; then
974   tonezone_extra="-lm"
975 fi
976
977 # new tonezone, version 1.4.0
978 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
979 # other case, old tonezone (0.80)
980 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
981
982 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
983
984 AC_LANG_PUSH(C++)
985
986 if test "${USE_VPB}" != "no"; then
987    AC_MSG_CHECKING(for vpb_open in -lvpb)
988    saved_libs="${LIBS}"
989    saved_cppflags="${CPPFLAGS}"
990    if test "x${VPB_DIR}" != "x"; then
991       if test -d ${VPB_DIR}/lib; then
992          vpblibdir=${VPB_DIR}/lib
993       else
994          vpblibdir=${VPB_DIR}
995       fi
996       LIBS="${LIBS} -L${vpblibdir}"
997       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
998    fi
999    LIBS="${LIBS} -lvpb -lpthread"
1000    AC_LINK_IFELSE(
1001         [
1002         AC_LANG_PROGRAM(
1003         [#include <vpbapi.h>],
1004         [int q = vpb_open(0,0);])
1005         ],
1006         [       AC_MSG_RESULT(yes) 
1007                 ac_cv_lib_vpb_vpb_open="yes" 
1008         ],
1009         [       AC_MSG_RESULT(no) 
1010                 ac_cv_lib_vpb_vpb_open="no" 
1011         ]
1012         )
1013    LIBS="${saved_libs}"
1014    CPPFLAGS="${saved_cppflags}"
1015    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1016         VPB_LIB="-lvpb"
1017         if test "${VPB_DIR}" != ""; then
1018            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1019            VPB_INCLUDE="-I${VPB_DIR}/include"
1020         fi
1021         PBX_VPB=1
1022         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1023    fi
1024 fi
1025
1026 AC_LANG_POP
1027
1028 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1029
1030 # Check for various zaptel features and locations.
1031 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1032 # will be used in the system headers to determine the location
1033 # of the zaptel.h header.
1034
1035 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1036 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1037
1038 # Check for VLDTMF support
1039 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1040
1041 # Check for transcode support
1042 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1043
1044 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1045 case "${host_os}" in
1046     freebsd*)
1047         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1048         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1049         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1050
1051         # other case, old tonezone (0.80)
1052         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1053         ;;
1054 esac
1055
1056 EDITLINE_LIB=""
1057 if test "x$TERMCAP_LIB" != "x" ; then
1058   EDITLINE_LIB="$TERMCAP_LIB"
1059 elif test "x$TINFO_LIB" != "x" ; then
1060   EDITLINE_LIB="$TINFO_LIB"
1061 elif test "x$CURSES_LIB" != "x" ; then
1062   EDITLINE_LIB="$CURSES_LIB"
1063 elif test "x$NCURSES_LIB" != "x" ; then
1064   EDITLINE_LIB="$NCURSES_LIB"
1065 else
1066   AC_MSG_ERROR(*** termcap support not found)
1067 fi
1068 AC_SUBST(EDITLINE_LIB)
1069
1070 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1071 AC_SUBST(PBX_H323)
1072
1073 AC_CHECK_HEADER([linux/compiler.h],
1074                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1075
1076 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1077                                    #include <linux/version.h>
1078                                    #ifdef HAVE_LINUX_COMPILER_H
1079                                    #include <linux/compiler.h>
1080                                    #endif
1081                                    ])
1082 AC_SUBST(PBX_IXJUSER)
1083
1084 PBX_GTK=0
1085 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1086 if test ! "x${GTKCONFIG}" = xNo; then
1087    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1088    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1089    PBX_GTK=1
1090    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1091 fi
1092 AC_SUBST(PBX_GTK)
1093 AC_SUBST(GTK_INCLUDE)
1094 AC_SUBST(GTK_LIB)
1095
1096 PBX_GTK2=0
1097 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1098 if test ! "x${PKGCONFIG}" = xNo; then
1099    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1100    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1101    PBX_GTK2=1
1102    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1103 fi
1104 AC_SUBST(PBX_GTK2)
1105 AC_SUBST(GTK2_INCLUDE)
1106 AC_SUBST(GTK2_LIB)
1107
1108 if test "${USE_CURL}" != "no"; then
1109    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1110    if test ! x"${CURL_CONFIG}" = xNo; then
1111    # check for version
1112       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1113          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1114          CURL_LIB=$(${CURL_CONFIG} --libs)
1115
1116          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1117          saved_cppflags="${CPPFLAGS}"
1118          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1119          AC_COMPILE_IFELSE(
1120             [AC_LANG_PROGRAM(
1121                 [#include <curl/curl.h>],
1122                     [curl_version();])
1123             ],[
1124                 AC_MSG_RESULT(yes)
1125                 ac_cv_curl_h="yes"
1126             ],[
1127                 AC_MSG_RESULT(no)
1128                 ac_cv_curl_h="no"
1129             ]
1130          )
1131          CPPFLAGS="${saved_cppflags}"
1132          if test "${ac_cv_curl_h}" = "yes"; then
1133              PBX_CURL=1
1134              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1135          fi
1136       fi
1137    fi
1138 fi
1139
1140 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1141 AST_CHECK_MANDATORY
1142
1143 AC_OUTPUT
1144
1145 if test "x${silent}" != "xyes" ; then
1146 echo
1147 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1148 echo "            .\$7\$7..          .7\$\$7:.    "
1149 echo "          .\$\$:.                 ,\$7.7   "
1150 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1151 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1152 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1153 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1154 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1155 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1156 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1157 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1158 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1159 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1160 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1161 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1162 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1163 echo " \$\$\$\$\$                        \$\$\$       "
1164 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1165 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1166 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1167 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1168 echo
1169 fi
1170
1171 AC_MSG_NOTICE(Package configured for: )
1172 AC_MSG_NOTICE( OS type  : $host_os)
1173 AC_MSG_NOTICE( Host CPU : $host_cpu)
1174 if test "${cross_compiling}" = "yes"; then
1175    AC_MSG_NOTICE( Cross Compilation = YES)
1176 fi