use autoconf to check for the existence of sys/poll.h
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.60)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${host_os}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
191 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
192 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
193 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
194 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
195 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
196 AST_EXT_LIB_SETUP([LUA], [Lua], [lua])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([USB], [usb], [usb])
224 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
225 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
226 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
227 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
228 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
229 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
230
231 AST_EXT_LIB_SETUP([SDL], [Sdl], [sdl])
232 AST_EXT_LIB_SETUP([SDL_IMAGE], [Sdl Image library], [SDL_image])
233 AST_EXT_LIB_SETUP([FFMPEG], [Ffmpeg and avcodec library], [avcodec])
234
235 # check for basic system features and functionality before
236 # checking for package libraries
237
238 AC_FUNC_ALLOCA
239 AC_HEADER_DIRENT
240 AC_HEADER_STDC
241 AC_HEADER_SYS_WAIT
242 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
243
244 AC_SYS_LARGEFILE
245
246 # Checks for typedefs, structures, and compiler characteristics.
247 AC_HEADER_STDBOOL
248 AC_C_CONST
249 AC_TYPE_UID_T
250 AC_C_INLINE
251 AC_TYPE_MODE_T
252 AC_TYPE_OFF_T
253 AC_TYPE_PID_T
254 AC_TYPE_SIZE_T
255 AC_CHECK_MEMBERS([struct stat.st_blksize])
256 AC_HEADER_TIME
257 AC_STRUCT_TM
258 AC_C_VOLATILE
259 AC_CHECK_TYPES([ptrdiff_t])
260
261 # Checks for library functions.
262 AC_FUNC_CHOWN
263 AC_FUNC_CLOSEDIR_VOID
264 AC_FUNC_ERROR_AT_LINE
265 AST_FUNC_FORK
266 AC_FUNC_FSEEKO
267 AC_PROG_GCC_TRADITIONAL
268 # XXX: these are commented out until we determine whether it matters if our malloc()
269 # acts exactly like glibc's or not
270 # AC_FUNC_MALLOC
271 # AC_FUNC_REALLOC
272 AC_FUNC_MEMCMP
273 AC_FUNC_MKTIME
274 AC_FUNC_MMAP
275 AC_FUNC_SELECT_ARGTYPES
276 AC_FUNC_SETVBUF_REVERSED
277 AC_TYPE_SIGNAL
278 AC_FUNC_STAT
279 AC_FUNC_STRCOLL
280 AC_FUNC_STRFTIME
281 AC_FUNC_STRNLEN
282 AC_FUNC_STRTOD
283 AC_FUNC_UTIME_NULL
284 AC_FUNC_VPRINTF
285 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap putenv re_comp regcomp select setenv socket strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
286
287 AC_CHECK_FUNCS([glob])
288 AC_CHECK_HEADER([sys/poll.h], [HAS_POLL=1],)
289 AC_SUBST(HAS_POLL)
290
291 # https support (in main/http.c) uses funopen on BSD systems,
292 # fopencookie on linux
293 AC_CHECK_FUNCS([funopen fopencookie])
294
295 # check if we have IP_PKTINFO constant defined
296 AC_LINK_IFELSE(
297                 AC_LANG_PROGRAM([#include <netinet/in.h>],
298                                                 [int pi = IP_PKTINFO;]),
299                 AC_MSG_RESULT(yes)
300                 AC_DEFINE([HAVE_PKTINFO], 1, [Define to 1 if your system defines IP_PKTINFO.]),
301                 AC_MSG_RESULT(no)
302 )
303
304 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
305 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
306
307 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
308 AC_LINK_IFELSE(
309         AC_LANG_PROGRAM([#include <stdlib.h>
310                          #include <netdb.h>],
311                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
312         AC_MSG_RESULT(yes)
313         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
314         AC_MSG_RESULT(no)
315 )
316
317 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
318 AC_LINK_IFELSE(
319         AC_LANG_PROGRAM([#include <stdlib.h>
320                          #include <netdb.h>],
321                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
322         AC_MSG_RESULT(yes)
323         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
324         AC_MSG_RESULT(no)
325 )
326
327 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
328
329 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
330 AC_LINK_IFELSE(
331 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
332 AC_MSG_RESULT(yes)
333 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
334 AC_MSG_RESULT(no)
335 )
336
337 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
338 AC_LINK_IFELSE(
339 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
340 AC_MSG_RESULT(yes)
341 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
342 AC_MSG_RESULT(no)
343 )
344
345 if test "${cross_compiling}" = "no";
346 then
347   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
348 fi
349
350 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
351 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
352
353 if test "${cross_compiling}" = "no";
354 then
355 AC_MSG_CHECKING(for working epoll support)
356 AC_LINK_IFELSE(
357 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
358                                           if (res < 0)
359                                              return 1;
360                                           close (res);
361                                           return 0;]),
362 AC_MSG_RESULT(yes)
363 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
364 AC_MSG_RESULT(no)
365 )
366 fi
367
368 AC_MSG_CHECKING(for compiler atomic operations)
369 AC_LINK_IFELSE(
370 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
371 AC_MSG_RESULT(yes)
372 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
373 AC_MSG_RESULT(no)
374 )
375
376 AST_GCC_ATTRIBUTE(pure)
377 AST_GCC_ATTRIBUTE(malloc)
378 AST_GCC_ATTRIBUTE(const)
379 AST_GCC_ATTRIBUTE(unused)
380 AST_GCC_ATTRIBUTE(always_inline)
381 AST_GCC_ATTRIBUTE(deprecated)
382
383 AC_MSG_CHECKING(for -ffunction-sections support)
384 saved_CFLAGS="${CFLAGS}"
385 CFLAGS="${CFLAGS} -ffunction-sections"
386 AC_COMPILE_IFELSE(
387         AC_LANG_PROGRAM([], [int x = 1;]),
388         AC_MSG_RESULT(yes)
389         [saved_LDFLAGS="${LDFLAGS}"]
390         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
391         AC_MSG_CHECKING(for --gc-sections support)
392         AC_LINK_IFELSE(
393                 AC_LANG_PROGRAM([], [int x = 1;]),
394                 AC_MSG_RESULT(yes)
395                 [GC_CFLAGS="-ffunction-sections"]
396                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
397                 AC_MSG_RESULT(no)
398         )
399         [LDFLAGS="${saved_LDFLAGS}"],
400         AC_MSG_RESULT(no)
401 )
402 CFLAGS="${saved_CFLAGS}"
403 AC_SUBST(GC_CFLAGS)
404 AC_SUBST(GC_LDFLAGS)
405
406 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
407 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
408         AC_MSG_RESULT(yes)
409         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
410 else
411         AC_MSG_RESULT(no)
412         AST_DECLARATION_AFTER_STATEMENT=
413 fi
414 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
415
416
417 AC_MSG_CHECKING(for sysinfo)
418 AC_LINK_IFELSE(
419         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
420                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
421         AC_MSG_RESULT(yes)
422         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
423         AC_MSG_RESULT(no)
424 )
425
426 AC_MSG_CHECKING(for res_ninit)
427 AC_LINK_IFELSE(
428         AC_LANG_PROGRAM([#include <resolv.h>],
429                         [int foo = res_ninit(NULL);]),
430         AC_MSG_RESULT(yes)
431         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
432         AC_MSG_CHECKING(for res_ndestroy)
433         AC_LINK_IFELSE(
434                 AC_LANG_PROGRAM([#include <resolv.h>],
435                                 [int foo = res_ndestroy(NULL);]),
436                 AC_MSG_RESULT(yes)
437                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
438                 AC_MSG_RESULT(no)
439         ),
440         AC_MSG_RESULT(no)
441 )
442
443 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
444
445 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
446
447 AC_CHECK_HEADER([libkern/OSAtomic.h],
448                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
449
450 AC_CHECK_SIZEOF(int)
451
452 # do the package library checks now
453
454 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
455
456 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
457
458 if test "x${host_os}" = "xlinux-gnu" ; then
459   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
460 fi
461
462 # BSD might not have exp2, and/or log2
463 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
464 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
465 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
466 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
467 AST_EXT_LIB_CHECK([SINL], [m], [sinl])
468 AST_EXT_LIB_CHECK([COSL], [m], [cosl])
469 AST_EXT_LIB_CHECK([TANL], [m], [tanl])
470 AST_EXT_LIB_CHECK([ASINL], [m], [asinl])
471 AST_EXT_LIB_CHECK([ACOSL], [m], [acosl])
472 AST_EXT_LIB_CHECK([ATANL], [m], [atanl])
473 AST_EXT_LIB_CHECK([ATAN2L], [m], [atan2l])
474 AST_EXT_LIB_CHECK([POWL], [m], [powl])
475 AST_EXT_LIB_CHECK([SQRTL], [m], [sqrtl])
476 AST_EXT_LIB_CHECK([RINTL], [m], [rintl])
477 AST_EXT_LIB_CHECK([EXPL], [m], [expl])
478 AST_EXT_LIB_CHECK([LOGL], [m], [logl])
479 AST_EXT_LIB_CHECK([REMAINDERL], [m], [remainderl])
480 AST_EXT_LIB_CHECK([FMODL], [m], [fmodl])
481 AST_EXT_LIB_CHECK([ROUNDL], [m], [roundl])
482 AST_EXT_LIB_CHECK([TRUNCL], [m], [truncl])
483 AST_EXT_LIB_CHECK([STRTOLD], [c], [strtold], [stdlib.h])
484 AST_EXT_LIB_CHECK([FLOORL], [m], [floorl])
485 AST_EXT_LIB_CHECK([CEILL], [m], [ceill])
486 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
487 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
488 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
489 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
490 AST_EXT_LIB_CHECK([SIN], [m], [sin])
491 AST_EXT_LIB_CHECK([COS], [m], [cos])
492 AST_EXT_LIB_CHECK([TAN], [m], [tan])
493 AST_EXT_LIB_CHECK([ASIN], [m], [asin])
494 AST_EXT_LIB_CHECK([ACOS], [m], [acos])
495 AST_EXT_LIB_CHECK([ATAN], [m], [atan])
496 AST_EXT_LIB_CHECK([ATAN2], [m], [atan2])
497 AST_EXT_LIB_CHECK([POW], [m], [pow])
498 AST_EXT_LIB_CHECK([SQRT], [m], [sqrt])
499 AST_EXT_LIB_CHECK([RINT], [m], [rint])
500 AST_EXT_LIB_CHECK([EXP], [m], [exp])
501 AST_EXT_LIB_CHECK([LOG], [m], [log])
502 AST_EXT_LIB_CHECK([REMAINDER], [m], [remainder])
503 AST_EXT_LIB_CHECK([FMOD], [m], [fmod])
504 AST_EXT_LIB_CHECK([ROUND], [m], [round])
505 AST_EXT_LIB_CHECK([TRUNC], [m], [trunc])
506 AST_EXT_LIB_CHECK([STRTOD], [c], [strtod], [stdlib.h])
507 AST_EXT_LIB_CHECK([FLOOR], [m], [floor])
508 AST_EXT_LIB_CHECK([CEIL], [m], [ceil])
509
510 GSM_INTERNAL="yes"
511 AC_SUBST(GSM_INTERNAL)
512 GSM_SYSTEM="yes"
513 if test "${USE_GSM}" != "no"; then
514    if test "${GSM_DIR}" = "internal"; then
515       GSM_SYSTEM="no"
516    elif test "${GSM_DIR}" != ""; then
517       GSM_INTERNAL="no"
518    fi
519    if test "${GSM_SYSTEM}" = "yes"; then
520       gsmlibdir=""
521       if test "x${GSM_DIR}" != "x"; then
522          if test -d ${GSM_DIR}/lib; then
523             gsmlibdir="-L${GSM_DIR}/lib"
524          else
525             gsmlibdir="-L${GSM_DIR}"
526          fi
527       fi
528       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
529       [Define to indicate the GSM library]), [], ${gsmlibdir})
530       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
531          if test "x${GSM_DIR}" != "x" ; then
532             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
533             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
534          else
535             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
536             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
537          fi
538          if test "${GSM_HEADER_FOUND}" = "0" ; then
539             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
540                if test "x${GSM_MANDATORY}" = "xyes" ; then
541                   AC_MSG_NOTICE([***])
542                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
543                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
544                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
545                   exit 1
546                fi
547             fi
548          fi
549          GSM_OK=0
550          if test "${GSM_HEADER_FOUND}" = "1" ; then
551             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
552             GSM_OK=1
553          else
554             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
555                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
556                GSM_OK=1
557             fi
558          fi
559          if test "${GSM_OK}" = "1" ; then
560             GSM_LIB="-lgsm"
561             if test "x${GSM_DIR}" != "x"; then
562                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
563                GSM_INCLUDE="-I${GSM_DIR}/include"
564             fi
565             PBX_GSM=1
566             GSM_INTERNAL="no"
567          fi
568       fi
569    fi
570    if test "${GSM_INTERNAL}" = "yes"; then
571       PBX_GSM=1
572       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
573    fi
574 fi
575
576 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
577
578 if test "${USE_IMAP_TK}" != "no"; then
579    if test "${IMAP_TK_DIR}" = "system" ; then
580       AC_MSG_NOTICE([Checking for system c-client library...])
581    elif test "${IMAP_TK_DIR}" = ""; then
582       IMAP_TK_DIR=`pwd`"/../imap-2004g"
583       if test  -n "${IMAP_TK_MANDATORY}"; then
584          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
585          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
586          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
587          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
588       fi
589    fi
590    if test "${IMAP_TK_DIR}" != "system" ; then
591       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
592    fi
593    saved_cppflags="${CPPFLAGS}"
594    saved_libs="${LIBS}"
595    if test "${IMAP_TK_DIR}" = "system" ; then
596       imap_ldflags=""
597       imap_libs="-lc-client"
598       imap_include="-DUSE_SYSTEM_IMAP"
599    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
600       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
601       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
602       imap_include="-I${IMAP_TK_DIR}/c-client"
603    fi
604    CPPFLAGS="${CPPFLAGS} ${imap_include}"
605    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
606    AC_LINK_IFELSE(
607         AC_LANG_PROGRAM(
608                 [#ifdef USE_SYSTEM_IMAP
609                 #include <imap/c-client.h>
610                 #else
611                 #include "c-client.h"
612                 #endif
613                 void mm_searched (MAILSTREAM *stream,unsigned long number)
614                 {
615                 }
616                 void mm_exists (MAILSTREAM *stream,unsigned long number)
617                 {
618                 }
619                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
620                 {
621                 }
622                 void mm_flags (MAILSTREAM *stream,unsigned long number)
623                 {
624                 }
625                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
626                 {
627                 }
628                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
629                 {
630                 }
631                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
632                 {
633                 }
634                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
635                 {
636                 }
637                 void mm_log (char *string,long errflg)
638                 {
639                 }
640                 void mm_dlog (char *string)
641                 {
642                 }
643                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
644                 {
645                 }
646                 void mm_critical (MAILSTREAM *stream)
647                 {
648                 }
649                 void mm_nocritical (MAILSTREAM *stream)
650                 {
651                 }
652                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
653                 {
654                 }
655                 void mm_fatal (char *string)
656                 {
657                 }],
658                 [
659                 MAILSTREAM *foo = mail_open(NULL, "", 0);
660                 ]
661         ),
662         [ac_cv_imap_tk="yes"],
663         [ac_cv_imap_tk="no"]
664    )
665    if test "${ac_cv_imap_tk}" = "yes"; then
666    AC_LINK_IFELSE(
667       AC_LANG_PROGRAM(
668          [#ifdef USE_SYSTEM_IMAP
669          #include <imap/c-client.h>
670          #else
671          #include "c-client.h"
672          #endif
673          void mm_searched (MAILSTREAM *stream,unsigned long number)
674          {
675          }
676          void mm_exists (MAILSTREAM *stream,unsigned long number)
677          {
678          }
679          void mm_expunged (MAILSTREAM *stream,unsigned long number)
680          {
681          }
682          void mm_flags (MAILSTREAM *stream,unsigned long number)
683          {
684          }
685          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
686          {
687          }
688          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
689          {
690          }
691          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
692          {
693          }
694          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
695          {
696          }
697          void mm_log (char *string,long errflg)
698          {
699          }
700          void mm_dlog (char *string)
701          {
702          }
703          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
704          {
705          }
706          void mm_critical (MAILSTREAM *stream)
707          {
708          }
709          void mm_nocritical (MAILSTREAM *stream)
710          {
711          }
712          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
713          {
714          }
715          void mm_fatal (char *string)
716          {
717          }],
718          [
719          long check = mail_expunge_full(NULL, "", 0);
720          ]
721       ),
722       [ac_cv_imap_tk2006="yes"],
723       [ac_cv_imap_tk2006="no"]
724   )
725   fi
726    CPPFLAGS="${saved_cppflags}"
727    LIBS="${saved_libs}"
728    if test "${ac_cv_imap_tk}" = "yes"; then
729       AC_MSG_RESULT(yes) 
730       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
731       IMAP_TK_INCLUDE="${imap_include}"
732       PBX_IMAP_TK=1
733       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
734       if test "${ac_cv_imap_tk2006}" = "yes"; then
735          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
736       fi
737    else
738       AC_MSG_RESULT(no) 
739    fi
740 fi
741
742 # Needed by unixodbc
743 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
744
745 AC_LANG_PUSH(C++)
746
747 if test "${USE_KDE}" != "no"; then
748    AC_MSG_CHECKING(for crashHandler in -lkdecore)
749    saved_libs="${LIBS}"
750    saved_cppflags="${CPPFLAGS}"
751    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
752    if test -d ${KDE_DIR}/lib; then
753       kdelibdir="${KDE_DIR}/lib"
754    else
755       kdelibdir="${KDE_DIR}"
756    fi
757    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
758
759    AC_LINK_IFELSE(
760         [AC_LANG_PROGRAM(
761                         [#include "kcrash.h"],
762                         [KCrash::defaultCrashHandler(1);])
763         ],
764         [ac_cv_lib_kde_crash="yes"],
765         [ac_cv_lib_kde_crash="no"])
766                 
767    LIBS="${saved_libs}"
768    CPPFLAGS="${saved_cppflags}"
769         
770    if test "${ac_cv_lib_kde_crash}" = "yes"; then
771       AC_MSG_RESULT(yes) 
772       KDE_LIB="-lkdecore -lkdeui"
773       if test "${KDE_DIR}" != ""; then
774          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
775          KDE_INCLUDE="-I${KDE_DIR}/include"
776       fi
777       PBX_KDE=1
778       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
779    else
780       AC_MSG_RESULT(no) 
781    fi
782 fi
783 if test "${PBX_KDE}" = 1; then
784    AC_PATH_TOOL(KDEINIT, kdeinit, No)
785    if test ! x"${KDEINIT}" = xNo; then
786       KDEDIR=$(${DIRNAME} ${KDEINIT})
787       KDEDIR=$(${DIRNAME} ${KDEDIR})
788    fi
789    AC_SUBST([KDEDIR])
790 fi
791
792 AC_LANG_POP
793
794 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
795
796 if test "${PBX_MISDN}" = 1; then
797    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
798    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
799    AST_C_DEFINE_CHECK([MISDN_FAC_RESULT], [Fac_RESULT], [mISDNuser/suppserv.h])
800    AST_C_DEFINE_CHECK([MISDN_FAC_ERROR], [Fac_ERROR], [mISDNuser/suppserv.h])
801    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
802 fi
803
804 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
805
806 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
807
808 NETSNMP_CONFIG=No
809 if test "${USE_NETSNMP}" != "no"; then  
810    if test "x${NETSNMP_DIR}" != "x"; then
811       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
812       if test x"${NETSNMP_CONFIG}" = xNo; then
813          AC_MSG_NOTICE([***])
814          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
815          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
816          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
817          AC_MSG_NOTICE([*** including --without-netsnmp])
818          exit 1
819       fi
820    else
821       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
822    fi
823 fi
824 if test x"${NETSNMP_CONFIG}" != xNo; then
825    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
826    
827    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
828    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
829
830    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
831       NETSNMP_LIB="${NETSNMP_libs}"
832       PBX_NETSNMP=1
833    fi
834 fi
835
836 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
837
838 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
839
840 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
841
842 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
843
844 # possible places for oss definitions
845 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
846 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
847 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
848
849 PG_CONFIG=No
850 if test "${USE_PGSQL}" != "no"; then    
851    if test "x${PGSQL_DIR}" != "x"; then
852       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
853       if test x"${PG_CONFIG}" = xNo; then
854          AC_MSG_NOTICE([***])
855          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
856          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
857          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
858          AC_MSG_NOTICE([*** including --without-postgres])
859          exit 1
860       fi
861    else
862       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
863    fi
864 fi
865 if test "${PG_CONFIG}" != No; then
866    PGSQL_libdir=`${PG_CONFIG} --libdir`
867    PGSQL_includedir=`${PG_CONFIG} --includedir`
868    if test "x$?" != "x0" ; then
869       if test -n "${PGSQL_MANDATORY}" ; then
870          AC_MSG_NOTICE([***])
871          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
872          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
873          AC_MSG_NOTICE([*** including --without-postgres])
874          exit 1
875           fi
876    else 
877       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
878       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
879
880       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
881          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
882          PGSQL_INCLUDE="-I${PGSQL_includedir}"
883          PBX_PGSQL=1
884       elif test -n "${PGSQL_MANDATORY}";
885       then
886          AC_MSG_NOTICE([***])
887          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
888          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
889          AC_MSG_NOTICE([*** including --without-postgres])
890          exit 1
891       fi
892    fi
893 fi
894
895 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
896
897 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
898
899 AST_EXT_LIB_CHECK([SS7], [ss7], [isup_cqr], [libss7.h])
900
901 if test "${USE_PWLIB}" != "no"; then
902         if test -n "${PWLIB_DIR}"; then
903                 PWLIBDIR="${PWLIB_DIR}"
904         fi
905         AST_CHECK_PWLIB()
906         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
907                 
908         if test "${HAS_PWLIB:-unset}" != "unset"; then
909                 AST_CHECK_OPENH323_PLATFORM()
910
911                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
912
913                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
914                         [Define if your system has the PWLib libraries.],
915                         [#include "ptlib.h"],
916                         [BOOL q = PTime::IsDaylightSavings();])
917         fi
918 fi
919
920 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
921         if test -n "${OPENH323_DIR}"; then
922                 OPENH323DIR="${OPENH323_DIR}"
923         fi
924         AST_CHECK_OPENH323()
925         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
926         AST_CHECK_OPENH323_BUILD()
927         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
928         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
929                 [Define if your system has the OpenH323 libraries.],
930                 [#include "ptlib.h"
931                 #include "h323.h"
932                 #include "h323ep.h"],
933                 [H323EndPoint ep = H323EndPoint();],
934                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
935 fi
936
937 AC_LANG_PUSH(C++)
938
939 if test "${USE_QT}" != "no"; then
940    AC_MSG_CHECKING(for QDate in -lqt)
941    saved_libs="${LIBS}"
942    saved_cppflags="${CPPFLAGS}"
943    if test "x${QT_DIR}" != "x"; then
944       LIBS="${LIBS} -L${QT_DIR}/lib"
945       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
946    fi
947    LIBS="${LIBS} -lqt"
948    qtlib="qt"
949    AC_LINK_IFELSE(
950         [
951                 AC_LANG_PROGRAM(
952                 [#include <qt3/qdatetime.h>],
953                 [QDate date();])
954         ],
955         [ac_cv_lib_qt_qt_date="yes"],
956         [ac_cv_lib_qt_qt_date="no"])
957    LIBS="${saved_libs}"
958    CPPFLAGS="${saved_cppflags}"
959         
960    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
961       saved_libs="${LIBS}"
962       saved_cppflags="${CPPFLAGS}"
963       if test "x${QT_DIR}" != "x"; then
964          LIBS="${LIBS} -L${QT_DIR}/lib"
965          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
966       fi
967       LIBS="${LIBS} -lqt-mt"
968       qtlib="qt-mt"     
969       AC_LINK_IFELSE(
970                 [
971                         AC_LANG_PROGRAM(
972                         [#include <qt3/qdatetime.h>],
973                         [QDate date();])
974                 ],
975                 [ac_cv_lib_qt_qt_date="yes"],
976                 [ac_cv_lib_qt_qt_date="no"])
977       LIBS="${saved_libs}"
978       CPPFLAGS="${saved_cppflags}"
979    fi   
980
981    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
982       AC_MSG_RESULT(yes) 
983    else
984       AC_MSG_RESULT(no) 
985    fi
986         
987    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
988       QT_LIB="-l${qtlib}"
989       if test "${QT_DIR}" != ""; then
990          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
991          QT_INCLUDE="-I${QT_DIR}/include"
992       fi
993       PBX_QT=1
994       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
995       AC_PATH_TOOL(QTMOC, moc, No)
996    fi
997 fi
998
999 AC_LANG_POP
1000
1001 LUA_INCLUDE="-I/usr/include/lua5.1"
1002 LUA_LIB="-llua5.1"
1003 AST_EXT_LIB_CHECK([LUA], [lua5.1], [luaL_newstate], [lua5.1/lua.h]) 
1004
1005 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
1006
1007 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
1008
1009 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
1010
1011 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
1012
1013 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
1014
1015 if test "$PBX_CRYPTO" = "1";
1016 then
1017     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
1018 fi
1019
1020 if test "$PBX_OPENSSL" = "1";
1021 then
1022     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
1023 fi
1024
1025 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
1026 if test "${PBX_FREETDS}" != "0";
1027 then
1028     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
1029         *0.64*)
1030                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
1031         ;;
1032     *0.63*)
1033         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
1034         ;;
1035     *0.62*)
1036         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
1037         ;;
1038     *)
1039         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
1040         ;;
1041     esac
1042 fi
1043
1044 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
1045
1046 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
1047
1048 if test "${host_os}" != "linux-gnu" ; then
1049   tonezone_extra="-lm"
1050 fi
1051
1052 # new tonezone, version 1.4.0
1053 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
1054 # other case, old tonezone (0.80)
1055 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
1056
1057 AST_EXT_LIB_CHECK([USB], [usb], [usb_init], [usb.h], [])
1058
1059 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1060
1061 AC_LANG_PUSH(C++)
1062
1063 if test "${USE_VPB}" != "no"; then
1064    AC_MSG_CHECKING(for vpb_open in -lvpb)
1065    saved_libs="${LIBS}"
1066    saved_cppflags="${CPPFLAGS}"
1067    if test "x${VPB_DIR}" != "x"; then
1068       if test -d ${VPB_DIR}/lib; then
1069          vpblibdir=${VPB_DIR}/lib
1070       else
1071          vpblibdir=${VPB_DIR}
1072       fi
1073       LIBS="${LIBS} -L${vpblibdir}"
1074       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1075    fi
1076    LIBS="${LIBS} -lvpb -lpthread"
1077    AC_LINK_IFELSE(
1078         [
1079         AC_LANG_PROGRAM(
1080         [#include <vpbapi.h>],
1081         [int q = vpb_open(0,0);])
1082         ],
1083         [       AC_MSG_RESULT(yes) 
1084                 ac_cv_lib_vpb_vpb_open="yes" 
1085         ],
1086         [       AC_MSG_RESULT(no) 
1087                 ac_cv_lib_vpb_vpb_open="no" 
1088         ]
1089         )
1090    LIBS="${saved_libs}"
1091    CPPFLAGS="${saved_cppflags}"
1092    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1093         VPB_LIB="-lvpb"
1094         if test "${VPB_DIR}" != ""; then
1095            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1096            VPB_INCLUDE="-I${VPB_DIR}/include"
1097         fi
1098         PBX_VPB=1
1099         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1100    fi
1101 fi
1102
1103 AC_LANG_POP
1104
1105 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1106
1107 # Check for various zaptel features and locations.
1108 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1109 # will be used in the system headers to determine the location
1110 # of the zaptel.h header.
1111
1112 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1113 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1114
1115 # Check for VLDTMF support
1116 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1117
1118 # Check for transcode support
1119 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1120
1121 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1122 case "${host_os}" in
1123     freebsd*)
1124         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1125         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1126         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1127
1128         # other case, old tonezone (0.80)
1129         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1130         ;;
1131 esac
1132
1133 EDITLINE_LIB=""
1134 if test "x$TERMCAP_LIB" != "x" ; then
1135   EDITLINE_LIB="$TERMCAP_LIB"
1136 elif test "x$TINFO_LIB" != "x" ; then
1137   EDITLINE_LIB="$TINFO_LIB"
1138 elif test "x$CURSES_LIB" != "x" ; then
1139   EDITLINE_LIB="$CURSES_LIB"
1140 elif test "x$NCURSES_LIB" != "x" ; then
1141   EDITLINE_LIB="$NCURSES_LIB"
1142 else
1143   AC_MSG_ERROR(*** termcap support not found)
1144 fi
1145 AC_SUBST(EDITLINE_LIB)
1146
1147 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1148 AC_SUBST(PBX_H323)
1149
1150 AC_CHECK_HEADER([linux/compiler.h],
1151                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1152
1153 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1154                                    #include <linux/version.h>
1155                                    #ifdef HAVE_LINUX_COMPILER_H
1156                                    #include <linux/compiler.h>
1157                                    #endif
1158                                    ])
1159 AC_SUBST(PBX_IXJUSER)
1160
1161 AST_EXT_TOOL_CHECK([SDL], [sdl])
1162 AST_EXT_LIB_CHECK([SDL_IMAGE], [SDL_image], [IMG_Load], [SDL/SDL_image.h], [${SDL_LIB}])
1163 AST_EXT_LIB_CHECK([FFMPEG], [avcodec], [sws_getContext], [ffmpeg/avcodec.h], [-lpthread -lz -lm])
1164
1165 PBX_GTK=0
1166 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1167 if test ! "x${GTKCONFIG}" = xNo; then
1168    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1169    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1170    PBX_GTK=1
1171    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1172 fi
1173 AC_SUBST(PBX_GTK)
1174 AC_SUBST(GTK_INCLUDE)
1175 AC_SUBST(GTK_LIB)
1176
1177 PBX_GTK2=0
1178 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1179 if test ! "x${PKGCONFIG}" = xNo; then
1180    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1181    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1182    PBX_GTK2=1
1183    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1184 fi
1185 AC_SUBST(PBX_GTK2)
1186 AC_SUBST(GTK2_INCLUDE)
1187 AC_SUBST(GTK2_LIB)
1188
1189 if test "${USE_CURL}" != "no"; then
1190    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1191    if test ! x"${CURL_CONFIG}" = xNo; then
1192    # check for version
1193       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1194          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1195          CURL_LIB=$(${CURL_CONFIG} --libs)
1196
1197          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1198          saved_cppflags="${CPPFLAGS}"
1199          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1200          AC_COMPILE_IFELSE(
1201             [AC_LANG_PROGRAM(
1202                 [#include <curl/curl.h>],
1203                     [curl_version();])
1204             ],[
1205                 AC_MSG_RESULT(yes)
1206                 ac_cv_curl_h="yes"
1207             ],[
1208                 AC_MSG_RESULT(no)
1209                 ac_cv_curl_h="no"
1210             ]
1211          )
1212          CPPFLAGS="${saved_cppflags}"
1213          if test "${ac_cv_curl_h}" = "yes"; then
1214              PBX_CURL=1
1215              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1216          fi
1217       fi
1218    fi
1219 fi
1220
1221 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1222 AST_CHECK_MANDATORY
1223
1224 AC_OUTPUT
1225
1226 if test "x${silent}" != "xyes" ; then
1227 echo
1228 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1229 echo "            .\$7\$7..          .7\$\$7:.    "
1230 echo "          .\$\$:.                 ,\$7.7   "
1231 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1232 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1233 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1234 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1235 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1236 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1237 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1238 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1239 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1240 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1241 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1242 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1243 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1244 echo " \$\$\$\$\$                        \$\$\$       "
1245 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1246 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1247 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1248 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1249 echo
1250 fi
1251
1252 AC_MSG_NOTICE(Package configured for: )
1253 AC_MSG_NOTICE( OS type  : $host_os)
1254 AC_MSG_NOTICE( Host CPU : $host_cpu)
1255 AC_MSG_NOTICE( build-cpu:vendor:os: $build_cpu : $build_vendor : $build_os :) 
1256 AC_MSG_NOTICE( host-cpu:vendor:os: $host_cpu : $host_vendor : $host_os :) 
1257 if test "${cross_compiling}" = "yes"; then
1258    AC_MSG_NOTICE( Cross Compilation = YES)
1259 fi