Add support for using epoll instead of poll. This should increase scalability and...
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <stdlib.h>
292                          #include <netdb.h>],
293                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
294         AC_MSG_RESULT(yes)
295         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
296         AC_MSG_RESULT(no)
297 )
298
299 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
300 AC_LINK_IFELSE(
301         AC_LANG_PROGRAM([#include <stdlib.h>
302                          #include <netdb.h>],
303                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
304         AC_MSG_RESULT(yes)
305         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
306         AC_MSG_RESULT(no)
307 )
308
309 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
310
311 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
312 AC_LINK_IFELSE(
313 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
314 AC_MSG_RESULT(yes)
315 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
316 AC_MSG_RESULT(no)
317 )
318
319 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
320 AC_LINK_IFELSE(
321 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
322 AC_MSG_RESULT(yes)
323 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
324 AC_MSG_RESULT(no)
325 )
326
327 if test "${cross_compiling}" = "no";
328 then
329   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
330 fi
331
332 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
333 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
334
335 AC_MSG_CHECKING(for working epoll support)
336 AC_LINK_IFELSE(
337 AC_LANG_PROGRAM([#include <sys/epoll.h>], [epoll_create(10);]),
338 AC_MSG_RESULT(yes)
339 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
340 AC_MSG_RESULT(no)
341 )
342
343 AC_MSG_CHECKING(for compiler atomic operations)
344 AC_LINK_IFELSE(
345 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
346 AC_MSG_RESULT(yes)
347 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
348 AC_MSG_RESULT(no)
349 )
350
351 AST_GCC_ATTRIBUTE(pure)
352 AST_GCC_ATTRIBUTE(malloc)
353 AST_GCC_ATTRIBUTE(const)
354 AST_GCC_ATTRIBUTE(unused)
355 AST_GCC_ATTRIBUTE(always_inline)
356 AST_GCC_ATTRIBUTE(deprecated)
357
358 AC_MSG_CHECKING(for -ffunction-sections support)
359 saved_CFLAGS="${CFLAGS}"
360 CFLAGS="${CFLAGS} -ffunction-sections"
361 AC_COMPILE_IFELSE(
362         AC_LANG_PROGRAM([], [int x = 1;]),
363         AC_MSG_RESULT(yes)
364         [saved_LDFLAGS="${LDFLAGS}"]
365         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
366         AC_MSG_CHECKING(for --gc-sections support)
367         AC_LINK_IFELSE(
368                 AC_LANG_PROGRAM([], [int x = 1;]),
369                 AC_MSG_RESULT(yes)
370                 [GC_CFLAGS="-ffunction-sections"]
371                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
372                 AC_MSG_RESULT(no)
373         )
374         [LDFLAGS="${saved_LDFLAGS}"],
375         AC_MSG_RESULT(no)
376 )
377 CFLAGS="${saved_CFLAGS}"
378 AC_SUBST(GC_CFLAGS)
379 AC_SUBST(GC_LDFLAGS)
380
381 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
382 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
383         AC_MSG_RESULT(yes)
384         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
385 else
386         AC_MSG_RESULT(no)
387         AST_DECLARATION_AFTER_STATEMENT=
388 fi
389 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
390
391
392 AC_MSG_CHECKING(for sysinfo)
393 AC_LINK_IFELSE(
394         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
395                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
396         AC_MSG_RESULT(yes)
397         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
398         AC_MSG_RESULT(no)
399 )
400
401 AC_MSG_CHECKING(for res_ninit)
402 AC_LINK_IFELSE(
403         AC_LANG_PROGRAM([#include <resolv.h>],
404                         [int foo = res_ninit(NULL);]),
405         AC_MSG_RESULT(yes)
406         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
407         AC_MSG_CHECKING(for res_ndestroy)
408         AC_LINK_IFELSE(
409                 AC_LANG_PROGRAM([#include <resolv.h>],
410                                 [int foo = res_ndestroy(NULL);]),
411                 AC_MSG_RESULT(yes)
412                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
413                 AC_MSG_RESULT(no)
414         ),
415         AC_MSG_RESULT(no)
416 )
417
418 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
419
420 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
421
422 AC_CHECK_HEADER([libkern/OSAtomic.h],
423                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
424
425 AC_CHECK_SIZEOF(int)
426
427 # do the package library checks now
428
429 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
430
431 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
432
433 if test "x${host_os}" = "xlinux-gnu" ; then
434   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
435 fi
436
437 # BSD might not have exp2, and/or log2
438 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
439 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
440 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
441 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
442 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
443 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
444 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
445 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
446
447 GSM_INTERNAL="yes"
448 AC_SUBST(GSM_INTERNAL)
449 GSM_SYSTEM="yes"
450 if test "${USE_GSM}" != "no"; then
451    if test "${GSM_DIR}" = "internal"; then
452       GSM_SYSTEM="no"
453    elif test "${GSM_DIR}" != ""; then
454       GSM_INTERNAL="no"
455    fi
456    if test "${GSM_SYSTEM}" = "yes"; then
457       gsmlibdir=""
458       if test "x${GSM_DIR}" != "x"; then
459          if test -d ${GSM_DIR}/lib; then
460             gsmlibdir="-L${GSM_DIR}/lib"
461          else
462             gsmlibdir="-L${GSM_DIR}"
463          fi
464       fi
465       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
466       [Define to indicate the GSM library]), [], ${gsmlibdir})
467       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
468          if test "x${GSM_DIR}" != "x" ; then
469             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
470             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
471          else
472             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
473             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
474          fi
475          if test "${GSM_HEADER_FOUND}" = "0" ; then
476             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
477                if test "x${GSM_MANDATORY}" = "xyes" ; then
478                   AC_MSG_NOTICE([***])
479                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
480                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
481                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
482                   exit 1
483                fi
484             fi
485          fi
486          GSM_OK=0
487          if test "${GSM_HEADER_FOUND}" = "1" ; then
488             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
489             GSM_OK=1
490          else
491             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
492                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
493                GSM_OK=1
494             fi
495          fi
496          if test "${GSM_OK}" = "1" ; then
497             GSM_LIB="-lgsm"
498             if test "x${GSM_DIR}" != "x"; then
499                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
500                GSM_INCLUDE="-I${GSM_DIR}/include"
501             fi
502             PBX_GSM=1
503             GSM_INTERNAL="no"
504          fi
505       fi
506    fi
507    if test "${GSM_INTERNAL}" = "yes"; then
508       PBX_GSM=1
509       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
510    fi
511 fi
512
513 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
514
515 if test "${PBX_IKSEMEL}" = 1; then
516    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
517 fi
518
519 if test "${USE_IMAP_TK}" != "no"; then
520    if test "${IMAP_TK_DIR}" = "system" ; then
521       AC_MSG_NOTICE([Checking for system c-client library...])
522    elif test "${IMAP_TK_DIR}" = ""; then
523       IMAP_TK_DIR=`pwd`"/../imap-2004g"
524       if test  -n "${IMAP_TK_MANDATORY}"; then
525          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
526          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
527          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
528          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
529       fi
530    fi
531    if test "${IMAP_TK_DIR}" != "system" ; then
532       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
533    fi
534    saved_cppflags="${CPPFLAGS}"
535    saved_libs="${LIBS}"
536    if test "${IMAP_TK_DIR}" = "system" ; then
537       imap_ldflags=""
538       imap_libs="-lc-client"
539       imap_include="-DUSE_SYSTEM_IMAP"
540    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
541       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
542       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
543       imap_include="-I${IMAP_TK_DIR}/c-client"
544    fi
545    CPPFLAGS="${CPPFLAGS} ${imap_include}"
546    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
547    AC_LINK_IFELSE(
548         AC_LANG_PROGRAM(
549                 [#ifdef USE_SYSTEM_IMAP
550                 #include <imap/c-client.h>
551                 #else
552                 #include "c-client.h"
553                 #endif
554                 void mm_searched (MAILSTREAM *stream,unsigned long number)
555                 {
556                 }
557                 void mm_exists (MAILSTREAM *stream,unsigned long number)
558                 {
559                 }
560                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
561                 {
562                 }
563                 void mm_flags (MAILSTREAM *stream,unsigned long number)
564                 {
565                 }
566                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
567                 {
568                 }
569                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
570                 {
571                 }
572                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
573                 {
574                 }
575                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
576                 {
577                 }
578                 void mm_log (char *string,long errflg)
579                 {
580                 }
581                 void mm_dlog (char *string)
582                 {
583                 }
584                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
585                 {
586                 }
587                 void mm_critical (MAILSTREAM *stream)
588                 {
589                 }
590                 void mm_nocritical (MAILSTREAM *stream)
591                 {
592                 }
593                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
594                 {
595                 }
596                 void mm_fatal (char *string)
597                 {
598                 }],
599                 [
600                 MAILSTREAM *foo = mail_open(NULL, "", 0);
601                 ]
602         ),
603         [ac_cv_imap_tk="yes"],
604         [ac_cv_imap_tk="no"]
605    )
606    if test "${ac_cv_imap_tk}" = "yes"; then
607    AC_LINK_IFELSE(
608       AC_LANG_PROGRAM(
609          [#ifdef USE_SYSTEM_IMAP
610          #include <imap/c-client.h>
611          #else
612          #include "c-client.h"
613          #endif
614          void mm_searched (MAILSTREAM *stream,unsigned long number)
615          {
616          }
617          void mm_exists (MAILSTREAM *stream,unsigned long number)
618          {
619          }
620          void mm_expunged (MAILSTREAM *stream,unsigned long number)
621          {
622          }
623          void mm_flags (MAILSTREAM *stream,unsigned long number)
624          {
625          }
626          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
627          {
628          }
629          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
630          {
631          }
632          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
633          {
634          }
635          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
636          {
637          }
638          void mm_log (char *string,long errflg)
639          {
640          }
641          void mm_dlog (char *string)
642          {
643          }
644          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
645          {
646          }
647          void mm_critical (MAILSTREAM *stream)
648          {
649          }
650          void mm_nocritical (MAILSTREAM *stream)
651          {
652          }
653          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
654          {
655          }
656          void mm_fatal (char *string)
657          {
658          }],
659          [
660          long check = mail_expunge_full(NULL, "", 0);
661          ]
662       ),
663       [ac_cv_imap_tk2006="yes"],
664       [ac_cv_imap_tk2006="no"]
665   )
666   fi
667    CPPFLAGS="${saved_cppflags}"
668    LIBS="${saved_libs}"
669    if test "${ac_cv_imap_tk}" = "yes"; then
670       AC_MSG_RESULT(yes) 
671       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
672       IMAP_TK_INCLUDE="${imap_include}"
673       PBX_IMAP_TK=1
674       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
675       if test "${ac_cv_imap_tk2006}" = "yes"; then
676          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
677       fi
678    else
679       AC_MSG_RESULT(no) 
680    fi
681 fi
682
683 # Needed by unixodbc
684 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
685
686 AC_LANG_PUSH(C++)
687
688 if test "${USE_KDE}" != "no"; then
689    AC_MSG_CHECKING(for crashHandler in -lkdecore)
690    saved_libs="${LIBS}"
691    saved_cppflags="${CPPFLAGS}"
692    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
693    if test -d ${KDE_DIR}/lib; then
694       kdelibdir="${KDE_DIR}/lib"
695    else
696       kdelibdir="${KDE_DIR}"
697    fi
698    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
699
700    AC_LINK_IFELSE(
701         [AC_LANG_PROGRAM(
702                         [#include "kcrash.h"],
703                         [KCrash::defaultCrashHandler(1);])
704         ],
705         [ac_cv_lib_kde_crash="yes"],
706         [ac_cv_lib_kde_crash="no"])
707                 
708    LIBS="${saved_libs}"
709    CPPFLAGS="${saved_cppflags}"
710         
711    if test "${ac_cv_lib_kde_crash}" = "yes"; then
712       AC_MSG_RESULT(yes) 
713       KDE_LIB="-lkdecore -lkdeui"
714       if test "${KDE_DIR}" != ""; then
715          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
716          KDE_INCLUDE="-I${KDE_DIR}/include"
717       fi
718       PBX_KDE=1
719       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
720    else
721       AC_MSG_RESULT(no) 
722    fi
723 fi
724 if test "${PBX_KDE}" = 1; then
725    AC_PATH_TOOL(KDEINIT, kdeinit, No)
726    if test ! x"${KDEINIT}" = xNo; then
727       KDEDIR=$(${DIRNAME} ${KDEINIT})
728       KDEDIR=$(${DIRNAME} ${KDEDIR})
729    fi
730    AC_SUBST([KDEDIR])
731 fi
732
733 AC_LANG_POP
734
735 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
736
737 if test "${PBX_MISDN}" = 1; then
738    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
739    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
740    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
741 fi
742
743 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
744
745 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
746
747 NETSNMP_CONFIG=No
748 if test "${USE_NETSNMP}" != "no"; then  
749    if test "x${NETSNMP_DIR}" != "x"; then
750       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
751       if test x"${NETSNMP_CONFIG}" = xNo; then
752          AC_MSG_NOTICE([***])
753          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
754          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
755          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
756          AC_MSG_NOTICE([*** including --without-netsnmp])
757          exit 1
758       fi
759    else
760       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
761    fi
762 fi
763 if test x"${NETSNMP_CONFIG}" != xNo; then
764    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
765    
766    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
767    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
768
769    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
770       NETSNMP_LIB="${NETSNMP_libs}"
771       PBX_NETSNMP=1
772    fi
773 fi
774
775 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
776
777 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
778
779 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
780
781 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
782
783 # possible places for oss definitions
784 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
785 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
786 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
787
788 PG_CONFIG=No
789 if test "${USE_PGSQL}" != "no"; then    
790    if test "x${PGSQL_DIR}" != "x"; then
791       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
792       if test x"${PG_CONFIG}" = xNo; then
793          AC_MSG_NOTICE([***])
794          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
795          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
796          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
797          AC_MSG_NOTICE([*** including --without-postgres])
798          exit 1
799       fi
800    else
801       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
802    fi
803 fi
804 if test "${PG_CONFIG}" != No; then
805    PGSQL_libdir=`${PG_CONFIG} --libdir`
806    PGSQL_includedir=`${PG_CONFIG} --includedir`
807    if test "x$?" != "x0" ; then
808       if test -n "${PGSQL_MANDATORY}" ; then
809          AC_MSG_NOTICE([***])
810          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
811          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
812          AC_MSG_NOTICE([*** including --without-postgres])
813          exit 1
814           fi
815    else 
816       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
817       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
818
819       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
820          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
821          PGSQL_INCLUDE="-I${PGSQL_includedir}"
822          PBX_PGSQL=1
823       elif test -n "${PGSQL_MANDATORY}";
824       then
825          AC_MSG_NOTICE([***])
826          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
827          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
828          AC_MSG_NOTICE([*** including --without-postgres])
829          exit 1
830       fi
831    fi
832 fi
833
834 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
835
836 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
837
838 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
839
840 if test "${USE_PWLIB}" != "no"; then
841         if test -n "${PWLIB_DIR}"; then
842                 PWLIBDIR="${PWLIB_DIR}"
843         fi
844         AST_CHECK_PWLIB()
845         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
846                 
847         if test "${HAS_PWLIB:-unset}" != "unset"; then
848                 AST_CHECK_OPENH323_PLATFORM()
849
850                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
851
852                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
853                         [Define if your system has the PWLib libraries.],
854                         [#include "ptlib.h"],
855                         [BOOL q = PTime::IsDaylightSavings();])
856         fi
857 fi
858
859 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
860         if test -n "${OPENH323_DIR}"; then
861                 OPENH323DIR="${OPENH323_DIR}"
862         fi
863         AST_CHECK_OPENH323()
864         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
865         AST_CHECK_OPENH323_BUILD()
866         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
867         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
868                 [Define if your system has the OpenH323 libraries.],
869                 [#include "ptlib.h"
870                 #include "h323.h"
871                 #include "h323ep.h"],
872                 [H323EndPoint ep = H323EndPoint();],
873                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
874 fi
875
876 AC_LANG_PUSH(C++)
877
878 if test "${USE_QT}" != "no"; then
879    AC_MSG_CHECKING(for QDate in -lqt)
880    saved_libs="${LIBS}"
881    saved_cppflags="${CPPFLAGS}"
882    if test "x${QT_DIR}" != "x"; then
883       LIBS="${LIBS} -L${QT_DIR}/lib"
884       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
885    fi
886    LIBS="${LIBS} -lqt"
887    qtlib="qt"
888    AC_LINK_IFELSE(
889         [
890                 AC_LANG_PROGRAM(
891                 [#include <qt3/qdatetime.h>],
892                 [QDate date();])
893         ],
894         [ac_cv_lib_qt_qt_date="yes"],
895         [ac_cv_lib_qt_qt_date="no"])
896    LIBS="${saved_libs}"
897    CPPFLAGS="${saved_cppflags}"
898         
899    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
900       saved_libs="${LIBS}"
901       saved_cppflags="${CPPFLAGS}"
902       if test "x${QT_DIR}" != "x"; then
903          LIBS="${LIBS} -L${QT_DIR}/lib"
904          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
905       fi
906       LIBS="${LIBS} -lqt-mt"
907       qtlib="qt-mt"     
908       AC_LINK_IFELSE(
909                 [
910                         AC_LANG_PROGRAM(
911                         [#include <qt3/qdatetime.h>],
912                         [QDate date();])
913                 ],
914                 [ac_cv_lib_qt_qt_date="yes"],
915                 [ac_cv_lib_qt_qt_date="no"])
916       LIBS="${saved_libs}"
917       CPPFLAGS="${saved_cppflags}"
918    fi   
919
920    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
921       AC_MSG_RESULT(yes) 
922    else
923       AC_MSG_RESULT(no) 
924    fi
925         
926    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
927       QT_LIB="-l${qtlib}"
928       if test "${QT_DIR}" != ""; then
929          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
930          QT_INCLUDE="-I${QT_DIR}/include"
931       fi
932       PBX_QT=1
933       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
934       AC_PATH_TOOL(QTMOC, moc, No)
935    fi
936 fi
937
938 AC_LANG_POP
939
940 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
941
942 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
943
944 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
945
946 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
947
948 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
949
950 if test "$PBX_CRYPTO" = "1";
951 then
952     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
953 fi
954
955 if test "$PBX_OPENSSL" = "1";
956 then
957     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
958 fi
959
960 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
961 if test "${PBX_FREETDS}" != "0";
962 then
963     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
964         *0.64*)
965                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
966         ;;
967     *0.63*)
968         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
969         ;;
970     *0.62*)
971         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
972         ;;
973     *)
974         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
975         ;;
976     esac
977 fi
978
979 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
980
981 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
982
983 if test "${host_os}" != "linux-gnu" ; then
984   tonezone_extra="-lm"
985 fi
986
987 # new tonezone, version 1.4.0
988 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
989 # other case, old tonezone (0.80)
990 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
991
992 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
993
994 AC_LANG_PUSH(C++)
995
996 if test "${USE_VPB}" != "no"; then
997    AC_MSG_CHECKING(for vpb_open in -lvpb)
998    saved_libs="${LIBS}"
999    saved_cppflags="${CPPFLAGS}"
1000    if test "x${VPB_DIR}" != "x"; then
1001       if test -d ${VPB_DIR}/lib; then
1002          vpblibdir=${VPB_DIR}/lib
1003       else
1004          vpblibdir=${VPB_DIR}
1005       fi
1006       LIBS="${LIBS} -L${vpblibdir}"
1007       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1008    fi
1009    LIBS="${LIBS} -lvpb -lpthread"
1010    AC_LINK_IFELSE(
1011         [
1012         AC_LANG_PROGRAM(
1013         [#include <vpbapi.h>],
1014         [int q = vpb_open(0,0);])
1015         ],
1016         [       AC_MSG_RESULT(yes) 
1017                 ac_cv_lib_vpb_vpb_open="yes" 
1018         ],
1019         [       AC_MSG_RESULT(no) 
1020                 ac_cv_lib_vpb_vpb_open="no" 
1021         ]
1022         )
1023    LIBS="${saved_libs}"
1024    CPPFLAGS="${saved_cppflags}"
1025    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1026         VPB_LIB="-lvpb"
1027         if test "${VPB_DIR}" != ""; then
1028            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1029            VPB_INCLUDE="-I${VPB_DIR}/include"
1030         fi
1031         PBX_VPB=1
1032         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1033    fi
1034 fi
1035
1036 AC_LANG_POP
1037
1038 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1039
1040 # Check for various zaptel features and locations.
1041 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1042 # will be used in the system headers to determine the location
1043 # of the zaptel.h header.
1044
1045 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1046 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1047
1048 # Check for VLDTMF support
1049 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1050
1051 # Check for transcode support
1052 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1053
1054 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1055 case "${host_os}" in
1056     freebsd*)
1057         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1058         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1059         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1060
1061         # other case, old tonezone (0.80)
1062         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1063         ;;
1064 esac
1065
1066 EDITLINE_LIB=""
1067 if test "x$TERMCAP_LIB" != "x" ; then
1068   EDITLINE_LIB="$TERMCAP_LIB"
1069 elif test "x$TINFO_LIB" != "x" ; then
1070   EDITLINE_LIB="$TINFO_LIB"
1071 elif test "x$CURSES_LIB" != "x" ; then
1072   EDITLINE_LIB="$CURSES_LIB"
1073 elif test "x$NCURSES_LIB" != "x" ; then
1074   EDITLINE_LIB="$NCURSES_LIB"
1075 else
1076   AC_MSG_ERROR(*** termcap support not found)
1077 fi
1078 AC_SUBST(EDITLINE_LIB)
1079
1080 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1081 AC_SUBST(PBX_H323)
1082
1083 AC_CHECK_HEADER([linux/compiler.h],
1084                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1085
1086 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1087                                    #include <linux/version.h>
1088                                    #ifdef HAVE_LINUX_COMPILER_H
1089                                    #include <linux/compiler.h>
1090                                    #endif
1091                                    ])
1092 AC_SUBST(PBX_IXJUSER)
1093
1094 PBX_GTK=0
1095 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1096 if test ! "x${GTKCONFIG}" = xNo; then
1097    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1098    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1099    PBX_GTK=1
1100    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1101 fi
1102 AC_SUBST(PBX_GTK)
1103 AC_SUBST(GTK_INCLUDE)
1104 AC_SUBST(GTK_LIB)
1105
1106 PBX_GTK2=0
1107 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1108 if test ! "x${PKGCONFIG}" = xNo; then
1109    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1110    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1111    PBX_GTK2=1
1112    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1113 fi
1114 AC_SUBST(PBX_GTK2)
1115 AC_SUBST(GTK2_INCLUDE)
1116 AC_SUBST(GTK2_LIB)
1117
1118 if test "${USE_CURL}" != "no"; then
1119    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1120    if test ! x"${CURL_CONFIG}" = xNo; then
1121    # check for version
1122       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1123          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1124          CURL_LIB=$(${CURL_CONFIG} --libs)
1125
1126          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1127          saved_cppflags="${CPPFLAGS}"
1128          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1129          AC_COMPILE_IFELSE(
1130             [AC_LANG_PROGRAM(
1131                 [#include <curl/curl.h>],
1132                     [curl_version();])
1133             ],[
1134                 AC_MSG_RESULT(yes)
1135                 ac_cv_curl_h="yes"
1136             ],[
1137                 AC_MSG_RESULT(no)
1138                 ac_cv_curl_h="no"
1139             ]
1140          )
1141          CPPFLAGS="${saved_cppflags}"
1142          if test "${ac_cv_curl_h}" = "yes"; then
1143              PBX_CURL=1
1144              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1145          fi
1146       fi
1147    fi
1148 fi
1149
1150 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1151 AST_CHECK_MANDATORY
1152
1153 AC_OUTPUT
1154
1155 if test "x${silent}" != "xyes" ; then
1156 echo
1157 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1158 echo "            .\$7\$7..          .7\$\$7:.    "
1159 echo "          .\$\$:.                 ,\$7.7   "
1160 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1161 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1162 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1163 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1164 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1165 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1166 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1167 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1168 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1169 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1170 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1171 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1172 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1173 echo " \$\$\$\$\$                        \$\$\$       "
1174 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1175 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1176 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1177 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1178 echo
1179 fi
1180
1181 AC_MSG_NOTICE(Package configured for: )
1182 AC_MSG_NOTICE( OS type  : $host_os)
1183 AC_MSG_NOTICE( Host CPU : $host_cpu)
1184 if test "${cross_compiling}" = "yes"; then
1185    AC_MSG_NOTICE( Cross Compilation = YES)
1186 fi