Restore EXP2 and LOG2 functions, by providing mathematical identify functions, when...
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_CHECK_FUNCS([gethostbyname_r])
288
289 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
290 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
291
292 AC_MSG_CHECKING(for compiler atomic operations)
293 AC_LINK_IFELSE(
294 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
295 AC_MSG_RESULT(yes)
296 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
297 AC_MSG_RESULT(no)
298 )
299
300 AST_GCC_ATTRIBUTE(pure)
301 AST_GCC_ATTRIBUTE(malloc)
302 AST_GCC_ATTRIBUTE(const)
303 AST_GCC_ATTRIBUTE(unused)
304 AST_GCC_ATTRIBUTE(always_inline)
305
306 AC_MSG_CHECKING(for -ffunction-sections support)
307 saved_CFLAGS="${CFLAGS}"
308 CFLAGS="${CFLAGS} -ffunction-sections"
309 AC_COMPILE_IFELSE(
310         AC_LANG_PROGRAM([], [int x = 1;]),
311         AC_MSG_RESULT(yes)
312         [saved_LDFLAGS="${LDFLAGS}"]
313         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
314         AC_MSG_CHECKING(for --gc-sections support)
315         AC_LINK_IFELSE(
316                 AC_LANG_PROGRAM([], [int x = 1;]),
317                 AC_MSG_RESULT(yes)
318                 [GC_CFLAGS="-ffunction-sections"]
319                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
320                 AC_MSG_RESULT(no)
321         )
322         [LDFLAGS="${saved_LDFLAGS}"],
323         AC_MSG_RESULT(no)
324 )
325 CFLAGS="${saved_CFLAGS}"
326 AC_SUBST(GC_CFLAGS)
327 AC_SUBST(GC_LDFLAGS)
328
329 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
330 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
331         AC_MSG_RESULT(yes)
332         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
333 else
334         AC_MSG_RESULT(no)
335         AST_DECLARATION_AFTER_STATEMENT=
336 fi
337 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
338
339
340 AC_MSG_CHECKING(for sysinfo)
341 AC_LINK_IFELSE(
342         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
343                         [struct sysinfo sys_info;]),
344         AC_MSG_RESULT(yes)
345         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
346         AC_MSG_RESULT(no)
347 )
348
349 AC_MSG_CHECKING(for res_ninit)
350 AC_LINK_IFELSE(
351         AC_LANG_PROGRAM([#include <resolv.h>],
352                         [int foo = res_ninit(NULL);]),
353         AC_MSG_RESULT(yes)
354         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
355         AC_MSG_RESULT(no)
356 )
357
358 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
359
360 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
361
362 AC_CHECK_HEADER([libkern/OSAtomic.h],
363                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
364
365 AC_CHECK_SIZEOF(int)
366
367 # do the package library checks now
368
369 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
370
371 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
372
373 if test "x${host_os}" = "xlinux-gnu" ; then
374   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
375 fi
376
377 # BSD might not have exp2, and/or log2
378 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
379 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
380 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
381 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
382 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
383 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
384 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
385 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
386
387 GSM_INTERNAL="yes"
388 AC_SUBST(GSM_INTERNAL)
389 GSM_SYSTEM="yes"
390 if test "${USE_GSM}" != "no"; then
391    if test "${GSM_DIR}" = "internal"; then
392       GSM_SYSTEM="no"
393    elif test "${GSM_DIR}" != ""; then
394       GSM_INTERNAL="no"
395    fi
396    if test "${GSM_SYSTEM}" = "yes"; then
397       gsmlibdir=""
398       if test "x${GSM_DIR}" != "x"; then
399          if test -d ${GSM_DIR}/lib; then
400             gsmlibdir="-L${GSM_DIR}/lib"
401          else
402             gsmlibdir="-L${GSM_DIR}"
403          fi
404       fi
405       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
406       [Define to indicate the GSM library]), [], ${gsmlibdir})
407       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
408          if test "x${GSM_DIR}" != "x" ; then
409             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
410             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
411          else
412             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
413             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
414          fi
415          if test "${GSM_HEADER_FOUND}" = "0" ; then
416             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
417                if test "x${GSM_MANDATORY}" = "xyes" ; then
418                   AC_MSG_NOTICE([***])
419                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
420                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
421                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
422                   exit 1
423                fi
424             fi
425          fi
426          GSM_OK=0
427          if test "${GSM_HEADER_FOUND}" = "1" ; then
428             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
429             GSM_OK=1
430          else
431             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
432                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
433                GSM_OK=1
434             fi
435          fi
436          if test "${GSM_OK}" = "1" ; then
437             GSM_LIB="-lgsm"
438             if test "x${GSM_DIR}" != "x"; then
439                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
440                GSM_INCLUDE="-I${GSM_DIR}/include"
441             fi
442             PBX_GSM=1
443             GSM_INTERNAL="no"
444          fi
445       fi
446    fi
447    if test "${GSM_INTERNAL}" = "yes"; then
448       PBX_GSM=1
449       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
450    fi
451 fi
452
453 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
454
455 if test "${PBX_IKSEMEL}" = 1; then
456    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
457 fi
458
459 if test "${USE_IMAP_TK}" != "no"; then
460    if test "${IMAP_TK_DIR}" = "system" ; then
461       AC_MSG_NOTICE([Checking for system c-client library...])
462    elif test "${IMAP_TK_DIR}" = ""; then
463       IMAP_TK_DIR=`pwd`"/../imap-2004g"
464       if test  -n "${IMAP_TK_MANDATORY}"; then
465          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
466          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
467          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
468          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
469       fi
470    fi
471    if test "${IMAP_TK_DIR}" != "system" ; then
472       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
473    fi
474    saved_cppflags="${CPPFLAGS}"
475    saved_libs="${LIBS}"
476    if test "${IMAP_TK_DIR}" = "system" ; then
477       imap_ldflags=""
478       imap_libs="-lc-client"
479       imap_include="-DUSE_SYSTEM_IMAP"
480    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
481       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
482       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
483       imap_include="-I${IMAP_TK_DIR}/c-client"
484    fi
485    CPPFLAGS="${CPPFLAGS} ${imap_include}"
486    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
487    AC_LINK_IFELSE(
488         AC_LANG_PROGRAM(
489                 [#ifdef USE_SYSTEM_IMAP
490                 #include <imap/c-client.h>
491                 #else
492                 #include "c-client.h"
493                 #endif
494                 void mm_searched (MAILSTREAM *stream,unsigned long number)
495                 {
496                 }
497                 void mm_exists (MAILSTREAM *stream,unsigned long number)
498                 {
499                 }
500                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
501                 {
502                 }
503                 void mm_flags (MAILSTREAM *stream,unsigned long number)
504                 {
505                 }
506                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
507                 {
508                 }
509                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
510                 {
511                 }
512                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
513                 {
514                 }
515                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
516                 {
517                 }
518                 void mm_log (char *string,long errflg)
519                 {
520                 }
521                 void mm_dlog (char *string)
522                 {
523                 }
524                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
525                 {
526                 }
527                 void mm_critical (MAILSTREAM *stream)
528                 {
529                 }
530                 void mm_nocritical (MAILSTREAM *stream)
531                 {
532                 }
533                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
534                 {
535                 }
536                 void mm_fatal (char *string)
537                 {
538                 }],
539                 [
540                 MAILSTREAM *foo = mail_open(NULL, "", 0);
541                 ]
542         ),
543         [ac_cv_imap_tk="yes"],
544         [ac_cv_imap_tk="no"]
545    )
546    if test "${ac_cv_imap_tk}" = "yes"; then
547    AC_LINK_IFELSE(
548       AC_LANG_PROGRAM(
549          [#ifdef USE_SYSTEM_IMAP
550          #include <imap/c-client.h>
551          #else
552          #include "c-client.h"
553          #endif
554          void mm_searched (MAILSTREAM *stream,unsigned long number)
555          {
556          }
557          void mm_exists (MAILSTREAM *stream,unsigned long number)
558          {
559          }
560          void mm_expunged (MAILSTREAM *stream,unsigned long number)
561          {
562          }
563          void mm_flags (MAILSTREAM *stream,unsigned long number)
564          {
565          }
566          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
567          {
568          }
569          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
570          {
571          }
572          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
573          {
574          }
575          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
576          {
577          }
578          void mm_log (char *string,long errflg)
579          {
580          }
581          void mm_dlog (char *string)
582          {
583          }
584          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
585          {
586          }
587          void mm_critical (MAILSTREAM *stream)
588          {
589          }
590          void mm_nocritical (MAILSTREAM *stream)
591          {
592          }
593          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
594          {
595          }
596          void mm_fatal (char *string)
597          {
598          }],
599          [
600          long check = mail_expunge_full(NULL, "", 0);
601          ]
602       ),
603       [ac_cv_imap_tk2006="yes"],
604       [ac_cv_imap_tk2006="no"]
605   )
606   fi
607    CPPFLAGS="${saved_cppflags}"
608    LIBS="${saved_libs}"
609    if test "${ac_cv_imap_tk}" = "yes"; then
610       AC_MSG_RESULT(yes) 
611       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
612       IMAP_TK_INCLUDE="${imap_include}"
613       PBX_IMAP_TK=1
614       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
615       if test "${ac_cv_imap_tk2006}" = "yes"; then
616          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
617       fi
618    else
619       AC_MSG_RESULT(no) 
620    fi
621 fi
622
623 # Needed by unixodbc
624 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
625
626 AC_LANG_PUSH(C++)
627
628 if test "${USE_KDE}" != "no"; then
629    AC_MSG_CHECKING(for crashHandler in -lkdecore)
630    saved_libs="${LIBS}"
631    saved_cppflags="${CPPFLAGS}"
632    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
633    if test -d ${KDE_DIR}/lib; then
634       kdelibdir="${KDE_DIR}/lib"
635    else
636       kdelibdir="${KDE_DIR}"
637    fi
638    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
639
640    AC_LINK_IFELSE(
641         [AC_LANG_PROGRAM(
642                         [#include "kcrash.h"],
643                         [KCrash::defaultCrashHandler(1);])
644         ],
645         [ac_cv_lib_kde_crash="yes"],
646         [ac_cv_lib_kde_crash="no"])
647                 
648    LIBS="${saved_libs}"
649    CPPFLAGS="${saved_cppflags}"
650         
651    if test "${ac_cv_lib_kde_crash}" = "yes"; then
652       AC_MSG_RESULT(yes) 
653       KDE_LIB="-lkdecore -lkdeui"
654       if test "${KDE_DIR}" != ""; then
655          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
656          KDE_INCLUDE="-I${KDE_DIR}/include"
657       fi
658       PBX_KDE=1
659       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
660    else
661       AC_MSG_RESULT(no) 
662    fi
663 fi
664 if test "${PBX_KDE}" = 1; then
665    AC_PATH_TOOL(KDEINIT, kdeinit, No)
666    if test ! x"${KDEINIT}" = xNo; then
667       KDEDIR=$(${DIRNAME} ${KDEINIT})
668       KDEDIR=$(${DIRNAME} ${KDEDIR})
669    fi
670    AC_SUBST([KDEDIR])
671 fi
672
673 AC_LANG_POP
674
675 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
676
677 if test "${PBX_MISDN}" = 1; then
678    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
679    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
680    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
681 fi
682
683 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
684
685 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
686
687 NETSNMP_CONFIG=No
688 if test "${USE_NETSNMP}" != "no"; then  
689    if test "x${NETSNMP_DIR}" != "x"; then
690       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
691       if test x"${NETSNMP_CONFIG}" = xNo; then
692          AC_MSG_NOTICE([***])
693          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
694          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
695          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
696          AC_MSG_NOTICE([*** including --without-netsnmp])
697          exit 1
698       fi
699    else
700       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
701    fi
702 fi
703 if test x"${NETSNMP_CONFIG}" != xNo; then
704    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
705    
706    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
707    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
708
709    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
710       NETSNMP_LIB="${NETSNMP_libs}"
711       PBX_NETSNMP=1
712    fi
713 fi
714
715 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
716
717 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
718
719 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
720
721 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
722
723 # possible places for oss definitions
724 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
725 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
726 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
727
728 PG_CONFIG=No
729 if test "${USE_PGSQL}" != "no"; then    
730    if test "x${PGSQL_DIR}" != "x"; then
731       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
732       if test x"${PG_CONFIG}" = xNo; then
733          AC_MSG_NOTICE([***])
734          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
735          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
736          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
737          AC_MSG_NOTICE([*** including --without-postgres])
738          exit 1
739       fi
740    else
741       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
742    fi
743 fi
744 if test "${PG_CONFIG}" != No; then
745    PGSQL_libdir=`${PG_CONFIG} --libdir`
746    PGSQL_includedir=`${PG_CONFIG} --includedir`
747    if test "x$?" != "x0" ; then
748       if test -n "${PGSQL_MANDATORY}" ; then
749          AC_MSG_NOTICE([***])
750          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
751          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
752          AC_MSG_NOTICE([*** including --without-postgres])
753          exit 1
754           fi
755    else 
756       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
757       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
758
759       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
760          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
761          PGSQL_INCLUDE="-I${PGSQL_includedir}"
762          PBX_PGSQL=1
763       elif test -n "${PGSQL_MANDATORY}";
764       then
765          AC_MSG_NOTICE([***])
766          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
767          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
768          AC_MSG_NOTICE([*** including --without-postgres])
769          exit 1
770       fi
771    fi
772 fi
773
774 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
775
776 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
777
778 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
779
780 if test "${USE_PWLIB}" != "no"; then
781         if test -n "${PWLIB_DIR}"; then
782                 PWLIBDIR="${PWLIB_DIR}"
783         fi
784         AST_CHECK_PWLIB()
785         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
786                 
787         if test "${HAS_PWLIB:-unset}" != "unset"; then
788                 AST_CHECK_OPENH323_PLATFORM()
789
790                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
791
792                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
793                         [Define if your system has the PWLib libraries.],
794                         [#include "ptlib.h"],
795                         [BOOL q = PTime::IsDaylightSavings();])
796         fi
797 fi
798
799 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
800         if test -n "${OPENH323_DIR}"; then
801                 OPENH323DIR="${OPENH323_DIR}"
802         fi
803         AST_CHECK_OPENH323()
804         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
805         AST_CHECK_OPENH323_BUILD()
806         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
807         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
808                 [Define if your system has the OpenH323 libraries.],
809                 [#include "ptlib.h"
810                 #include "h323.h"
811                 #include "h323ep.h"],
812                 [H323EndPoint ep = H323EndPoint();],
813                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
814 fi
815
816 AC_LANG_PUSH(C++)
817
818 if test "${USE_QT}" != "no"; then
819    AC_MSG_CHECKING(for QDate in -lqt)
820    saved_libs="${LIBS}"
821    saved_cppflags="${CPPFLAGS}"
822    if test "x${QT_DIR}" != "x"; then
823       LIBS="${LIBS} -L${QT_DIR}/lib"
824       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
825    fi
826    LIBS="${LIBS} -lqt"
827    qtlib="qt"
828    AC_LINK_IFELSE(
829         [
830                 AC_LANG_PROGRAM(
831                 [#include <qt3/qdatetime.h>],
832                 [QDate date();])
833         ],
834         [ac_cv_lib_qt_qt_date="yes"],
835         [ac_cv_lib_qt_qt_date="no"])
836    LIBS="${saved_libs}"
837    CPPFLAGS="${saved_cppflags}"
838         
839    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
840       saved_libs="${LIBS}"
841       saved_cppflags="${CPPFLAGS}"
842       if test "x${QT_DIR}" != "x"; then
843          LIBS="${LIBS} -L${QT_DIR}/lib"
844          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
845       fi
846       LIBS="${LIBS} -lqt-mt"
847       qtlib="qt-mt"     
848       AC_LINK_IFELSE(
849                 [
850                         AC_LANG_PROGRAM(
851                         [#include <qt3/qdatetime.h>],
852                         [QDate date();])
853                 ],
854                 [ac_cv_lib_qt_qt_date="yes"],
855                 [ac_cv_lib_qt_qt_date="no"])
856       LIBS="${saved_libs}"
857       CPPFLAGS="${saved_cppflags}"
858    fi   
859
860    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
861       AC_MSG_RESULT(yes) 
862    else
863       AC_MSG_RESULT(no) 
864    fi
865         
866    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
867       QT_LIB="-l${qtlib}"
868       if test "${QT_DIR}" != ""; then
869          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
870          QT_INCLUDE="-I${QT_DIR}/include"
871       fi
872       PBX_QT=1
873       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
874       AC_PATH_TOOL(QTMOC, moc, No)
875    fi
876 fi
877
878 AC_LANG_POP
879
880 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
881
882 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
883
884 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
885
886 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
887
888 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
889
890 if test "$PBX_CRYPTO" = "1";
891 then
892     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
893 fi
894
895 if test "$PBX_OPENSSL" = "1";
896 then
897     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
898 fi
899
900 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
901 if test "${PBX_FREETDS}" != "0";
902 then
903     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
904         *0.64*)
905                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
906         ;;
907     *0.63*)
908         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
909         ;;
910     *0.62*)
911         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
912         ;;
913     *)
914         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
915         ;;
916     esac
917 fi
918
919 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
920
921 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
922
923 if test "${host_os}" != "linux-gnu" ; then
924   tonezone_extra="-lm"
925 fi
926
927 # new tonezone, version 1.4.0
928 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
929 # other case, old tonezone (0.80)
930 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
931
932 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
933
934 AC_LANG_PUSH(C++)
935
936 if test "${USE_VPB}" != "no"; then
937    AC_MSG_CHECKING(for vpb_open in -lvpb)
938    saved_libs="${LIBS}"
939    saved_cppflags="${CPPFLAGS}"
940    if test "x${VPB_DIR}" != "x"; then
941       if test -d ${VPB_DIR}/lib; then
942          vpblibdir=${VPB_DIR}/lib
943       else
944          vpblibdir=${VPB_DIR}
945       fi
946       LIBS="${LIBS} -L${vpblibdir}"
947       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
948    fi
949    LIBS="${LIBS} -lvpb -lpthread"
950    AC_LINK_IFELSE(
951         [
952         AC_LANG_PROGRAM(
953         [#include <vpbapi.h>],
954         [int q = vpb_open(0,0);])
955         ],
956         [       AC_MSG_RESULT(yes) 
957                 ac_cv_lib_vpb_vpb_open="yes" 
958         ],
959         [       AC_MSG_RESULT(no) 
960                 ac_cv_lib_vpb_vpb_open="no" 
961         ]
962         )
963    LIBS="${saved_libs}"
964    CPPFLAGS="${saved_cppflags}"
965    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
966         VPB_LIB="-lvpb"
967         if test "${VPB_DIR}" != ""; then
968            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
969            VPB_INCLUDE="-I${VPB_DIR}/include"
970         fi
971         PBX_VPB=1
972         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
973    fi
974 fi
975
976 AC_LANG_POP
977
978 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
979
980 # Check for various zaptel features and locations.
981 # The version number, which goes into HAVE_ZAPTEL_VERSION,
982 # will be used in the system headers to determine the location
983 # of the zaptel.h header.
984
985 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
986 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
987
988 # Check for VLDTMF support
989 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
990
991 # Check for transcode support
992 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
993
994 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
995 case "${host_os}" in
996     freebsd*)
997         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
998         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
999         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1000
1001         # other case, old tonezone (0.80)
1002         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1003         ;;
1004 esac
1005
1006 EDITLINE_LIB=""
1007 if test "x$TERMCAP_LIB" != "x" ; then
1008   EDITLINE_LIB="$TERMCAP_LIB"
1009 elif test "x$TINFO_LIB" != "x" ; then
1010   EDITLINE_LIB="$TINFO_LIB"
1011 elif test "x$CURSES_LIB" != "x" ; then
1012   EDITLINE_LIB="$CURSES_LIB"
1013 elif test "x$NCURSES_LIB" != "x" ; then
1014   EDITLINE_LIB="$NCURSES_LIB"
1015 else
1016   AC_MSG_ERROR(*** termcap support not found)
1017 fi
1018 AC_SUBST(EDITLINE_LIB)
1019
1020 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1021 AC_SUBST(PBX_H323)
1022
1023 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1024                                    #include <linux/version.h>
1025                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
1026                                    #include <linux/compiler.h>
1027                                    #endif
1028                                    ])
1029 AC_SUBST(PBX_IXJUSER)
1030
1031 PBX_GTK=0
1032 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1033 if test ! "x${GTKCONFIG}" = xNo; then
1034    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1035    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1036    PBX_GTK=1
1037    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1038 fi
1039 AC_SUBST(PBX_GTK)
1040 AC_SUBST(GTK_INCLUDE)
1041 AC_SUBST(GTK_LIB)
1042
1043 PBX_GTK2=0
1044 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1045 if test ! "x${PKGCONFIG}" = xNo; then
1046    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1047    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1048    PBX_GTK2=1
1049    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1050 fi
1051 AC_SUBST(PBX_GTK2)
1052 AC_SUBST(GTK2_INCLUDE)
1053 AC_SUBST(GTK2_LIB)
1054
1055 if test "${USE_CURL}" != "no"; then
1056    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1057    if test ! x"${CURL_CONFIG}" = xNo; then
1058    # check for version
1059       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1060          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1061          CURL_LIB=$(${CURL_CONFIG} --libs)
1062
1063          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1064          saved_cppflags="${CPPFLAGS}"
1065          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1066          AC_COMPILE_IFELSE(
1067             [AC_LANG_PROGRAM(
1068                 [#include <curl/curl.h>],
1069                     [curl_version();])
1070             ],[
1071                 AC_MSG_RESULT(yes)
1072                 ac_cv_curl_h="yes"
1073             ],[
1074                 AC_MSG_RESULT(no)
1075                 ac_cv_curl_h="no"
1076             ]
1077          )
1078          CPPFLAGS="${saved_cppflags}"
1079          if test "${ac_cv_curl_h}" = "yes"; then
1080              PBX_CURL=1
1081              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1082          fi
1083       fi
1084    fi
1085 fi
1086
1087 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1088 AST_CHECK_MANDATORY
1089
1090 AC_OUTPUT
1091
1092 if test "x${silent}" != "xyes" ; then
1093 echo
1094 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1095 echo "            .\$7\$7..          .7\$\$7:.    "
1096 echo "          .\$\$:.                 ,\$7.7   "
1097 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1098 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1099 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1100 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1101 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1102 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1103 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1104 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1105 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1106 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1107 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1108 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1109 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1110 echo " \$\$\$\$\$                        \$\$\$       "
1111 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1112 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1113 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1114 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1115 echo
1116 fi
1117
1118 AC_MSG_NOTICE(Package configured for: )
1119 AC_MSG_NOTICE( OS type  : $host_os)
1120 AC_MSG_NOTICE( Host CPU : $host_cpu)
1121 if test "${cross_compiling}" = "yes"; then
1122    AC_MSG_NOTICE( Cross Compilation = YES)
1123 fi