These changes fix 10145 and 10150, a prob with BSD and exp2/log2 not existing, as...
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_CHECK_FUNCS([gethostbyname_r])
288
289 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
290 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
291
292 AC_MSG_CHECKING(for compiler atomic operations)
293 AC_LINK_IFELSE(
294 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
295 AC_MSG_RESULT(yes)
296 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
297 AC_MSG_RESULT(no)
298 )
299
300 AST_GCC_ATTRIBUTE(pure)
301 AST_GCC_ATTRIBUTE(malloc)
302 AST_GCC_ATTRIBUTE(const)
303 AST_GCC_ATTRIBUTE(unused)
304 AST_GCC_ATTRIBUTE(always_inline)
305
306 AC_MSG_CHECKING(for -ffunction-sections support)
307 saved_CFLAGS="${CFLAGS}"
308 CFLAGS="${CFLAGS} -ffunction-sections"
309 AC_COMPILE_IFELSE(
310         AC_LANG_PROGRAM([], [int x = 1;]),
311         AC_MSG_RESULT(yes)
312         [saved_LDFLAGS="${LDFLAGS}"]
313         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
314         AC_MSG_CHECKING(for --gc-sections support)
315         AC_LINK_IFELSE(
316                 AC_LANG_PROGRAM([], [int x = 1;]),
317                 AC_MSG_RESULT(yes)
318                 [GC_CFLAGS="-ffunction-sections"]
319                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
320                 AC_MSG_RESULT(no)
321         )
322         [LDFLAGS="${saved_LDFLAGS}"],
323         AC_MSG_RESULT(no)
324 )
325 CFLAGS="${saved_CFLAGS}"
326 AC_SUBST(GC_CFLAGS)
327 AC_SUBST(GC_LDFLAGS)
328
329 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
330 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
331         AC_MSG_RESULT(yes)
332         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
333 else
334         AC_MSG_RESULT(no)
335         AST_DECLARATION_AFTER_STATEMENT=
336 fi
337 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
338
339
340 AC_MSG_CHECKING(for sysinfo)
341 AC_LINK_IFELSE(
342         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
343                         [struct sysinfo sys_info;]),
344         AC_MSG_RESULT(yes)
345         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
346         AC_MSG_RESULT(no)
347 )
348
349 AC_MSG_CHECKING(for res_ninit)
350 AC_LINK_IFELSE(
351         AC_LANG_PROGRAM([#include <resolv.h>],
352                         [int foo = res_ninit(NULL);]),
353         AC_MSG_RESULT(yes)
354         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
355         AC_MSG_RESULT(no)
356 )
357
358 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
359
360 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
361
362 AC_CHECK_HEADER([libkern/OSAtomic.h],
363                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
364
365 AC_CHECK_SIZEOF(int)
366
367 # do the package library checks now
368
369 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
370
371 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
372
373 if test "x${host_os}" = "xlinux-gnu" ; then
374   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
375 fi
376
377 # BSD might not have exp2, and/or log2
378 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
379 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
380
381 GSM_INTERNAL="yes"
382 AC_SUBST(GSM_INTERNAL)
383 GSM_SYSTEM="yes"
384 if test "${USE_GSM}" != "no"; then
385    if test "${GSM_DIR}" = "internal"; then
386       GSM_SYSTEM="no"
387    elif test "${GSM_DIR}" != ""; then
388       GSM_INTERNAL="no"
389    fi
390    if test "${GSM_SYSTEM}" = "yes"; then
391       gsmlibdir=""
392       if test "x${GSM_DIR}" != "x"; then
393          if test -d ${GSM_DIR}/lib; then
394             gsmlibdir="-L${GSM_DIR}/lib"
395          else
396             gsmlibdir="-L${GSM_DIR}"
397          fi
398       fi
399       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
400       [Define to indicate the GSM library]), [], ${gsmlibdir})
401       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
402          if test "x${GSM_DIR}" != "x" ; then
403             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
404             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
405          else
406             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
407             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
408          fi
409          if test "${GSM_HEADER_FOUND}" = "0" ; then
410             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
411                if test "x${GSM_MANDATORY}" = "xyes" ; then
412                   AC_MSG_NOTICE([***])
413                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
414                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
415                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
416                   exit 1
417                fi
418             fi
419          fi
420          GSM_OK=0
421          if test "${GSM_HEADER_FOUND}" = "1" ; then
422             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
423             GSM_OK=1
424          else
425             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
426                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
427                GSM_OK=1
428             fi
429          fi
430          if test "${GSM_OK}" = "1" ; then
431             GSM_LIB="-lgsm"
432             if test "x${GSM_DIR}" != "x"; then
433                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
434                GSM_INCLUDE="-I${GSM_DIR}/include"
435             fi
436             PBX_GSM=1
437             GSM_INTERNAL="no"
438          fi
439       fi
440    fi
441    if test "${GSM_INTERNAL}" = "yes"; then
442       PBX_GSM=1
443       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
444    fi
445 fi
446
447 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
448
449 if test "${PBX_IKSEMEL}" = 1; then
450    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
451 fi
452
453 if test "${USE_IMAP_TK}" != "no"; then
454    if test "${IMAP_TK_DIR}" = "system" ; then
455       AC_MSG_NOTICE([Checking for system c-client library...])
456    elif test "${IMAP_TK_DIR}" = ""; then
457       IMAP_TK_DIR=`pwd`"/../imap-2004g"
458       if test  -n "${IMAP_TK_MANDATORY}"; then
459          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
460          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
461          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
462          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
463       fi
464    fi
465    if test "${IMAP_TK_DIR}" != "system" ; then
466       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
467    fi
468    saved_cppflags="${CPPFLAGS}"
469    saved_libs="${LIBS}"
470    if test "${IMAP_TK_DIR}" = "system" ; then
471       imap_ldflags=""
472       imap_libs="-lc-client"
473       imap_include="-DUSE_SYSTEM_IMAP"
474    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
475       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
476       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
477       imap_include="-I${IMAP_TK_DIR}/c-client"
478    fi
479    CPPFLAGS="${CPPFLAGS} ${imap_include}"
480    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
481    AC_LINK_IFELSE(
482         AC_LANG_PROGRAM(
483                 [#ifdef USE_SYSTEM_IMAP
484                 #include <imap/c-client.h>
485                 #else
486                 #include "c-client.h"
487                 #endif
488                 void mm_searched (MAILSTREAM *stream,unsigned long number)
489                 {
490                 }
491                 void mm_exists (MAILSTREAM *stream,unsigned long number)
492                 {
493                 }
494                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
495                 {
496                 }
497                 void mm_flags (MAILSTREAM *stream,unsigned long number)
498                 {
499                 }
500                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
501                 {
502                 }
503                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
504                 {
505                 }
506                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
507                 {
508                 }
509                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
510                 {
511                 }
512                 void mm_log (char *string,long errflg)
513                 {
514                 }
515                 void mm_dlog (char *string)
516                 {
517                 }
518                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
519                 {
520                 }
521                 void mm_critical (MAILSTREAM *stream)
522                 {
523                 }
524                 void mm_nocritical (MAILSTREAM *stream)
525                 {
526                 }
527                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
528                 {
529                 }
530                 void mm_fatal (char *string)
531                 {
532                 }],
533                 [
534                 MAILSTREAM *foo = mail_open(NULL, "", 0);
535                 ]
536         ),
537         [ac_cv_imap_tk="yes"],
538         [ac_cv_imap_tk="no"]
539    )
540    if test "${ac_cv_imap_tk}" = "yes"; then
541    AC_LINK_IFELSE(
542       AC_LANG_PROGRAM(
543          [#ifdef USE_SYSTEM_IMAP
544          #include <imap/c-client.h>
545          #else
546          #include "c-client.h"
547          #endif
548          void mm_searched (MAILSTREAM *stream,unsigned long number)
549          {
550          }
551          void mm_exists (MAILSTREAM *stream,unsigned long number)
552          {
553          }
554          void mm_expunged (MAILSTREAM *stream,unsigned long number)
555          {
556          }
557          void mm_flags (MAILSTREAM *stream,unsigned long number)
558          {
559          }
560          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
561          {
562          }
563          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
564          {
565          }
566          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
567          {
568          }
569          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
570          {
571          }
572          void mm_log (char *string,long errflg)
573          {
574          }
575          void mm_dlog (char *string)
576          {
577          }
578          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
579          {
580          }
581          void mm_critical (MAILSTREAM *stream)
582          {
583          }
584          void mm_nocritical (MAILSTREAM *stream)
585          {
586          }
587          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
588          {
589          }
590          void mm_fatal (char *string)
591          {
592          }],
593          [
594          long check = mail_expunge_full(NULL, "", 0);
595          ]
596       ),
597       [ac_cv_imap_tk2006="yes"],
598       [ac_cv_imap_tk2006="no"]
599   )
600   fi
601    CPPFLAGS="${saved_cppflags}"
602    LIBS="${saved_libs}"
603    if test "${ac_cv_imap_tk}" = "yes"; then
604       AC_MSG_RESULT(yes) 
605       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
606       IMAP_TK_INCLUDE="${imap_include}"
607       PBX_IMAP_TK=1
608       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
609       if test "${ac_cv_imap_tk2006}" = "yes"; then
610          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
611       fi
612    else
613       AC_MSG_RESULT(no) 
614    fi
615 fi
616
617 # Needed by unixodbc
618 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
619
620 AC_LANG_PUSH(C++)
621
622 if test "${USE_KDE}" != "no"; then
623    AC_MSG_CHECKING(for crashHandler in -lkdecore)
624    saved_libs="${LIBS}"
625    saved_cppflags="${CPPFLAGS}"
626    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
627    if test -d ${KDE_DIR}/lib; then
628       kdelibdir="${KDE_DIR}/lib"
629    else
630       kdelibdir="${KDE_DIR}"
631    fi
632    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
633
634    AC_LINK_IFELSE(
635         [AC_LANG_PROGRAM(
636                         [#include "kcrash.h"],
637                         [KCrash::defaultCrashHandler(1);])
638         ],
639         [ac_cv_lib_kde_crash="yes"],
640         [ac_cv_lib_kde_crash="no"])
641                 
642    LIBS="${saved_libs}"
643    CPPFLAGS="${saved_cppflags}"
644         
645    if test "${ac_cv_lib_kde_crash}" = "yes"; then
646       AC_MSG_RESULT(yes) 
647       KDE_LIB="-lkdecore -lkdeui"
648       if test "${KDE_DIR}" != ""; then
649          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
650          KDE_INCLUDE="-I${KDE_DIR}/include"
651       fi
652       PBX_KDE=1
653       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
654    else
655       AC_MSG_RESULT(no) 
656    fi
657 fi
658 if test "${PBX_KDE}" = 1; then
659    AC_PATH_TOOL(KDEINIT, kdeinit, No)
660    if test ! x"${KDEINIT}" = xNo; then
661       KDEDIR=$(${DIRNAME} ${KDEINIT})
662       KDEDIR=$(${DIRNAME} ${KDEDIR})
663    fi
664    AC_SUBST([KDEDIR])
665 fi
666
667 AC_LANG_POP
668
669 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
670
671 if test "${PBX_MISDN}" = 1; then
672    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
673    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
674    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
675 fi
676
677 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
678
679 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
680
681 NETSNMP_CONFIG=No
682 if test "${USE_NETSNMP}" != "no"; then  
683    if test "x${NETSNMP_DIR}" != "x"; then
684       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
685       if test x"${NETSNMP_CONFIG}" = xNo; then
686          AC_MSG_NOTICE([***])
687          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
688          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
689          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
690          AC_MSG_NOTICE([*** including --without-netsnmp])
691          exit 1
692       fi
693    else
694       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
695    fi
696 fi
697 if test x"${NETSNMP_CONFIG}" != xNo; then
698    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
699    
700    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
701    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
702
703    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
704       NETSNMP_LIB="${NETSNMP_libs}"
705       PBX_NETSNMP=1
706    fi
707 fi
708
709 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
710
711 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
712
713 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
714
715 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
716
717 # possible places for oss definitions
718 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
719 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
720 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
721
722 PG_CONFIG=No
723 if test "${USE_PGSQL}" != "no"; then    
724    if test "x${PGSQL_DIR}" != "x"; then
725       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
726       if test x"${PG_CONFIG}" = xNo; then
727          AC_MSG_NOTICE([***])
728          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
729          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
730          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
731          AC_MSG_NOTICE([*** including --without-postgres])
732          exit 1
733       fi
734    else
735       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
736    fi
737 fi
738 if test "${PG_CONFIG}" != No; then
739    PGSQL_libdir=`${PG_CONFIG} --libdir`
740    PGSQL_includedir=`${PG_CONFIG} --includedir`
741    if test "x$?" != "x0" ; then
742       if test -n "${PGSQL_MANDATORY}" ; then
743          AC_MSG_NOTICE([***])
744          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
745          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
746          AC_MSG_NOTICE([*** including --without-postgres])
747          exit 1
748           fi
749    else 
750       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
751       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
752
753       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
754          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
755          PGSQL_INCLUDE="-I${PGSQL_includedir}"
756          PBX_PGSQL=1
757       elif test -n "${PGSQL_MANDATORY}";
758       then
759          AC_MSG_NOTICE([***])
760          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
761          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
762          AC_MSG_NOTICE([*** including --without-postgres])
763          exit 1
764       fi
765    fi
766 fi
767
768 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
769
770 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
771
772 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
773
774 if test "${USE_PWLIB}" != "no"; then
775         if test -n "${PWLIB_DIR}"; then
776                 PWLIBDIR="${PWLIB_DIR}"
777         fi
778         AST_CHECK_PWLIB()
779         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
780                 
781         if test "${HAS_PWLIB:-unset}" != "unset"; then
782                 AST_CHECK_OPENH323_PLATFORM()
783
784                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
785
786                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
787                         [Define if your system has the PWLib libraries.],
788                         [#include "ptlib.h"],
789                         [BOOL q = PTime::IsDaylightSavings();])
790         fi
791 fi
792
793 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
794         if test -n "${OPENH323_DIR}"; then
795                 OPENH323DIR="${OPENH323_DIR}"
796         fi
797         AST_CHECK_OPENH323()
798         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
799         AST_CHECK_OPENH323_BUILD()
800         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
801         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
802                 [Define if your system has the OpenH323 libraries.],
803                 [#include "ptlib.h"
804                 #include "h323.h"
805                 #include "h323ep.h"],
806                 [H323EndPoint ep = H323EndPoint();],
807                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
808 fi
809
810 AC_LANG_PUSH(C++)
811
812 if test "${USE_QT}" != "no"; then
813    AC_MSG_CHECKING(for QDate in -lqt)
814    saved_libs="${LIBS}"
815    saved_cppflags="${CPPFLAGS}"
816    if test "x${QT_DIR}" != "x"; then
817       LIBS="${LIBS} -L${QT_DIR}/lib"
818       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
819    fi
820    LIBS="${LIBS} -lqt"
821    qtlib="qt"
822    AC_LINK_IFELSE(
823         [
824                 AC_LANG_PROGRAM(
825                 [#include <qt3/qdatetime.h>],
826                 [QDate date();])
827         ],
828         [ac_cv_lib_qt_qt_date="yes"],
829         [ac_cv_lib_qt_qt_date="no"])
830    LIBS="${saved_libs}"
831    CPPFLAGS="${saved_cppflags}"
832         
833    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
834       saved_libs="${LIBS}"
835       saved_cppflags="${CPPFLAGS}"
836       if test "x${QT_DIR}" != "x"; then
837          LIBS="${LIBS} -L${QT_DIR}/lib"
838          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
839       fi
840       LIBS="${LIBS} -lqt-mt"
841       qtlib="qt-mt"     
842       AC_LINK_IFELSE(
843                 [
844                         AC_LANG_PROGRAM(
845                         [#include <qt3/qdatetime.h>],
846                         [QDate date();])
847                 ],
848                 [ac_cv_lib_qt_qt_date="yes"],
849                 [ac_cv_lib_qt_qt_date="no"])
850       LIBS="${saved_libs}"
851       CPPFLAGS="${saved_cppflags}"
852    fi   
853
854    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
855       AC_MSG_RESULT(yes) 
856    else
857       AC_MSG_RESULT(no) 
858    fi
859         
860    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
861       QT_LIB="-l${qtlib}"
862       if test "${QT_DIR}" != ""; then
863          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
864          QT_INCLUDE="-I${QT_DIR}/include"
865       fi
866       PBX_QT=1
867       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
868       AC_PATH_TOOL(QTMOC, moc, No)
869    fi
870 fi
871
872 AC_LANG_POP
873
874 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
875
876 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
877
878 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
879
880 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
881
882 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
883
884 if test "$PBX_CRYPTO" = "1";
885 then
886     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
887 fi
888
889 if test "$PBX_OPENSSL" = "1";
890 then
891     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
892 fi
893
894 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
895 if test "${PBX_FREETDS}" != "0";
896 then
897     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
898         *0.64*)
899                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
900         ;;
901     *0.63*)
902         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
903         ;;
904     *0.62*)
905         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
906         ;;
907     *)
908         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
909         ;;
910     esac
911 fi
912
913 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
914
915 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
916
917 if test "${host_os}" != "linux-gnu" ; then
918   tonezone_extra="-lm"
919 fi
920
921 # new tonezone, version 1.4.0
922 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
923 # other case, old tonezone (0.80)
924 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
925
926 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
927
928 AC_LANG_PUSH(C++)
929
930 if test "${USE_VPB}" != "no"; then
931    AC_MSG_CHECKING(for vpb_open in -lvpb)
932    saved_libs="${LIBS}"
933    saved_cppflags="${CPPFLAGS}"
934    if test "x${VPB_DIR}" != "x"; then
935       if test -d ${VPB_DIR}/lib; then
936          vpblibdir=${VPB_DIR}/lib
937       else
938          vpblibdir=${VPB_DIR}
939       fi
940       LIBS="${LIBS} -L${vpblibdir}"
941       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
942    fi
943    LIBS="${LIBS} -lvpb -lpthread"
944    AC_LINK_IFELSE(
945         [
946         AC_LANG_PROGRAM(
947         [#include <vpbapi.h>],
948         [int q = vpb_open(0,0);])
949         ],
950         [       AC_MSG_RESULT(yes) 
951                 ac_cv_lib_vpb_vpb_open="yes" 
952         ],
953         [       AC_MSG_RESULT(no) 
954                 ac_cv_lib_vpb_vpb_open="no" 
955         ]
956         )
957    LIBS="${saved_libs}"
958    CPPFLAGS="${saved_cppflags}"
959    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
960         VPB_LIB="-lvpb"
961         if test "${VPB_DIR}" != ""; then
962            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
963            VPB_INCLUDE="-I${VPB_DIR}/include"
964         fi
965         PBX_VPB=1
966         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
967    fi
968 fi
969
970 AC_LANG_POP
971
972 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
973
974 # Check for various zaptel features and locations.
975 # The version number, which goes into HAVE_ZAPTEL_VERSION,
976 # will be used in the system headers to determine the location
977 # of the zaptel.h header.
978
979 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
980 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
981
982 # Check for VLDTMF support
983 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
984
985 # Check for transcode support
986 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
987
988 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
989 case "${host_os}" in
990     freebsd*)
991         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
992         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
993         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
994
995         # other case, old tonezone (0.80)
996         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
997         ;;
998 esac
999
1000 EDITLINE_LIB=""
1001 if test "x$TERMCAP_LIB" != "x" ; then
1002   EDITLINE_LIB="$TERMCAP_LIB"
1003 elif test "x$TINFO_LIB" != "x" ; then
1004   EDITLINE_LIB="$TINFO_LIB"
1005 elif test "x$CURSES_LIB" != "x" ; then
1006   EDITLINE_LIB="$CURSES_LIB"
1007 elif test "x$NCURSES_LIB" != "x" ; then
1008   EDITLINE_LIB="$NCURSES_LIB"
1009 else
1010   AC_MSG_ERROR(*** termcap support not found)
1011 fi
1012 AC_SUBST(EDITLINE_LIB)
1013
1014 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1015 AC_SUBST(PBX_H323)
1016
1017 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1018                                    #include <linux/version.h>
1019                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
1020                                    #include <linux/compiler.h>
1021                                    #endif
1022                                    ])
1023 AC_SUBST(PBX_IXJUSER)
1024
1025 PBX_GTK=0
1026 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1027 if test ! "x${GTKCONFIG}" = xNo; then
1028    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1029    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1030    PBX_GTK=1
1031    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1032 fi
1033 AC_SUBST(PBX_GTK)
1034 AC_SUBST(GTK_INCLUDE)
1035 AC_SUBST(GTK_LIB)
1036
1037 PBX_GTK2=0
1038 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1039 if test ! "x${PKGCONFIG}" = xNo; then
1040    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1041    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1042    PBX_GTK2=1
1043    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1044 fi
1045 AC_SUBST(PBX_GTK2)
1046 AC_SUBST(GTK2_INCLUDE)
1047 AC_SUBST(GTK2_LIB)
1048
1049 if test "${USE_CURL}" != "no"; then
1050    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1051    if test ! x"${CURL_CONFIG}" = xNo; then
1052    # check for version
1053       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1054          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1055          CURL_LIB=$(${CURL_CONFIG} --libs)
1056
1057          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1058          saved_cppflags="${CPPFLAGS}"
1059          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1060          AC_COMPILE_IFELSE(
1061             [AC_LANG_PROGRAM(
1062                 [#include <curl/curl.h>],
1063                     [curl_version();])
1064             ],[
1065                 AC_MSG_RESULT(yes)
1066                 ac_cv_curl_h="yes"
1067             ],[
1068                 AC_MSG_RESULT(no)
1069                 ac_cv_curl_h="no"
1070             ]
1071          )
1072          CPPFLAGS="${saved_cppflags}"
1073          if test "${ac_cv_curl_h}" = "yes"; then
1074              PBX_CURL=1
1075              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1076          fi
1077       fi
1078    fi
1079 fi
1080
1081 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1082 AST_CHECK_MANDATORY
1083
1084 AC_OUTPUT
1085
1086 if test "x${silent}" != "xyes" ; then
1087 echo
1088 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1089 echo "            .\$7\$7..          .7\$\$7:.    "
1090 echo "          .\$\$:.                 ,\$7.7   "
1091 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1092 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1093 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1094 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1095 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1096 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1097 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1098 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1099 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1100 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1101 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1102 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1103 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1104 echo " \$\$\$\$\$                        \$\$\$       "
1105 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1106 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1107 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1108 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1109 echo
1110 fi
1111
1112 AC_MSG_NOTICE(Package configured for: )
1113 AC_MSG_NOTICE( OS type  : $host_os)
1114 AC_MSG_NOTICE( Host CPU : $host_cpu)
1115 if test "${cross_compiling}" = "yes"; then
1116    AC_MSG_NOTICE( Cross Compilation = YES)
1117 fi