Actually check the return value of epoll_create to make sure it works.
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121 fi
122
123 # Checks for programs.
124 AC_PROG_CC
125 AC_PROG_CXX
126 AC_PROG_CPP
127 AC_PROG_CXXCPP
128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
129 # the developers regenerating the configure script don't have to install libtool.
130 AST_PROG_LD     # note, does not work on FreeBSD
131 AC_PROG_AWK
132 AC_PROG_INSTALL
133 AC_PROG_LN_S
134 AC_PROG_RANLIB
135 AST_CHECK_GNU_MAKE
136
137 AC_PATH_TOOL([STRIP], [strip], :)
138 AC_PATH_TOOL([AR], [ar], :)
139
140 GNU_LD=0
141 if test "x$with_gnu_ld" = "xyes" ; then
142    GNU_LD=1
143 fi
144 AC_SUBST(GNU_LD)
145
146 AC_PATH_PROG([GREP], [grep], :)
147 AC_PATH_PROG([FIND], [find], :)
148 AC_PATH_PROG([COMPRESS], [compress], :)
149 AC_PATH_PROG([BASENAME], [basename], :)
150 AC_PATH_PROG([ID], [id], :)
151 AC_PATH_PROG([DIRNAME], [dirname], :)
152 AC_PATH_PROG([SHELL], [sh], :)
153 AC_PATH_PROG([LN], [ln], :)
154 AC_PATH_PROG([DOT], [dot], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 AC_PATH_PROG([RUBBER], [rubber], :)
157 if test "${WGET}" != ":" ; then
158   DOWNLOAD=${WGET}
159 else
160   AC_PATH_PROG([FETCH], [fetch], [:])
161   DOWNLOAD=${FETCH}
162 fi
163 AC_SUBST(DOWNLOAD)
164
165 ACX_PTHREAD
166
167 AC_LANG(C)
168
169 AC_ARG_ENABLE(dev-mode,
170         [  --enable-dev-mode    Turn on developer mode],
171         [case "${enableval}" in
172               y|ye|yes) AST_DEVMODE=yes ;;
173               n|no)  AST_DEVMODE=no ;;
174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
175         esac])
176 AC_SUBST(AST_DEVMODE)
177
178 # package option names should be in alphabetical order
179 # by the --with option name, to make things easier for the users :-)
180
181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
182
183 # BKTR is used for backtrace support on platforms that do not
184 # have it natively.
185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
190 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
191 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
192 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
193 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
194 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
195 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
196 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
223 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
224 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
225 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
226 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
227 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
228 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
229
230 # check for basic system features and functionality before
231 # checking for package libraries
232
233 AC_FUNC_ALLOCA
234 AC_HEADER_DIRENT
235 AC_HEADER_STDC
236 AC_HEADER_SYS_WAIT
237 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
238
239 AC_SYS_LARGEFILE
240
241 # Checks for typedefs, structures, and compiler characteristics.
242 AC_HEADER_STDBOOL
243 AC_C_CONST
244 AC_TYPE_UID_T
245 AC_C_INLINE
246 AC_TYPE_MODE_T
247 AC_TYPE_OFF_T
248 AC_TYPE_PID_T
249 AC_TYPE_SIZE_T
250 AC_CHECK_MEMBERS([struct stat.st_blksize])
251 AC_HEADER_TIME
252 AC_STRUCT_TM
253 AC_C_VOLATILE
254 AC_CHECK_TYPES([ptrdiff_t])
255
256 # Checks for library functions.
257 AC_FUNC_CHOWN
258 AC_FUNC_CLOSEDIR_VOID
259 AC_FUNC_ERROR_AT_LINE
260 AST_FUNC_FORK
261 AC_FUNC_FSEEKO
262 AC_PROG_GCC_TRADITIONAL
263 # XXX: these are commented out until we determine whether it matters if our malloc()
264 # acts exactly like glibc's or not
265 # AC_FUNC_MALLOC
266 # AC_FUNC_REALLOC
267 AC_FUNC_MEMCMP
268 AC_FUNC_MKTIME
269 AC_FUNC_MMAP
270 AC_FUNC_SELECT_ARGTYPES
271 AC_FUNC_SETVBUF_REVERSED
272 AC_TYPE_SIGNAL
273 AC_FUNC_STAT
274 AC_FUNC_STRCOLL
275 AC_FUNC_STRFTIME
276 AC_FUNC_STRNLEN
277 AC_FUNC_STRTOD
278 AC_FUNC_UTIME_NULL
279 AC_FUNC_VPRINTF
280 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
281
282 # https support (in main/http.c) uses funopen on BSD systems,
283 # fopencookie on linux
284 AC_CHECK_FUNCS([funopen fopencookie])
285
286 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
287 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
288
289 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
290 AC_LINK_IFELSE(
291         AC_LANG_PROGRAM([#include <stdlib.h>
292                          #include <netdb.h>],
293                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
294         AC_MSG_RESULT(yes)
295         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
296         AC_MSG_RESULT(no)
297 )
298
299 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
300 AC_LINK_IFELSE(
301         AC_LANG_PROGRAM([#include <stdlib.h>
302                          #include <netdb.h>],
303                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
304         AC_MSG_RESULT(yes)
305         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
306         AC_MSG_RESULT(no)
307 )
308
309 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
310
311 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
312 AC_LINK_IFELSE(
313 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
314 AC_MSG_RESULT(yes)
315 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
316 AC_MSG_RESULT(no)
317 )
318
319 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
320 AC_LINK_IFELSE(
321 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
322 AC_MSG_RESULT(yes)
323 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
324 AC_MSG_RESULT(no)
325 )
326
327 if test "${cross_compiling}" = "no";
328 then
329   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
330 fi
331
332 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
333 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
334
335 AC_MSG_CHECKING(for working epoll support)
336 AC_LINK_IFELSE(
337 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
338                                           if (res < 0)
339                                              return 1;
340                                           close (res);
341                                           return 0;]),
342 AC_MSG_RESULT(yes)
343 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
344 AC_MSG_RESULT(no)
345 )
346
347 AC_MSG_CHECKING(for compiler atomic operations)
348 AC_LINK_IFELSE(
349 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
350 AC_MSG_RESULT(yes)
351 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
352 AC_MSG_RESULT(no)
353 )
354
355 AST_GCC_ATTRIBUTE(pure)
356 AST_GCC_ATTRIBUTE(malloc)
357 AST_GCC_ATTRIBUTE(const)
358 AST_GCC_ATTRIBUTE(unused)
359 AST_GCC_ATTRIBUTE(always_inline)
360 AST_GCC_ATTRIBUTE(deprecated)
361
362 AC_MSG_CHECKING(for -ffunction-sections support)
363 saved_CFLAGS="${CFLAGS}"
364 CFLAGS="${CFLAGS} -ffunction-sections"
365 AC_COMPILE_IFELSE(
366         AC_LANG_PROGRAM([], [int x = 1;]),
367         AC_MSG_RESULT(yes)
368         [saved_LDFLAGS="${LDFLAGS}"]
369         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
370         AC_MSG_CHECKING(for --gc-sections support)
371         AC_LINK_IFELSE(
372                 AC_LANG_PROGRAM([], [int x = 1;]),
373                 AC_MSG_RESULT(yes)
374                 [GC_CFLAGS="-ffunction-sections"]
375                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
376                 AC_MSG_RESULT(no)
377         )
378         [LDFLAGS="${saved_LDFLAGS}"],
379         AC_MSG_RESULT(no)
380 )
381 CFLAGS="${saved_CFLAGS}"
382 AC_SUBST(GC_CFLAGS)
383 AC_SUBST(GC_LDFLAGS)
384
385 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
386 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
387         AC_MSG_RESULT(yes)
388         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
389 else
390         AC_MSG_RESULT(no)
391         AST_DECLARATION_AFTER_STATEMENT=
392 fi
393 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
394
395
396 AC_MSG_CHECKING(for sysinfo)
397 AC_LINK_IFELSE(
398         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
399                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
400         AC_MSG_RESULT(yes)
401         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
402         AC_MSG_RESULT(no)
403 )
404
405 AC_MSG_CHECKING(for res_ninit)
406 AC_LINK_IFELSE(
407         AC_LANG_PROGRAM([#include <resolv.h>],
408                         [int foo = res_ninit(NULL);]),
409         AC_MSG_RESULT(yes)
410         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
411         AC_MSG_CHECKING(for res_ndestroy)
412         AC_LINK_IFELSE(
413                 AC_LANG_PROGRAM([#include <resolv.h>],
414                                 [int foo = res_ndestroy(NULL);]),
415                 AC_MSG_RESULT(yes)
416                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
417                 AC_MSG_RESULT(no)
418         ),
419         AC_MSG_RESULT(no)
420 )
421
422 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
423
424 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
425
426 AC_CHECK_HEADER([libkern/OSAtomic.h],
427                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
428
429 AC_CHECK_SIZEOF(int)
430
431 # do the package library checks now
432
433 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
434
435 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
436
437 if test "x${host_os}" = "xlinux-gnu" ; then
438   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
439 fi
440
441 # BSD might not have exp2, and/or log2
442 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
443 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
444 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
445 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
446 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
447 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
448 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
449 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
450
451 GSM_INTERNAL="yes"
452 AC_SUBST(GSM_INTERNAL)
453 GSM_SYSTEM="yes"
454 if test "${USE_GSM}" != "no"; then
455    if test "${GSM_DIR}" = "internal"; then
456       GSM_SYSTEM="no"
457    elif test "${GSM_DIR}" != ""; then
458       GSM_INTERNAL="no"
459    fi
460    if test "${GSM_SYSTEM}" = "yes"; then
461       gsmlibdir=""
462       if test "x${GSM_DIR}" != "x"; then
463          if test -d ${GSM_DIR}/lib; then
464             gsmlibdir="-L${GSM_DIR}/lib"
465          else
466             gsmlibdir="-L${GSM_DIR}"
467          fi
468       fi
469       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
470       [Define to indicate the GSM library]), [], ${gsmlibdir})
471       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
472          if test "x${GSM_DIR}" != "x" ; then
473             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
474             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
475          else
476             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
477             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
478          fi
479          if test "${GSM_HEADER_FOUND}" = "0" ; then
480             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
481                if test "x${GSM_MANDATORY}" = "xyes" ; then
482                   AC_MSG_NOTICE([***])
483                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
484                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
485                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
486                   exit 1
487                fi
488             fi
489          fi
490          GSM_OK=0
491          if test "${GSM_HEADER_FOUND}" = "1" ; then
492             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
493             GSM_OK=1
494          else
495             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
496                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
497                GSM_OK=1
498             fi
499          fi
500          if test "${GSM_OK}" = "1" ; then
501             GSM_LIB="-lgsm"
502             if test "x${GSM_DIR}" != "x"; then
503                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
504                GSM_INCLUDE="-I${GSM_DIR}/include"
505             fi
506             PBX_GSM=1
507             GSM_INTERNAL="no"
508          fi
509       fi
510    fi
511    if test "${GSM_INTERNAL}" = "yes"; then
512       PBX_GSM=1
513       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
514    fi
515 fi
516
517 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
518
519 if test "${PBX_IKSEMEL}" = 1; then
520    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye], [gnutls/gnutls.h], [-lz -lgcrypt -lgpg-error])
521 fi
522
523 if test "${USE_IMAP_TK}" != "no"; then
524    if test "${IMAP_TK_DIR}" = "system" ; then
525       AC_MSG_NOTICE([Checking for system c-client library...])
526    elif test "${IMAP_TK_DIR}" = ""; then
527       IMAP_TK_DIR=`pwd`"/../imap-2004g"
528       if test  -n "${IMAP_TK_MANDATORY}"; then
529          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
530          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
531          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
532          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
533       fi
534    fi
535    if test "${IMAP_TK_DIR}" != "system" ; then
536       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
537    fi
538    saved_cppflags="${CPPFLAGS}"
539    saved_libs="${LIBS}"
540    if test "${IMAP_TK_DIR}" = "system" ; then
541       imap_ldflags=""
542       imap_libs="-lc-client"
543       imap_include="-DUSE_SYSTEM_IMAP"
544    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
545       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
546       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
547       imap_include="-I${IMAP_TK_DIR}/c-client"
548    fi
549    CPPFLAGS="${CPPFLAGS} ${imap_include}"
550    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
551    AC_LINK_IFELSE(
552         AC_LANG_PROGRAM(
553                 [#ifdef USE_SYSTEM_IMAP
554                 #include <imap/c-client.h>
555                 #else
556                 #include "c-client.h"
557                 #endif
558                 void mm_searched (MAILSTREAM *stream,unsigned long number)
559                 {
560                 }
561                 void mm_exists (MAILSTREAM *stream,unsigned long number)
562                 {
563                 }
564                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
565                 {
566                 }
567                 void mm_flags (MAILSTREAM *stream,unsigned long number)
568                 {
569                 }
570                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
571                 {
572                 }
573                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
574                 {
575                 }
576                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
577                 {
578                 }
579                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
580                 {
581                 }
582                 void mm_log (char *string,long errflg)
583                 {
584                 }
585                 void mm_dlog (char *string)
586                 {
587                 }
588                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
589                 {
590                 }
591                 void mm_critical (MAILSTREAM *stream)
592                 {
593                 }
594                 void mm_nocritical (MAILSTREAM *stream)
595                 {
596                 }
597                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
598                 {
599                 }
600                 void mm_fatal (char *string)
601                 {
602                 }],
603                 [
604                 MAILSTREAM *foo = mail_open(NULL, "", 0);
605                 ]
606         ),
607         [ac_cv_imap_tk="yes"],
608         [ac_cv_imap_tk="no"]
609    )
610    if test "${ac_cv_imap_tk}" = "yes"; then
611    AC_LINK_IFELSE(
612       AC_LANG_PROGRAM(
613          [#ifdef USE_SYSTEM_IMAP
614          #include <imap/c-client.h>
615          #else
616          #include "c-client.h"
617          #endif
618          void mm_searched (MAILSTREAM *stream,unsigned long number)
619          {
620          }
621          void mm_exists (MAILSTREAM *stream,unsigned long number)
622          {
623          }
624          void mm_expunged (MAILSTREAM *stream,unsigned long number)
625          {
626          }
627          void mm_flags (MAILSTREAM *stream,unsigned long number)
628          {
629          }
630          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
631          {
632          }
633          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
634          {
635          }
636          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
637          {
638          }
639          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
640          {
641          }
642          void mm_log (char *string,long errflg)
643          {
644          }
645          void mm_dlog (char *string)
646          {
647          }
648          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
649          {
650          }
651          void mm_critical (MAILSTREAM *stream)
652          {
653          }
654          void mm_nocritical (MAILSTREAM *stream)
655          {
656          }
657          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
658          {
659          }
660          void mm_fatal (char *string)
661          {
662          }],
663          [
664          long check = mail_expunge_full(NULL, "", 0);
665          ]
666       ),
667       [ac_cv_imap_tk2006="yes"],
668       [ac_cv_imap_tk2006="no"]
669   )
670   fi
671    CPPFLAGS="${saved_cppflags}"
672    LIBS="${saved_libs}"
673    if test "${ac_cv_imap_tk}" = "yes"; then
674       AC_MSG_RESULT(yes) 
675       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
676       IMAP_TK_INCLUDE="${imap_include}"
677       PBX_IMAP_TK=1
678       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
679       if test "${ac_cv_imap_tk2006}" = "yes"; then
680          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
681       fi
682    else
683       AC_MSG_RESULT(no) 
684    fi
685 fi
686
687 # Needed by unixodbc
688 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
689
690 AC_LANG_PUSH(C++)
691
692 if test "${USE_KDE}" != "no"; then
693    AC_MSG_CHECKING(for crashHandler in -lkdecore)
694    saved_libs="${LIBS}"
695    saved_cppflags="${CPPFLAGS}"
696    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
697    if test -d ${KDE_DIR}/lib; then
698       kdelibdir="${KDE_DIR}/lib"
699    else
700       kdelibdir="${KDE_DIR}"
701    fi
702    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
703
704    AC_LINK_IFELSE(
705         [AC_LANG_PROGRAM(
706                         [#include "kcrash.h"],
707                         [KCrash::defaultCrashHandler(1);])
708         ],
709         [ac_cv_lib_kde_crash="yes"],
710         [ac_cv_lib_kde_crash="no"])
711                 
712    LIBS="${saved_libs}"
713    CPPFLAGS="${saved_cppflags}"
714         
715    if test "${ac_cv_lib_kde_crash}" = "yes"; then
716       AC_MSG_RESULT(yes) 
717       KDE_LIB="-lkdecore -lkdeui"
718       if test "${KDE_DIR}" != ""; then
719          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
720          KDE_INCLUDE="-I${KDE_DIR}/include"
721       fi
722       PBX_KDE=1
723       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
724    else
725       AC_MSG_RESULT(no) 
726    fi
727 fi
728 if test "${PBX_KDE}" = 1; then
729    AC_PATH_TOOL(KDEINIT, kdeinit, No)
730    if test ! x"${KDEINIT}" = xNo; then
731       KDEDIR=$(${DIRNAME} ${KDEINIT})
732       KDEDIR=$(${DIRNAME} ${KDEDIR})
733    fi
734    AC_SUBST([KDEDIR])
735 fi
736
737 AC_LANG_POP
738
739 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
740
741 if test "${PBX_MISDN}" = 1; then
742    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
743    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
744    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
745 fi
746
747 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
748
749 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
750
751 NETSNMP_CONFIG=No
752 if test "${USE_NETSNMP}" != "no"; then  
753    if test "x${NETSNMP_DIR}" != "x"; then
754       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
755       if test x"${NETSNMP_CONFIG}" = xNo; then
756          AC_MSG_NOTICE([***])
757          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
758          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
759          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
760          AC_MSG_NOTICE([*** including --without-netsnmp])
761          exit 1
762       fi
763    else
764       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
765    fi
766 fi
767 if test x"${NETSNMP_CONFIG}" != xNo; then
768    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
769    
770    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
771    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
772
773    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
774       NETSNMP_LIB="${NETSNMP_libs}"
775       PBX_NETSNMP=1
776    fi
777 fi
778
779 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
780
781 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
782
783 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
784
785 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
786
787 # possible places for oss definitions
788 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
789 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
790 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
791
792 PG_CONFIG=No
793 if test "${USE_PGSQL}" != "no"; then    
794    if test "x${PGSQL_DIR}" != "x"; then
795       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
796       if test x"${PG_CONFIG}" = xNo; then
797          AC_MSG_NOTICE([***])
798          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
799          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
800          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
801          AC_MSG_NOTICE([*** including --without-postgres])
802          exit 1
803       fi
804    else
805       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
806    fi
807 fi
808 if test "${PG_CONFIG}" != No; then
809    PGSQL_libdir=`${PG_CONFIG} --libdir`
810    PGSQL_includedir=`${PG_CONFIG} --includedir`
811    if test "x$?" != "x0" ; then
812       if test -n "${PGSQL_MANDATORY}" ; then
813          AC_MSG_NOTICE([***])
814          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
815          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
816          AC_MSG_NOTICE([*** including --without-postgres])
817          exit 1
818           fi
819    else 
820       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
821       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
822
823       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
824          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
825          PGSQL_INCLUDE="-I${PGSQL_includedir}"
826          PBX_PGSQL=1
827       elif test -n "${PGSQL_MANDATORY}";
828       then
829          AC_MSG_NOTICE([***])
830          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
831          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
832          AC_MSG_NOTICE([*** including --without-postgres])
833          exit 1
834       fi
835    fi
836 fi
837
838 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
839
840 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
841
842 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
843
844 if test "${USE_PWLIB}" != "no"; then
845         if test -n "${PWLIB_DIR}"; then
846                 PWLIBDIR="${PWLIB_DIR}"
847         fi
848         AST_CHECK_PWLIB()
849         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
850                 
851         if test "${HAS_PWLIB:-unset}" != "unset"; then
852                 AST_CHECK_OPENH323_PLATFORM()
853
854                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
855
856                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
857                         [Define if your system has the PWLib libraries.],
858                         [#include "ptlib.h"],
859                         [BOOL q = PTime::IsDaylightSavings();])
860         fi
861 fi
862
863 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
864         if test -n "${OPENH323_DIR}"; then
865                 OPENH323DIR="${OPENH323_DIR}"
866         fi
867         AST_CHECK_OPENH323()
868         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
869         AST_CHECK_OPENH323_BUILD()
870         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
871         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
872                 [Define if your system has the OpenH323 libraries.],
873                 [#include "ptlib.h"
874                 #include "h323.h"
875                 #include "h323ep.h"],
876                 [H323EndPoint ep = H323EndPoint();],
877                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
878 fi
879
880 AC_LANG_PUSH(C++)
881
882 if test "${USE_QT}" != "no"; then
883    AC_MSG_CHECKING(for QDate in -lqt)
884    saved_libs="${LIBS}"
885    saved_cppflags="${CPPFLAGS}"
886    if test "x${QT_DIR}" != "x"; then
887       LIBS="${LIBS} -L${QT_DIR}/lib"
888       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
889    fi
890    LIBS="${LIBS} -lqt"
891    qtlib="qt"
892    AC_LINK_IFELSE(
893         [
894                 AC_LANG_PROGRAM(
895                 [#include <qt3/qdatetime.h>],
896                 [QDate date();])
897         ],
898         [ac_cv_lib_qt_qt_date="yes"],
899         [ac_cv_lib_qt_qt_date="no"])
900    LIBS="${saved_libs}"
901    CPPFLAGS="${saved_cppflags}"
902         
903    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
904       saved_libs="${LIBS}"
905       saved_cppflags="${CPPFLAGS}"
906       if test "x${QT_DIR}" != "x"; then
907          LIBS="${LIBS} -L${QT_DIR}/lib"
908          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
909       fi
910       LIBS="${LIBS} -lqt-mt"
911       qtlib="qt-mt"     
912       AC_LINK_IFELSE(
913                 [
914                         AC_LANG_PROGRAM(
915                         [#include <qt3/qdatetime.h>],
916                         [QDate date();])
917                 ],
918                 [ac_cv_lib_qt_qt_date="yes"],
919                 [ac_cv_lib_qt_qt_date="no"])
920       LIBS="${saved_libs}"
921       CPPFLAGS="${saved_cppflags}"
922    fi   
923
924    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
925       AC_MSG_RESULT(yes) 
926    else
927       AC_MSG_RESULT(no) 
928    fi
929         
930    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
931       QT_LIB="-l${qtlib}"
932       if test "${QT_DIR}" != ""; then
933          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
934          QT_INCLUDE="-I${QT_DIR}/include"
935       fi
936       PBX_QT=1
937       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
938       AC_PATH_TOOL(QTMOC, moc, No)
939    fi
940 fi
941
942 AC_LANG_POP
943
944 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
945
946 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
947
948 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
949
950 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
951
952 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
953
954 if test "$PBX_CRYPTO" = "1";
955 then
956     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
957 fi
958
959 if test "$PBX_OPENSSL" = "1";
960 then
961     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
962 fi
963
964 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
965 if test "${PBX_FREETDS}" != "0";
966 then
967     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
968         *0.64*)
969                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
970         ;;
971     *0.63*)
972         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
973         ;;
974     *0.62*)
975         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
976         ;;
977     *)
978         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
979         ;;
980     esac
981 fi
982
983 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
984
985 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
986
987 if test "${host_os}" != "linux-gnu" ; then
988   tonezone_extra="-lm"
989 fi
990
991 # new tonezone, version 1.4.0
992 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
993 # other case, old tonezone (0.80)
994 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
995
996 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
997
998 AC_LANG_PUSH(C++)
999
1000 if test "${USE_VPB}" != "no"; then
1001    AC_MSG_CHECKING(for vpb_open in -lvpb)
1002    saved_libs="${LIBS}"
1003    saved_cppflags="${CPPFLAGS}"
1004    if test "x${VPB_DIR}" != "x"; then
1005       if test -d ${VPB_DIR}/lib; then
1006          vpblibdir=${VPB_DIR}/lib
1007       else
1008          vpblibdir=${VPB_DIR}
1009       fi
1010       LIBS="${LIBS} -L${vpblibdir}"
1011       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1012    fi
1013    LIBS="${LIBS} -lvpb -lpthread"
1014    AC_LINK_IFELSE(
1015         [
1016         AC_LANG_PROGRAM(
1017         [#include <vpbapi.h>],
1018         [int q = vpb_open(0,0);])
1019         ],
1020         [       AC_MSG_RESULT(yes) 
1021                 ac_cv_lib_vpb_vpb_open="yes" 
1022         ],
1023         [       AC_MSG_RESULT(no) 
1024                 ac_cv_lib_vpb_vpb_open="no" 
1025         ]
1026         )
1027    LIBS="${saved_libs}"
1028    CPPFLAGS="${saved_cppflags}"
1029    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1030         VPB_LIB="-lvpb"
1031         if test "${VPB_DIR}" != ""; then
1032            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1033            VPB_INCLUDE="-I${VPB_DIR}/include"
1034         fi
1035         PBX_VPB=1
1036         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1037    fi
1038 fi
1039
1040 AC_LANG_POP
1041
1042 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1043
1044 # Check for various zaptel features and locations.
1045 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1046 # will be used in the system headers to determine the location
1047 # of the zaptel.h header.
1048
1049 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1050 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1051
1052 # Check for VLDTMF support
1053 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1054
1055 # Check for transcode support
1056 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1057
1058 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1059 case "${host_os}" in
1060     freebsd*)
1061         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1062         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1063         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1064
1065         # other case, old tonezone (0.80)
1066         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1067         ;;
1068 esac
1069
1070 EDITLINE_LIB=""
1071 if test "x$TERMCAP_LIB" != "x" ; then
1072   EDITLINE_LIB="$TERMCAP_LIB"
1073 elif test "x$TINFO_LIB" != "x" ; then
1074   EDITLINE_LIB="$TINFO_LIB"
1075 elif test "x$CURSES_LIB" != "x" ; then
1076   EDITLINE_LIB="$CURSES_LIB"
1077 elif test "x$NCURSES_LIB" != "x" ; then
1078   EDITLINE_LIB="$NCURSES_LIB"
1079 else
1080   AC_MSG_ERROR(*** termcap support not found)
1081 fi
1082 AC_SUBST(EDITLINE_LIB)
1083
1084 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1085 AC_SUBST(PBX_H323)
1086
1087 AC_CHECK_HEADER([linux/compiler.h],
1088                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1089
1090 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1091                                    #include <linux/version.h>
1092                                    #ifdef HAVE_LINUX_COMPILER_H
1093                                    #include <linux/compiler.h>
1094                                    #endif
1095                                    ])
1096 AC_SUBST(PBX_IXJUSER)
1097
1098 PBX_GTK=0
1099 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1100 if test ! "x${GTKCONFIG}" = xNo; then
1101    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1102    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1103    PBX_GTK=1
1104    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1105 fi
1106 AC_SUBST(PBX_GTK)
1107 AC_SUBST(GTK_INCLUDE)
1108 AC_SUBST(GTK_LIB)
1109
1110 PBX_GTK2=0
1111 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1112 if test ! "x${PKGCONFIG}" = xNo; then
1113    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1114    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1115    PBX_GTK2=1
1116    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1117 fi
1118 AC_SUBST(PBX_GTK2)
1119 AC_SUBST(GTK2_INCLUDE)
1120 AC_SUBST(GTK2_LIB)
1121
1122 if test "${USE_CURL}" != "no"; then
1123    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1124    if test ! x"${CURL_CONFIG}" = xNo; then
1125    # check for version
1126       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1127          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1128          CURL_LIB=$(${CURL_CONFIG} --libs)
1129
1130          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1131          saved_cppflags="${CPPFLAGS}"
1132          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1133          AC_COMPILE_IFELSE(
1134             [AC_LANG_PROGRAM(
1135                 [#include <curl/curl.h>],
1136                     [curl_version();])
1137             ],[
1138                 AC_MSG_RESULT(yes)
1139                 ac_cv_curl_h="yes"
1140             ],[
1141                 AC_MSG_RESULT(no)
1142                 ac_cv_curl_h="no"
1143             ]
1144          )
1145          CPPFLAGS="${saved_cppflags}"
1146          if test "${ac_cv_curl_h}" = "yes"; then
1147              PBX_CURL=1
1148              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1149          fi
1150       fi
1151    fi
1152 fi
1153
1154 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1155 AST_CHECK_MANDATORY
1156
1157 AC_OUTPUT
1158
1159 if test "x${silent}" != "xyes" ; then
1160 echo
1161 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1162 echo "            .\$7\$7..          .7\$\$7:.    "
1163 echo "          .\$\$:.                 ,\$7.7   "
1164 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1165 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1166 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1167 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1168 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1169 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1170 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1171 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1172 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1173 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1174 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1175 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1176 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1177 echo " \$\$\$\$\$                        \$\$\$       "
1178 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1179 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1180 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1181 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1182 echo
1183 fi
1184
1185 AC_MSG_NOTICE(Package configured for: )
1186 AC_MSG_NOTICE( OS type  : $host_os)
1187 AC_MSG_NOTICE( Host CPU : $host_cpu)
1188 if test "${cross_compiling}" = "yes"; then
1189    AC_MSG_NOTICE( Cross Compilation = YES)
1190 fi