Merge changes from team/russell/http_filetxfer
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_CHECK_FUNCS([gethostbyname_r])
288
289 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
290 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
291
292 AC_MSG_CHECKING(for compiler atomic operations)
293 AC_LINK_IFELSE(
294 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
295 AC_MSG_RESULT(yes)
296 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
297 AC_MSG_RESULT(no)
298 )
299
300 AST_GCC_ATTRIBUTE(pure)
301 AST_GCC_ATTRIBUTE(malloc)
302 AST_GCC_ATTRIBUTE(const)
303 AST_GCC_ATTRIBUTE(unused)
304 AST_GCC_ATTRIBUTE(always_inline)
305
306 AC_MSG_CHECKING(for -ffunction-sections support)
307 saved_CFLAGS="${CFLAGS}"
308 CFLAGS="${CFLAGS} -ffunction-sections"
309 AC_COMPILE_IFELSE(
310         AC_LANG_PROGRAM([], [int x = 1;]),
311         AC_MSG_RESULT(yes)
312         [saved_LDFLAGS="${LDFLAGS}"]
313         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
314         AC_MSG_CHECKING(for --gc-sections support)
315         AC_LINK_IFELSE(
316                 AC_LANG_PROGRAM([], [int x = 1;]),
317                 AC_MSG_RESULT(yes)
318                 [GC_CFLAGS="-ffunction-sections"]
319                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
320                 AC_MSG_RESULT(no)
321         )
322         [LDFLAGS="${saved_LDFLAGS}"],
323         AC_MSG_RESULT(no)
324 )
325 CFLAGS="${saved_CFLAGS}"
326 AC_SUBST(GC_CFLAGS)
327 AC_SUBST(GC_LDFLAGS)
328
329 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
330 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
331         AC_MSG_RESULT(yes)
332         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
333 else
334         AC_MSG_RESULT(no)
335         AST_DECLARATION_AFTER_STATEMENT=
336 fi
337 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
338
339
340 AC_MSG_CHECKING(for sysinfo)
341 AC_LINK_IFELSE(
342         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
343                         [struct sysinfo sys_info;]),
344         AC_MSG_RESULT(yes)
345         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
346         AC_MSG_RESULT(no)
347 )
348
349 AC_MSG_CHECKING(for res_ninit)
350 AC_LINK_IFELSE(
351         AC_LANG_PROGRAM([#include <resolv.h>],
352                         [int foo = res_ninit(NULL);]),
353         AC_MSG_RESULT(yes)
354         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
355         AC_MSG_RESULT(no)
356 )
357
358 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
359
360 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
361
362 AC_CHECK_HEADER([libkern/OSAtomic.h],
363                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
364
365 AC_CHECK_SIZEOF(int)
366
367 AC_COMPILE_IFELSE(
368   [AC_LANG_PROGRAM(
369     [#include <stdlib.h>
370      #include <sys/sendfile.h>],
371     [sendfile(1, 0, NULL, 1);])
372   ],[
373     AC_MSG_RESULT(yes)
374        have_sendfile=yes
375   ],[
376     AC_MSG_RESULT(no)
377        have_sendfile=no
378   ]
379 )
380 if test "${have_sendfile}" = "yes"; then
381   AC_DEFINE([HAVE_SENDFILE], 1, [Define if your system has the sendfile syscall.])
382 fi
383
384 # do the package library checks now
385
386 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
387
388 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
389
390 if test "x${host_os}" = "xlinux-gnu" ; then
391   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
392 fi
393
394 GSM_INTERNAL="yes"
395 AC_SUBST(GSM_INTERNAL)
396 GSM_SYSTEM="yes"
397 if test "${USE_GSM}" != "no"; then
398    if test "${GSM_DIR}" = "internal"; then
399       GSM_SYSTEM="no"
400    elif test "${GSM_DIR}" != ""; then
401       GSM_INTERNAL="no"
402    fi
403    if test "${GSM_SYSTEM}" = "yes"; then
404       gsmlibdir=""
405       if test "x${GSM_DIR}" != "x"; then
406          if test -d ${GSM_DIR}/lib; then
407             gsmlibdir="-L${GSM_DIR}/lib"
408          else
409             gsmlibdir="-L${GSM_DIR}"
410          fi
411       fi
412       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
413       [Define to indicate the GSM library]), [], ${gsmlibdir})
414       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
415          if test "x${GSM_DIR}" != "x" ; then
416             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
417             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
418          else
419             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
420             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
421          fi
422          if test "${GSM_HEADER_FOUND}" = "0" ; then
423             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
424                if test "x${GSM_MANDATORY}" = "xyes" ; then
425                   AC_MSG_NOTICE([***])
426                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
427                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
428                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
429                   exit 1
430                fi
431             fi
432          fi
433          GSM_OK=0
434          if test "${GSM_HEADER_FOUND}" = "1" ; then
435             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
436             GSM_OK=1
437          else
438             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
439                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
440                GSM_OK=1
441             fi
442          fi
443          if test "${GSM_OK}" = "1" ; then
444             GSM_LIB="-lgsm"
445             if test "x${GSM_DIR}" != "x"; then
446                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
447                GSM_INCLUDE="-I${GSM_DIR}/include"
448             fi
449             PBX_GSM=1
450             GSM_INTERNAL="no"
451          fi
452       fi
453    fi
454    if test "${GSM_INTERNAL}" = "yes"; then
455       PBX_GSM=1
456       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
457    fi
458 fi
459
460 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
461
462 if test "${PBX_IKSEMEL}" = 1; then
463    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
464 fi
465
466 if test "${USE_IMAP_TK}" != "no"; then
467    if test "${IMAP_TK_DIR}" = "system" ; then
468       AC_MSG_NOTICE([Checking for system c-client library...])
469    elif test "${IMAP_TK_DIR}" = ""; then
470       IMAP_TK_DIR=`pwd`"/../imap-2004g"
471       if test  -n "${IMAP_TK_MANDATORY}"; then
472          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
473          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
474          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
475          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
476       fi
477    fi
478    if test "${IMAP_TK_DIR}" != "system" ; then
479       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
480    fi
481    saved_cppflags="${CPPFLAGS}"
482    saved_libs="${LIBS}"
483    if test "${IMAP_TK_DIR}" = "system" ; then
484       imap_ldflags=""
485       imap_libs="-lc-client"
486       imap_include="-DUSE_SYSTEM_IMAP"
487    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
488       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
489       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
490       imap_include="-I${IMAP_TK_DIR}/c-client"
491    fi
492    CPPFLAGS="${CPPFLAGS} ${imap_include}"
493    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
494    AC_LINK_IFELSE(
495         AC_LANG_PROGRAM(
496                 [#ifdef USE_SYSTEM_IMAP
497                 #include <imap/c-client.h>
498                 #else
499                 #include "c-client.h"
500                 #endif
501                 void mm_searched (MAILSTREAM *stream,unsigned long number)
502                 {
503                 }
504                 void mm_exists (MAILSTREAM *stream,unsigned long number)
505                 {
506                 }
507                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
508                 {
509                 }
510                 void mm_flags (MAILSTREAM *stream,unsigned long number)
511                 {
512                 }
513                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
514                 {
515                 }
516                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
517                 {
518                 }
519                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
520                 {
521                 }
522                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
523                 {
524                 }
525                 void mm_log (char *string,long errflg)
526                 {
527                 }
528                 void mm_dlog (char *string)
529                 {
530                 }
531                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
532                 {
533                 }
534                 void mm_critical (MAILSTREAM *stream)
535                 {
536                 }
537                 void mm_nocritical (MAILSTREAM *stream)
538                 {
539                 }
540                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
541                 {
542                 }
543                 void mm_fatal (char *string)
544                 {
545                 }],
546                 [
547                 MAILSTREAM *foo = mail_open(NULL, "", 0);
548                 ]
549         ),
550         [ac_cv_imap_tk="yes"],
551         [ac_cv_imap_tk="no"]
552    )
553    if test "${ac_cv_imap_tk}" = "yes"; then
554    AC_LINK_IFELSE(
555       AC_LANG_PROGRAM(
556          [#ifdef USE_SYSTEM_IMAP
557          #include <imap/c-client.h>
558          #else
559          #include "c-client.h"
560          #endif
561          void mm_searched (MAILSTREAM *stream,unsigned long number)
562          {
563          }
564          void mm_exists (MAILSTREAM *stream,unsigned long number)
565          {
566          }
567          void mm_expunged (MAILSTREAM *stream,unsigned long number)
568          {
569          }
570          void mm_flags (MAILSTREAM *stream,unsigned long number)
571          {
572          }
573          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
574          {
575          }
576          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
577          {
578          }
579          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
580          {
581          }
582          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
583          {
584          }
585          void mm_log (char *string,long errflg)
586          {
587          }
588          void mm_dlog (char *string)
589          {
590          }
591          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
592          {
593          }
594          void mm_critical (MAILSTREAM *stream)
595          {
596          }
597          void mm_nocritical (MAILSTREAM *stream)
598          {
599          }
600          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
601          {
602          }
603          void mm_fatal (char *string)
604          {
605          }],
606          [
607          long check = mail_expunge_full(NULL, "", 0);
608          ]
609       ),
610       [ac_cv_imap_tk2006="yes"],
611       [ac_cv_imap_tk2006="no"]
612   )
613   fi
614    CPPFLAGS="${saved_cppflags}"
615    LIBS="${saved_libs}"
616    if test "${ac_cv_imap_tk}" = "yes"; then
617       AC_MSG_RESULT(yes) 
618       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
619       IMAP_TK_INCLUDE="${imap_include}"
620       PBX_IMAP_TK=1
621       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
622       if test "${ac_cv_imap_tk2006}" = "yes"; then
623          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
624       fi
625    else
626       AC_MSG_RESULT(no) 
627    fi
628 fi
629
630 # Needed by unixodbc
631 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
632
633 AC_LANG_PUSH(C++)
634
635 if test "${USE_KDE}" != "no"; then
636    AC_MSG_CHECKING(for crashHandler in -lkdecore)
637    saved_libs="${LIBS}"
638    saved_cppflags="${CPPFLAGS}"
639    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
640    if test -d ${KDE_DIR}/lib; then
641       kdelibdir="${KDE_DIR}/lib"
642    else
643       kdelibdir="${KDE_DIR}"
644    fi
645    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
646
647    AC_LINK_IFELSE(
648         [AC_LANG_PROGRAM(
649                         [#include "kcrash.h"],
650                         [KCrash::defaultCrashHandler(1);])
651         ],
652         [ac_cv_lib_kde_crash="yes"],
653         [ac_cv_lib_kde_crash="no"])
654                 
655    LIBS="${saved_libs}"
656    CPPFLAGS="${saved_cppflags}"
657         
658    if test "${ac_cv_lib_kde_crash}" = "yes"; then
659       AC_MSG_RESULT(yes) 
660       KDE_LIB="-lkdecore -lkdeui"
661       if test "${KDE_DIR}" != ""; then
662          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
663          KDE_INCLUDE="-I${KDE_DIR}/include"
664       fi
665       PBX_KDE=1
666       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
667    else
668       AC_MSG_RESULT(no) 
669    fi
670 fi
671 if test "${PBX_KDE}" = 1; then
672    AC_PATH_TOOL(KDEINIT, kdeinit, No)
673    if test ! x"${KDEINIT}" = xNo; then
674       KDEDIR=$(${DIRNAME} ${KDEINIT})
675       KDEDIR=$(${DIRNAME} ${KDEDIR})
676    fi
677    AC_SUBST([KDEDIR])
678 fi
679
680 AC_LANG_POP
681
682 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
683
684 if test "${PBX_MISDN}" = 1; then
685    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
686    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
687    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
688 fi
689
690 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
691
692 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
693
694 NETSNMP_CONFIG=No
695 if test "${USE_NETSNMP}" != "no"; then  
696    if test "x${NETSNMP_DIR}" != "x"; then
697       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
698       if test x"${NETSNMP_CONFIG}" = xNo; then
699          AC_MSG_NOTICE([***])
700          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
701          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
702          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
703          AC_MSG_NOTICE([*** including --without-netsnmp])
704          exit 1
705       fi
706    else
707       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
708    fi
709 fi
710 if test x"${NETSNMP_CONFIG}" != xNo; then
711    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
712    
713    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
714    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
715
716    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
717       NETSNMP_LIB="${NETSNMP_libs}"
718       PBX_NETSNMP=1
719    fi
720 fi
721
722 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
723
724 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
725
726 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
727
728 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
729
730 # possible places for oss definitions
731 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
732 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
733 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
734
735 PG_CONFIG=No
736 if test "${USE_PGSQL}" != "no"; then    
737    if test "x${PGSQL_DIR}" != "x"; then
738       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
739       if test x"${PG_CONFIG}" = xNo; then
740          AC_MSG_NOTICE([***])
741          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
742          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
743          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
744          AC_MSG_NOTICE([*** including --without-postgres])
745          exit 1
746       fi
747    else
748       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
749    fi
750 fi
751 if test "${PG_CONFIG}" != No; then
752    PGSQL_libdir=`${PG_CONFIG} --libdir`
753    PGSQL_includedir=`${PG_CONFIG} --includedir`
754    if test "x$?" != "x0" ; then
755       if test -n "${PGSQL_MANDATORY}" ; then
756          AC_MSG_NOTICE([***])
757          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
758          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
759          AC_MSG_NOTICE([*** including --without-postgres])
760          exit 1
761           fi
762    else 
763       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
764       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
765
766       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
767          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
768          PGSQL_INCLUDE="-I${PGSQL_includedir}"
769          PBX_PGSQL=1
770       elif test -n "${PGSQL_MANDATORY}";
771       then
772          AC_MSG_NOTICE([***])
773          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
774          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
775          AC_MSG_NOTICE([*** including --without-postgres])
776          exit 1
777       fi
778    fi
779 fi
780
781 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
782
783 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
784
785 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
786
787 if test "${USE_PWLIB}" != "no"; then
788         if test -n "${PWLIB_DIR}"; then
789                 PWLIBDIR="${PWLIB_DIR}"
790         fi
791         AST_CHECK_PWLIB()
792         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
793                 
794         if test "${HAS_PWLIB:-unset}" != "unset"; then
795                 AST_CHECK_OPENH323_PLATFORM()
796
797                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
798
799                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
800                         [Define if your system has the PWLib libraries.],
801                         [#include "ptlib.h"],
802                         [BOOL q = PTime::IsDaylightSavings();])
803         fi
804 fi
805
806 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
807         if test -n "${OPENH323_DIR}"; then
808                 OPENH323DIR="${OPENH323_DIR}"
809         fi
810         AST_CHECK_OPENH323()
811         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
812         AST_CHECK_OPENH323_BUILD()
813         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
814         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
815                 [Define if your system has the OpenH323 libraries.],
816                 [#include "ptlib.h"
817                 #include "h323.h"
818                 #include "h323ep.h"],
819                 [H323EndPoint ep = H323EndPoint();],
820                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
821 fi
822
823 AC_LANG_PUSH(C++)
824
825 if test "${USE_QT}" != "no"; then
826    AC_MSG_CHECKING(for QDate in -lqt)
827    saved_libs="${LIBS}"
828    saved_cppflags="${CPPFLAGS}"
829    if test "x${QT_DIR}" != "x"; then
830       LIBS="${LIBS} -L${QT_DIR}/lib"
831       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
832    fi
833    LIBS="${LIBS} -lqt"
834    qtlib="qt"
835    AC_LINK_IFELSE(
836         [
837                 AC_LANG_PROGRAM(
838                 [#include <qt3/qdatetime.h>],
839                 [QDate date();])
840         ],
841         [ac_cv_lib_qt_qt_date="yes"],
842         [ac_cv_lib_qt_qt_date="no"])
843    LIBS="${saved_libs}"
844    CPPFLAGS="${saved_cppflags}"
845         
846    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
847       saved_libs="${LIBS}"
848       saved_cppflags="${CPPFLAGS}"
849       if test "x${QT_DIR}" != "x"; then
850          LIBS="${LIBS} -L${QT_DIR}/lib"
851          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
852       fi
853       LIBS="${LIBS} -lqt-mt"
854       qtlib="qt-mt"     
855       AC_LINK_IFELSE(
856                 [
857                         AC_LANG_PROGRAM(
858                         [#include <qt3/qdatetime.h>],
859                         [QDate date();])
860                 ],
861                 [ac_cv_lib_qt_qt_date="yes"],
862                 [ac_cv_lib_qt_qt_date="no"])
863       LIBS="${saved_libs}"
864       CPPFLAGS="${saved_cppflags}"
865    fi   
866
867    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
868       AC_MSG_RESULT(yes) 
869    else
870       AC_MSG_RESULT(no) 
871    fi
872         
873    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
874       QT_LIB="-l${qtlib}"
875       if test "${QT_DIR}" != ""; then
876          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
877          QT_INCLUDE="-I${QT_DIR}/include"
878       fi
879       PBX_QT=1
880       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
881       AC_PATH_TOOL(QTMOC, moc, No)
882    fi
883 fi
884
885 AC_LANG_POP
886
887 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
888
889 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
890
891 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
892
893 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
894
895 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
896
897 if test "$PBX_CRYPTO" = "1";
898 then
899     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
900 fi
901
902 if test "$PBX_OPENSSL" = "1";
903 then
904     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
905 fi
906
907 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
908 if test "${PBX_FREETDS}" != "0";
909 then
910     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
911         *0.64*)
912                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
913         ;;
914     *0.63*)
915         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
916         ;;
917     *0.62*)
918         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
919         ;;
920     *)
921         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
922         ;;
923     esac
924 fi
925
926 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
927
928 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
929
930 if test "${host_os}" != "linux-gnu" ; then
931   tonezone_extra="-lm"
932 fi
933
934 # new tonezone, version 1.4.0
935 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
936 # other case, old tonezone (0.80)
937 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
938
939 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
940
941 AC_LANG_PUSH(C++)
942
943 if test "${USE_VPB}" != "no"; then
944    AC_MSG_CHECKING(for vpb_open in -lvpb)
945    saved_libs="${LIBS}"
946    saved_cppflags="${CPPFLAGS}"
947    if test "x${VPB_DIR}" != "x"; then
948       if test -d ${VPB_DIR}/lib; then
949          vpblibdir=${VPB_DIR}/lib
950       else
951          vpblibdir=${VPB_DIR}
952       fi
953       LIBS="${LIBS} -L${vpblibdir}"
954       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
955    fi
956    LIBS="${LIBS} -lvpb -lpthread"
957    AC_LINK_IFELSE(
958         [
959         AC_LANG_PROGRAM(
960         [#include <vpbapi.h>],
961         [int q = vpb_open(0,0);])
962         ],
963         [       AC_MSG_RESULT(yes) 
964                 ac_cv_lib_vpb_vpb_open="yes" 
965         ],
966         [       AC_MSG_RESULT(no) 
967                 ac_cv_lib_vpb_vpb_open="no" 
968         ]
969         )
970    LIBS="${saved_libs}"
971    CPPFLAGS="${saved_cppflags}"
972    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
973         VPB_LIB="-lvpb"
974         if test "${VPB_DIR}" != ""; then
975            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
976            VPB_INCLUDE="-I${VPB_DIR}/include"
977         fi
978         PBX_VPB=1
979         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
980    fi
981 fi
982
983 AC_LANG_POP
984
985 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
986
987 # Check for various zaptel features and locations.
988 # The version number, which goes into HAVE_ZAPTEL_VERSION,
989 # will be used in the system headers to determine the location
990 # of the zaptel.h header.
991
992 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
993 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
994
995 # Check for VLDTMF support
996 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
997
998 # Check for transcode support
999 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1000
1001 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1002 case "${host_os}" in
1003     freebsd*)
1004         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1005         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1006         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1007
1008         # other case, old tonezone (0.80)
1009         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1010         ;;
1011 esac
1012
1013 EDITLINE_LIB=""
1014 if test "x$TERMCAP_LIB" != "x" ; then
1015   EDITLINE_LIB="$TERMCAP_LIB"
1016 elif test "x$TINFO_LIB" != "x" ; then
1017   EDITLINE_LIB="$TINFO_LIB"
1018 elif test "x$CURSES_LIB" != "x" ; then
1019   EDITLINE_LIB="$CURSES_LIB"
1020 elif test "x$NCURSES_LIB" != "x" ; then
1021   EDITLINE_LIB="$NCURSES_LIB"
1022 else
1023   AC_MSG_ERROR(*** termcap support not found)
1024 fi
1025 AC_SUBST(EDITLINE_LIB)
1026
1027 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1028 AC_SUBST(PBX_H323)
1029
1030 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1031                                    #include <linux/version.h>
1032                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
1033                                    #include <linux/compiler.h>
1034                                    #endif
1035                                    ])
1036 AC_SUBST(PBX_IXJUSER)
1037
1038 PBX_GTK=0
1039 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1040 if test ! "x${GTKCONFIG}" = xNo; then
1041    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1042    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1043    PBX_GTK=1
1044    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1045 fi
1046 AC_SUBST(PBX_GTK)
1047 AC_SUBST(GTK_INCLUDE)
1048 AC_SUBST(GTK_LIB)
1049
1050 PBX_GTK2=0
1051 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1052 if test ! "x${PKGCONFIG}" = xNo; then
1053    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags)
1054    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1055    PBX_GTK2=1
1056    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1057 fi
1058 AC_SUBST(PBX_GTK2)
1059 AC_SUBST(GTK2_INCLUDE)
1060 AC_SUBST(GTK2_LIB)
1061
1062 if test "${USE_CURL}" != "no"; then
1063    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1064    if test ! x"${CURL_CONFIG}" = xNo; then
1065    # check for version
1066       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1067          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1068          CURL_LIB=$(${CURL_CONFIG} --libs)
1069
1070          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1071          saved_cppflags="${CPPFLAGS}"
1072          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1073          AC_COMPILE_IFELSE(
1074             [AC_LANG_PROGRAM(
1075                 [#include <curl/curl.h>],
1076                     [curl_version();])
1077             ],[
1078                 AC_MSG_RESULT(yes)
1079                 ac_cv_curl_h="yes"
1080             ],[
1081                 AC_MSG_RESULT(no)
1082                 ac_cv_curl_h="no"
1083             ]
1084          )
1085          CPPFLAGS="${saved_cppflags}"
1086          if test "${ac_cv_curl_h}" = "yes"; then
1087              PBX_CURL=1
1088              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1089          fi
1090       fi
1091    fi
1092 fi
1093
1094 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1095 AST_CHECK_MANDATORY
1096
1097 AC_OUTPUT
1098
1099 if test "x${silent}" != "xyes" ; then
1100 echo
1101 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1102 echo "            .\$7\$7..          .7\$\$7:.    "
1103 echo "          .\$\$:.                 ,\$7.7   "
1104 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1105 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1106 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1107 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1108 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1109 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1110 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1111 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1112 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1113 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1114 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1115 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1116 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1117 echo " \$\$\$\$\$                        \$\$\$       "
1118 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1119 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1120 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1121 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1122 echo
1123 fi
1124
1125 AC_MSG_NOTICE(Package configured for: )
1126 AC_MSG_NOTICE( OS type  : $host_os)
1127 AC_MSG_NOTICE( Host CPU : $host_cpu)
1128 if test "${cross_compiling}" = "yes"; then
1129    AC_MSG_NOTICE( Cross Compilation = YES)
1130 fi