Merged revisions 66029-66030 via svnmerge from
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
190 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
191 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
192 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
193 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
194 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
195 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
196 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
197 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
198 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
199 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
200 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
201 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
202 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
203 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
204 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
205 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
206 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
207 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
208 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
209 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
210 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
211 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
212 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
213 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
214 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
215 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
216 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL], [ssl])
217 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
218 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
219 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
220 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
221 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
222 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
223 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
224 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
225 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
226 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
227
228 # check for basic system features and functionality before
229 # checking for package libraries
230
231 AC_FUNC_ALLOCA
232 AC_HEADER_DIRENT
233 AC_HEADER_STDC
234 AC_HEADER_SYS_WAIT
235 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
236
237 AC_SYS_LARGEFILE
238
239 # Checks for typedefs, structures, and compiler characteristics.
240 AC_HEADER_STDBOOL
241 AC_C_CONST
242 AC_TYPE_UID_T
243 AC_C_INLINE
244 AC_TYPE_MODE_T
245 AC_TYPE_OFF_T
246 AC_TYPE_PID_T
247 AC_TYPE_SIZE_T
248 AC_CHECK_MEMBERS([struct stat.st_blksize])
249 AC_HEADER_TIME
250 AC_STRUCT_TM
251 AC_C_VOLATILE
252 AC_CHECK_TYPES([ptrdiff_t])
253
254 # Checks for library functions.
255 AC_FUNC_CHOWN
256 AC_FUNC_CLOSEDIR_VOID
257 AC_FUNC_ERROR_AT_LINE
258 AST_FUNC_FORK
259 AC_FUNC_FSEEKO
260 AC_PROG_GCC_TRADITIONAL
261 # XXX: these are commented out until we determine whether it matters if our malloc()
262 # acts exactly like glibc's or not
263 # AC_FUNC_MALLOC
264 # AC_FUNC_REALLOC
265 AC_FUNC_MEMCMP
266 AC_FUNC_MKTIME
267 AC_FUNC_MMAP
268 AC_FUNC_SELECT_ARGTYPES
269 AC_FUNC_SETVBUF_REVERSED
270 AC_TYPE_SIGNAL
271 AC_FUNC_STAT
272 AC_FUNC_STRCOLL
273 AC_FUNC_STRFTIME
274 AC_FUNC_STRNLEN
275 AC_FUNC_STRTOD
276 AC_FUNC_UTIME_NULL
277 AC_FUNC_VPRINTF
278 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
279
280 # https support (in main/http.c) uses funopen on BSD systems,
281 # fopencookie on linux
282 AC_CHECK_FUNCS([funopen fopencookie])
283
284 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
285 AC_CHECK_FUNCS([gethostbyname_r])
286
287 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
288 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
289
290 AC_MSG_CHECKING(for compiler atomic operations)
291 AC_LINK_IFELSE(
292 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
293 AC_MSG_RESULT(yes)
294 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
295 AC_MSG_RESULT(no)
296 )
297
298 AST_GCC_ATTRIBUTE(pure)
299 AST_GCC_ATTRIBUTE(malloc)
300 AST_GCC_ATTRIBUTE(const)
301 AST_GCC_ATTRIBUTE(unused)
302 AST_GCC_ATTRIBUTE(always_inline)
303
304 AC_MSG_CHECKING(for -ffunction-sections support)
305 saved_CFLAGS="${CFLAGS}"
306 CFLAGS="${CFLAGS} -ffunction-sections"
307 AC_COMPILE_IFELSE(
308         AC_LANG_PROGRAM([], [int x = 1;]),
309         AC_MSG_RESULT(yes)
310         [saved_LDFLAGS="${LDFLAGS}"]
311         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
312         AC_MSG_CHECKING(for --gc-sections support)
313         AC_LINK_IFELSE(
314                 AC_LANG_PROGRAM([], [int x = 1;]),
315                 AC_MSG_RESULT(yes)
316                 [GC_CFLAGS="-ffunction-sections"]
317                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
318                 AC_MSG_RESULT(no)
319         )
320         [LDFLAGS="${saved_LDFLAGS}"],
321         AC_MSG_RESULT(no)
322 )
323 CFLAGS="${saved_CFLAGS}"
324 AC_SUBST(GC_CFLAGS)
325 AC_SUBST(GC_LDFLAGS)
326
327 AC_MSG_CHECKING(for sysinfo)
328 AC_LINK_IFELSE(
329         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
330                         [struct sysinfo sys_info;]),
331         AC_MSG_RESULT(yes)
332         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
333         AC_MSG_RESULT(no)
334 )
335
336 AC_MSG_CHECKING(for res_ninit)
337 AC_LINK_IFELSE(
338         AC_LANG_PROGRAM([#include <resolv.h>],
339                         [int foo = res_ninit(NULL);]),
340         AC_MSG_RESULT(yes)
341         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
342         AC_MSG_RESULT(no)
343 )
344
345 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
346
347 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
348
349 AC_CHECK_HEADER([libkern/OSAtomic.h],
350                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
351
352 AC_CHECK_SIZEOF(int)
353
354 # do the package library checks now
355
356 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
357
358 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
359
360 if test "x${host_os}" = "xlinux-gnu" ; then
361   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
362 fi
363
364 GSM_INTERNAL="yes"
365 AC_SUBST(GSM_INTERNAL)
366 GSM_SYSTEM="yes"
367 if test "${USE_GSM}" != "no"; then
368    if test "${GSM_DIR}" = "internal"; then
369       GSM_SYSTEM="no"
370    elif test "${GSM_DIR}" != ""; then
371       GSM_INTERNAL="no"
372    fi
373    if test "${GSM_SYSTEM}" = "yes"; then
374       gsmlibdir=""
375       if test "x${GSM_DIR}" != "x"; then
376          if test -d ${GSM_DIR}/lib; then
377             gsmlibdir="-L${GSM_DIR}/lib"
378          else
379             gsmlibdir="-L${GSM_DIR}"
380          fi
381       fi
382       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
383       [Define to indicate the GSM library]), [], ${gsmlibdir})
384       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
385          if test "x${GSM_DIR}" != "x" ; then
386             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
387             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
388          else
389             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
390             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
391          fi
392          if test "${GSM_HEADER_FOUND}" = "0" ; then
393             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
394                if test "x${GSM_MANDATORY}" = "xyes" ; then
395                   AC_MSG_NOTICE([***])
396                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
397                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
398                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
399                   exit 1
400                fi
401             fi
402          fi
403          GSM_OK=0
404          if test "${GSM_HEADER_FOUND}" = "1" ; then
405             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
406             GSM_OK=1
407          else
408             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
409                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
410                GSM_OK=1
411             fi
412          fi
413          if test "${GSM_OK}" = "1" ; then
414             GSM_LIB="-lgsm"
415             if test "x${GSM_DIR}" != "x"; then
416                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
417                GSM_INCLUDE="-I${GSM_DIR}/include"
418             fi
419             PBX_GSM=1
420             GSM_INTERNAL="no"
421          fi
422       fi
423    fi
424    if test "${GSM_INTERNAL}" = "yes"; then
425       PBX_GSM=1
426       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
427    fi
428 fi
429
430 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
431
432 if test "${PBX_IKSEMEL}" = 1; then
433    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye])
434    if test "${PBX_GNUTLS}" = 1; then
435       IKSEMEL_LIB="${IKSEMEL_LIB} -lgnutls -lz -lgcrypt -lgpg-error"
436    fi
437 fi
438
439 if test "${USE_IMAP_TK}" != "no"; then
440    if test "${IMAP_TK_DIR}" = ""; then
441       IMAP_TK_DIR=`pwd`"/../imap-2004g"
442       if test  -n "${IMAP_TK_MANDATORY}"; then
443          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
444          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
445          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
446          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
447       fi
448    fi
449    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
450    saved_cppflags="${CPPFLAGS}"
451    saved_libs="${LIBS}"
452    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
453       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
454    fi
455    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
456    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
457    AC_LINK_IFELSE(
458         AC_LANG_PROGRAM(
459                 [#include "c-client.h"
460                 void mm_searched (MAILSTREAM *stream,unsigned long number)
461                 {
462                 }
463                 void mm_exists (MAILSTREAM *stream,unsigned long number)
464                 {
465                 }
466                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
467                 {
468                 }
469                 void mm_flags (MAILSTREAM *stream,unsigned long number)
470                 {
471                 }
472                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
473                 {
474                 }
475                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
476                 {
477                 }
478                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
479                 {
480                 }
481                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
482                 {
483                 }
484                 void mm_log (char *string,long errflg)
485                 {
486                 }
487                 void mm_dlog (char *string)
488                 {
489                 }
490                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
491                 {
492                 }
493                 void mm_critical (MAILSTREAM *stream)
494                 {
495                 }
496                 void mm_nocritical (MAILSTREAM *stream)
497                 {
498                 }
499                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
500                 {
501                 }
502                 void mm_fatal (char *string)
503                 {
504                 }],
505                 [
506                 MAILSTREAM *foo = mail_open(NULL, "", 0);
507                 ]
508         ),
509         [ac_cv_imap_tk="yes"],
510         [ac_cv_imap_tk="no"]
511    )
512    if test "${ac_cv_imap_tk}" = "yes"; then
513    AC_LINK_IFELSE(
514       AC_LANG_PROGRAM(
515          [#include "c-client.h"
516          void mm_searched (MAILSTREAM *stream,unsigned long number)
517          {
518          }
519          void mm_exists (MAILSTREAM *stream,unsigned long number)
520          {
521          }
522          void mm_expunged (MAILSTREAM *stream,unsigned long number)
523          {
524          }
525          void mm_flags (MAILSTREAM *stream,unsigned long number)
526          {
527          }
528          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
529          {
530          }
531          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
532          {
533          }
534          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
535          {
536          }
537          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
538          {
539          }
540          void mm_log (char *string,long errflg)
541          {
542          }
543          void mm_dlog (char *string)
544          {
545          }
546          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
547          {
548          }
549          void mm_critical (MAILSTREAM *stream)
550          {
551          }
552          void mm_nocritical (MAILSTREAM *stream)
553          {
554          }
555          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
556          {
557          }
558          void mm_fatal (char *string)
559          {
560          }],
561          [
562          long check = mail_expunge_full(NULL, "", 0);
563          ]
564       ),
565       [ac_cv_imap_tk2006="yes"],
566       [ac_cv_imap_tk2006="no"]
567   )
568   fi
569    CPPFLAGS="${saved_cppflags}"
570    LIBS="${saved_libs}"
571    if test "${ac_cv_imap_tk}" = "yes"; then
572       AC_MSG_RESULT(yes) 
573       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
574       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
575       PBX_IMAP_TK=1
576       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
577       if test "${ac_cv_imap_tk2006}" = "yes"; then
578          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
579       fi
580    else
581       AC_MSG_RESULT(no) 
582    fi
583 fi
584
585 AC_LANG_PUSH(C++)
586
587 if test "${USE_KDE}" != "no"; then
588    AC_MSG_CHECKING(for crashHandler in -lkdecore)
589    saved_libs="${LIBS}"
590    saved_cppflags="${CPPFLAGS}"
591    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
592    if test -d ${KDE_DIR}/lib; then
593       kdelibdir="${KDE_DIR}/lib"
594    else
595       kdelibdir="${KDE_DIR}"
596    fi
597    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
598
599    AC_LINK_IFELSE(
600         [AC_LANG_PROGRAM(
601                         [#include "kcrash.h"],
602                         [KCrash::defaultCrashHandler(1);])
603         ],
604         [ac_cv_lib_kde_crash="yes"],
605         [ac_cv_lib_kde_crash="no"])
606                 
607    LIBS="${saved_libs}"
608    CPPFLAGS="${saved_cppflags}"
609         
610    if test "${ac_cv_lib_kde_crash}" = "yes"; then
611       AC_MSG_RESULT(yes) 
612       KDE_LIB="-lkdecore -lkdeui"
613       if test "${KDE_DIR}" != ""; then
614          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
615          KDE_INCLUDE="-I${KDE_DIR}/include"
616       fi
617       PBX_KDE=1
618       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
619    else
620       AC_MSG_RESULT(no) 
621    fi
622 fi
623 if test "${PBX_KDE}" = 1; then
624    AC_PATH_TOOL(KDEINIT, kdeinit, No)
625    if test ! x"${KDEINIT}" = xNo; then
626       KDEDIR=$(${DIRNAME} ${KDEINIT})
627       KDEDIR=$(${DIRNAME} ${KDEDIR})
628    fi
629    AC_SUBST([KDEDIR])
630 fi
631
632 AC_LANG_POP
633
634 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
635
636 if test "${PBX_MISDN}" = 1; then
637    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
638    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
639    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
640 fi
641
642 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
643
644 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
645
646 NETSNMP_CONFIG=No
647 if test "${USE_NETSNMP}" != "no"; then  
648    if test "x${NETSNMP_DIR}" != "x"; then
649       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
650       if test x"${NETSNMP_CONFIG}" = xNo; then
651          AC_MSG_NOTICE([***])
652          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
653          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
654          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
655          AC_MSG_NOTICE([*** including --without-netsnmp])
656          exit 1
657       fi
658    else
659       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
660    fi
661 fi
662 if test x"${NETSNMP_CONFIG}" != xNo; then
663    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
664    
665    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
666    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
667
668    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
669       NETSNMP_LIB="${NETSNMP_libs}"
670       PBX_NETSNMP=1
671    fi
672 fi
673
674 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
675
676 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [-lltdl])
677
678 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
679
680 AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
681
682 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
683
684 # possible places for oss definitions
685 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
686 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
687 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
688
689 PG_CONFIG=No
690 if test "${USE_PGSQL}" != "no"; then    
691    if test "x${PGSQL_DIR}" != "x"; then
692       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
693       if test x"${PG_CONFIG}" = xNo; then
694          AC_MSG_NOTICE([***])
695          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
696          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
697          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
698          AC_MSG_NOTICE([*** including --without-postgres])
699          exit 1
700       fi
701    else
702       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
703    fi
704 fi
705 if test "${PG_CONFIG}" != No; then
706    PGSQL_libdir=`${PG_CONFIG} --libdir`
707    PGSQL_includedir=`${PG_CONFIG} --includedir`
708    if test "x$?" != "x0" ; then
709       if test -n "${PGSQL_MANDATORY}" ; then
710          AC_MSG_NOTICE([***])
711          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
712          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
713          AC_MSG_NOTICE([*** including --without-postgres])
714          exit 1
715           fi
716    else 
717       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
718       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
719
720       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
721          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
722          PGSQL_INCLUDE="-I${PGSQL_includedir}"
723          PBX_PGSQL=1
724       elif test -n "${PGSQL_MANDATORY}";
725       then
726          AC_MSG_NOTICE([***])
727          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
728          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
729          AC_MSG_NOTICE([*** including --without-postgres])
730          exit 1
731       fi
732    fi
733 fi
734
735 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
736
737 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
738
739 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
740
741 if test "${USE_PWLIB}" != "no"; then
742         if test -n "${PWLIB_DIR}"; then
743                 PWLIBDIR="${PWLIB_DIR}"
744         fi
745         AST_CHECK_PWLIB()
746         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
747                 
748         if test "${HAS_PWLIB:-unset}" != "unset"; then
749                 AST_CHECK_OPENH323_PLATFORM()
750
751                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
752
753                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
754                         [Define if your system has the PWLib libraries.],
755                         [#include "ptlib.h"],
756                         [BOOL q = PTime::IsDaylightSavings();])
757         fi
758 fi
759
760 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
761         if test -n "${OPENH323_DIR}"; then
762                 OPENH323DIR="${OPENH323_DIR}"
763         fi
764         AST_CHECK_OPENH323()
765         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
766         AST_CHECK_OPENH323_BUILD()
767         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
768         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
769                 [Define if your system has the OpenH323 libraries.],
770                 [#include "ptlib.h"
771                 #include "h323.h"
772                 #include "h323ep.h"],
773                 [H323EndPoint ep = H323EndPoint();],
774                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
775 fi
776
777 AC_LANG_PUSH(C++)
778
779 if test "${USE_QT}" != "no"; then
780    AC_MSG_CHECKING(for QDate in -lqt)
781    saved_libs="${LIBS}"
782    saved_cppflags="${CPPFLAGS}"
783    if test "x${QT_DIR}" != "x"; then
784       LIBS="${LIBS} -L${QT_DIR}/lib"
785       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
786    fi
787    LIBS="${LIBS} -lqt"
788    qtlib="qt"
789    AC_LINK_IFELSE(
790         [
791                 AC_LANG_PROGRAM(
792                 [#include <qt3/qdatetime.h>],
793                 [QDate date();])
794         ],
795         [ac_cv_lib_qt_qt_date="yes"],
796         [ac_cv_lib_qt_qt_date="no"])
797    LIBS="${saved_libs}"
798    CPPFLAGS="${saved_cppflags}"
799         
800    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
801       saved_libs="${LIBS}"
802       saved_cppflags="${CPPFLAGS}"
803       if test "x${QT_DIR}" != "x"; then
804          LIBS="${LIBS} -L${QT_DIR}/lib"
805          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
806       fi
807       LIBS="${LIBS} -lqt-mt"
808       qtlib="qt-mt"     
809       AC_LINK_IFELSE(
810                 [
811                         AC_LANG_PROGRAM(
812                         [#include <qt3/qdatetime.h>],
813                         [QDate date();])
814                 ],
815                 [ac_cv_lib_qt_qt_date="yes"],
816                 [ac_cv_lib_qt_qt_date="no"])
817       LIBS="${saved_libs}"
818       CPPFLAGS="${saved_cppflags}"
819    fi   
820
821    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
822       AC_MSG_RESULT(yes) 
823    else
824       AC_MSG_RESULT(no) 
825    fi
826         
827    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
828       QT_LIB="-l${qtlib}"
829       if test "${QT_DIR}" != ""; then
830          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
831          QT_INCLUDE="-I${QT_DIR}/include"
832       fi
833       PBX_QT=1
834       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
835       AC_PATH_TOOL(QTMOC, moc, No)
836    fi
837 fi
838
839 AC_LANG_POP
840
841 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
842
843 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
844
845 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
846
847 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
848
849 AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
850
851 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
852 if test "${PBX_FREETDS}" != "0";
853 then
854     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
855         *0.64*)
856                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
857         ;;
858     *0.63*)
859         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
860         ;;
861     *0.62*)
862         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
863         ;;
864     *)
865         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
866         ;;
867     esac
868 fi
869
870 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
871
872 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
873
874 if test "${host_os}" != "linux-gnu" ; then
875   tonezone_extra="-lm"
876 fi
877
878 # new tonezone, version 1.4.0
879 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
880 # other case, old tonezone (0.80)
881 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
882
883 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
884
885 AC_LANG_PUSH(C++)
886
887 if test "${USE_VPB}" != "no"; then
888    AC_MSG_CHECKING(for vpb_open in -lvpb)
889    saved_libs="${LIBS}"
890    saved_cppflags="${CPPFLAGS}"
891    if test "x${VPB_DIR}" != "x"; then
892       if test -d ${VPB_DIR}/lib; then
893          vpblibdir=${VPB_DIR}/lib
894       else
895          vpblibdir=${VPB_DIR}
896       fi
897       LIBS="${LIBS} -L${vpblibdir}"
898       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
899    fi
900    LIBS="${LIBS} -lvpb -lpthread"
901    AC_LINK_IFELSE(
902         [
903         AC_LANG_PROGRAM(
904         [#include <vpbapi.h>],
905         [int q = vpb_open(0,0);])
906         ],
907         [       AC_MSG_RESULT(yes) 
908                 ac_cv_lib_vpb_vpb_open="yes" 
909         ],
910         [       AC_MSG_RESULT(no) 
911                 ac_cv_lib_vpb_vpb_open="no" 
912         ]
913         )
914    LIBS="${saved_libs}"
915    CPPFLAGS="${saved_cppflags}"
916    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
917         VPB_LIB="-lvpb"
918         if test "${VPB_DIR}" != ""; then
919            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
920            VPB_INCLUDE="-I${VPB_DIR}/include"
921         fi
922         PBX_VPB=1
923         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
924    fi
925 fi
926
927 AC_LANG_POP
928
929 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
930
931 # Check for various zaptel features and locations.
932 # The version number, which goes into HAVE_ZAPTEL_VERSION,
933 # will be used in the system headers to determine the location
934 # of the zaptel.h header.
935
936 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
937 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
938
939 # Check for VLDTMF support
940 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
941
942 # Check for transcode support
943 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
944
945 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
946 case "${host_os}" in
947     freebsd*)
948         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
949         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
950         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
951
952         # other case, old tonezone (0.80)
953         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
954         ;;
955 esac
956
957 EDITLINE_LIB=""
958 if test "x$TERMCAP_LIB" != "x" ; then
959   EDITLINE_LIB="$TERMCAP_LIB"
960 elif test "x$TINFO_LIB" != "x" ; then
961   EDITLINE_LIB="$TINFO_LIB"
962 elif test "x$CURSES_LIB" != "x" ; then
963   EDITLINE_LIB="$CURSES_LIB"
964 elif test "x$NCURSES_LIB" != "x" ; then
965   EDITLINE_LIB="$NCURSES_LIB"
966 else
967   AC_MSG_ERROR(*** termcap support not found)
968 fi
969 AC_SUBST(EDITLINE_LIB)
970
971 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
972 AC_SUBST(PBX_H323)
973
974 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
975                                    #include <linux/version.h>
976                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
977                                    #include <linux/compiler.h>
978                                    #endif
979                                    ])
980 AC_SUBST(PBX_IXJUSER)
981
982 PBX_GTK=0
983 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
984 if test ! "x${GTKCONFIG}" = xNo; then
985    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
986    GTK_LIB=$(${GTKCONFIG} --libs gthread)
987    PBX_GTK=1
988    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
989 fi
990 AC_SUBST(PBX_GTK)
991 AC_SUBST(GTK_INCLUDE)
992 AC_SUBST(GTK_LIB)
993
994 PBX_GTK2=0
995 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
996 if test ! "x${PKGCONFIG}" = xNo; then
997    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags)
998    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
999    PBX_GTK2=1
1000    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1001 fi
1002 AC_SUBST(PBX_GTK2)
1003 AC_SUBST(GTK2_INCLUDE)
1004 AC_SUBST(GTK2_LIB)
1005
1006 if test "${USE_CURL}" != "no"; then
1007    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1008    if test ! x"${CURL_CONFIG}" = xNo; then
1009    # check for version
1010       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1011          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1012          CURL_LIB=$(${CURL_CONFIG} --libs)
1013          PBX_CURL=1
1014          AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1015       fi
1016    fi
1017 fi
1018
1019 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1020 AST_CHECK_MANDATORY
1021
1022 AC_OUTPUT
1023
1024 if test "x${silent}" != "xyes" ; then
1025 echo
1026 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1027 echo "            .\$7\$7..          .7\$\$7:.    "
1028 echo "          .\$\$:.                 ,\$7.7   "
1029 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1030 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1031 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1032 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1033 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1034 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1035 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1036 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1037 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1038 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1039 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1040 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1041 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1042 echo " \$\$\$\$\$                        \$\$\$       "
1043 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1044 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1045 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1046 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1047 echo
1048 fi
1049
1050 AC_MSG_NOTICE(Package configured for: )
1051 AC_MSG_NOTICE( OS type  : $host_os)
1052 AC_MSG_NOTICE( Host CPU : $host_cpu)
1053 if test "${cross_compiling}" = "yes"; then
1054    AC_MSG_NOTICE( Cross Compilation = YES)
1055 fi