Various code and documentation cleanups for res_config_sqlite
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <stdlib.h>
292                          #include <netdb.h>],
293                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
294         AC_MSG_RESULT(yes)
295         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
296         AC_MSG_RESULT(no)
297 )
298
299 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
300 AC_LINK_IFELSE(
301         AC_LANG_PROGRAM([#include <stdlib.h>
302                          #include <netdb.h>],
303                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
304         AC_MSG_RESULT(yes)
305         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
306         AC_MSG_RESULT(no)
307 )
308
309 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
310
311 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
312 AC_LINK_IFELSE(
313 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
314 AC_MSG_RESULT(yes)
315 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
316 AC_MSG_RESULT(no)
317 )
318
319 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
320 AC_LINK_IFELSE(
321 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
322 AC_MSG_RESULT(yes)
323 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
324 AC_MSG_RESULT(no)
325 )
326
327 if test "${cross_compiling}" = "no";
328 then
329   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
330 fi
331
332 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
333 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
334
335 if test "${cross_compiling}" = "no";
336 then
337 AC_MSG_CHECKING(for working epoll support)
338 AC_LINK_IFELSE(
339 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
340                                           if (res < 0)
341                                              return 1;
342                                           close (res);
343                                           return 0;]),
344 AC_MSG_RESULT(yes)
345 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
346 AC_MSG_RESULT(no)
347 )
348 fi
349
350 AC_MSG_CHECKING(for compiler atomic operations)
351 AC_LINK_IFELSE(
352 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
353 AC_MSG_RESULT(yes)
354 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
355 AC_MSG_RESULT(no)
356 )
357
358 AST_GCC_ATTRIBUTE(pure)
359 AST_GCC_ATTRIBUTE(malloc)
360 AST_GCC_ATTRIBUTE(const)
361 AST_GCC_ATTRIBUTE(unused)
362 AST_GCC_ATTRIBUTE(always_inline)
363 AST_GCC_ATTRIBUTE(deprecated)
364
365 AC_MSG_CHECKING(for -ffunction-sections support)
366 saved_CFLAGS="${CFLAGS}"
367 CFLAGS="${CFLAGS} -ffunction-sections"
368 AC_COMPILE_IFELSE(
369         AC_LANG_PROGRAM([], [int x = 1;]),
370         AC_MSG_RESULT(yes)
371         [saved_LDFLAGS="${LDFLAGS}"]
372         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
373         AC_MSG_CHECKING(for --gc-sections support)
374         AC_LINK_IFELSE(
375                 AC_LANG_PROGRAM([], [int x = 1;]),
376                 AC_MSG_RESULT(yes)
377                 [GC_CFLAGS="-ffunction-sections"]
378                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
379                 AC_MSG_RESULT(no)
380         )
381         [LDFLAGS="${saved_LDFLAGS}"],
382         AC_MSG_RESULT(no)
383 )
384 CFLAGS="${saved_CFLAGS}"
385 AC_SUBST(GC_CFLAGS)
386 AC_SUBST(GC_LDFLAGS)
387
388 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
389 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
390         AC_MSG_RESULT(yes)
391         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
392 else
393         AC_MSG_RESULT(no)
394         AST_DECLARATION_AFTER_STATEMENT=
395 fi
396 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
397
398
399 AC_MSG_CHECKING(for sysinfo)
400 AC_LINK_IFELSE(
401         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
402                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
403         AC_MSG_RESULT(yes)
404         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
405         AC_MSG_RESULT(no)
406 )
407
408 AC_MSG_CHECKING(for res_ninit)
409 AC_LINK_IFELSE(
410         AC_LANG_PROGRAM([#include <resolv.h>],
411                         [int foo = res_ninit(NULL);]),
412         AC_MSG_RESULT(yes)
413         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
414         AC_MSG_CHECKING(for res_ndestroy)
415         AC_LINK_IFELSE(
416                 AC_LANG_PROGRAM([#include <resolv.h>],
417                                 [int foo = res_ndestroy(NULL);]),
418                 AC_MSG_RESULT(yes)
419                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
420                 AC_MSG_RESULT(no)
421         ),
422         AC_MSG_RESULT(no)
423 )
424
425 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
426
427 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
428
429 AC_CHECK_HEADER([libkern/OSAtomic.h],
430                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
431
432 AC_CHECK_SIZEOF(int)
433
434 # do the package library checks now
435
436 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
437
438 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
439
440 if test "x${host_os}" = "xlinux-gnu" ; then
441   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
442 fi
443
444 # BSD might not have exp2, and/or log2
445 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
446 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
447 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
448 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
449 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
450 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
451 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
452 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
453
454 GSM_INTERNAL="yes"
455 AC_SUBST(GSM_INTERNAL)
456 GSM_SYSTEM="yes"
457 if test "${USE_GSM}" != "no"; then
458    if test "${GSM_DIR}" = "internal"; then
459       GSM_SYSTEM="no"
460    elif test "${GSM_DIR}" != ""; then
461       GSM_INTERNAL="no"
462    fi
463    if test "${GSM_SYSTEM}" = "yes"; then
464       gsmlibdir=""
465       if test "x${GSM_DIR}" != "x"; then
466          if test -d ${GSM_DIR}/lib; then
467             gsmlibdir="-L${GSM_DIR}/lib"
468          else
469             gsmlibdir="-L${GSM_DIR}"
470          fi
471       fi
472       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
473       [Define to indicate the GSM library]), [], ${gsmlibdir})
474       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
475          if test "x${GSM_DIR}" != "x" ; then
476             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
477             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
478          else
479             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
480             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
481          fi
482          if test "${GSM_HEADER_FOUND}" = "0" ; then
483             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
484                if test "x${GSM_MANDATORY}" = "xyes" ; then
485                   AC_MSG_NOTICE([***])
486                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
487                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
488                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
489                   exit 1
490                fi
491             fi
492          fi
493          GSM_OK=0
494          if test "${GSM_HEADER_FOUND}" = "1" ; then
495             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
496             GSM_OK=1
497          else
498             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
499                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
500                GSM_OK=1
501             fi
502          fi
503          if test "${GSM_OK}" = "1" ; then
504             GSM_LIB="-lgsm"
505             if test "x${GSM_DIR}" != "x"; then
506                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
507                GSM_INCLUDE="-I${GSM_DIR}/include"
508             fi
509             PBX_GSM=1
510             GSM_INTERNAL="no"
511          fi
512       fi
513    fi
514    if test "${GSM_INTERNAL}" = "yes"; then
515       PBX_GSM=1
516       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
517    fi
518 fi
519
520 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
521
522 if test "${PBX_IKSEMEL}" = 1; then
523    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
524 fi
525
526 if test "${USE_IMAP_TK}" != "no"; then
527    if test "${IMAP_TK_DIR}" = "system" ; then
528       AC_MSG_NOTICE([Checking for system c-client library...])
529    elif test "${IMAP_TK_DIR}" = ""; then
530       IMAP_TK_DIR=`pwd`"/../imap-2004g"
531       if test  -n "${IMAP_TK_MANDATORY}"; then
532          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
533          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
534          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
535          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
536       fi
537    fi
538    if test "${IMAP_TK_DIR}" != "system" ; then
539       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
540    fi
541    saved_cppflags="${CPPFLAGS}"
542    saved_libs="${LIBS}"
543    if test "${IMAP_TK_DIR}" = "system" ; then
544       imap_ldflags=""
545       imap_libs="-lc-client"
546       imap_include="-DUSE_SYSTEM_IMAP"
547    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
548       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
549       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
550       imap_include="-I${IMAP_TK_DIR}/c-client"
551    fi
552    CPPFLAGS="${CPPFLAGS} ${imap_include}"
553    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
554    AC_LINK_IFELSE(
555         AC_LANG_PROGRAM(
556                 [#ifdef USE_SYSTEM_IMAP
557                 #include <imap/c-client.h>
558                 #else
559                 #include "c-client.h"
560                 #endif
561                 void mm_searched (MAILSTREAM *stream,unsigned long number)
562                 {
563                 }
564                 void mm_exists (MAILSTREAM *stream,unsigned long number)
565                 {
566                 }
567                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
568                 {
569                 }
570                 void mm_flags (MAILSTREAM *stream,unsigned long number)
571                 {
572                 }
573                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
574                 {
575                 }
576                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
577                 {
578                 }
579                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
580                 {
581                 }
582                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
583                 {
584                 }
585                 void mm_log (char *string,long errflg)
586                 {
587                 }
588                 void mm_dlog (char *string)
589                 {
590                 }
591                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
592                 {
593                 }
594                 void mm_critical (MAILSTREAM *stream)
595                 {
596                 }
597                 void mm_nocritical (MAILSTREAM *stream)
598                 {
599                 }
600                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
601                 {
602                 }
603                 void mm_fatal (char *string)
604                 {
605                 }],
606                 [
607                 MAILSTREAM *foo = mail_open(NULL, "", 0);
608                 ]
609         ),
610         [ac_cv_imap_tk="yes"],
611         [ac_cv_imap_tk="no"]
612    )
613    if test "${ac_cv_imap_tk}" = "yes"; then
614    AC_LINK_IFELSE(
615       AC_LANG_PROGRAM(
616          [#ifdef USE_SYSTEM_IMAP
617          #include <imap/c-client.h>
618          #else
619          #include "c-client.h"
620          #endif
621          void mm_searched (MAILSTREAM *stream,unsigned long number)
622          {
623          }
624          void mm_exists (MAILSTREAM *stream,unsigned long number)
625          {
626          }
627          void mm_expunged (MAILSTREAM *stream,unsigned long number)
628          {
629          }
630          void mm_flags (MAILSTREAM *stream,unsigned long number)
631          {
632          }
633          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
634          {
635          }
636          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
637          {
638          }
639          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
640          {
641          }
642          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
643          {
644          }
645          void mm_log (char *string,long errflg)
646          {
647          }
648          void mm_dlog (char *string)
649          {
650          }
651          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
652          {
653          }
654          void mm_critical (MAILSTREAM *stream)
655          {
656          }
657          void mm_nocritical (MAILSTREAM *stream)
658          {
659          }
660          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
661          {
662          }
663          void mm_fatal (char *string)
664          {
665          }],
666          [
667          long check = mail_expunge_full(NULL, "", 0);
668          ]
669       ),
670       [ac_cv_imap_tk2006="yes"],
671       [ac_cv_imap_tk2006="no"]
672   )
673   fi
674    CPPFLAGS="${saved_cppflags}"
675    LIBS="${saved_libs}"
676    if test "${ac_cv_imap_tk}" = "yes"; then
677       AC_MSG_RESULT(yes) 
678       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
679       IMAP_TK_INCLUDE="${imap_include}"
680       PBX_IMAP_TK=1
681       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
682       if test "${ac_cv_imap_tk2006}" = "yes"; then
683          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
684       fi
685    else
686       AC_MSG_RESULT(no) 
687    fi
688 fi
689
690 # Needed by unixodbc
691 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
692
693 AC_LANG_PUSH(C++)
694
695 if test "${USE_KDE}" != "no"; then
696    AC_MSG_CHECKING(for crashHandler in -lkdecore)
697    saved_libs="${LIBS}"
698    saved_cppflags="${CPPFLAGS}"
699    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
700    if test -d ${KDE_DIR}/lib; then
701       kdelibdir="${KDE_DIR}/lib"
702    else
703       kdelibdir="${KDE_DIR}"
704    fi
705    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
706
707    AC_LINK_IFELSE(
708         [AC_LANG_PROGRAM(
709                         [#include "kcrash.h"],
710                         [KCrash::defaultCrashHandler(1);])
711         ],
712         [ac_cv_lib_kde_crash="yes"],
713         [ac_cv_lib_kde_crash="no"])
714                 
715    LIBS="${saved_libs}"
716    CPPFLAGS="${saved_cppflags}"
717         
718    if test "${ac_cv_lib_kde_crash}" = "yes"; then
719       AC_MSG_RESULT(yes) 
720       KDE_LIB="-lkdecore -lkdeui"
721       if test "${KDE_DIR}" != ""; then
722          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
723          KDE_INCLUDE="-I${KDE_DIR}/include"
724       fi
725       PBX_KDE=1
726       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
727    else
728       AC_MSG_RESULT(no) 
729    fi
730 fi
731 if test "${PBX_KDE}" = 1; then
732    AC_PATH_TOOL(KDEINIT, kdeinit, No)
733    if test ! x"${KDEINIT}" = xNo; then
734       KDEDIR=$(${DIRNAME} ${KDEINIT})
735       KDEDIR=$(${DIRNAME} ${KDEDIR})
736    fi
737    AC_SUBST([KDEDIR])
738 fi
739
740 AC_LANG_POP
741
742 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
743
744 if test "${PBX_MISDN}" = 1; then
745    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
746    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
747    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
748 fi
749
750 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
751
752 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
753
754 NETSNMP_CONFIG=No
755 if test "${USE_NETSNMP}" != "no"; then  
756    if test "x${NETSNMP_DIR}" != "x"; then
757       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
758       if test x"${NETSNMP_CONFIG}" = xNo; then
759          AC_MSG_NOTICE([***])
760          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
761          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
762          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
763          AC_MSG_NOTICE([*** including --without-netsnmp])
764          exit 1
765       fi
766    else
767       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
768    fi
769 fi
770 if test x"${NETSNMP_CONFIG}" != xNo; then
771    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
772    
773    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
774    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
775
776    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
777       NETSNMP_LIB="${NETSNMP_libs}"
778       PBX_NETSNMP=1
779    fi
780 fi
781
782 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
783
784 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
785
786 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
787
788 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
789
790 # possible places for oss definitions
791 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
792 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
793 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
794
795 PG_CONFIG=No
796 if test "${USE_PGSQL}" != "no"; then    
797    if test "x${PGSQL_DIR}" != "x"; then
798       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
799       if test x"${PG_CONFIG}" = xNo; then
800          AC_MSG_NOTICE([***])
801          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
802          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
803          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
804          AC_MSG_NOTICE([*** including --without-postgres])
805          exit 1
806       fi
807    else
808       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
809    fi
810 fi
811 if test "${PG_CONFIG}" != No; then
812    PGSQL_libdir=`${PG_CONFIG} --libdir`
813    PGSQL_includedir=`${PG_CONFIG} --includedir`
814    if test "x$?" != "x0" ; then
815       if test -n "${PGSQL_MANDATORY}" ; then
816          AC_MSG_NOTICE([***])
817          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
818          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
819          AC_MSG_NOTICE([*** including --without-postgres])
820          exit 1
821           fi
822    else 
823       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
824       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
825
826       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
827          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
828          PGSQL_INCLUDE="-I${PGSQL_includedir}"
829          PBX_PGSQL=1
830       elif test -n "${PGSQL_MANDATORY}";
831       then
832          AC_MSG_NOTICE([***])
833          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
834          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
835          AC_MSG_NOTICE([*** including --without-postgres])
836          exit 1
837       fi
838    fi
839 fi
840
841 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
842
843 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
844
845 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
846
847 if test "${USE_PWLIB}" != "no"; then
848         if test -n "${PWLIB_DIR}"; then
849                 PWLIBDIR="${PWLIB_DIR}"
850         fi
851         AST_CHECK_PWLIB()
852         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
853                 
854         if test "${HAS_PWLIB:-unset}" != "unset"; then
855                 AST_CHECK_OPENH323_PLATFORM()
856
857                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
858
859                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
860                         [Define if your system has the PWLib libraries.],
861                         [#include "ptlib.h"],
862                         [BOOL q = PTime::IsDaylightSavings();])
863         fi
864 fi
865
866 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
867         if test -n "${OPENH323_DIR}"; then
868                 OPENH323DIR="${OPENH323_DIR}"
869         fi
870         AST_CHECK_OPENH323()
871         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
872         AST_CHECK_OPENH323_BUILD()
873         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
874         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
875                 [Define if your system has the OpenH323 libraries.],
876                 [#include "ptlib.h"
877                 #include "h323.h"
878                 #include "h323ep.h"],
879                 [H323EndPoint ep = H323EndPoint();],
880                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
881 fi
882
883 AC_LANG_PUSH(C++)
884
885 if test "${USE_QT}" != "no"; then
886    AC_MSG_CHECKING(for QDate in -lqt)
887    saved_libs="${LIBS}"
888    saved_cppflags="${CPPFLAGS}"
889    if test "x${QT_DIR}" != "x"; then
890       LIBS="${LIBS} -L${QT_DIR}/lib"
891       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
892    fi
893    LIBS="${LIBS} -lqt"
894    qtlib="qt"
895    AC_LINK_IFELSE(
896         [
897                 AC_LANG_PROGRAM(
898                 [#include <qt3/qdatetime.h>],
899                 [QDate date();])
900         ],
901         [ac_cv_lib_qt_qt_date="yes"],
902         [ac_cv_lib_qt_qt_date="no"])
903    LIBS="${saved_libs}"
904    CPPFLAGS="${saved_cppflags}"
905         
906    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
907       saved_libs="${LIBS}"
908       saved_cppflags="${CPPFLAGS}"
909       if test "x${QT_DIR}" != "x"; then
910          LIBS="${LIBS} -L${QT_DIR}/lib"
911          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
912       fi
913       LIBS="${LIBS} -lqt-mt"
914       qtlib="qt-mt"     
915       AC_LINK_IFELSE(
916                 [
917                         AC_LANG_PROGRAM(
918                         [#include <qt3/qdatetime.h>],
919                         [QDate date();])
920                 ],
921                 [ac_cv_lib_qt_qt_date="yes"],
922                 [ac_cv_lib_qt_qt_date="no"])
923       LIBS="${saved_libs}"
924       CPPFLAGS="${saved_cppflags}"
925    fi   
926
927    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
928       AC_MSG_RESULT(yes) 
929    else
930       AC_MSG_RESULT(no) 
931    fi
932         
933    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
934       QT_LIB="-l${qtlib}"
935       if test "${QT_DIR}" != ""; then
936          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
937          QT_INCLUDE="-I${QT_DIR}/include"
938       fi
939       PBX_QT=1
940       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
941       AC_PATH_TOOL(QTMOC, moc, No)
942    fi
943 fi
944
945 AC_LANG_POP
946
947 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
948
949 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
950
951 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
952
953 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
954
955 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
956
957 if test "$PBX_CRYPTO" = "1";
958 then
959     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
960 fi
961
962 if test "$PBX_OPENSSL" = "1";
963 then
964     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
965 fi
966
967 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
968 if test "${PBX_FREETDS}" != "0";
969 then
970     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
971         *0.64*)
972                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
973         ;;
974     *0.63*)
975         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
976         ;;
977     *0.62*)
978         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
979         ;;
980     *)
981         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
982         ;;
983     esac
984 fi
985
986 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
987
988 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
989
990 if test "${host_os}" != "linux-gnu" ; then
991   tonezone_extra="-lm"
992 fi
993
994 # new tonezone, version 1.4.0
995 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
996 # other case, old tonezone (0.80)
997 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
998
999 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1000
1001 AC_LANG_PUSH(C++)
1002
1003 if test "${USE_VPB}" != "no"; then
1004    AC_MSG_CHECKING(for vpb_open in -lvpb)
1005    saved_libs="${LIBS}"
1006    saved_cppflags="${CPPFLAGS}"
1007    if test "x${VPB_DIR}" != "x"; then
1008       if test -d ${VPB_DIR}/lib; then
1009          vpblibdir=${VPB_DIR}/lib
1010       else
1011          vpblibdir=${VPB_DIR}
1012       fi
1013       LIBS="${LIBS} -L${vpblibdir}"
1014       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1015    fi
1016    LIBS="${LIBS} -lvpb -lpthread"
1017    AC_LINK_IFELSE(
1018         [
1019         AC_LANG_PROGRAM(
1020         [#include <vpbapi.h>],
1021         [int q = vpb_open(0,0);])
1022         ],
1023         [       AC_MSG_RESULT(yes) 
1024                 ac_cv_lib_vpb_vpb_open="yes" 
1025         ],
1026         [       AC_MSG_RESULT(no) 
1027                 ac_cv_lib_vpb_vpb_open="no" 
1028         ]
1029         )
1030    LIBS="${saved_libs}"
1031    CPPFLAGS="${saved_cppflags}"
1032    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1033         VPB_LIB="-lvpb"
1034         if test "${VPB_DIR}" != ""; then
1035            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1036            VPB_INCLUDE="-I${VPB_DIR}/include"
1037         fi
1038         PBX_VPB=1
1039         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1040    fi
1041 fi
1042
1043 AC_LANG_POP
1044
1045 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1046
1047 # Check for various zaptel features and locations.
1048 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1049 # will be used in the system headers to determine the location
1050 # of the zaptel.h header.
1051
1052 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1053 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1054
1055 # Check for VLDTMF support
1056 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1057
1058 # Check for transcode support
1059 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1060
1061 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1062 case "${host_os}" in
1063     freebsd*)
1064         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1065         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1066         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1067
1068         # other case, old tonezone (0.80)
1069         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1070         ;;
1071 esac
1072
1073 EDITLINE_LIB=""
1074 if test "x$TERMCAP_LIB" != "x" ; then
1075   EDITLINE_LIB="$TERMCAP_LIB"
1076 elif test "x$TINFO_LIB" != "x" ; then
1077   EDITLINE_LIB="$TINFO_LIB"
1078 elif test "x$CURSES_LIB" != "x" ; then
1079   EDITLINE_LIB="$CURSES_LIB"
1080 elif test "x$NCURSES_LIB" != "x" ; then
1081   EDITLINE_LIB="$NCURSES_LIB"
1082 else
1083   AC_MSG_ERROR(*** termcap support not found)
1084 fi
1085 AC_SUBST(EDITLINE_LIB)
1086
1087 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1088 AC_SUBST(PBX_H323)
1089
1090 AC_CHECK_HEADER([linux/compiler.h],
1091                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1092
1093 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1094                                    #include <linux/version.h>
1095                                    #ifdef HAVE_LINUX_COMPILER_H
1096                                    #include <linux/compiler.h>
1097                                    #endif
1098                                    ])
1099 AC_SUBST(PBX_IXJUSER)
1100
1101 PBX_GTK=0
1102 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1103 if test ! "x${GTKCONFIG}" = xNo; then
1104    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1105    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1106    PBX_GTK=1
1107    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1108 fi
1109 AC_SUBST(PBX_GTK)
1110 AC_SUBST(GTK_INCLUDE)
1111 AC_SUBST(GTK_LIB)
1112
1113 PBX_GTK2=0
1114 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1115 if test ! "x${PKGCONFIG}" = xNo; then
1116    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1117    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1118    PBX_GTK2=1
1119    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1120 fi
1121 AC_SUBST(PBX_GTK2)
1122 AC_SUBST(GTK2_INCLUDE)
1123 AC_SUBST(GTK2_LIB)
1124
1125 if test "${USE_CURL}" != "no"; then
1126    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1127    if test ! x"${CURL_CONFIG}" = xNo; then
1128    # check for version
1129       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1130          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1131          CURL_LIB=$(${CURL_CONFIG} --libs)
1132
1133          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1134          saved_cppflags="${CPPFLAGS}"
1135          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1136          AC_COMPILE_IFELSE(
1137             [AC_LANG_PROGRAM(
1138                 [#include <curl/curl.h>],
1139                     [curl_version();])
1140             ],[
1141                 AC_MSG_RESULT(yes)
1142                 ac_cv_curl_h="yes"
1143             ],[
1144                 AC_MSG_RESULT(no)
1145                 ac_cv_curl_h="no"
1146             ]
1147          )
1148          CPPFLAGS="${saved_cppflags}"
1149          if test "${ac_cv_curl_h}" = "yes"; then
1150              PBX_CURL=1
1151              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1152          fi
1153       fi
1154    fi
1155 fi
1156
1157 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1158 AST_CHECK_MANDATORY
1159
1160 AC_OUTPUT
1161
1162 if test "x${silent}" != "xyes" ; then
1163 echo
1164 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1165 echo "            .\$7\$7..          .7\$\$7:.    "
1166 echo "          .\$\$:.                 ,\$7.7   "
1167 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1168 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1169 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1170 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1171 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1172 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1173 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1174 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1175 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1176 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1177 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1178 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1179 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1180 echo " \$\$\$\$\$                        \$\$\$       "
1181 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1182 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1183 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1184 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1185 echo
1186 fi
1187
1188 AC_MSG_NOTICE(Package configured for: )
1189 AC_MSG_NOTICE( OS type  : $host_os)
1190 AC_MSG_NOTICE( Host CPU : $host_cpu)
1191 if test "${cross_compiling}" = "yes"; then
1192    AC_MSG_NOTICE( Cross Compilation = YES)
1193 fi