Remove traces of gnutls, since we no longer use/need it.
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.60)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
191 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
192 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
193 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
194 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
195 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
196 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
197 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
198 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
199 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
200 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
201 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
202 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
203 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
204 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
205 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
206 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
207 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
208 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
209 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
210 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
211 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
212 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
213 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
214 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
215 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
216 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
217 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
218 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
219 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
220 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
221 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
222 AST_EXT_LIB_SETUP([USB], [usb], [usb])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap putenv re_comp regcomp select setenv socket strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <stdlib.h>
292                          #include <netdb.h>],
293                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
294         AC_MSG_RESULT(yes)
295         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
296         AC_MSG_RESULT(no)
297 )
298
299 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
300 AC_LINK_IFELSE(
301         AC_LANG_PROGRAM([#include <stdlib.h>
302                          #include <netdb.h>],
303                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
304         AC_MSG_RESULT(yes)
305         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
306         AC_MSG_RESULT(no)
307 )
308
309 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
310
311 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
312 AC_LINK_IFELSE(
313 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
314 AC_MSG_RESULT(yes)
315 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
316 AC_MSG_RESULT(no)
317 )
318
319 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
320 AC_LINK_IFELSE(
321 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
322 AC_MSG_RESULT(yes)
323 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
324 AC_MSG_RESULT(no)
325 )
326
327 if test "${cross_compiling}" = "no";
328 then
329   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
330 fi
331
332 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
333 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
334
335 if test "${cross_compiling}" = "no";
336 then
337 AC_MSG_CHECKING(for working epoll support)
338 AC_LINK_IFELSE(
339 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
340                                           if (res < 0)
341                                              return 1;
342                                           close (res);
343                                           return 0;]),
344 AC_MSG_RESULT(yes)
345 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
346 AC_MSG_RESULT(no)
347 )
348 fi
349
350 AC_MSG_CHECKING(for compiler atomic operations)
351 AC_LINK_IFELSE(
352 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
353 AC_MSG_RESULT(yes)
354 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
355 AC_MSG_RESULT(no)
356 )
357
358 AST_GCC_ATTRIBUTE(pure)
359 AST_GCC_ATTRIBUTE(malloc)
360 AST_GCC_ATTRIBUTE(const)
361 AST_GCC_ATTRIBUTE(unused)
362 AST_GCC_ATTRIBUTE(always_inline)
363 AST_GCC_ATTRIBUTE(deprecated)
364
365 AC_MSG_CHECKING(for -ffunction-sections support)
366 saved_CFLAGS="${CFLAGS}"
367 CFLAGS="${CFLAGS} -ffunction-sections"
368 AC_COMPILE_IFELSE(
369         AC_LANG_PROGRAM([], [int x = 1;]),
370         AC_MSG_RESULT(yes)
371         [saved_LDFLAGS="${LDFLAGS}"]
372         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
373         AC_MSG_CHECKING(for --gc-sections support)
374         AC_LINK_IFELSE(
375                 AC_LANG_PROGRAM([], [int x = 1;]),
376                 AC_MSG_RESULT(yes)
377                 [GC_CFLAGS="-ffunction-sections"]
378                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
379                 AC_MSG_RESULT(no)
380         )
381         [LDFLAGS="${saved_LDFLAGS}"],
382         AC_MSG_RESULT(no)
383 )
384 CFLAGS="${saved_CFLAGS}"
385 AC_SUBST(GC_CFLAGS)
386 AC_SUBST(GC_LDFLAGS)
387
388 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
389 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
390         AC_MSG_RESULT(yes)
391         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
392 else
393         AC_MSG_RESULT(no)
394         AST_DECLARATION_AFTER_STATEMENT=
395 fi
396 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
397
398
399 AC_MSG_CHECKING(for sysinfo)
400 AC_LINK_IFELSE(
401         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
402                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
403         AC_MSG_RESULT(yes)
404         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
405         AC_MSG_RESULT(no)
406 )
407
408 AC_MSG_CHECKING(for res_ninit)
409 AC_LINK_IFELSE(
410         AC_LANG_PROGRAM([#include <resolv.h>],
411                         [int foo = res_ninit(NULL);]),
412         AC_MSG_RESULT(yes)
413         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
414         AC_MSG_CHECKING(for res_ndestroy)
415         AC_LINK_IFELSE(
416                 AC_LANG_PROGRAM([#include <resolv.h>],
417                                 [int foo = res_ndestroy(NULL);]),
418                 AC_MSG_RESULT(yes)
419                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
420                 AC_MSG_RESULT(no)
421         ),
422         AC_MSG_RESULT(no)
423 )
424
425 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
426
427 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
428
429 AC_CHECK_HEADER([libkern/OSAtomic.h],
430                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
431
432 AC_CHECK_SIZEOF(int)
433
434 # do the package library checks now
435
436 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
437
438 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
439
440 if test "x${host_os}" = "xlinux-gnu" ; then
441   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
442 fi
443
444 # BSD might not have exp2, and/or log2
445 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
446 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
447 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
448 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
449 AST_EXT_LIB_CHECK([SINL], [m], [sinl])
450 AST_EXT_LIB_CHECK([COSL], [m], [cosl])
451 AST_EXT_LIB_CHECK([TANL], [m], [tanl])
452 AST_EXT_LIB_CHECK([ASINL], [m], [asinl])
453 AST_EXT_LIB_CHECK([ACOSL], [m], [acosl])
454 AST_EXT_LIB_CHECK([ATANL], [m], [atanl])
455 AST_EXT_LIB_CHECK([ATAN2L], [m], [atan2l])
456 AST_EXT_LIB_CHECK([POWL], [m], [powl])
457 AST_EXT_LIB_CHECK([SQRTL], [m], [sqrtl])
458 AST_EXT_LIB_CHECK([RINTL], [m], [rintl])
459 AST_EXT_LIB_CHECK([EXPL], [m], [expl])
460 AST_EXT_LIB_CHECK([LOGL], [m], [logl])
461 AST_EXT_LIB_CHECK([REMAINDERL], [m], [remainderl])
462 AST_EXT_LIB_CHECK([FMODL], [m], [fmodl])
463 AST_EXT_LIB_CHECK([ROUNDL], [m], [roundl])
464 AST_EXT_LIB_CHECK([TRUNCL], [m], [truncl])
465 AST_EXT_LIB_CHECK([STRTOLD], [c], [strtold], [stdlib.h])
466 AST_EXT_LIB_CHECK([FLOORL], [m], [floorl])
467 AST_EXT_LIB_CHECK([CEILL], [m], [ceill])
468 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
469 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
470 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
471 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
472 AST_EXT_LIB_CHECK([SIN], [m], [sin])
473 AST_EXT_LIB_CHECK([COS], [m], [cos])
474 AST_EXT_LIB_CHECK([TAN], [m], [tan])
475 AST_EXT_LIB_CHECK([ASIN], [m], [asin])
476 AST_EXT_LIB_CHECK([ACOS], [m], [acos])
477 AST_EXT_LIB_CHECK([ATAN], [m], [atan])
478 AST_EXT_LIB_CHECK([ATAN2], [m], [atan2])
479 AST_EXT_LIB_CHECK([POW], [m], [pow])
480 AST_EXT_LIB_CHECK([SQRT], [m], [sqrt])
481 AST_EXT_LIB_CHECK([RINT], [m], [rint])
482 AST_EXT_LIB_CHECK([EXP], [m], [exp])
483 AST_EXT_LIB_CHECK([LOG], [m], [log])
484 AST_EXT_LIB_CHECK([REMAINDER], [m], [remainder])
485 AST_EXT_LIB_CHECK([FMOD], [m], [fmod])
486 AST_EXT_LIB_CHECK([ROUND], [m], [round])
487 AST_EXT_LIB_CHECK([TRUNC], [m], [trunc])
488 AST_EXT_LIB_CHECK([STRTOD], [c], [strtod], [stdlib.h])
489 AST_EXT_LIB_CHECK([FLOOR], [m], [floor])
490 AST_EXT_LIB_CHECK([CEIL], [m], [ceil])
491
492 GSM_INTERNAL="yes"
493 AC_SUBST(GSM_INTERNAL)
494 GSM_SYSTEM="yes"
495 if test "${USE_GSM}" != "no"; then
496    if test "${GSM_DIR}" = "internal"; then
497       GSM_SYSTEM="no"
498    elif test "${GSM_DIR}" != ""; then
499       GSM_INTERNAL="no"
500    fi
501    if test "${GSM_SYSTEM}" = "yes"; then
502       gsmlibdir=""
503       if test "x${GSM_DIR}" != "x"; then
504          if test -d ${GSM_DIR}/lib; then
505             gsmlibdir="-L${GSM_DIR}/lib"
506          else
507             gsmlibdir="-L${GSM_DIR}"
508          fi
509       fi
510       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
511       [Define to indicate the GSM library]), [], ${gsmlibdir})
512       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
513          if test "x${GSM_DIR}" != "x" ; then
514             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
515             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
516          else
517             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
518             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
519          fi
520          if test "${GSM_HEADER_FOUND}" = "0" ; then
521             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
522                if test "x${GSM_MANDATORY}" = "xyes" ; then
523                   AC_MSG_NOTICE([***])
524                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
525                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
526                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
527                   exit 1
528                fi
529             fi
530          fi
531          GSM_OK=0
532          if test "${GSM_HEADER_FOUND}" = "1" ; then
533             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
534             GSM_OK=1
535          else
536             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
537                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
538                GSM_OK=1
539             fi
540          fi
541          if test "${GSM_OK}" = "1" ; then
542             GSM_LIB="-lgsm"
543             if test "x${GSM_DIR}" != "x"; then
544                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
545                GSM_INCLUDE="-I${GSM_DIR}/include"
546             fi
547             PBX_GSM=1
548             GSM_INTERNAL="no"
549          fi
550       fi
551    fi
552    if test "${GSM_INTERNAL}" = "yes"; then
553       PBX_GSM=1
554       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
555    fi
556 fi
557
558 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
559
560 if test "${USE_IMAP_TK}" != "no"; then
561    if test "${IMAP_TK_DIR}" = "system" ; then
562       AC_MSG_NOTICE([Checking for system c-client library...])
563    elif test "${IMAP_TK_DIR}" = ""; then
564       IMAP_TK_DIR=`pwd`"/../imap-2004g"
565       if test  -n "${IMAP_TK_MANDATORY}"; then
566          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
567          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
568          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
569          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
570       fi
571    fi
572    if test "${IMAP_TK_DIR}" != "system" ; then
573       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
574    fi
575    saved_cppflags="${CPPFLAGS}"
576    saved_libs="${LIBS}"
577    if test "${IMAP_TK_DIR}" = "system" ; then
578       imap_ldflags=""
579       imap_libs="-lc-client"
580       imap_include="-DUSE_SYSTEM_IMAP"
581    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
582       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
583       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
584       imap_include="-I${IMAP_TK_DIR}/c-client"
585    fi
586    CPPFLAGS="${CPPFLAGS} ${imap_include}"
587    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
588    AC_LINK_IFELSE(
589         AC_LANG_PROGRAM(
590                 [#ifdef USE_SYSTEM_IMAP
591                 #include <imap/c-client.h>
592                 #else
593                 #include "c-client.h"
594                 #endif
595                 void mm_searched (MAILSTREAM *stream,unsigned long number)
596                 {
597                 }
598                 void mm_exists (MAILSTREAM *stream,unsigned long number)
599                 {
600                 }
601                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
602                 {
603                 }
604                 void mm_flags (MAILSTREAM *stream,unsigned long number)
605                 {
606                 }
607                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
608                 {
609                 }
610                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
611                 {
612                 }
613                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
614                 {
615                 }
616                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
617                 {
618                 }
619                 void mm_log (char *string,long errflg)
620                 {
621                 }
622                 void mm_dlog (char *string)
623                 {
624                 }
625                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
626                 {
627                 }
628                 void mm_critical (MAILSTREAM *stream)
629                 {
630                 }
631                 void mm_nocritical (MAILSTREAM *stream)
632                 {
633                 }
634                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
635                 {
636                 }
637                 void mm_fatal (char *string)
638                 {
639                 }],
640                 [
641                 MAILSTREAM *foo = mail_open(NULL, "", 0);
642                 ]
643         ),
644         [ac_cv_imap_tk="yes"],
645         [ac_cv_imap_tk="no"]
646    )
647    if test "${ac_cv_imap_tk}" = "yes"; then
648    AC_LINK_IFELSE(
649       AC_LANG_PROGRAM(
650          [#ifdef USE_SYSTEM_IMAP
651          #include <imap/c-client.h>
652          #else
653          #include "c-client.h"
654          #endif
655          void mm_searched (MAILSTREAM *stream,unsigned long number)
656          {
657          }
658          void mm_exists (MAILSTREAM *stream,unsigned long number)
659          {
660          }
661          void mm_expunged (MAILSTREAM *stream,unsigned long number)
662          {
663          }
664          void mm_flags (MAILSTREAM *stream,unsigned long number)
665          {
666          }
667          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
668          {
669          }
670          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
671          {
672          }
673          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
674          {
675          }
676          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
677          {
678          }
679          void mm_log (char *string,long errflg)
680          {
681          }
682          void mm_dlog (char *string)
683          {
684          }
685          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
686          {
687          }
688          void mm_critical (MAILSTREAM *stream)
689          {
690          }
691          void mm_nocritical (MAILSTREAM *stream)
692          {
693          }
694          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
695          {
696          }
697          void mm_fatal (char *string)
698          {
699          }],
700          [
701          long check = mail_expunge_full(NULL, "", 0);
702          ]
703       ),
704       [ac_cv_imap_tk2006="yes"],
705       [ac_cv_imap_tk2006="no"]
706   )
707   fi
708    CPPFLAGS="${saved_cppflags}"
709    LIBS="${saved_libs}"
710    if test "${ac_cv_imap_tk}" = "yes"; then
711       AC_MSG_RESULT(yes) 
712       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
713       IMAP_TK_INCLUDE="${imap_include}"
714       PBX_IMAP_TK=1
715       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
716       if test "${ac_cv_imap_tk2006}" = "yes"; then
717          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
718       fi
719    else
720       AC_MSG_RESULT(no) 
721    fi
722 fi
723
724 # Needed by unixodbc
725 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
726
727 AC_LANG_PUSH(C++)
728
729 if test "${USE_KDE}" != "no"; then
730    AC_MSG_CHECKING(for crashHandler in -lkdecore)
731    saved_libs="${LIBS}"
732    saved_cppflags="${CPPFLAGS}"
733    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
734    if test -d ${KDE_DIR}/lib; then
735       kdelibdir="${KDE_DIR}/lib"
736    else
737       kdelibdir="${KDE_DIR}"
738    fi
739    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
740
741    AC_LINK_IFELSE(
742         [AC_LANG_PROGRAM(
743                         [#include "kcrash.h"],
744                         [KCrash::defaultCrashHandler(1);])
745         ],
746         [ac_cv_lib_kde_crash="yes"],
747         [ac_cv_lib_kde_crash="no"])
748                 
749    LIBS="${saved_libs}"
750    CPPFLAGS="${saved_cppflags}"
751         
752    if test "${ac_cv_lib_kde_crash}" = "yes"; then
753       AC_MSG_RESULT(yes) 
754       KDE_LIB="-lkdecore -lkdeui"
755       if test "${KDE_DIR}" != ""; then
756          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
757          KDE_INCLUDE="-I${KDE_DIR}/include"
758       fi
759       PBX_KDE=1
760       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
761    else
762       AC_MSG_RESULT(no) 
763    fi
764 fi
765 if test "${PBX_KDE}" = 1; then
766    AC_PATH_TOOL(KDEINIT, kdeinit, No)
767    if test ! x"${KDEINIT}" = xNo; then
768       KDEDIR=$(${DIRNAME} ${KDEINIT})
769       KDEDIR=$(${DIRNAME} ${KDEDIR})
770    fi
771    AC_SUBST([KDEDIR])
772 fi
773
774 AC_LANG_POP
775
776 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
777
778 if test "${PBX_MISDN}" = 1; then
779    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
780    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
781    AST_C_DEFINE_CHECK([MISDN_FAC_RESULT], [Fac_RESULT], [mISDNuser/suppserv.h])
782    AST_C_DEFINE_CHECK([MISDN_FAC_ERROR], [Fac_ERROR], [mISDNuser/suppserv.h])
783    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
784 fi
785
786 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
787
788 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
789
790 NETSNMP_CONFIG=No
791 if test "${USE_NETSNMP}" != "no"; then  
792    if test "x${NETSNMP_DIR}" != "x"; then
793       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
794       if test x"${NETSNMP_CONFIG}" = xNo; then
795          AC_MSG_NOTICE([***])
796          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
797          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
798          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
799          AC_MSG_NOTICE([*** including --without-netsnmp])
800          exit 1
801       fi
802    else
803       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
804    fi
805 fi
806 if test x"${NETSNMP_CONFIG}" != xNo; then
807    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
808    
809    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
810    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
811
812    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
813       NETSNMP_LIB="${NETSNMP_libs}"
814       PBX_NETSNMP=1
815    fi
816 fi
817
818 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
819
820 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
821
822 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
823
824 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
825
826 # possible places for oss definitions
827 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
828 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
829 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
830
831 PG_CONFIG=No
832 if test "${USE_PGSQL}" != "no"; then    
833    if test "x${PGSQL_DIR}" != "x"; then
834       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
835       if test x"${PG_CONFIG}" = xNo; then
836          AC_MSG_NOTICE([***])
837          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
838          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
839          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
840          AC_MSG_NOTICE([*** including --without-postgres])
841          exit 1
842       fi
843    else
844       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
845    fi
846 fi
847 if test "${PG_CONFIG}" != No; then
848    PGSQL_libdir=`${PG_CONFIG} --libdir`
849    PGSQL_includedir=`${PG_CONFIG} --includedir`
850    if test "x$?" != "x0" ; then
851       if test -n "${PGSQL_MANDATORY}" ; then
852          AC_MSG_NOTICE([***])
853          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
854          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
855          AC_MSG_NOTICE([*** including --without-postgres])
856          exit 1
857           fi
858    else 
859       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
860       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
861
862       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
863          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
864          PGSQL_INCLUDE="-I${PGSQL_includedir}"
865          PBX_PGSQL=1
866       elif test -n "${PGSQL_MANDATORY}";
867       then
868          AC_MSG_NOTICE([***])
869          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
870          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
871          AC_MSG_NOTICE([*** including --without-postgres])
872          exit 1
873       fi
874    fi
875 fi
876
877 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
878
879 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
880
881 AST_EXT_LIB_CHECK([SS7], [ss7], [isup_cqr], [libss7.h])
882
883 if test "${USE_PWLIB}" != "no"; then
884         if test -n "${PWLIB_DIR}"; then
885                 PWLIBDIR="${PWLIB_DIR}"
886         fi
887         AST_CHECK_PWLIB()
888         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
889                 
890         if test "${HAS_PWLIB:-unset}" != "unset"; then
891                 AST_CHECK_OPENH323_PLATFORM()
892
893                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
894
895                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
896                         [Define if your system has the PWLib libraries.],
897                         [#include "ptlib.h"],
898                         [BOOL q = PTime::IsDaylightSavings();])
899         fi
900 fi
901
902 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
903         if test -n "${OPENH323_DIR}"; then
904                 OPENH323DIR="${OPENH323_DIR}"
905         fi
906         AST_CHECK_OPENH323()
907         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
908         AST_CHECK_OPENH323_BUILD()
909         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
910         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
911                 [Define if your system has the OpenH323 libraries.],
912                 [#include "ptlib.h"
913                 #include "h323.h"
914                 #include "h323ep.h"],
915                 [H323EndPoint ep = H323EndPoint();],
916                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
917 fi
918
919 AC_LANG_PUSH(C++)
920
921 if test "${USE_QT}" != "no"; then
922    AC_MSG_CHECKING(for QDate in -lqt)
923    saved_libs="${LIBS}"
924    saved_cppflags="${CPPFLAGS}"
925    if test "x${QT_DIR}" != "x"; then
926       LIBS="${LIBS} -L${QT_DIR}/lib"
927       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
928    fi
929    LIBS="${LIBS} -lqt"
930    qtlib="qt"
931    AC_LINK_IFELSE(
932         [
933                 AC_LANG_PROGRAM(
934                 [#include <qt3/qdatetime.h>],
935                 [QDate date();])
936         ],
937         [ac_cv_lib_qt_qt_date="yes"],
938         [ac_cv_lib_qt_qt_date="no"])
939    LIBS="${saved_libs}"
940    CPPFLAGS="${saved_cppflags}"
941         
942    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
943       saved_libs="${LIBS}"
944       saved_cppflags="${CPPFLAGS}"
945       if test "x${QT_DIR}" != "x"; then
946          LIBS="${LIBS} -L${QT_DIR}/lib"
947          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
948       fi
949       LIBS="${LIBS} -lqt-mt"
950       qtlib="qt-mt"     
951       AC_LINK_IFELSE(
952                 [
953                         AC_LANG_PROGRAM(
954                         [#include <qt3/qdatetime.h>],
955                         [QDate date();])
956                 ],
957                 [ac_cv_lib_qt_qt_date="yes"],
958                 [ac_cv_lib_qt_qt_date="no"])
959       LIBS="${saved_libs}"
960       CPPFLAGS="${saved_cppflags}"
961    fi   
962
963    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
964       AC_MSG_RESULT(yes) 
965    else
966       AC_MSG_RESULT(no) 
967    fi
968         
969    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
970       QT_LIB="-l${qtlib}"
971       if test "${QT_DIR}" != ""; then
972          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
973          QT_INCLUDE="-I${QT_DIR}/include"
974       fi
975       PBX_QT=1
976       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
977       AC_PATH_TOOL(QTMOC, moc, No)
978    fi
979 fi
980
981 AC_LANG_POP
982
983 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
984
985 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
986
987 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
988
989 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
990
991 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
992
993 if test "$PBX_CRYPTO" = "1";
994 then
995     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
996 fi
997
998 if test "$PBX_OPENSSL" = "1";
999 then
1000     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
1001 fi
1002
1003 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
1004 if test "${PBX_FREETDS}" != "0";
1005 then
1006     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
1007         *0.64*)
1008                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
1009         ;;
1010     *0.63*)
1011         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
1012         ;;
1013     *0.62*)
1014         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
1015         ;;
1016     *)
1017         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
1018         ;;
1019     esac
1020 fi
1021
1022 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
1023
1024 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
1025
1026 if test "${host_os}" != "linux-gnu" ; then
1027   tonezone_extra="-lm"
1028 fi
1029
1030 # new tonezone, version 1.4.0
1031 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
1032 # other case, old tonezone (0.80)
1033 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
1034
1035 AST_EXT_LIB_CHECK([USB], [usb], [usb_init], [usb.h], [])
1036
1037 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1038
1039 AC_LANG_PUSH(C++)
1040
1041 if test "${USE_VPB}" != "no"; then
1042    AC_MSG_CHECKING(for vpb_open in -lvpb)
1043    saved_libs="${LIBS}"
1044    saved_cppflags="${CPPFLAGS}"
1045    if test "x${VPB_DIR}" != "x"; then
1046       if test -d ${VPB_DIR}/lib; then
1047          vpblibdir=${VPB_DIR}/lib
1048       else
1049          vpblibdir=${VPB_DIR}
1050       fi
1051       LIBS="${LIBS} -L${vpblibdir}"
1052       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1053    fi
1054    LIBS="${LIBS} -lvpb -lpthread"
1055    AC_LINK_IFELSE(
1056         [
1057         AC_LANG_PROGRAM(
1058         [#include <vpbapi.h>],
1059         [int q = vpb_open(0,0);])
1060         ],
1061         [       AC_MSG_RESULT(yes) 
1062                 ac_cv_lib_vpb_vpb_open="yes" 
1063         ],
1064         [       AC_MSG_RESULT(no) 
1065                 ac_cv_lib_vpb_vpb_open="no" 
1066         ]
1067         )
1068    LIBS="${saved_libs}"
1069    CPPFLAGS="${saved_cppflags}"
1070    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1071         VPB_LIB="-lvpb"
1072         if test "${VPB_DIR}" != ""; then
1073            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1074            VPB_INCLUDE="-I${VPB_DIR}/include"
1075         fi
1076         PBX_VPB=1
1077         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1078    fi
1079 fi
1080
1081 AC_LANG_POP
1082
1083 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1084
1085 # Check for various zaptel features and locations.
1086 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1087 # will be used in the system headers to determine the location
1088 # of the zaptel.h header.
1089
1090 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1091 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1092
1093 # Check for VLDTMF support
1094 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1095
1096 # Check for transcode support
1097 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1098
1099 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1100 case "${host_os}" in
1101     freebsd*)
1102         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1103         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1104         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1105
1106         # other case, old tonezone (0.80)
1107         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1108         ;;
1109 esac
1110
1111 EDITLINE_LIB=""
1112 if test "x$TERMCAP_LIB" != "x" ; then
1113   EDITLINE_LIB="$TERMCAP_LIB"
1114 elif test "x$TINFO_LIB" != "x" ; then
1115   EDITLINE_LIB="$TINFO_LIB"
1116 elif test "x$CURSES_LIB" != "x" ; then
1117   EDITLINE_LIB="$CURSES_LIB"
1118 elif test "x$NCURSES_LIB" != "x" ; then
1119   EDITLINE_LIB="$NCURSES_LIB"
1120 else
1121   AC_MSG_ERROR(*** termcap support not found)
1122 fi
1123 AC_SUBST(EDITLINE_LIB)
1124
1125 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1126 AC_SUBST(PBX_H323)
1127
1128 AC_CHECK_HEADER([linux/compiler.h],
1129                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1130
1131 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1132                                    #include <linux/version.h>
1133                                    #ifdef HAVE_LINUX_COMPILER_H
1134                                    #include <linux/compiler.h>
1135                                    #endif
1136                                    ])
1137 AC_SUBST(PBX_IXJUSER)
1138
1139 PBX_GTK=0
1140 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1141 if test ! "x${GTKCONFIG}" = xNo; then
1142    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1143    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1144    PBX_GTK=1
1145    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1146 fi
1147 AC_SUBST(PBX_GTK)
1148 AC_SUBST(GTK_INCLUDE)
1149 AC_SUBST(GTK_LIB)
1150
1151 PBX_GTK2=0
1152 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1153 if test ! "x${PKGCONFIG}" = xNo; then
1154    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1155    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1156    PBX_GTK2=1
1157    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1158 fi
1159 AC_SUBST(PBX_GTK2)
1160 AC_SUBST(GTK2_INCLUDE)
1161 AC_SUBST(GTK2_LIB)
1162
1163 if test "${USE_CURL}" != "no"; then
1164    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1165    if test ! x"${CURL_CONFIG}" = xNo; then
1166    # check for version
1167       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1168          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1169          CURL_LIB=$(${CURL_CONFIG} --libs)
1170
1171          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1172          saved_cppflags="${CPPFLAGS}"
1173          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1174          AC_COMPILE_IFELSE(
1175             [AC_LANG_PROGRAM(
1176                 [#include <curl/curl.h>],
1177                     [curl_version();])
1178             ],[
1179                 AC_MSG_RESULT(yes)
1180                 ac_cv_curl_h="yes"
1181             ],[
1182                 AC_MSG_RESULT(no)
1183                 ac_cv_curl_h="no"
1184             ]
1185          )
1186          CPPFLAGS="${saved_cppflags}"
1187          if test "${ac_cv_curl_h}" = "yes"; then
1188              PBX_CURL=1
1189              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1190          fi
1191       fi
1192    fi
1193 fi
1194
1195 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1196 AST_CHECK_MANDATORY
1197
1198 AC_OUTPUT
1199
1200 if test "x${silent}" != "xyes" ; then
1201 echo
1202 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1203 echo "            .\$7\$7..          .7\$\$7:.    "
1204 echo "          .\$\$:.                 ,\$7.7   "
1205 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1206 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1207 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1208 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1209 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1210 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1211 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1212 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1213 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1214 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1215 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1216 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1217 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1218 echo " \$\$\$\$\$                        \$\$\$       "
1219 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1220 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1221 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1222 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1223 echo
1224 fi
1225
1226 AC_MSG_NOTICE(Package configured for: )
1227 AC_MSG_NOTICE( OS type  : $host_os)
1228 AC_MSG_NOTICE( Host CPU : $host_cpu)
1229 if test "${cross_compiling}" = "yes"; then
1230    AC_MSG_NOTICE( Cross Compilation = YES)
1231 fi