Merge changes from team/russell/sqlite:
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.59)
10
11 m4_define([PBX_VERSION],
12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
13                        [\([0-9.]*\)\(\w\|\W\)*],
14                        [\1]))
15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
16
17 # cross-compile macros
18 AC_CANONICAL_BUILD
19 AC_CANONICAL_HOST
20
21 # check existence of the package
22 AC_CONFIG_SRCDIR([main/asterisk.c])
23
24 # specify output header file
25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
26
27 AC_COPYRIGHT("Asterisk")
28 AC_REVISION($Revision$)
29
30 AC_GNU_SOURCE
31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
32
33 case "${host_os}" in
34      freebsd*)
35      ac_default_prefix=/usr/local
36      CPPFLAGS=-I/usr/local/include
37      LDFLAGS=-L/usr/local/lib
38      ;;
39
40      *)
41      ac_default_prefix=/usr
42      if test ${sysconfdir} = '${prefix}/etc'; then
43         sysconfdir=/etc
44      fi
45      if test ${mandir} = '${prefix}/man'; then
46         mandir=/usr/share/man
47      fi
48      ;;
49 esac
50
51 if test ${localstatedir} = '${prefix}/var'; then
52      localstatedir=/var
53 fi
54
55 BUILD_PLATFORM=${build}
56 BUILD_CPU=${build_cpu}
57 BUILD_VENDOR=${build_vendor}
58 BUILD_OS=${build_os}
59
60 AC_SUBST(BUILD_PLATFORM)
61 AC_SUBST(BUILD_CPU)
62 AC_SUBST(BUILD_VENDOR)
63 AC_SUBST(BUILD_OS)
64
65 HOST_PLATFORM=${host}
66 HOST_CPU=${host_cpu}
67 HOST_VENDOR=${host_vendor}
68 HOST_OS=${host_os}
69
70 AC_SUBST(HOST_PLATFORM)
71 AC_SUBST(HOST_CPU)
72 AC_SUBST(HOST_VENDOR)
73 AC_SUBST(HOST_OS)
74
75 case "${host_os}" in
76      freebsd*)
77      OSARCH=FreeBSD
78      ;;
79      netbsd*)
80      OSARCH=NetBSD
81      ;;
82      openbsd*)
83      OSARCH=OpenBSD
84      ;;
85      solaris*)
86      OSARCH=SunOS
87      ;;
88      *)
89      OSARCH=${HOST_OS}
90      ;;
91 esac
92
93 AC_SUBST(OSARCH)
94
95 #  check for uname
96 AC_PATH_TOOL([UNAME], [uname], No)
97 if test ! x"${UNAME}" = xNo; then
98    PBX_OSREV=$(${UNAME} -r)
99 fi
100 AC_SUBST(PBX_OSREV)
101
102 AH_TOP(
103 #ifndef ASTERISK_AUTOCONFIG_H
104 #define ASTERISK_AUTOCONFIG_H
105
106 #include "asterisk/buildopts.h"
107
108 )
109
110 AH_BOTTOM(
111 #endif
112 )
113
114 # cross-compile checks
115 if test "${cross_compiling}" = "yes"; 
116 then
117    AC_CHECK_TOOL(CC, gcc, :)
118    AC_CHECK_TOOL(CXX, g++, :)
119    AC_CHECK_TOOL(LD, ld, :)
120    AC_CHECK_TOOL(RANLIB, ranlib, :)
121    AC_CHECK_TOOL(AR, ar, :)
122 fi
123
124 # Checks for programs.
125 AC_PROG_CC
126 AC_PROG_CXX
127 AC_PROG_CPP
128 AC_PROG_CXXCPP
129 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
130 # the developers regenerating the configure script don't have to install libtool.
131 AST_PROG_LD     # note, does not work on FreeBSD
132 AC_PROG_AWK
133 AC_PROG_INSTALL
134 AC_PROG_LN_S
135 AC_PROG_RANLIB
136 AST_CHECK_GNU_MAKE
137
138 GNU_LD=0
139 if test "x$with_gnu_ld" = "xyes" ; then
140    GNU_LD=1
141 fi
142 AC_SUBST(GNU_LD)
143
144 AC_PATH_PROG([GREP], [grep], :)
145 AC_PATH_PROG([AR], [ar], :)
146 AC_PATH_PROG([FIND], [find], :)
147 AC_PATH_PROG([COMPRESS], [compress], :)
148 AC_PATH_PROG([BASENAME], [basename], :)
149 AC_PATH_PROG([ID], [id], :)
150 AC_PATH_PROG([DIRNAME], [dirname], :)
151 AC_PATH_PROG([SHELL], [sh], :)
152 AC_PATH_PROG([LN], [ln], :)
153 AC_PATH_PROG([DOT], [dot], :)
154 AC_PATH_PROG([STRIP], [strip], :)
155 AC_PATH_PROG([WGET], [wget], :)
156 if test "${WGET}" != ":" ; then
157   DOWNLOAD=${WGET}
158 else
159   AC_PATH_PROG([FETCH], [fetch], [:])
160   DOWNLOAD=${FETCH}
161 fi
162 AC_SUBST(DOWNLOAD)
163
164 ACX_PTHREAD
165
166 AC_LANG(C)
167
168 AC_ARG_ENABLE(dev-mode,
169         [  --enable-dev-mode    Turn on developer mode],
170         [case "${enableval}" in
171               y|ye|yes) AST_DEVMODE=yes ;;
172               n|no)  AST_DEVMODE=no ;;
173               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
174         esac])
175 AC_SUBST(AST_DEVMODE)
176
177 # package option names should be in alphabetical order
178 # by the --with option name, to make things easier for the users :-)
179
180 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
181
182 # BKTR is used for backtrace support on platforms that do not
183 # have it natively.
184 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
185 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
186 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
187 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
188 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
189 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
190 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
191 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
192 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
193 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
194 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
195 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
196 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
197 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
198 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
199 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
200 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
201 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
202 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
203 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
204 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
205 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
206 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
207 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
208 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
209 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
210 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
211 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
212 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
213 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
214 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
215 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL], [ssl])
216 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
217 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
218 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
219 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
220 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
221 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
222 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
223 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
224 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
225 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
226
227 # check for basic system features and functionality before
228 # checking for package libraries
229
230 AC_FUNC_ALLOCA
231 AC_HEADER_DIRENT
232 AC_HEADER_STDC
233 AC_HEADER_SYS_WAIT
234 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
235
236 AC_SYS_LARGEFILE
237
238 # Checks for typedefs, structures, and compiler characteristics.
239 AC_HEADER_STDBOOL
240 AC_C_CONST
241 AC_TYPE_UID_T
242 AC_C_INLINE
243 AC_TYPE_MODE_T
244 AC_TYPE_OFF_T
245 AC_TYPE_PID_T
246 AC_TYPE_SIZE_T
247 AC_CHECK_MEMBERS([struct stat.st_blksize])
248 AC_HEADER_TIME
249 AC_STRUCT_TM
250 AC_C_VOLATILE
251 AC_CHECK_TYPES([ptrdiff_t])
252
253 # Checks for library functions.
254 AC_FUNC_CHOWN
255 AC_FUNC_CLOSEDIR_VOID
256 AC_FUNC_ERROR_AT_LINE
257 AST_FUNC_FORK
258 AC_FUNC_FSEEKO
259 AC_PROG_GCC_TRADITIONAL
260 # XXX: these are commented out until we determine whether it matters if our malloc()
261 # acts exactly like glibc's or not
262 # AC_FUNC_MALLOC
263 # AC_FUNC_REALLOC
264 AC_FUNC_MEMCMP
265 AC_FUNC_MKTIME
266 AC_FUNC_MMAP
267 AC_FUNC_SELECT_ARGTYPES
268 AC_FUNC_SETVBUF_REVERSED
269 AC_TYPE_SIGNAL
270 AC_FUNC_STAT
271 AC_FUNC_STRCOLL
272 AC_FUNC_STRFTIME
273 AC_FUNC_STRNLEN
274 AC_FUNC_STRTOD
275 AC_FUNC_UTIME_NULL
276 AC_FUNC_VPRINTF
277 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
278
279 # https support (in main/http.c) uses funopen on BSD systems,
280 # fopencookie on linux
281 AC_CHECK_FUNCS([funopen fopencookie])
282
283 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
284 AC_CHECK_FUNCS([gethostbyname_r])
285
286 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
287 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
288
289 AC_MSG_CHECKING(for compiler atomic operations)
290 AC_LINK_IFELSE(
291 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
292 AC_MSG_RESULT(yes)
293 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
294 AC_MSG_RESULT(no)
295 )
296
297 AST_GCC_ATTRIBUTE(pure)
298 AST_GCC_ATTRIBUTE(malloc)
299 AST_GCC_ATTRIBUTE(const)
300 AST_GCC_ATTRIBUTE(unused)
301 AST_GCC_ATTRIBUTE(always_inline)
302
303 AC_MSG_CHECKING(for -ffunction-sections support)
304 saved_CFLAGS="${CFLAGS}"
305 CFLAGS="${CFLAGS} -ffunction-sections"
306 AC_COMPILE_IFELSE(
307         AC_LANG_PROGRAM([], [int x = 1;]),
308         AC_MSG_RESULT(yes)
309         [saved_LDFLAGS="${LDFLAGS}"]
310         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
311         AC_MSG_CHECKING(for --gc-sections support)
312         AC_LINK_IFELSE(
313                 AC_LANG_PROGRAM([], [int x = 1;]),
314                 AC_MSG_RESULT(yes)
315                 [GC_CFLAGS="-ffunction-sections"]
316                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
317                 AC_MSG_RESULT(no)
318         )
319         [LDFLAGS="${saved_LDFLAGS}"],
320         AC_MSG_RESULT(no)
321 )
322 CFLAGS="${saved_CFLAGS}"
323 AC_SUBST(GC_CFLAGS)
324 AC_SUBST(GC_LDFLAGS)
325
326 AC_MSG_CHECKING(for res_ninit)
327 AC_LINK_IFELSE(
328         AC_LANG_PROGRAM([#include <resolv.h>],
329                         [int foo = res_ninit(NULL);]),
330         AC_MSG_RESULT(yes)
331         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
332         AC_MSG_RESULT(no)
333 )
334
335 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
336
337 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
338
339 AC_CHECK_HEADER([libkern/OSAtomic.h],
340                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
341
342 AC_CHECK_SIZEOF(int)
343
344 # do the package library checks now
345
346 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
347
348 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
349
350 if test "x${host_os}" = "xlinux-gnu" ; then
351   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
352 fi
353
354 GSM_INTERNAL="yes"
355 AC_SUBST(GSM_INTERNAL)
356 GSM_SYSTEM="yes"
357 if test "${USE_GSM}" != "no"; then
358    if test "${GSM_DIR}" = "internal"; then
359       GSM_SYSTEM="no"
360    elif test "${GSM_DIR}" != ""; then
361       GSM_INTERNAL="no"
362    fi
363    if test "${GSM_SYSTEM}" = "yes"; then
364       gsmlibdir=""
365       if test "x${GSM_DIR}" != "x"; then
366          if test -d ${GSM_DIR}/lib; then
367             gsmlibdir="-L${GSM_DIR}/lib"
368          else
369             gsmlibdir="-L${GSM_DIR}"
370          fi
371       fi
372       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
373       [Define to indicate the GSM library]), [], ${gsmlibdir})
374       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
375          if test "x${GSM_DIR}" != "x" ; then
376             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
377             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
378          else
379             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
380             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
381          fi
382          if test "${GSM_HEADER_FOUND}" = "0" ; then
383             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
384                if test "x${GSM_MANDATORY}" = "xyes" ; then
385                   AC_MSG_NOTICE([***])
386                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
387                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
388                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
389                   exit 1
390                fi
391             fi
392          fi
393          GSM_OK=0
394          if test "${GSM_HEADER_FOUND}" = "1" ; then
395             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
396             GSM_OK=1
397          else
398             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
399                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
400                GSM_OK=1
401             fi
402          fi
403          if test "${GSM_OK}" = "1" ; then
404             GSM_LIB="-lgsm"
405             if test "x${GSM_DIR}" != "x"; then
406                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
407                GSM_INCLUDE="-I${GSM_DIR}/include"
408             fi
409             PBX_GSM=1
410             GSM_INTERNAL="no"
411          fi
412       fi
413    fi
414    if test "${GSM_INTERNAL}" = "yes"; then
415       PBX_GSM=1
416       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
417    fi
418 fi
419
420 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
421
422 if test "${PBX_IKSEMEL}" = 1; then
423    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye])
424    if test "${PBX_GNUTLS}" = 1; then
425       IKSEMEL_LIB="${IKSEMEL_LIB} -lgnutls -lz -lgcrypt -lgpg-error"
426    fi
427 fi
428
429 if test "${USE_IMAP_TK}" != "no"; then
430    if test "${IMAP_TK_DIR}" = ""; then
431       IMAP_TK_DIR=`pwd`"/../imap-2004g"
432       if test  -n "${IMAP_TK_MANDATORY}"; then
433          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
434          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
435          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
436          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
437       fi
438    fi
439    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
440    saved_cppflags="${CPPFLAGS}"
441    saved_libs="${LIBS}"
442    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
443       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
444    fi
445    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
446    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
447    AC_LINK_IFELSE(
448         AC_LANG_PROGRAM(
449                 [#include "c-client.h"
450                 void mm_searched (MAILSTREAM *stream,unsigned long number)
451                 {
452                 }
453                 void mm_exists (MAILSTREAM *stream,unsigned long number)
454                 {
455                 }
456                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
457                 {
458                 }
459                 void mm_flags (MAILSTREAM *stream,unsigned long number)
460                 {
461                 }
462                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
463                 {
464                 }
465                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
466                 {
467                 }
468                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
469                 {
470                 }
471                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
472                 {
473                 }
474                 void mm_log (char *string,long errflg)
475                 {
476                 }
477                 void mm_dlog (char *string)
478                 {
479                 }
480                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
481                 {
482                 }
483                 void mm_critical (MAILSTREAM *stream)
484                 {
485                 }
486                 void mm_nocritical (MAILSTREAM *stream)
487                 {
488                 }
489                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
490                 {
491                 }
492                 void mm_fatal (char *string)
493                 {
494                 }],
495                 [
496                 MAILSTREAM *foo = mail_open(NULL, "", 0);
497                 ]
498         ),
499         [ac_cv_imap_tk="yes"],
500         [ac_cv_imap_tk="no"]
501    )
502    if test "${ac_cv_imap_tk}" = "yes"; then
503    AC_LINK_IFELSE(
504       AC_LANG_PROGRAM(
505          [#include "c-client.h"
506          void mm_searched (MAILSTREAM *stream,unsigned long number)
507          {
508          }
509          void mm_exists (MAILSTREAM *stream,unsigned long number)
510          {
511          }
512          void mm_expunged (MAILSTREAM *stream,unsigned long number)
513          {
514          }
515          void mm_flags (MAILSTREAM *stream,unsigned long number)
516          {
517          }
518          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
519          {
520          }
521          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
522          {
523          }
524          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
525          {
526          }
527          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
528          {
529          }
530          void mm_log (char *string,long errflg)
531          {
532          }
533          void mm_dlog (char *string)
534          {
535          }
536          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
537          {
538          }
539          void mm_critical (MAILSTREAM *stream)
540          {
541          }
542          void mm_nocritical (MAILSTREAM *stream)
543          {
544          }
545          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
546          {
547          }
548          void mm_fatal (char *string)
549          {
550          }],
551          [
552          long check = mail_expunge_full(NULL, "", 0);
553          ]
554       ),
555       [ac_cv_imap_tk2006="yes"],
556       [ac_cv_imap_tk2006="no"]
557   )
558   fi
559    CPPFLAGS="${saved_cppflags}"
560    LIBS="${saved_libs}"
561    if test "${ac_cv_imap_tk}" = "yes"; then
562       AC_MSG_RESULT(yes) 
563       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
564       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
565       PBX_IMAP_TK=1
566       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
567       if test "${ac_cv_imap_tk2006}" = "yes"; then
568          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
569       fi
570    else
571       AC_MSG_RESULT(no) 
572    fi
573 fi
574
575 AC_LANG_PUSH(C++)
576
577 if test "${USE_KDE}" != "no"; then
578    AC_MSG_CHECKING(for crashHandler in -lkdecore)
579    saved_libs="${LIBS}"
580    saved_cppflags="${CPPFLAGS}"
581    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
582    if test -d ${KDE_DIR}/lib; then
583       kdelibdir="${KDE_DIR}/lib"
584    else
585       kdelibdir="${KDE_DIR}"
586    fi
587    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
588
589    AC_LINK_IFELSE(
590         [AC_LANG_PROGRAM(
591                         [#include "kcrash.h"],
592                         [KCrash::defaultCrashHandler(1);])
593         ],
594         [ac_cv_lib_kde_crash="yes"],
595         [ac_cv_lib_kde_crash="no"])
596                 
597    LIBS="${saved_libs}"
598    CPPFLAGS="${saved_cppflags}"
599         
600    if test "${ac_cv_lib_kde_crash}" = "yes"; then
601       AC_MSG_RESULT(yes) 
602       KDE_LIB="-lkdecore -lkdeui"
603       if test "${KDE_DIR}" != ""; then
604          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
605          KDE_INCLUDE="-I${KDE_DIR}/include"
606       fi
607       PBX_KDE=1
608       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
609    else
610       AC_MSG_RESULT(no) 
611    fi
612 fi
613 if test "${PBX_KDE}" = 1; then
614    AC_PATH_TOOL(KDEINIT, kdeinit, No)
615    if test ! x"${KDEINIT}" = xNo; then
616       KDEDIR=$(${DIRNAME} ${KDEINIT})
617       KDEDIR=$(${DIRNAME} ${KDEDIR})
618    fi
619    AC_SUBST([KDEDIR])
620 fi
621
622 AC_LANG_POP
623
624 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
625
626 if test "${PBX_MISDN}" = 1; then
627    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
628    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
629 fi
630
631 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
632
633 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
634
635 NETSNMP_CONFIG=No
636 if test "${USE_NETSNMP}" != "no"; then  
637    if test "x${NETSNMP_DIR}" != "x"; then
638       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
639       if test x"${NETSNMP_CONFIG}" = xNo; then
640          AC_MSG_NOTICE([***])
641          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
642          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
643          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
644          AC_MSG_NOTICE([*** including --without-netsnmp])
645          exit 1
646       fi
647    else
648       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
649    fi
650 fi
651 if test x"${NETSNMP_CONFIG}" != xNo; then
652    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
653    
654    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
655    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
656
657    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
658       NETSNMP_LIB="${NETSNMP_libs}"
659       PBX_NETSNMP=1
660    fi
661 fi
662
663 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
664
665 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [-lltdl])
666
667 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
668
669 AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
670
671 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
672
673 # possible places for oss definitions
674 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
675 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
676 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
677
678 PG_CONFIG=No
679 if test "${USE_PGSQL}" != "no"; then    
680    if test "x${PGSQL_DIR}" != "x"; then
681       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
682       if test x"${PG_CONFIG}" = xNo; then
683          AC_MSG_NOTICE([***])
684          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
685          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
686          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
687          AC_MSG_NOTICE([*** including --without-postgres])
688          exit 1
689       fi
690    else
691       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
692    fi
693 fi
694 if test "${PG_CONFIG}" != No; then
695    PGSQL_libdir=`${PG_CONFIG} --libdir`
696    PGSQL_includedir=`${PG_CONFIG} --includedir`
697    if test "x$?" != "x0" ; then
698       if test -n "${PGSQL_MANDATORY}" ; then
699          AC_MSG_NOTICE([***])
700          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
701          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
702          AC_MSG_NOTICE([*** including --without-postgres])
703          exit 1
704           fi
705    else 
706       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
707       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
708
709       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
710          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
711          PGSQL_INCLUDE="-I${PGSQL_includedir}"
712          PBX_PGSQL=1
713       elif test -n "${PGSQL_MANDATORY}";
714       then
715          AC_MSG_NOTICE([***])
716          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
717          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
718          AC_MSG_NOTICE([*** including --without-postgres])
719          exit 1
720       fi
721    fi
722 fi
723
724 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
725
726 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
727
728 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
729
730 if test "${USE_PWLIB}" != "no"; then
731         if test -n "${PWLIB_DIR}"; then
732                 PWLIBDIR="${PWLIB_DIR}"
733         fi
734         AST_CHECK_PWLIB()
735         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
736                 
737         if test "${HAS_PWLIB:-unset}" != "unset"; then
738                 AST_CHECK_OPENH323_PLATFORM()
739
740                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
741
742                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
743                         [Define if your system has the PWLib libraries.],
744                         [#include "ptlib.h"],
745                         [BOOL q = PTime::IsDaylightSavings();])
746         fi
747 fi
748
749 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
750         if test -n "${OPENH323_DIR}"; then
751                 OPENH323DIR="${OPENH323_DIR}"
752         fi
753         AST_CHECK_OPENH323()
754         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
755         AST_CHECK_OPENH323_BUILD()
756         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
757         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
758                 [Define if your system has the OpenH323 libraries.],
759                 [#include "ptlib.h"
760                 #include "h323.h"
761                 #include "h323ep.h"],
762                 [H323EndPoint ep = H323EndPoint();],
763                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
764 fi
765
766 AC_LANG_PUSH(C++)
767
768 if test "${USE_QT}" != "no"; then
769    AC_MSG_CHECKING(for QDate in -lqt)
770    saved_libs="${LIBS}"
771    saved_cppflags="${CPPFLAGS}"
772    if test "x${QT_DIR}" != "x"; then
773       LIBS="${LIBS} -L${QT_DIR}/lib"
774       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
775    fi
776    LIBS="${LIBS} -lqt"
777    qtlib="qt"
778    AC_LINK_IFELSE(
779         [
780                 AC_LANG_PROGRAM(
781                 [#include <qt3/qdatetime.h>],
782                 [QDate date();])
783         ],
784         [ac_cv_lib_qt_qt_date="yes"],
785         [ac_cv_lib_qt_qt_date="no"])
786    LIBS="${saved_libs}"
787    CPPFLAGS="${saved_cppflags}"
788         
789    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
790       saved_libs="${LIBS}"
791       saved_cppflags="${CPPFLAGS}"
792       if test "x${QT_DIR}" != "x"; then
793          LIBS="${LIBS} -L${QT_DIR}/lib"
794          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
795       fi
796       LIBS="${LIBS} -lqt-mt"
797       qtlib="qt-mt"     
798       AC_LINK_IFELSE(
799                 [
800                         AC_LANG_PROGRAM(
801                         [#include <qt3/qdatetime.h>],
802                         [QDate date();])
803                 ],
804                 [ac_cv_lib_qt_qt_date="yes"],
805                 [ac_cv_lib_qt_qt_date="no"])
806       LIBS="${saved_libs}"
807       CPPFLAGS="${saved_cppflags}"
808    fi   
809
810    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
811       AC_MSG_RESULT(yes) 
812    else
813       AC_MSG_RESULT(no) 
814    fi
815         
816    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
817       QT_LIB="-l${qtlib}"
818       if test "${QT_DIR}" != ""; then
819          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
820          QT_INCLUDE="-I${QT_DIR}/include"
821       fi
822       PBX_QT=1
823       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
824       AC_PATH_TOOL(QTMOC, moc, No)
825    fi
826 fi
827
828 AC_LANG_POP
829
830 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
831
832 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
833
834 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
835
836 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
837
838 AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
839
840 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
841 if test "${PBX_FREETDS}" != "0";
842 then
843     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
844         *0.64*)
845                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
846         ;;
847     *0.63*)
848         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
849         ;;
850     *0.62*)
851         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
852         ;;
853     *)
854         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
855         ;;
856     esac
857 fi
858
859 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
860
861 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
862
863 if test "${host_os}" != "linux-gnu" ; then
864   tonezone_extra="-lm"
865 fi
866
867 # new tonezone, version 1.4.0
868 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
869 # other case, old tonezone (0.80)
870 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
871
872 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
873
874 AC_LANG_PUSH(C++)
875
876 if test "${USE_VPB}" != "no"; then
877    AC_MSG_CHECKING(for vpb_open in -lvpb)
878    saved_libs="${LIBS}"
879    saved_cppflags="${CPPFLAGS}"
880    if test "x${VPB_DIR}" != "x"; then
881       if test -d ${VPB_DIR}/lib; then
882          vpblibdir=${VPB_DIR}/lib
883       else
884          vpblibdir=${VPB_DIR}
885       fi
886       LIBS="${LIBS} -L${vpblibdir}"
887       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
888    fi
889    LIBS="${LIBS} -lvpb -lpthread"
890    AC_LINK_IFELSE(
891         [
892         AC_LANG_PROGRAM(
893         [#include <vpbapi.h>],
894         [int q = vpb_open(0,0);])
895         ],
896         [       AC_MSG_RESULT(yes) 
897                 ac_cv_lib_vpb_vpb_open="yes" 
898         ],
899         [       AC_MSG_RESULT(no) 
900                 ac_cv_lib_vpb_vpb_open="no" 
901         ]
902         )
903    LIBS="${saved_libs}"
904    CPPFLAGS="${saved_cppflags}"
905    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
906         VPB_LIB="-lvpb"
907         if test "${VPB_DIR}" != ""; then
908            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
909            VPB_INCLUDE="-I${VPB_DIR}/include"
910         fi
911         PBX_VPB=1
912         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
913    fi
914 fi
915
916 AC_LANG_POP
917
918 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
919
920 # Check for various zaptel features and locations.
921 # The version number, which goes into HAVE_ZAPTEL_VERSION,
922 # will be used in the system headers to determine the location
923 # of the zaptel.h header.
924
925 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
926 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
927
928 # Check for VLDTMF support
929 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
930
931 # Check for transcode support
932 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
933
934 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
935 case "${host_os}" in
936     freebsd*)
937         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
938         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
939         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
940
941         # other case, old tonezone (0.80)
942         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
943         ;;
944 esac
945
946 EDITLINE_LIB=""
947 if test "x$TERMCAP_LIB" != "x" ; then
948   EDITLINE_LIB="$TERMCAP_LIB"
949 elif test "x$TINFO_LIB" != "x" ; then
950   EDITLINE_LIB="$TINFO_LIB"
951 elif test "x$CURSES_LIB" != "x" ; then
952   EDITLINE_LIB="$CURSES_LIB"
953 elif test "x$NCURSES_LIB" != "x" ; then
954   EDITLINE_LIB="$NCURSES_LIB"
955 else
956   AC_MSG_ERROR(*** termcap support not found)
957 fi
958 AC_SUBST(EDITLINE_LIB)
959
960 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
961 AC_SUBST(PBX_H323)
962
963 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
964                                    #include <linux/version.h>
965                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
966                                    #include <linux/compiler.h>
967                                    #endif
968                                    ])
969 AC_SUBST(PBX_IXJUSER)
970
971 PBX_GTK=0
972 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
973 if test ! "x${GTKCONFIG}" = xNo; then
974    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
975    GTK_LIB=$(${GTKCONFIG} --libs gthread)
976    PBX_GTK=1
977    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
978 fi
979 AC_SUBST(PBX_GTK)
980 AC_SUBST(GTK_INCLUDE)
981 AC_SUBST(GTK_LIB)
982
983 if test "${USE_CURL}" != "no"; then
984    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
985    if test ! x"${CURL_CONFIG}" = xNo; then
986    # check for version
987       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
988          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
989          CURL_LIB=$(${CURL_CONFIG} --libs)
990          PBX_CURL=1
991          AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
992       fi
993    fi
994 fi
995
996 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
997 AST_CHECK_MANDATORY
998
999 AC_OUTPUT
1000
1001 if test "x${silent}" != "xyes" ; then
1002 echo
1003 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1004 echo "            .\$7\$7..          .7\$\$7:.    "
1005 echo "          .\$\$:.                 ,\$7.7   "
1006 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1007 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1008 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1009 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1010 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1011 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1012 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1013 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1014 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1015 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1016 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1017 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1018 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1019 echo " \$\$\$\$\$                        \$\$\$       "
1020 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1021 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1022 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1023 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1024 echo
1025 fi
1026
1027 AC_MSG_NOTICE(Package configured for: )
1028 AC_MSG_NOTICE( OS type  : $host_os)
1029 AC_MSG_NOTICE( Host CPU : $host_cpu)
1030 if test "${cross_compiling}" = "yes"; then
1031    AC_MSG_NOTICE( Cross Compilation = YES)
1032 fi