Merged revisions 77865 via svnmerge from
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <netdb.h>],
292                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
293         AC_MSG_RESULT(yes)
294         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
295         AC_MSG_RESULT(no)
296 )
297
298 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
299 AC_LINK_IFELSE(
300         AC_LANG_PROGRAM([#include <netdb.h>],
301                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
302         AC_MSG_RESULT(yes)
303         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
304         AC_MSG_RESULT(no)
305 )
306
307 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
308
309 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
310 AC_LINK_IFELSE(
311 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
312 AC_MSG_RESULT(yes)
313 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
314 AC_MSG_RESULT(no)
315 )
316
317 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
318 AC_LINK_IFELSE(
319 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
320 AC_MSG_RESULT(yes)
321 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
322 AC_MSG_RESULT(no)
323 )
324
325 AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
326
327 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
328 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
329
330 AC_MSG_CHECKING(for compiler atomic operations)
331 AC_LINK_IFELSE(
332 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
333 AC_MSG_RESULT(yes)
334 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
335 AC_MSG_RESULT(no)
336 )
337
338 AST_GCC_ATTRIBUTE(pure)
339 AST_GCC_ATTRIBUTE(malloc)
340 AST_GCC_ATTRIBUTE(const)
341 AST_GCC_ATTRIBUTE(unused)
342 AST_GCC_ATTRIBUTE(always_inline)
343 AST_GCC_ATTRIBUTE(deprecated)
344
345 AC_MSG_CHECKING(for -ffunction-sections support)
346 saved_CFLAGS="${CFLAGS}"
347 CFLAGS="${CFLAGS} -ffunction-sections"
348 AC_COMPILE_IFELSE(
349         AC_LANG_PROGRAM([], [int x = 1;]),
350         AC_MSG_RESULT(yes)
351         [saved_LDFLAGS="${LDFLAGS}"]
352         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
353         AC_MSG_CHECKING(for --gc-sections support)
354         AC_LINK_IFELSE(
355                 AC_LANG_PROGRAM([], [int x = 1;]),
356                 AC_MSG_RESULT(yes)
357                 [GC_CFLAGS="-ffunction-sections"]
358                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
359                 AC_MSG_RESULT(no)
360         )
361         [LDFLAGS="${saved_LDFLAGS}"],
362         AC_MSG_RESULT(no)
363 )
364 CFLAGS="${saved_CFLAGS}"
365 AC_SUBST(GC_CFLAGS)
366 AC_SUBST(GC_LDFLAGS)
367
368 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
369 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
370         AC_MSG_RESULT(yes)
371         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
372 else
373         AC_MSG_RESULT(no)
374         AST_DECLARATION_AFTER_STATEMENT=
375 fi
376 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
377
378
379 AC_MSG_CHECKING(for sysinfo)
380 AC_LINK_IFELSE(
381         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
382                         [struct sysinfo sys_info;]),
383         AC_MSG_RESULT(yes)
384         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
385         AC_MSG_RESULT(no)
386 )
387
388 AC_MSG_CHECKING(for res_ninit)
389 AC_LINK_IFELSE(
390         AC_LANG_PROGRAM([#include <resolv.h>],
391                         [int foo = res_ninit(NULL);]),
392         AC_MSG_RESULT(yes)
393         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
394         AC_MSG_CHECKING(for res_ndestroy)
395         AC_LINK_IFELSE(
396                 AC_LANG_PROGRAM([#include <resolv.h>],
397                                 [int foo = res_ndestroy(NULL);]),
398                 AC_MSG_RESULT(yes)
399                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
400                 AC_MSG_RESULT(no)
401         ),
402         AC_MSG_RESULT(no)
403 )
404
405 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
406
407 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
408
409 AC_CHECK_HEADER([libkern/OSAtomic.h],
410                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
411
412 AC_CHECK_SIZEOF(int)
413
414 # do the package library checks now
415
416 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
417
418 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
419
420 if test "x${host_os}" = "xlinux-gnu" ; then
421   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
422 fi
423
424 # BSD might not have exp2, and/or log2
425 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
426 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
427 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
428 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
429 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
430 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
431 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
432 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
433
434 GSM_INTERNAL="yes"
435 AC_SUBST(GSM_INTERNAL)
436 GSM_SYSTEM="yes"
437 if test "${USE_GSM}" != "no"; then
438    if test "${GSM_DIR}" = "internal"; then
439       GSM_SYSTEM="no"
440    elif test "${GSM_DIR}" != ""; then
441       GSM_INTERNAL="no"
442    fi
443    if test "${GSM_SYSTEM}" = "yes"; then
444       gsmlibdir=""
445       if test "x${GSM_DIR}" != "x"; then
446          if test -d ${GSM_DIR}/lib; then
447             gsmlibdir="-L${GSM_DIR}/lib"
448          else
449             gsmlibdir="-L${GSM_DIR}"
450          fi
451       fi
452       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
453       [Define to indicate the GSM library]), [], ${gsmlibdir})
454       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
455          if test "x${GSM_DIR}" != "x" ; then
456             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
457             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
458          else
459             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
460             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
461          fi
462          if test "${GSM_HEADER_FOUND}" = "0" ; then
463             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
464                if test "x${GSM_MANDATORY}" = "xyes" ; then
465                   AC_MSG_NOTICE([***])
466                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
467                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
468                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
469                   exit 1
470                fi
471             fi
472          fi
473          GSM_OK=0
474          if test "${GSM_HEADER_FOUND}" = "1" ; then
475             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
476             GSM_OK=1
477          else
478             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
479                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
480                GSM_OK=1
481             fi
482          fi
483          if test "${GSM_OK}" = "1" ; then
484             GSM_LIB="-lgsm"
485             if test "x${GSM_DIR}" != "x"; then
486                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
487                GSM_INCLUDE="-I${GSM_DIR}/include"
488             fi
489             PBX_GSM=1
490             GSM_INTERNAL="no"
491          fi
492       fi
493    fi
494    if test "${GSM_INTERNAL}" = "yes"; then
495       PBX_GSM=1
496       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
497    fi
498 fi
499
500 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
501
502 if test "${PBX_IKSEMEL}" = 1; then
503    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
504 fi
505
506 if test "${USE_IMAP_TK}" != "no"; then
507    if test "${IMAP_TK_DIR}" = "system" ; then
508       AC_MSG_NOTICE([Checking for system c-client library...])
509    elif test "${IMAP_TK_DIR}" = ""; then
510       IMAP_TK_DIR=`pwd`"/../imap-2004g"
511       if test  -n "${IMAP_TK_MANDATORY}"; then
512          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
513          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
514          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
515          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
516       fi
517    fi
518    if test "${IMAP_TK_DIR}" != "system" ; then
519       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
520    fi
521    saved_cppflags="${CPPFLAGS}"
522    saved_libs="${LIBS}"
523    if test "${IMAP_TK_DIR}" = "system" ; then
524       imap_ldflags=""
525       imap_libs="-lc-client"
526       imap_include="-DUSE_SYSTEM_IMAP"
527    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
528       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
529       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
530       imap_include="-I${IMAP_TK_DIR}/c-client"
531    fi
532    CPPFLAGS="${CPPFLAGS} ${imap_include}"
533    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
534    AC_LINK_IFELSE(
535         AC_LANG_PROGRAM(
536                 [#ifdef USE_SYSTEM_IMAP
537                 #include <imap/c-client.h>
538                 #else
539                 #include "c-client.h"
540                 #endif
541                 void mm_searched (MAILSTREAM *stream,unsigned long number)
542                 {
543                 }
544                 void mm_exists (MAILSTREAM *stream,unsigned long number)
545                 {
546                 }
547                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
548                 {
549                 }
550                 void mm_flags (MAILSTREAM *stream,unsigned long number)
551                 {
552                 }
553                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
554                 {
555                 }
556                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
557                 {
558                 }
559                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
560                 {
561                 }
562                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
563                 {
564                 }
565                 void mm_log (char *string,long errflg)
566                 {
567                 }
568                 void mm_dlog (char *string)
569                 {
570                 }
571                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
572                 {
573                 }
574                 void mm_critical (MAILSTREAM *stream)
575                 {
576                 }
577                 void mm_nocritical (MAILSTREAM *stream)
578                 {
579                 }
580                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
581                 {
582                 }
583                 void mm_fatal (char *string)
584                 {
585                 }],
586                 [
587                 MAILSTREAM *foo = mail_open(NULL, "", 0);
588                 ]
589         ),
590         [ac_cv_imap_tk="yes"],
591         [ac_cv_imap_tk="no"]
592    )
593    if test "${ac_cv_imap_tk}" = "yes"; then
594    AC_LINK_IFELSE(
595       AC_LANG_PROGRAM(
596          [#ifdef USE_SYSTEM_IMAP
597          #include <imap/c-client.h>
598          #else
599          #include "c-client.h"
600          #endif
601          void mm_searched (MAILSTREAM *stream,unsigned long number)
602          {
603          }
604          void mm_exists (MAILSTREAM *stream,unsigned long number)
605          {
606          }
607          void mm_expunged (MAILSTREAM *stream,unsigned long number)
608          {
609          }
610          void mm_flags (MAILSTREAM *stream,unsigned long number)
611          {
612          }
613          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
614          {
615          }
616          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
617          {
618          }
619          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
620          {
621          }
622          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
623          {
624          }
625          void mm_log (char *string,long errflg)
626          {
627          }
628          void mm_dlog (char *string)
629          {
630          }
631          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
632          {
633          }
634          void mm_critical (MAILSTREAM *stream)
635          {
636          }
637          void mm_nocritical (MAILSTREAM *stream)
638          {
639          }
640          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
641          {
642          }
643          void mm_fatal (char *string)
644          {
645          }],
646          [
647          long check = mail_expunge_full(NULL, "", 0);
648          ]
649       ),
650       [ac_cv_imap_tk2006="yes"],
651       [ac_cv_imap_tk2006="no"]
652   )
653   fi
654    CPPFLAGS="${saved_cppflags}"
655    LIBS="${saved_libs}"
656    if test "${ac_cv_imap_tk}" = "yes"; then
657       AC_MSG_RESULT(yes) 
658       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
659       IMAP_TK_INCLUDE="${imap_include}"
660       PBX_IMAP_TK=1
661       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
662       if test "${ac_cv_imap_tk2006}" = "yes"; then
663          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
664       fi
665    else
666       AC_MSG_RESULT(no) 
667    fi
668 fi
669
670 # Needed by unixodbc
671 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
672
673 AC_LANG_PUSH(C++)
674
675 if test "${USE_KDE}" != "no"; then
676    AC_MSG_CHECKING(for crashHandler in -lkdecore)
677    saved_libs="${LIBS}"
678    saved_cppflags="${CPPFLAGS}"
679    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
680    if test -d ${KDE_DIR}/lib; then
681       kdelibdir="${KDE_DIR}/lib"
682    else
683       kdelibdir="${KDE_DIR}"
684    fi
685    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
686
687    AC_LINK_IFELSE(
688         [AC_LANG_PROGRAM(
689                         [#include "kcrash.h"],
690                         [KCrash::defaultCrashHandler(1);])
691         ],
692         [ac_cv_lib_kde_crash="yes"],
693         [ac_cv_lib_kde_crash="no"])
694                 
695    LIBS="${saved_libs}"
696    CPPFLAGS="${saved_cppflags}"
697         
698    if test "${ac_cv_lib_kde_crash}" = "yes"; then
699       AC_MSG_RESULT(yes) 
700       KDE_LIB="-lkdecore -lkdeui"
701       if test "${KDE_DIR}" != ""; then
702          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
703          KDE_INCLUDE="-I${KDE_DIR}/include"
704       fi
705       PBX_KDE=1
706       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
707    else
708       AC_MSG_RESULT(no) 
709    fi
710 fi
711 if test "${PBX_KDE}" = 1; then
712    AC_PATH_TOOL(KDEINIT, kdeinit, No)
713    if test ! x"${KDEINIT}" = xNo; then
714       KDEDIR=$(${DIRNAME} ${KDEINIT})
715       KDEDIR=$(${DIRNAME} ${KDEDIR})
716    fi
717    AC_SUBST([KDEDIR])
718 fi
719
720 AC_LANG_POP
721
722 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
723
724 if test "${PBX_MISDN}" = 1; then
725    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
726    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
727    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
728 fi
729
730 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
731
732 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
733
734 NETSNMP_CONFIG=No
735 if test "${USE_NETSNMP}" != "no"; then  
736    if test "x${NETSNMP_DIR}" != "x"; then
737       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
738       if test x"${NETSNMP_CONFIG}" = xNo; then
739          AC_MSG_NOTICE([***])
740          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
741          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
742          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
743          AC_MSG_NOTICE([*** including --without-netsnmp])
744          exit 1
745       fi
746    else
747       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
748    fi
749 fi
750 if test x"${NETSNMP_CONFIG}" != xNo; then
751    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
752    
753    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
754    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
755
756    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
757       NETSNMP_LIB="${NETSNMP_libs}"
758       PBX_NETSNMP=1
759    fi
760 fi
761
762 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
763
764 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
765
766 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
767
768 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
769
770 # possible places for oss definitions
771 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
772 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
773 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
774
775 PG_CONFIG=No
776 if test "${USE_PGSQL}" != "no"; then    
777    if test "x${PGSQL_DIR}" != "x"; then
778       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
779       if test x"${PG_CONFIG}" = xNo; then
780          AC_MSG_NOTICE([***])
781          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
782          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
783          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
784          AC_MSG_NOTICE([*** including --without-postgres])
785          exit 1
786       fi
787    else
788       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
789    fi
790 fi
791 if test "${PG_CONFIG}" != No; then
792    PGSQL_libdir=`${PG_CONFIG} --libdir`
793    PGSQL_includedir=`${PG_CONFIG} --includedir`
794    if test "x$?" != "x0" ; then
795       if test -n "${PGSQL_MANDATORY}" ; then
796          AC_MSG_NOTICE([***])
797          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
798          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
799          AC_MSG_NOTICE([*** including --without-postgres])
800          exit 1
801           fi
802    else 
803       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
804       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
805
806       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
807          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
808          PGSQL_INCLUDE="-I${PGSQL_includedir}"
809          PBX_PGSQL=1
810       elif test -n "${PGSQL_MANDATORY}";
811       then
812          AC_MSG_NOTICE([***])
813          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
814          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
815          AC_MSG_NOTICE([*** including --without-postgres])
816          exit 1
817       fi
818    fi
819 fi
820
821 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
822
823 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
824
825 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
826
827 if test "${USE_PWLIB}" != "no"; then
828         if test -n "${PWLIB_DIR}"; then
829                 PWLIBDIR="${PWLIB_DIR}"
830         fi
831         AST_CHECK_PWLIB()
832         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
833                 
834         if test "${HAS_PWLIB:-unset}" != "unset"; then
835                 AST_CHECK_OPENH323_PLATFORM()
836
837                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
838
839                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
840                         [Define if your system has the PWLib libraries.],
841                         [#include "ptlib.h"],
842                         [BOOL q = PTime::IsDaylightSavings();])
843         fi
844 fi
845
846 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
847         if test -n "${OPENH323_DIR}"; then
848                 OPENH323DIR="${OPENH323_DIR}"
849         fi
850         AST_CHECK_OPENH323()
851         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
852         AST_CHECK_OPENH323_BUILD()
853         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
854         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
855                 [Define if your system has the OpenH323 libraries.],
856                 [#include "ptlib.h"
857                 #include "h323.h"
858                 #include "h323ep.h"],
859                 [H323EndPoint ep = H323EndPoint();],
860                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
861 fi
862
863 AC_LANG_PUSH(C++)
864
865 if test "${USE_QT}" != "no"; then
866    AC_MSG_CHECKING(for QDate in -lqt)
867    saved_libs="${LIBS}"
868    saved_cppflags="${CPPFLAGS}"
869    if test "x${QT_DIR}" != "x"; then
870       LIBS="${LIBS} -L${QT_DIR}/lib"
871       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
872    fi
873    LIBS="${LIBS} -lqt"
874    qtlib="qt"
875    AC_LINK_IFELSE(
876         [
877                 AC_LANG_PROGRAM(
878                 [#include <qt3/qdatetime.h>],
879                 [QDate date();])
880         ],
881         [ac_cv_lib_qt_qt_date="yes"],
882         [ac_cv_lib_qt_qt_date="no"])
883    LIBS="${saved_libs}"
884    CPPFLAGS="${saved_cppflags}"
885         
886    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
887       saved_libs="${LIBS}"
888       saved_cppflags="${CPPFLAGS}"
889       if test "x${QT_DIR}" != "x"; then
890          LIBS="${LIBS} -L${QT_DIR}/lib"
891          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
892       fi
893       LIBS="${LIBS} -lqt-mt"
894       qtlib="qt-mt"     
895       AC_LINK_IFELSE(
896                 [
897                         AC_LANG_PROGRAM(
898                         [#include <qt3/qdatetime.h>],
899                         [QDate date();])
900                 ],
901                 [ac_cv_lib_qt_qt_date="yes"],
902                 [ac_cv_lib_qt_qt_date="no"])
903       LIBS="${saved_libs}"
904       CPPFLAGS="${saved_cppflags}"
905    fi   
906
907    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
908       AC_MSG_RESULT(yes) 
909    else
910       AC_MSG_RESULT(no) 
911    fi
912         
913    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
914       QT_LIB="-l${qtlib}"
915       if test "${QT_DIR}" != ""; then
916          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
917          QT_INCLUDE="-I${QT_DIR}/include"
918       fi
919       PBX_QT=1
920       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
921       AC_PATH_TOOL(QTMOC, moc, No)
922    fi
923 fi
924
925 AC_LANG_POP
926
927 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
928
929 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
930
931 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
932
933 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
934
935 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
936
937 if test "$PBX_CRYPTO" = "1";
938 then
939     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
940 fi
941
942 if test "$PBX_OPENSSL" = "1";
943 then
944     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
945 fi
946
947 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
948 if test "${PBX_FREETDS}" != "0";
949 then
950     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
951         *0.64*)
952                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
953         ;;
954     *0.63*)
955         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
956         ;;
957     *0.62*)
958         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
959         ;;
960     *)
961         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
962         ;;
963     esac
964 fi
965
966 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
967
968 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
969
970 if test "${host_os}" != "linux-gnu" ; then
971   tonezone_extra="-lm"
972 fi
973
974 # new tonezone, version 1.4.0
975 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
976 # other case, old tonezone (0.80)
977 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
978
979 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
980
981 AC_LANG_PUSH(C++)
982
983 if test "${USE_VPB}" != "no"; then
984    AC_MSG_CHECKING(for vpb_open in -lvpb)
985    saved_libs="${LIBS}"
986    saved_cppflags="${CPPFLAGS}"
987    if test "x${VPB_DIR}" != "x"; then
988       if test -d ${VPB_DIR}/lib; then
989          vpblibdir=${VPB_DIR}/lib
990       else
991          vpblibdir=${VPB_DIR}
992       fi
993       LIBS="${LIBS} -L${vpblibdir}"
994       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
995    fi
996    LIBS="${LIBS} -lvpb -lpthread"
997    AC_LINK_IFELSE(
998         [
999         AC_LANG_PROGRAM(
1000         [#include <vpbapi.h>],
1001         [int q = vpb_open(0,0);])
1002         ],
1003         [       AC_MSG_RESULT(yes) 
1004                 ac_cv_lib_vpb_vpb_open="yes" 
1005         ],
1006         [       AC_MSG_RESULT(no) 
1007                 ac_cv_lib_vpb_vpb_open="no" 
1008         ]
1009         )
1010    LIBS="${saved_libs}"
1011    CPPFLAGS="${saved_cppflags}"
1012    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1013         VPB_LIB="-lvpb"
1014         if test "${VPB_DIR}" != ""; then
1015            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1016            VPB_INCLUDE="-I${VPB_DIR}/include"
1017         fi
1018         PBX_VPB=1
1019         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1020    fi
1021 fi
1022
1023 AC_LANG_POP
1024
1025 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1026
1027 # Check for various zaptel features and locations.
1028 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1029 # will be used in the system headers to determine the location
1030 # of the zaptel.h header.
1031
1032 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1033 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1034
1035 # Check for VLDTMF support
1036 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1037
1038 # Check for transcode support
1039 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1040
1041 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1042 case "${host_os}" in
1043     freebsd*)
1044         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1045         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1046         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1047
1048         # other case, old tonezone (0.80)
1049         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1050         ;;
1051 esac
1052
1053 EDITLINE_LIB=""
1054 if test "x$TERMCAP_LIB" != "x" ; then
1055   EDITLINE_LIB="$TERMCAP_LIB"
1056 elif test "x$TINFO_LIB" != "x" ; then
1057   EDITLINE_LIB="$TINFO_LIB"
1058 elif test "x$CURSES_LIB" != "x" ; then
1059   EDITLINE_LIB="$CURSES_LIB"
1060 elif test "x$NCURSES_LIB" != "x" ; then
1061   EDITLINE_LIB="$NCURSES_LIB"
1062 else
1063   AC_MSG_ERROR(*** termcap support not found)
1064 fi
1065 AC_SUBST(EDITLINE_LIB)
1066
1067 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1068 AC_SUBST(PBX_H323)
1069
1070 AC_CHECK_HEADER([linux/compiler.h],
1071                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1072
1073 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1074                                    #include <linux/version.h>
1075                                    #ifdef HAVE_LINUX_COMPILER_H
1076                                    #include <linux/compiler.h>
1077                                    #endif
1078                                    ])
1079 AC_SUBST(PBX_IXJUSER)
1080
1081 PBX_GTK=0
1082 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1083 if test ! "x${GTKCONFIG}" = xNo; then
1084    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1085    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1086    PBX_GTK=1
1087    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1088 fi
1089 AC_SUBST(PBX_GTK)
1090 AC_SUBST(GTK_INCLUDE)
1091 AC_SUBST(GTK_LIB)
1092
1093 PBX_GTK2=0
1094 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1095 if test ! "x${PKGCONFIG}" = xNo; then
1096    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1097    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1098    PBX_GTK2=1
1099    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1100 fi
1101 AC_SUBST(PBX_GTK2)
1102 AC_SUBST(GTK2_INCLUDE)
1103 AC_SUBST(GTK2_LIB)
1104
1105 if test "${USE_CURL}" != "no"; then
1106    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1107    if test ! x"${CURL_CONFIG}" = xNo; then
1108    # check for version
1109       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1110          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1111          CURL_LIB=$(${CURL_CONFIG} --libs)
1112
1113          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1114          saved_cppflags="${CPPFLAGS}"
1115          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1116          AC_COMPILE_IFELSE(
1117             [AC_LANG_PROGRAM(
1118                 [#include <curl/curl.h>],
1119                     [curl_version();])
1120             ],[
1121                 AC_MSG_RESULT(yes)
1122                 ac_cv_curl_h="yes"
1123             ],[
1124                 AC_MSG_RESULT(no)
1125                 ac_cv_curl_h="no"
1126             ]
1127          )
1128          CPPFLAGS="${saved_cppflags}"
1129          if test "${ac_cv_curl_h}" = "yes"; then
1130              PBX_CURL=1
1131              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1132          fi
1133       fi
1134    fi
1135 fi
1136
1137 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1138 AST_CHECK_MANDATORY
1139
1140 AC_OUTPUT
1141
1142 if test "x${silent}" != "xyes" ; then
1143 echo
1144 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1145 echo "            .\$7\$7..          .7\$\$7:.    "
1146 echo "          .\$\$:.                 ,\$7.7   "
1147 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1148 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1149 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1150 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1151 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1152 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1153 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1154 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1155 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1156 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1157 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1158 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1159 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1160 echo " \$\$\$\$\$                        \$\$\$       "
1161 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1162 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1163 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1164 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1165 echo
1166 fi
1167
1168 AC_MSG_NOTICE(Package configured for: )
1169 AC_MSG_NOTICE( OS type  : $host_os)
1170 AC_MSG_NOTICE( Host CPU : $host_cpu)
1171 if test "${cross_compiling}" = "yes"; then
1172    AC_MSG_NOTICE( Cross Compilation = YES)
1173 fi