Add in check for the GCC attribute deprecated. It may be used soon!
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_CHECK_FUNCS([gethostbyname_r])
288
289 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
290 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
291
292 AC_MSG_CHECKING(for compiler atomic operations)
293 AC_LINK_IFELSE(
294 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
295 AC_MSG_RESULT(yes)
296 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
297 AC_MSG_RESULT(no)
298 )
299
300 AST_GCC_ATTRIBUTE(pure)
301 AST_GCC_ATTRIBUTE(malloc)
302 AST_GCC_ATTRIBUTE(const)
303 AST_GCC_ATTRIBUTE(unused)
304 AST_GCC_ATTRIBUTE(always_inline)
305 AST_GCC_ATTRIBUTE(deprecated)
306
307 AC_MSG_CHECKING(for -ffunction-sections support)
308 saved_CFLAGS="${CFLAGS}"
309 CFLAGS="${CFLAGS} -ffunction-sections"
310 AC_COMPILE_IFELSE(
311         AC_LANG_PROGRAM([], [int x = 1;]),
312         AC_MSG_RESULT(yes)
313         [saved_LDFLAGS="${LDFLAGS}"]
314         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
315         AC_MSG_CHECKING(for --gc-sections support)
316         AC_LINK_IFELSE(
317                 AC_LANG_PROGRAM([], [int x = 1;]),
318                 AC_MSG_RESULT(yes)
319                 [GC_CFLAGS="-ffunction-sections"]
320                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
321                 AC_MSG_RESULT(no)
322         )
323         [LDFLAGS="${saved_LDFLAGS}"],
324         AC_MSG_RESULT(no)
325 )
326 CFLAGS="${saved_CFLAGS}"
327 AC_SUBST(GC_CFLAGS)
328 AC_SUBST(GC_LDFLAGS)
329
330 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
331 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
332         AC_MSG_RESULT(yes)
333         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
334 else
335         AC_MSG_RESULT(no)
336         AST_DECLARATION_AFTER_STATEMENT=
337 fi
338 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
339
340
341 AC_MSG_CHECKING(for sysinfo)
342 AC_LINK_IFELSE(
343         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
344                         [struct sysinfo sys_info;]),
345         AC_MSG_RESULT(yes)
346         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
347         AC_MSG_RESULT(no)
348 )
349
350 AC_MSG_CHECKING(for res_ninit)
351 AC_LINK_IFELSE(
352         AC_LANG_PROGRAM([#include <resolv.h>],
353                         [int foo = res_ninit(NULL);]),
354         AC_MSG_RESULT(yes)
355         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
356         AC_MSG_CHECKING(for res_ndestroy)
357         AC_LINK_IFELSE(
358                 AC_LANG_PROGRAM([#include <resolv.h>],
359                                 [int foo = res_ndestroy(NULL);]),
360                 AC_MSG_RESULT(yes)
361                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
362                 AC_MSG_RESULT(no)
363         ),
364         AC_MSG_RESULT(no)
365 )
366
367 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
368
369 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
370
371 AC_CHECK_HEADER([libkern/OSAtomic.h],
372                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
373
374 AC_CHECK_SIZEOF(int)
375
376 # do the package library checks now
377
378 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
379
380 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
381
382 if test "x${host_os}" = "xlinux-gnu" ; then
383   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
384 fi
385
386 # BSD might not have exp2, and/or log2
387 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
388 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
389 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
390 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
391 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
392 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
393 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
394 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
395
396 GSM_INTERNAL="yes"
397 AC_SUBST(GSM_INTERNAL)
398 GSM_SYSTEM="yes"
399 if test "${USE_GSM}" != "no"; then
400    if test "${GSM_DIR}" = "internal"; then
401       GSM_SYSTEM="no"
402    elif test "${GSM_DIR}" != ""; then
403       GSM_INTERNAL="no"
404    fi
405    if test "${GSM_SYSTEM}" = "yes"; then
406       gsmlibdir=""
407       if test "x${GSM_DIR}" != "x"; then
408          if test -d ${GSM_DIR}/lib; then
409             gsmlibdir="-L${GSM_DIR}/lib"
410          else
411             gsmlibdir="-L${GSM_DIR}"
412          fi
413       fi
414       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
415       [Define to indicate the GSM library]), [], ${gsmlibdir})
416       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
417          if test "x${GSM_DIR}" != "x" ; then
418             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
419             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
420          else
421             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
422             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
423          fi
424          if test "${GSM_HEADER_FOUND}" = "0" ; then
425             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
426                if test "x${GSM_MANDATORY}" = "xyes" ; then
427                   AC_MSG_NOTICE([***])
428                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
429                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
430                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
431                   exit 1
432                fi
433             fi
434          fi
435          GSM_OK=0
436          if test "${GSM_HEADER_FOUND}" = "1" ; then
437             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
438             GSM_OK=1
439          else
440             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
441                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
442                GSM_OK=1
443             fi
444          fi
445          if test "${GSM_OK}" = "1" ; then
446             GSM_LIB="-lgsm"
447             if test "x${GSM_DIR}" != "x"; then
448                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
449                GSM_INCLUDE="-I${GSM_DIR}/include"
450             fi
451             PBX_GSM=1
452             GSM_INTERNAL="no"
453          fi
454       fi
455    fi
456    if test "${GSM_INTERNAL}" = "yes"; then
457       PBX_GSM=1
458       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
459    fi
460 fi
461
462 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
463
464 if test "${PBX_IKSEMEL}" = 1; then
465    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
466 fi
467
468 if test "${USE_IMAP_TK}" != "no"; then
469    if test "${IMAP_TK_DIR}" = "system" ; then
470       AC_MSG_NOTICE([Checking for system c-client library...])
471    elif test "${IMAP_TK_DIR}" = ""; then
472       IMAP_TK_DIR=`pwd`"/../imap-2004g"
473       if test  -n "${IMAP_TK_MANDATORY}"; then
474          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
475          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
476          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
477          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
478       fi
479    fi
480    if test "${IMAP_TK_DIR}" != "system" ; then
481       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
482    fi
483    saved_cppflags="${CPPFLAGS}"
484    saved_libs="${LIBS}"
485    if test "${IMAP_TK_DIR}" = "system" ; then
486       imap_ldflags=""
487       imap_libs="-lc-client"
488       imap_include="-DUSE_SYSTEM_IMAP"
489    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
490       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
491       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
492       imap_include="-I${IMAP_TK_DIR}/c-client"
493    fi
494    CPPFLAGS="${CPPFLAGS} ${imap_include}"
495    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
496    AC_LINK_IFELSE(
497         AC_LANG_PROGRAM(
498                 [#ifdef USE_SYSTEM_IMAP
499                 #include <imap/c-client.h>
500                 #else
501                 #include "c-client.h"
502                 #endif
503                 void mm_searched (MAILSTREAM *stream,unsigned long number)
504                 {
505                 }
506                 void mm_exists (MAILSTREAM *stream,unsigned long number)
507                 {
508                 }
509                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
510                 {
511                 }
512                 void mm_flags (MAILSTREAM *stream,unsigned long number)
513                 {
514                 }
515                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
516                 {
517                 }
518                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
519                 {
520                 }
521                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
522                 {
523                 }
524                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
525                 {
526                 }
527                 void mm_log (char *string,long errflg)
528                 {
529                 }
530                 void mm_dlog (char *string)
531                 {
532                 }
533                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
534                 {
535                 }
536                 void mm_critical (MAILSTREAM *stream)
537                 {
538                 }
539                 void mm_nocritical (MAILSTREAM *stream)
540                 {
541                 }
542                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
543                 {
544                 }
545                 void mm_fatal (char *string)
546                 {
547                 }],
548                 [
549                 MAILSTREAM *foo = mail_open(NULL, "", 0);
550                 ]
551         ),
552         [ac_cv_imap_tk="yes"],
553         [ac_cv_imap_tk="no"]
554    )
555    if test "${ac_cv_imap_tk}" = "yes"; then
556    AC_LINK_IFELSE(
557       AC_LANG_PROGRAM(
558          [#ifdef USE_SYSTEM_IMAP
559          #include <imap/c-client.h>
560          #else
561          #include "c-client.h"
562          #endif
563          void mm_searched (MAILSTREAM *stream,unsigned long number)
564          {
565          }
566          void mm_exists (MAILSTREAM *stream,unsigned long number)
567          {
568          }
569          void mm_expunged (MAILSTREAM *stream,unsigned long number)
570          {
571          }
572          void mm_flags (MAILSTREAM *stream,unsigned long number)
573          {
574          }
575          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
576          {
577          }
578          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
579          {
580          }
581          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
582          {
583          }
584          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
585          {
586          }
587          void mm_log (char *string,long errflg)
588          {
589          }
590          void mm_dlog (char *string)
591          {
592          }
593          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
594          {
595          }
596          void mm_critical (MAILSTREAM *stream)
597          {
598          }
599          void mm_nocritical (MAILSTREAM *stream)
600          {
601          }
602          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
603          {
604          }
605          void mm_fatal (char *string)
606          {
607          }],
608          [
609          long check = mail_expunge_full(NULL, "", 0);
610          ]
611       ),
612       [ac_cv_imap_tk2006="yes"],
613       [ac_cv_imap_tk2006="no"]
614   )
615   fi
616    CPPFLAGS="${saved_cppflags}"
617    LIBS="${saved_libs}"
618    if test "${ac_cv_imap_tk}" = "yes"; then
619       AC_MSG_RESULT(yes) 
620       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
621       IMAP_TK_INCLUDE="${imap_include}"
622       PBX_IMAP_TK=1
623       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
624       if test "${ac_cv_imap_tk2006}" = "yes"; then
625          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
626       fi
627    else
628       AC_MSG_RESULT(no) 
629    fi
630 fi
631
632 # Needed by unixodbc
633 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
634
635 AC_LANG_PUSH(C++)
636
637 if test "${USE_KDE}" != "no"; then
638    AC_MSG_CHECKING(for crashHandler in -lkdecore)
639    saved_libs="${LIBS}"
640    saved_cppflags="${CPPFLAGS}"
641    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
642    if test -d ${KDE_DIR}/lib; then
643       kdelibdir="${KDE_DIR}/lib"
644    else
645       kdelibdir="${KDE_DIR}"
646    fi
647    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
648
649    AC_LINK_IFELSE(
650         [AC_LANG_PROGRAM(
651                         [#include "kcrash.h"],
652                         [KCrash::defaultCrashHandler(1);])
653         ],
654         [ac_cv_lib_kde_crash="yes"],
655         [ac_cv_lib_kde_crash="no"])
656                 
657    LIBS="${saved_libs}"
658    CPPFLAGS="${saved_cppflags}"
659         
660    if test "${ac_cv_lib_kde_crash}" = "yes"; then
661       AC_MSG_RESULT(yes) 
662       KDE_LIB="-lkdecore -lkdeui"
663       if test "${KDE_DIR}" != ""; then
664          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
665          KDE_INCLUDE="-I${KDE_DIR}/include"
666       fi
667       PBX_KDE=1
668       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
669    else
670       AC_MSG_RESULT(no) 
671    fi
672 fi
673 if test "${PBX_KDE}" = 1; then
674    AC_PATH_TOOL(KDEINIT, kdeinit, No)
675    if test ! x"${KDEINIT}" = xNo; then
676       KDEDIR=$(${DIRNAME} ${KDEINIT})
677       KDEDIR=$(${DIRNAME} ${KDEDIR})
678    fi
679    AC_SUBST([KDEDIR])
680 fi
681
682 AC_LANG_POP
683
684 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
685
686 if test "${PBX_MISDN}" = 1; then
687    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
688    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
689    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
690 fi
691
692 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
693
694 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
695
696 NETSNMP_CONFIG=No
697 if test "${USE_NETSNMP}" != "no"; then  
698    if test "x${NETSNMP_DIR}" != "x"; then
699       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
700       if test x"${NETSNMP_CONFIG}" = xNo; then
701          AC_MSG_NOTICE([***])
702          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
703          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
704          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
705          AC_MSG_NOTICE([*** including --without-netsnmp])
706          exit 1
707       fi
708    else
709       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
710    fi
711 fi
712 if test x"${NETSNMP_CONFIG}" != xNo; then
713    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
714    
715    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
716    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
717
718    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
719       NETSNMP_LIB="${NETSNMP_libs}"
720       PBX_NETSNMP=1
721    fi
722 fi
723
724 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
725
726 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
727
728 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
729
730 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
731
732 # possible places for oss definitions
733 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
734 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
735 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
736
737 PG_CONFIG=No
738 if test "${USE_PGSQL}" != "no"; then    
739    if test "x${PGSQL_DIR}" != "x"; then
740       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
741       if test x"${PG_CONFIG}" = xNo; then
742          AC_MSG_NOTICE([***])
743          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
744          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
745          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
746          AC_MSG_NOTICE([*** including --without-postgres])
747          exit 1
748       fi
749    else
750       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
751    fi
752 fi
753 if test "${PG_CONFIG}" != No; then
754    PGSQL_libdir=`${PG_CONFIG} --libdir`
755    PGSQL_includedir=`${PG_CONFIG} --includedir`
756    if test "x$?" != "x0" ; then
757       if test -n "${PGSQL_MANDATORY}" ; then
758          AC_MSG_NOTICE([***])
759          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
760          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
761          AC_MSG_NOTICE([*** including --without-postgres])
762          exit 1
763           fi
764    else 
765       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
766       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
767
768       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
769          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
770          PGSQL_INCLUDE="-I${PGSQL_includedir}"
771          PBX_PGSQL=1
772       elif test -n "${PGSQL_MANDATORY}";
773       then
774          AC_MSG_NOTICE([***])
775          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
776          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
777          AC_MSG_NOTICE([*** including --without-postgres])
778          exit 1
779       fi
780    fi
781 fi
782
783 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
784
785 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
786
787 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
788
789 if test "${USE_PWLIB}" != "no"; then
790         if test -n "${PWLIB_DIR}"; then
791                 PWLIBDIR="${PWLIB_DIR}"
792         fi
793         AST_CHECK_PWLIB()
794         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
795                 
796         if test "${HAS_PWLIB:-unset}" != "unset"; then
797                 AST_CHECK_OPENH323_PLATFORM()
798
799                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
800
801                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
802                         [Define if your system has the PWLib libraries.],
803                         [#include "ptlib.h"],
804                         [BOOL q = PTime::IsDaylightSavings();])
805         fi
806 fi
807
808 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
809         if test -n "${OPENH323_DIR}"; then
810                 OPENH323DIR="${OPENH323_DIR}"
811         fi
812         AST_CHECK_OPENH323()
813         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
814         AST_CHECK_OPENH323_BUILD()
815         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
816         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
817                 [Define if your system has the OpenH323 libraries.],
818                 [#include "ptlib.h"
819                 #include "h323.h"
820                 #include "h323ep.h"],
821                 [H323EndPoint ep = H323EndPoint();],
822                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
823 fi
824
825 AC_LANG_PUSH(C++)
826
827 if test "${USE_QT}" != "no"; then
828    AC_MSG_CHECKING(for QDate in -lqt)
829    saved_libs="${LIBS}"
830    saved_cppflags="${CPPFLAGS}"
831    if test "x${QT_DIR}" != "x"; then
832       LIBS="${LIBS} -L${QT_DIR}/lib"
833       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
834    fi
835    LIBS="${LIBS} -lqt"
836    qtlib="qt"
837    AC_LINK_IFELSE(
838         [
839                 AC_LANG_PROGRAM(
840                 [#include <qt3/qdatetime.h>],
841                 [QDate date();])
842         ],
843         [ac_cv_lib_qt_qt_date="yes"],
844         [ac_cv_lib_qt_qt_date="no"])
845    LIBS="${saved_libs}"
846    CPPFLAGS="${saved_cppflags}"
847         
848    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
849       saved_libs="${LIBS}"
850       saved_cppflags="${CPPFLAGS}"
851       if test "x${QT_DIR}" != "x"; then
852          LIBS="${LIBS} -L${QT_DIR}/lib"
853          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
854       fi
855       LIBS="${LIBS} -lqt-mt"
856       qtlib="qt-mt"     
857       AC_LINK_IFELSE(
858                 [
859                         AC_LANG_PROGRAM(
860                         [#include <qt3/qdatetime.h>],
861                         [QDate date();])
862                 ],
863                 [ac_cv_lib_qt_qt_date="yes"],
864                 [ac_cv_lib_qt_qt_date="no"])
865       LIBS="${saved_libs}"
866       CPPFLAGS="${saved_cppflags}"
867    fi   
868
869    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
870       AC_MSG_RESULT(yes) 
871    else
872       AC_MSG_RESULT(no) 
873    fi
874         
875    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
876       QT_LIB="-l${qtlib}"
877       if test "${QT_DIR}" != ""; then
878          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
879          QT_INCLUDE="-I${QT_DIR}/include"
880       fi
881       PBX_QT=1
882       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
883       AC_PATH_TOOL(QTMOC, moc, No)
884    fi
885 fi
886
887 AC_LANG_POP
888
889 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
890
891 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
892
893 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
894
895 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
896
897 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
898
899 if test "$PBX_CRYPTO" = "1";
900 then
901     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
902 fi
903
904 if test "$PBX_OPENSSL" = "1";
905 then
906     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
907 fi
908
909 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
910 if test "${PBX_FREETDS}" != "0";
911 then
912     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
913         *0.64*)
914                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
915         ;;
916     *0.63*)
917         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
918         ;;
919     *0.62*)
920         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
921         ;;
922     *)
923         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
924         ;;
925     esac
926 fi
927
928 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
929
930 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
931
932 if test "${host_os}" != "linux-gnu" ; then
933   tonezone_extra="-lm"
934 fi
935
936 # new tonezone, version 1.4.0
937 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
938 # other case, old tonezone (0.80)
939 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
940
941 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
942
943 AC_LANG_PUSH(C++)
944
945 if test "${USE_VPB}" != "no"; then
946    AC_MSG_CHECKING(for vpb_open in -lvpb)
947    saved_libs="${LIBS}"
948    saved_cppflags="${CPPFLAGS}"
949    if test "x${VPB_DIR}" != "x"; then
950       if test -d ${VPB_DIR}/lib; then
951          vpblibdir=${VPB_DIR}/lib
952       else
953          vpblibdir=${VPB_DIR}
954       fi
955       LIBS="${LIBS} -L${vpblibdir}"
956       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
957    fi
958    LIBS="${LIBS} -lvpb -lpthread"
959    AC_LINK_IFELSE(
960         [
961         AC_LANG_PROGRAM(
962         [#include <vpbapi.h>],
963         [int q = vpb_open(0,0);])
964         ],
965         [       AC_MSG_RESULT(yes) 
966                 ac_cv_lib_vpb_vpb_open="yes" 
967         ],
968         [       AC_MSG_RESULT(no) 
969                 ac_cv_lib_vpb_vpb_open="no" 
970         ]
971         )
972    LIBS="${saved_libs}"
973    CPPFLAGS="${saved_cppflags}"
974    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
975         VPB_LIB="-lvpb"
976         if test "${VPB_DIR}" != ""; then
977            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
978            VPB_INCLUDE="-I${VPB_DIR}/include"
979         fi
980         PBX_VPB=1
981         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
982    fi
983 fi
984
985 AC_LANG_POP
986
987 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
988
989 # Check for various zaptel features and locations.
990 # The version number, which goes into HAVE_ZAPTEL_VERSION,
991 # will be used in the system headers to determine the location
992 # of the zaptel.h header.
993
994 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
995 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
996
997 # Check for VLDTMF support
998 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
999
1000 # Check for transcode support
1001 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1002
1003 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1004 case "${host_os}" in
1005     freebsd*)
1006         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1007         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1008         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1009
1010         # other case, old tonezone (0.80)
1011         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1012         ;;
1013 esac
1014
1015 EDITLINE_LIB=""
1016 if test "x$TERMCAP_LIB" != "x" ; then
1017   EDITLINE_LIB="$TERMCAP_LIB"
1018 elif test "x$TINFO_LIB" != "x" ; then
1019   EDITLINE_LIB="$TINFO_LIB"
1020 elif test "x$CURSES_LIB" != "x" ; then
1021   EDITLINE_LIB="$CURSES_LIB"
1022 elif test "x$NCURSES_LIB" != "x" ; then
1023   EDITLINE_LIB="$NCURSES_LIB"
1024 else
1025   AC_MSG_ERROR(*** termcap support not found)
1026 fi
1027 AC_SUBST(EDITLINE_LIB)
1028
1029 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1030 AC_SUBST(PBX_H323)
1031
1032 AC_CHECK_HEADER([linux/compiler.h],
1033                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1034
1035 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1036                                    #include <linux/version.h>
1037                                    #ifdef HAVE_LINUX_COMPILER_H
1038                                    #include <linux/compiler.h>
1039                                    #endif
1040                                    ])
1041 AC_SUBST(PBX_IXJUSER)
1042
1043 PBX_GTK=0
1044 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1045 if test ! "x${GTKCONFIG}" = xNo; then
1046    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1047    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1048    PBX_GTK=1
1049    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1050 fi
1051 AC_SUBST(PBX_GTK)
1052 AC_SUBST(GTK_INCLUDE)
1053 AC_SUBST(GTK_LIB)
1054
1055 PBX_GTK2=0
1056 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1057 if test ! "x${PKGCONFIG}" = xNo; then
1058    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1059    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1060    PBX_GTK2=1
1061    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1062 fi
1063 AC_SUBST(PBX_GTK2)
1064 AC_SUBST(GTK2_INCLUDE)
1065 AC_SUBST(GTK2_LIB)
1066
1067 if test "${USE_CURL}" != "no"; then
1068    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1069    if test ! x"${CURL_CONFIG}" = xNo; then
1070    # check for version
1071       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1072          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1073          CURL_LIB=$(${CURL_CONFIG} --libs)
1074
1075          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1076          saved_cppflags="${CPPFLAGS}"
1077          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1078          AC_COMPILE_IFELSE(
1079             [AC_LANG_PROGRAM(
1080                 [#include <curl/curl.h>],
1081                     [curl_version();])
1082             ],[
1083                 AC_MSG_RESULT(yes)
1084                 ac_cv_curl_h="yes"
1085             ],[
1086                 AC_MSG_RESULT(no)
1087                 ac_cv_curl_h="no"
1088             ]
1089          )
1090          CPPFLAGS="${saved_cppflags}"
1091          if test "${ac_cv_curl_h}" = "yes"; then
1092              PBX_CURL=1
1093              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1094          fi
1095       fi
1096    fi
1097 fi
1098
1099 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1100 AST_CHECK_MANDATORY
1101
1102 AC_OUTPUT
1103
1104 if test "x${silent}" != "xyes" ; then
1105 echo
1106 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1107 echo "            .\$7\$7..          .7\$\$7:.    "
1108 echo "          .\$\$:.                 ,\$7.7   "
1109 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1110 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1111 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1112 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1113 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1114 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1115 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1116 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1117 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1118 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1119 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1120 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1121 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1122 echo " \$\$\$\$\$                        \$\$\$       "
1123 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1124 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1125 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1126 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1127 echo
1128 fi
1129
1130 AC_MSG_NOTICE(Package configured for: )
1131 AC_MSG_NOTICE( OS type  : $host_os)
1132 AC_MSG_NOTICE( Host CPU : $host_cpu)
1133 if test "${cross_compiling}" = "yes"; then
1134    AC_MSG_NOTICE( Cross Compilation = YES)
1135 fi