removed GAIN preprocessor definition, removed needsgain from struct wav_desc, removed...
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121    AC_CHECK_TOOL(AR, ar, :)
122 fi
123
124 # Checks for programs.
125 AC_PROG_CC
126 AC_PROG_CXX
127 AC_PROG_CPP
128 AC_PROG_CXXCPP
129 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
130 # the developers regenerating the configure script don't have to install libtool.
131 AST_PROG_LD     # note, does not work on FreeBSD
132 AC_PROG_AWK
133 AC_PROG_INSTALL
134 AC_PROG_LN_S
135 AC_PROG_RANLIB
136 AST_CHECK_GNU_MAKE
137
138 GNU_LD=0
139 if test "x$with_gnu_ld" = "xyes" ; then
140    GNU_LD=1
141 fi
142 AC_SUBST(GNU_LD)
143
144 AC_PATH_PROG([GREP], [grep], :)
145 AC_PATH_PROG([AR], [ar], :)
146 AC_PATH_PROG([FIND], [find], :)
147 AC_PATH_PROG([COMPRESS], [compress], :)
148 AC_PATH_PROG([BASENAME], [basename], :)
149 AC_PATH_PROG([ID], [id], :)
150 AC_PATH_PROG([DIRNAME], [dirname], :)
151 AC_PATH_PROG([SHELL], [sh], :)
152 AC_PATH_PROG([LN], [ln], :)
153 AC_PATH_PROG([DOT], [dot], :)
154 AC_PATH_PROG([STRIP], [strip], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
190 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
191 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
192 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
193 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
194 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
195 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
196 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
197 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
198 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
199 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
200 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
201 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
202 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
203 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
204 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
205 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
206 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
207 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
208 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
209 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
210 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
211 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
212 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
213 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
214 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
215 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
216 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL], [ssl])
217 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
218 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
219 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
220 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
221 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
222 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
223 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
224 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
225 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
226 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
227
228 # check for basic system features and functionality before
229 # checking for package libraries
230
231 AC_FUNC_ALLOCA
232 AC_HEADER_DIRENT
233 AC_HEADER_STDC
234 AC_HEADER_SYS_WAIT
235 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
236
237 AC_SYS_LARGEFILE
238
239 # Checks for typedefs, structures, and compiler characteristics.
240 AC_HEADER_STDBOOL
241 AC_C_CONST
242 AC_TYPE_UID_T
243 AC_C_INLINE
244 AC_TYPE_MODE_T
245 AC_TYPE_OFF_T
246 AC_TYPE_PID_T
247 AC_TYPE_SIZE_T
248 AC_CHECK_MEMBERS([struct stat.st_blksize])
249 AC_HEADER_TIME
250 AC_STRUCT_TM
251 AC_C_VOLATILE
252 AC_CHECK_TYPES([ptrdiff_t])
253
254 # Checks for library functions.
255 AC_FUNC_CHOWN
256 AC_FUNC_CLOSEDIR_VOID
257 AC_FUNC_ERROR_AT_LINE
258 AST_FUNC_FORK
259 AC_FUNC_FSEEKO
260 AC_PROG_GCC_TRADITIONAL
261 # XXX: these are commented out until we determine whether it matters if our malloc()
262 # acts exactly like glibc's or not
263 # AC_FUNC_MALLOC
264 # AC_FUNC_REALLOC
265 AC_FUNC_MEMCMP
266 AC_FUNC_MKTIME
267 AC_FUNC_MMAP
268 AC_FUNC_SELECT_ARGTYPES
269 AC_FUNC_SETVBUF_REVERSED
270 AC_TYPE_SIGNAL
271 AC_FUNC_STAT
272 AC_FUNC_STRCOLL
273 AC_FUNC_STRFTIME
274 AC_FUNC_STRNLEN
275 AC_FUNC_STRTOD
276 AC_FUNC_UTIME_NULL
277 AC_FUNC_VPRINTF
278 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
279
280 # https support (in main/http.c) uses funopen on BSD systems,
281 # fopencookie on linux
282 AC_CHECK_FUNCS([funopen fopencookie])
283
284 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
285 AC_CHECK_FUNCS([gethostbyname_r])
286
287 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
288 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
289
290 AC_MSG_CHECKING(for compiler atomic operations)
291 AC_LINK_IFELSE(
292 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
293 AC_MSG_RESULT(yes)
294 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
295 AC_MSG_RESULT(no)
296 )
297
298 AST_GCC_ATTRIBUTE(pure)
299 AST_GCC_ATTRIBUTE(malloc)
300 AST_GCC_ATTRIBUTE(const)
301 AST_GCC_ATTRIBUTE(unused)
302 AST_GCC_ATTRIBUTE(always_inline)
303
304 AC_MSG_CHECKING(for -ffunction-sections support)
305 saved_CFLAGS="${CFLAGS}"
306 CFLAGS="${CFLAGS} -ffunction-sections"
307 AC_COMPILE_IFELSE(
308         AC_LANG_PROGRAM([], [int x = 1;]),
309         AC_MSG_RESULT(yes)
310         [saved_LDFLAGS="${LDFLAGS}"]
311         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
312         AC_MSG_CHECKING(for --gc-sections support)
313         AC_LINK_IFELSE(
314                 AC_LANG_PROGRAM([], [int x = 1;]),
315                 AC_MSG_RESULT(yes)
316                 [GC_CFLAGS="-ffunction-sections"]
317                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
318                 AC_MSG_RESULT(no)
319         )
320         [LDFLAGS="${saved_LDFLAGS}"],
321         AC_MSG_RESULT(no)
322 )
323 CFLAGS="${saved_CFLAGS}"
324 AC_SUBST(GC_CFLAGS)
325 AC_SUBST(GC_LDFLAGS)
326
327 AC_MSG_CHECKING(for res_ninit)
328 AC_LINK_IFELSE(
329         AC_LANG_PROGRAM([#include <resolv.h>],
330                         [int foo = res_ninit(NULL);]),
331         AC_MSG_RESULT(yes)
332         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
333         AC_MSG_RESULT(no)
334 )
335
336 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
337
338 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
339
340 AC_CHECK_HEADER([libkern/OSAtomic.h],
341                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
342
343 AC_CHECK_SIZEOF(int)
344
345 # do the package library checks now
346
347 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
348
349 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
350
351 if test "x${host_os}" = "xlinux-gnu" ; then
352   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
353 fi
354
355 GSM_INTERNAL="yes"
356 AC_SUBST(GSM_INTERNAL)
357 GSM_SYSTEM="yes"
358 if test "${USE_GSM}" != "no"; then
359    if test "${GSM_DIR}" = "internal"; then
360       GSM_SYSTEM="no"
361    elif test "${GSM_DIR}" != ""; then
362       GSM_INTERNAL="no"
363    fi
364    if test "${GSM_SYSTEM}" = "yes"; then
365       gsmlibdir=""
366       if test "x${GSM_DIR}" != "x"; then
367          if test -d ${GSM_DIR}/lib; then
368             gsmlibdir="-L${GSM_DIR}/lib"
369          else
370             gsmlibdir="-L${GSM_DIR}"
371          fi
372       fi
373       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
374       [Define to indicate the GSM library]), [], ${gsmlibdir})
375       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
376          if test "x${GSM_DIR}" != "x" ; then
377             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
378             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
379          else
380             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
381             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
382          fi
383          if test "${GSM_HEADER_FOUND}" = "0" ; then
384             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
385                if test "x${GSM_MANDATORY}" = "xyes" ; then
386                   AC_MSG_NOTICE([***])
387                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
388                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
389                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
390                   exit 1
391                fi
392             fi
393          fi
394          GSM_OK=0
395          if test "${GSM_HEADER_FOUND}" = "1" ; then
396             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
397             GSM_OK=1
398          else
399             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
400                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
401                GSM_OK=1
402             fi
403          fi
404          if test "${GSM_OK}" = "1" ; then
405             GSM_LIB="-lgsm"
406             if test "x${GSM_DIR}" != "x"; then
407                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
408                GSM_INCLUDE="-I${GSM_DIR}/include"
409             fi
410             PBX_GSM=1
411             GSM_INTERNAL="no"
412          fi
413       fi
414    fi
415    if test "${GSM_INTERNAL}" = "yes"; then
416       PBX_GSM=1
417       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
418    fi
419 fi
420
421 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
422
423 if test "${PBX_IKSEMEL}" = 1; then
424    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye])
425    if test "${PBX_GNUTLS}" = 1; then
426       IKSEMEL_LIB="${IKSEMEL_LIB} -lgnutls -lz -lgcrypt -lgpg-error"
427    fi
428 fi
429
430 if test "${USE_IMAP_TK}" != "no"; then
431    if test "${IMAP_TK_DIR}" = ""; then
432       IMAP_TK_DIR=`pwd`"/../imap-2004g"
433       if test  -n "${IMAP_TK_MANDATORY}"; then
434          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
435          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
436          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
437          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
438       fi
439    fi
440    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
441    saved_cppflags="${CPPFLAGS}"
442    saved_libs="${LIBS}"
443    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
444       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
445    fi
446    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
447    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
448    AC_LINK_IFELSE(
449         AC_LANG_PROGRAM(
450                 [#include "c-client.h"
451                 void mm_searched (MAILSTREAM *stream,unsigned long number)
452                 {
453                 }
454                 void mm_exists (MAILSTREAM *stream,unsigned long number)
455                 {
456                 }
457                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
458                 {
459                 }
460                 void mm_flags (MAILSTREAM *stream,unsigned long number)
461                 {
462                 }
463                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
464                 {
465                 }
466                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
467                 {
468                 }
469                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
470                 {
471                 }
472                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
473                 {
474                 }
475                 void mm_log (char *string,long errflg)
476                 {
477                 }
478                 void mm_dlog (char *string)
479                 {
480                 }
481                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
482                 {
483                 }
484                 void mm_critical (MAILSTREAM *stream)
485                 {
486                 }
487                 void mm_nocritical (MAILSTREAM *stream)
488                 {
489                 }
490                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
491                 {
492                 }
493                 void mm_fatal (char *string)
494                 {
495                 }],
496                 [
497                 MAILSTREAM *foo = mail_open(NULL, "", 0);
498                 ]
499         ),
500         [ac_cv_imap_tk="yes"],
501         [ac_cv_imap_tk="no"]
502    )
503    if test "${ac_cv_imap_tk}" = "yes"; then
504    AC_LINK_IFELSE(
505       AC_LANG_PROGRAM(
506          [#include "c-client.h"
507          void mm_searched (MAILSTREAM *stream,unsigned long number)
508          {
509          }
510          void mm_exists (MAILSTREAM *stream,unsigned long number)
511          {
512          }
513          void mm_expunged (MAILSTREAM *stream,unsigned long number)
514          {
515          }
516          void mm_flags (MAILSTREAM *stream,unsigned long number)
517          {
518          }
519          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
520          {
521          }
522          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
523          {
524          }
525          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
526          {
527          }
528          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
529          {
530          }
531          void mm_log (char *string,long errflg)
532          {
533          }
534          void mm_dlog (char *string)
535          {
536          }
537          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
538          {
539          }
540          void mm_critical (MAILSTREAM *stream)
541          {
542          }
543          void mm_nocritical (MAILSTREAM *stream)
544          {
545          }
546          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
547          {
548          }
549          void mm_fatal (char *string)
550          {
551          }],
552          [
553          long check = mail_expunge_full(NULL, "", 0);
554          ]
555       ),
556       [ac_cv_imap_tk2006="yes"],
557       [ac_cv_imap_tk2006="no"]
558   )
559   fi
560    CPPFLAGS="${saved_cppflags}"
561    LIBS="${saved_libs}"
562    if test "${ac_cv_imap_tk}" = "yes"; then
563       AC_MSG_RESULT(yes) 
564       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
565       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
566       PBX_IMAP_TK=1
567       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
568       if test "${ac_cv_imap_tk2006}" = "yes"; then
569          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
570       fi
571    else
572       AC_MSG_RESULT(no) 
573    fi
574 fi
575
576 AC_LANG_PUSH(C++)
577
578 if test "${USE_KDE}" != "no"; then
579    AC_MSG_CHECKING(for crashHandler in -lkdecore)
580    saved_libs="${LIBS}"
581    saved_cppflags="${CPPFLAGS}"
582    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
583    if test -d ${KDE_DIR}/lib; then
584       kdelibdir="${KDE_DIR}/lib"
585    else
586       kdelibdir="${KDE_DIR}"
587    fi
588    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
589
590    AC_LINK_IFELSE(
591         [AC_LANG_PROGRAM(
592                         [#include "kcrash.h"],
593                         [KCrash::defaultCrashHandler(1);])
594         ],
595         [ac_cv_lib_kde_crash="yes"],
596         [ac_cv_lib_kde_crash="no"])
597                 
598    LIBS="${saved_libs}"
599    CPPFLAGS="${saved_cppflags}"
600         
601    if test "${ac_cv_lib_kde_crash}" = "yes"; then
602       AC_MSG_RESULT(yes) 
603       KDE_LIB="-lkdecore -lkdeui"
604       if test "${KDE_DIR}" != ""; then
605          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
606          KDE_INCLUDE="-I${KDE_DIR}/include"
607       fi
608       PBX_KDE=1
609       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
610    else
611       AC_MSG_RESULT(no) 
612    fi
613 fi
614 if test "${PBX_KDE}" = 1; then
615    AC_PATH_TOOL(KDEINIT, kdeinit, No)
616    if test ! x"${KDEINIT}" = xNo; then
617       KDEDIR=$(${DIRNAME} ${KDEINIT})
618       KDEDIR=$(${DIRNAME} ${KDEDIR})
619    fi
620    AC_SUBST([KDEDIR])
621 fi
622
623 AC_LANG_POP
624
625 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
626
627 if test "${PBX_MISDN}" = 1; then
628    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
629    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
630    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
631 fi
632
633 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
634
635 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
636
637 NETSNMP_CONFIG=No
638 if test "${USE_NETSNMP}" != "no"; then  
639    if test "x${NETSNMP_DIR}" != "x"; then
640       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
641       if test x"${NETSNMP_CONFIG}" = xNo; then
642          AC_MSG_NOTICE([***])
643          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
644          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
645          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
646          AC_MSG_NOTICE([*** including --without-netsnmp])
647          exit 1
648       fi
649    else
650       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
651    fi
652 fi
653 if test x"${NETSNMP_CONFIG}" != xNo; then
654    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
655    
656    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
657    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
658
659    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
660       NETSNMP_LIB="${NETSNMP_libs}"
661       PBX_NETSNMP=1
662    fi
663 fi
664
665 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
666
667 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [-lltdl])
668
669 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
670
671 AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
672
673 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
674
675 # possible places for oss definitions
676 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
677 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
678 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
679
680 PG_CONFIG=No
681 if test "${USE_PGSQL}" != "no"; then    
682    if test "x${PGSQL_DIR}" != "x"; then
683       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
684       if test x"${PG_CONFIG}" = xNo; then
685          AC_MSG_NOTICE([***])
686          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
687          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
688          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
689          AC_MSG_NOTICE([*** including --without-postgres])
690          exit 1
691       fi
692    else
693       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
694    fi
695 fi
696 if test "${PG_CONFIG}" != No; then
697    PGSQL_libdir=`${PG_CONFIG} --libdir`
698    PGSQL_includedir=`${PG_CONFIG} --includedir`
699    if test "x$?" != "x0" ; then
700       if test -n "${PGSQL_MANDATORY}" ; then
701          AC_MSG_NOTICE([***])
702          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
703          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
704          AC_MSG_NOTICE([*** including --without-postgres])
705          exit 1
706           fi
707    else 
708       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
709       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
710
711       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
712          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
713          PGSQL_INCLUDE="-I${PGSQL_includedir}"
714          PBX_PGSQL=1
715       elif test -n "${PGSQL_MANDATORY}";
716       then
717          AC_MSG_NOTICE([***])
718          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
719          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
720          AC_MSG_NOTICE([*** including --without-postgres])
721          exit 1
722       fi
723    fi
724 fi
725
726 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
727
728 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
729
730 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
731
732 if test "${USE_PWLIB}" != "no"; then
733         if test -n "${PWLIB_DIR}"; then
734                 PWLIBDIR="${PWLIB_DIR}"
735         fi
736         AST_CHECK_PWLIB()
737         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
738                 
739         if test "${HAS_PWLIB:-unset}" != "unset"; then
740                 AST_CHECK_OPENH323_PLATFORM()
741
742                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
743
744                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
745                         [Define if your system has the PWLib libraries.],
746                         [#include "ptlib.h"],
747                         [BOOL q = PTime::IsDaylightSavings();])
748         fi
749 fi
750
751 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
752         if test -n "${OPENH323_DIR}"; then
753                 OPENH323DIR="${OPENH323_DIR}"
754         fi
755         AST_CHECK_OPENH323()
756         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
757         AST_CHECK_OPENH323_BUILD()
758         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
759         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
760                 [Define if your system has the OpenH323 libraries.],
761                 [#include "ptlib.h"
762                 #include "h323.h"
763                 #include "h323ep.h"],
764                 [H323EndPoint ep = H323EndPoint();],
765                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
766 fi
767
768 AC_LANG_PUSH(C++)
769
770 if test "${USE_QT}" != "no"; then
771    AC_MSG_CHECKING(for QDate in -lqt)
772    saved_libs="${LIBS}"
773    saved_cppflags="${CPPFLAGS}"
774    if test "x${QT_DIR}" != "x"; then
775       LIBS="${LIBS} -L${QT_DIR}/lib"
776       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
777    fi
778    LIBS="${LIBS} -lqt"
779    qtlib="qt"
780    AC_LINK_IFELSE(
781         [
782                 AC_LANG_PROGRAM(
783                 [#include <qt3/qdatetime.h>],
784                 [QDate date();])
785         ],
786         [ac_cv_lib_qt_qt_date="yes"],
787         [ac_cv_lib_qt_qt_date="no"])
788    LIBS="${saved_libs}"
789    CPPFLAGS="${saved_cppflags}"
790         
791    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
792       saved_libs="${LIBS}"
793       saved_cppflags="${CPPFLAGS}"
794       if test "x${QT_DIR}" != "x"; then
795          LIBS="${LIBS} -L${QT_DIR}/lib"
796          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
797       fi
798       LIBS="${LIBS} -lqt-mt"
799       qtlib="qt-mt"     
800       AC_LINK_IFELSE(
801                 [
802                         AC_LANG_PROGRAM(
803                         [#include <qt3/qdatetime.h>],
804                         [QDate date();])
805                 ],
806                 [ac_cv_lib_qt_qt_date="yes"],
807                 [ac_cv_lib_qt_qt_date="no"])
808       LIBS="${saved_libs}"
809       CPPFLAGS="${saved_cppflags}"
810    fi   
811
812    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
813       AC_MSG_RESULT(yes) 
814    else
815       AC_MSG_RESULT(no) 
816    fi
817         
818    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
819       QT_LIB="-l${qtlib}"
820       if test "${QT_DIR}" != ""; then
821          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
822          QT_INCLUDE="-I${QT_DIR}/include"
823       fi
824       PBX_QT=1
825       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
826       AC_PATH_TOOL(QTMOC, moc, No)
827    fi
828 fi
829
830 AC_LANG_POP
831
832 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
833
834 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
835
836 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
837
838 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
839
840 AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
841
842 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
843 if test "${PBX_FREETDS}" != "0";
844 then
845     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
846         *0.64*)
847                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
848         ;;
849     *0.63*)
850         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
851         ;;
852     *0.62*)
853         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
854         ;;
855     *)
856         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
857         ;;
858     esac
859 fi
860
861 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
862
863 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
864
865 if test "${host_os}" != "linux-gnu" ; then
866   tonezone_extra="-lm"
867 fi
868
869 # new tonezone, version 1.4.0
870 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
871 # other case, old tonezone (0.80)
872 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
873
874 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
875
876 AC_LANG_PUSH(C++)
877
878 if test "${USE_VPB}" != "no"; then
879    AC_MSG_CHECKING(for vpb_open in -lvpb)
880    saved_libs="${LIBS}"
881    saved_cppflags="${CPPFLAGS}"
882    if test "x${VPB_DIR}" != "x"; then
883       if test -d ${VPB_DIR}/lib; then
884          vpblibdir=${VPB_DIR}/lib
885       else
886          vpblibdir=${VPB_DIR}
887       fi
888       LIBS="${LIBS} -L${vpblibdir}"
889       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
890    fi
891    LIBS="${LIBS} -lvpb -lpthread"
892    AC_LINK_IFELSE(
893         [
894         AC_LANG_PROGRAM(
895         [#include <vpbapi.h>],
896         [int q = vpb_open(0,0);])
897         ],
898         [       AC_MSG_RESULT(yes) 
899                 ac_cv_lib_vpb_vpb_open="yes" 
900         ],
901         [       AC_MSG_RESULT(no) 
902                 ac_cv_lib_vpb_vpb_open="no" 
903         ]
904         )
905    LIBS="${saved_libs}"
906    CPPFLAGS="${saved_cppflags}"
907    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
908         VPB_LIB="-lvpb"
909         if test "${VPB_DIR}" != ""; then
910            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
911            VPB_INCLUDE="-I${VPB_DIR}/include"
912         fi
913         PBX_VPB=1
914         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
915    fi
916 fi
917
918 AC_LANG_POP
919
920 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
921
922 # Check for various zaptel features and locations.
923 # The version number, which goes into HAVE_ZAPTEL_VERSION,
924 # will be used in the system headers to determine the location
925 # of the zaptel.h header.
926
927 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
928 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
929
930 # Check for VLDTMF support
931 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
932
933 # Check for transcode support
934 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
935
936 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
937 case "${host_os}" in
938     freebsd*)
939         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
940         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
941         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
942
943         # other case, old tonezone (0.80)
944         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
945         ;;
946 esac
947
948 EDITLINE_LIB=""
949 if test "x$TERMCAP_LIB" != "x" ; then
950   EDITLINE_LIB="$TERMCAP_LIB"
951 elif test "x$TINFO_LIB" != "x" ; then
952   EDITLINE_LIB="$TINFO_LIB"
953 elif test "x$CURSES_LIB" != "x" ; then
954   EDITLINE_LIB="$CURSES_LIB"
955 elif test "x$NCURSES_LIB" != "x" ; then
956   EDITLINE_LIB="$NCURSES_LIB"
957 else
958   AC_MSG_ERROR(*** termcap support not found)
959 fi
960 AC_SUBST(EDITLINE_LIB)
961
962 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
963 AC_SUBST(PBX_H323)
964
965 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
966                                    #include <linux/version.h>
967                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
968                                    #include <linux/compiler.h>
969                                    #endif
970                                    ])
971 AC_SUBST(PBX_IXJUSER)
972
973 PBX_GTK=0
974 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
975 if test ! "x${GTKCONFIG}" = xNo; then
976    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
977    GTK_LIB=$(${GTKCONFIG} --libs gthread)
978    PBX_GTK=1
979    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
980 fi
981 AC_SUBST(PBX_GTK)
982 AC_SUBST(GTK_INCLUDE)
983 AC_SUBST(GTK_LIB)
984
985 PBX_GTK2=0
986 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
987 if test ! "x${PKGCONFIG}" = xNo; then
988    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags)
989    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
990    PBX_GTK2=1
991    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
992 fi
993 AC_SUBST(PBX_GTK2)
994 AC_SUBST(GTK2_INCLUDE)
995 AC_SUBST(GTK2_LIB)
996
997 if test "${USE_CURL}" != "no"; then
998    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
999    if test ! x"${CURL_CONFIG}" = xNo; then
1000    # check for version
1001       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1002          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1003          CURL_LIB=$(${CURL_CONFIG} --libs)
1004          PBX_CURL=1
1005          AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1006       fi
1007    fi
1008 fi
1009
1010 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1011 AST_CHECK_MANDATORY
1012
1013 AC_OUTPUT
1014
1015 if test "x${silent}" != "xyes" ; then
1016 echo
1017 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1018 echo "            .\$7\$7..          .7\$\$7:.    "
1019 echo "          .\$\$:.                 ,\$7.7   "
1020 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1021 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1022 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1023 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1024 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1025 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1026 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1027 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1028 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1029 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1030 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1031 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1032 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1033 echo " \$\$\$\$\$                        \$\$\$       "
1034 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1035 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1036 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1037 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1038 echo
1039 fi
1040
1041 AC_MSG_NOTICE(Package configured for: )
1042 AC_MSG_NOTICE( OS type  : $host_os)
1043 AC_MSG_NOTICE( Host CPU : $host_cpu)
1044 if test "${cross_compiling}" = "yes"; then
1045    AC_MSG_NOTICE( Cross Compilation = YES)
1046 fi