Merge in SS7 changes.... need to still cleanup zapata.conf
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2
3 AC_PREREQ(2.60)
4
5 m4_define([PBX_VERSION],
6           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
7                        [\([0-9.]*\)\(\w\|\W\)*],
8                        [\1]))
9 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
10
11 # cross-compile macros
12 AC_CANONICAL_BUILD
13 AC_CANONICAL_HOST
14
15 # check existence of the package
16 AC_CONFIG_SRCDIR([main/asterisk.c])
17
18 # specify output header file
19 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
20
21 AC_COPYRIGHT("Asterisk")
22 AC_REVISION($Revision$)
23
24 case "${host_os}" in
25      freebsd*)
26      ac_default_prefix=/usr/local
27      ;;
28      *)
29      ac_default_prefix=/usr
30      if test ${sysconfdir} = '${prefix}/etc'; then
31         sysconfdir=/etc
32      fi
33      if test ${mandir} = '${prefix}/man'; then
34         mandir=/usr/share/man
35      fi
36      ;;
37 esac
38
39 if test ${localstatedir} = '${prefix}/var'; then
40      localstatedir=/var
41 fi
42
43 BUILD_PLATFORM=${build}
44 BUILD_CPU=${build_cpu}
45 BUILD_VENDOR=${build_vendor}
46 BUILD_OS=${build_os}
47
48 AC_SUBST(BUILD_PLATFORM)
49 AC_SUBST(BUILD_CPU)
50 AC_SUBST(BUILD_VENDOR)
51 AC_SUBST(BUILD_OS)
52
53 HOST_PLATFORM=${host}
54 HOST_CPU=${host_cpu}
55 HOST_VENDOR=${host_vendor}
56 HOST_OS=${host_os}
57
58 AC_SUBST(HOST_PLATFORM)
59 AC_SUBST(HOST_CPU)
60 AC_SUBST(HOST_VENDOR)
61 AC_SUBST(HOST_OS)
62
63 case "${host_os}" in
64      freebsd*)
65      OSARCH=FreeBSD
66      ;;
67      netbsd*)
68      OSARCH=NetBSD
69      ;;
70      openbsd*)
71      OSARCH=OpenBSD
72      ;;
73      solaris*)
74      OSARCH=SunOS
75      ;;
76      *)
77      OSARCH=${HOST_OS}
78      ;;
79 esac
80
81 AC_SUBST(OSARCH)
82
83 #  check for uname
84 AC_PATH_TOOL([UNAME], [uname], No)
85 if test ! x"${UNAME}" = xNo; then
86    PBX_OSREV=$(${UNAME} -r)
87 fi
88 AC_SUBST(PBX_OSREV)
89
90 # This needs to be before any macros that use the C compiler
91 AC_GNU_SOURCE
92
93 AH_TOP(
94 #ifndef ASTERISK_AUTOCONFIG_H
95 #define ASTERISK_AUTOCONFIG_H
96
97 #include "asterisk/buildopts.h"
98
99 #ifndef _REENTRANT
100 #define _REENTRANT
101 #endif
102 )
103
104 AH_BOTTOM(
105 #endif
106 )
107
108 # cross-compile checks
109 if test "${cross_compiling}" = "yes"; 
110 then
111    AC_CHECK_TOOL(CC, gcc, :)
112    AC_CHECK_TOOL(CXX, g++, :)
113    AC_CHECK_TOOL(LD, ld, :)
114    AC_CHECK_TOOL(RANLIB, ranlib, :)
115    AC_CHECK_TOOL(AR, ar, :)
116 fi
117
118 # Checks for programs.
119 AC_PROG_CC
120 AC_PROG_CXX
121 AC_PROG_CPP
122 AC_PROG_CXXCPP
123 AC_PROG_AWK
124 AC_PROG_INSTALL
125 AC_PROG_LN_S
126 AC_PROG_RANLIB
127 AST_CHECK_GNU_MAKE
128
129 # http://www.mail-archive.com/bug-make@gnu.org/msg02871.html
130 echo 'define A' > testMakefile
131 echo '12345: $(1:.idl=.hh) $(1:.idl=S.h) $(1:.idl=C.h) $(1:.idl=SK.cc) $(1:.idl=DynSK.cc)' >> testMakefile
132 echo 'endef' >> testMakefile
133 echo '$(eval $(call A,01234567890123456789012345678901.idl))' >> testMakefile
134 echo '01234567890123456789012345678901.hh:' >> testMakefile
135 echo '01234567890123456789012345678901S.h:' >> testMakefile
136 echo '01234567890123456789012345678901C.h:' >> testMakefile
137 echo '01234567890123456789012345678901SK.cc:' >> testMakefile
138 echo '01234567890123456789012345678901DynSK.cc:' >> testMakefile
139 $GNU_MAKE -r -f testMakefile 2>&1 > /dev/null
140 if test "$?" != "0" ; then
141   rm -f testMakefile
142   AC_MSG_NOTICE(********** ERROR **********)
143   AC_MSG_NOTICE(Your version of GNU Make contains a bug that will cause the Asterisk build)
144   AC_MSG_NOTICE(system to not function properly.  This bug is known to be fixed in version)
145   AC_MSG_NOTICE(3.81 as well as distributions of 3.80 that contain backported bug fixes.  You)
146   AC_MSG_NOTICE(must update GNU make to build Asterisk.)
147   AC_MSG_NOTICE(***************************)
148   exit 1
149 fi
150 rm -f testMakefile
151
152 AC_PATH_PROG([GREP], [grep], :)
153 AC_PATH_PROG([AR], [ar], :)
154 AC_PATH_PROG([FIND], [find], :)
155 AC_PATH_PROG([COMPRESS], [compress], :)
156 AC_PATH_PROG([BASENAME], [basename], :)
157 AC_PATH_PROG([ID], [id], :)
158 AC_PATH_PROG([DIRNAME], [dirname], :)
159 AC_PATH_PROG([SHELL], [sh], :)
160 AC_PATH_PROG([LN], [ln], :)
161 AC_PATH_PROG([DOT], [dot], :)
162
163 AC_LANG(C)
164
165 AC_ARG_ENABLE(dev-mode,
166         [  --enable-dev-mode    Turn on developer mode],
167         [case "${enableval}" in
168               y|ye|yes) AST_DEVMODE=yes ;;
169               n|no)  AST_DEVMODE=no ;;
170               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
171         esac])
172 AC_SUBST(AST_DEVMODE)
173
174 # package option names should be in alphabetical order
175 # by the --with option name, to make things easier for the users :-)
176
177 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
178 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
179 AST_EXT_LIB_SETUP([GNUTLS], [GNU TLS support (used for iksemel only)], [gnutls])
180 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
181 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
182 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
183 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
184 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
185 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
186 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
187 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
188 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
189 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
190 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
191 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
192 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
193 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
194 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
195 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
196 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
197 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
198 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
199 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
200 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
201 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
202 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
203 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
204 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
205 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL], [ssl])
206 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
207 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
208 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
209 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
210 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
211 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
212 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
213 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
214
215 # check for basic system features and functionality before
216 # checking for package libraries
217
218 AC_FUNC_ALLOCA
219 AC_HEADER_DIRENT
220 AC_HEADER_STDC
221 AC_HEADER_SYS_WAIT
222 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
223
224 AC_SYS_LARGEFILE
225
226 # Checks for typedefs, structures, and compiler characteristics.
227 AC_HEADER_STDBOOL
228 AC_C_CONST
229 AC_TYPE_UID_T
230 AC_C_INLINE
231 AC_TYPE_MODE_T
232 AC_TYPE_OFF_T
233 AC_TYPE_PID_T
234 AC_TYPE_SIZE_T
235 AC_CHECK_MEMBERS([struct stat.st_blksize])
236 AC_HEADER_TIME
237 AC_STRUCT_TM
238 AC_C_VOLATILE
239 AC_CHECK_TYPES([ptrdiff_t])
240
241 # Checks for library functions.
242 AC_FUNC_CHOWN
243 AC_FUNC_CLOSEDIR_VOID
244 AC_FUNC_ERROR_AT_LINE
245 AST_FUNC_FORK
246 AC_FUNC_FSEEKO
247 AC_PROG_GCC_TRADITIONAL
248 # XXX: these are commented out until we determine whether it matters if our malloc()
249 # acts exactly like glibc's or not
250 # AC_FUNC_MALLOC
251 # AC_FUNC_REALLOC
252 AC_FUNC_MEMCMP
253 AC_FUNC_MKTIME
254 AC_FUNC_MMAP
255 AC_FUNC_SELECT_ARGTYPES
256 AC_FUNC_SETVBUF_REVERSED
257 AC_TYPE_SIGNAL
258 AC_FUNC_STAT
259 AC_FUNC_STRCOLL
260 AC_FUNC_STRFTIME
261 AC_FUNC_STRNLEN
262 AC_FUNC_STRTOD
263 AC_FUNC_UTIME_NULL
264 AC_FUNC_VPRINTF
265 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent floor ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap pow putenv re_comp regcomp rint select setenv socket sqrt strcasecmp strcasestr strchr strcspn strdup strerror strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
266
267 AC_MSG_CHECKING(for compiler atomic operations)
268 AC_LINK_IFELSE(
269 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
270 AC_MSG_RESULT(yes)
271 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
272 AC_MSG_RESULT(no)
273 )
274
275 AST_GCC_ATTRIBUTE(pure)
276 AST_GCC_ATTRIBUTE(malloc)
277 AST_GCC_ATTRIBUTE(const)
278 AST_GCC_ATTRIBUTE(unused)
279 AST_GCC_ATTRIBUTE(always_inline)
280
281 AC_MSG_CHECKING(for -ffunction-sections support)
282 saved_CFLAGS="${CFLAGS}"
283 CFLAGS="${CFLAGS} -ffunction-sections"
284 AC_COMPILE_IFELSE(
285         AC_LANG_PROGRAM([], [int x = 1;]),
286         AC_MSG_RESULT(yes)
287         [saved_LDFLAGS="${LDFLAGS}"]
288         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
289         AC_MSG_CHECKING(for --gc-sections support)
290         AC_LINK_IFELSE(
291                 AC_LANG_PROGRAM([], [int x = 1;]),
292                 AC_MSG_RESULT(yes)
293                 [GC_CFLAGS="-ffunction-sections"]
294                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
295                 AC_MSG_RESULT(no)
296         )
297         [LDFLAGS="${saved_LDFLAGS}"],
298         AC_MSG_RESULT(no)
299 )
300 CFLAGS="${saved_CFLAGS}"
301 AC_SUBST(GC_CFLAGS)
302 AC_SUBST(GC_LDFLAGS)
303
304 AC_MSG_CHECKING(for res_ninit)
305 AC_LINK_IFELSE(
306         AC_LANG_PROGRAM([#include <resolv.h>],
307                         [int foo = res_ninit(NULL);]),
308         AC_MSG_RESULT(yes)
309         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.]),
310         AC_MSG_RESULT(no)
311 )
312
313 AC_MSG_CHECKING(for RTLD_NOLOAD)
314 AC_LINK_IFELSE(
315         AC_LANG_PROGRAM([#include <dlfcn.h>],
316                         [int foo = RTLD_NOLOAD;]),
317         AC_MSG_RESULT(yes)
318         AC_DEFINE([HAVE_RTLD_NOLOAD], 1, [Define to 1 if your system has a dynamic linker that supports RTLD_NOLOAD.]),
319         AC_MSG_RESULT(no)
320 )
321
322 AC_CHECK_HEADER([libkern/OSAtomic.h],
323                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
324
325 AC_CHECK_SIZEOF(int)
326
327 # do the package library checks now
328
329 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
330
331 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
332
333 GSM_INTERNAL="yes"
334 AC_SUBST(GSM_INTERNAL)
335 GSM_SYSTEM="yes"
336 if test "${USE_GSM}" != "no"; then
337    if test "${GSM_DIR}" = "internal"; then
338       GSM_SYSTEM="no"
339    elif test "${GSM_DIR}" != ""; then
340       GSM_INTERNAL="no"
341    fi
342    if test "${GSM_SYSTEM}" = "yes"; then
343       gsmlibdir=""
344       if test "x${GSM_DIR}" != "x"; then
345          if test -d ${GSM_DIR}/lib; then
346             gsmlibdir="-L${GSM_DIR}/lib"
347          else
348             gsmlibdir="-L${GSM_DIR}"
349          fi
350       fi
351       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
352       [Define to indicate the GSM library]), [], ${gsmlibdir})
353       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
354          GSM_LIB="-lgsm"
355          if test "x${GSM_DIR}" != "x"; then
356             GSM_LIB="${gsmlibdir} ${GSM_LIB}"
357             GSM_INCLUDE="-I${GSM_DIR}/include"
358          fi
359          PBX_GSM=1
360          GSM_INTERNAL="no"
361       fi
362    fi
363    if test "${GSM_INTERNAL}" = "yes"; then
364       PBX_GSM=1
365    fi
366 fi
367
368 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
369
370 if test "${PBX_IKSEMEL}" = 1; then
371    AST_EXT_LIB_CHECK([GNUTLS], [gnutls], [gnutls_bye])
372    if test "${PBX_GNUTLS}" = 1; then
373       IKSEMEL_LIB="${IKSEMEL_LIB} -lgnutls -lz -lgcrypt -lnsl -lgpg-error"
374    fi
375 fi
376
377 if test "${USE_IMAP_TK}" != "no"; then
378    if test "${IMAP_TK_DIR}" = ""; then
379       IMAP_TK_DIR=`pwd`"/../imap-2004g"
380    fi
381    AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
382    saved_cppflags="${CPPFLAGS}"
383    saved_libs="${LIBS}"
384    if test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
385       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
386    fi
387    CPPFLAGS="${CPPFLAGS} -I${IMAP_TK_DIR}/c-client"
388    LIBS="${LIBS} ${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
389    AC_LINK_IFELSE(
390         AC_LANG_PROGRAM(
391                 [#include "c-client.h"
392                 void mm_searched (MAILSTREAM *stream,unsigned long number)
393                 {
394                 }
395                 void mm_exists (MAILSTREAM *stream,unsigned long number)
396                 {
397                 }
398                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
399                 {
400                 }
401                 void mm_flags (MAILSTREAM *stream,unsigned long number)
402                 {
403                 }
404                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
405                 {
406                 }
407                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
408                 {
409                 }
410                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
411                 {
412                 }
413                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
414                 {
415                 }
416                 void mm_log (char *string,long errflg)
417                 {
418                 }
419                 void mm_dlog (char *string)
420                 {
421                 }
422                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
423                 {
424                 }
425                 void mm_critical (MAILSTREAM *stream)
426                 {
427                 }
428                 void mm_nocritical (MAILSTREAM *stream)
429                 {
430                 }
431                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
432                 {
433                 }
434                 void mm_fatal (char *string)
435                 {
436                 }],
437                 [
438                 MAILSTREAM *foo = mail_open(NULL, "", 0);
439                 ]
440         ),
441         [ac_cv_imap_tk="yes"],
442         [ac_cv_imap_tk="no"]
443    )
444    if test "${ac_cv_imap_tk}" = "yes"; then
445    AC_LINK_IFELSE(
446       AC_LANG_PROGRAM(
447          [#include "c-client.h"
448          void mm_searched (MAILSTREAM *stream,unsigned long number)
449          {
450          }
451          void mm_exists (MAILSTREAM *stream,unsigned long number)
452          {
453          }
454          void mm_expunged (MAILSTREAM *stream,unsigned long number)
455          {
456          }
457          void mm_flags (MAILSTREAM *stream,unsigned long number)
458          {
459          }
460          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
461          {
462          }
463          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
464          {
465          }
466          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
467          {
468          }
469          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
470          {
471          }
472          void mm_log (char *string,long errflg)
473          {
474          }
475          void mm_dlog (char *string)
476          {
477          }
478          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
479          {
480          }
481          void mm_critical (MAILSTREAM *stream)
482          {
483          }
484          void mm_nocritical (MAILSTREAM *stream)
485          {
486          }
487          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
488          {
489          }
490          void mm_fatal (char *string)
491          {
492          }],
493          [
494          long check = mail_expunge_full(NULL, "", 0);
495          ]
496       ),
497       [ac_cv_imap_tk2006="yes"],
498       [ac_cv_imap_tk2006="no"]
499   )
500   fi
501    CPPFLAGS="${saved_cppflags}"
502    LIBS="${saved_libs}"
503    if test "${ac_cv_imap_tk}" = "yes"; then
504       AC_MSG_RESULT(yes) 
505       IMAP_TK_LIB="${IMAP_TK_DIR}/c-client/c-client.a "`echo ${imap_ldflags}`
506       IMAP_TK_INCLUDE="-I${IMAP_TK_DIR}/c-client"
507       PBX_IMAP_TK=1
508       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
509       if test "${ac_cv_imap_tk2006}" = "yes"; then
510          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
511       fi
512    elif test ! -z "${IMAP_TK_MANDATORY}"; then
513       AC_MSG_RESULT(no) 
514       AC_MSG_NOTICE(***)
515       AC_MSG_NOTICE(*** The UW IMAP Toolkit installation on this system appears to be broken.)
516       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
517       AC_MSG_NOTICE(*** including --without-imap.)
518       exit 1
519    else
520       AC_MSG_RESULT(no) 
521    fi
522 fi
523
524 AC_LANG_PUSH(C++)
525
526 if test "${USE_KDE}" != "no"; then
527    AC_MSG_CHECKING(for crashHandler in -lkdecore)
528    saved_libs="${LIBS}"
529    saved_cppflags="${CPPFLAGS}"
530    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
531    if test -d ${KDE_DIR}/lib; then
532       kdelibdir="${KDE_DIR}/lib"
533    else
534       kdelibdir="${KDE_DIR}"
535    fi
536    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
537
538    AC_LINK_IFELSE(
539         [AC_LANG_PROGRAM(
540                         [#include "kcrash.h"],
541                         [KCrash::defaultCrashHandler(1);])
542         ],
543         [ac_cv_lib_kde_crash="yes"],
544         [ac_cv_lib_kde_crash="no"])
545                 
546    LIBS="${saved_libs}"
547    CPPFLAGS="${saved_cppflags}"
548         
549    if test "${ac_cv_lib_kde_crash}" = "yes"; then
550       AC_MSG_RESULT(yes) 
551       KDE_LIB="-lkdecore -lkdeui"
552       if test "${KDE_DIR}" != ""; then
553          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
554          KDE_INCLUDE="-I${KDE_DIR}/include"
555       fi
556       PBX_KDE=1
557       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
558    elif test ! -z "${KDE_MANDATORY}"; then
559       AC_MSG_RESULT(no) 
560       AC_MSG_NOTICE(***)
561       AC_MSG_NOTICE(*** The KDE installation on this system appears to be broken.)
562       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
563       AC_MSG_NOTICE(*** including --without-kde.)
564       exit 1
565    else
566       AC_MSG_RESULT(no) 
567    fi
568 fi
569 if test "${PBX_KDE}" = 1; then
570    AC_PATH_TOOL(KDEINIT, kdeinit, No)
571    if test ! x"${KDEINIT}" = xNo; then
572       KDEDIR=$(${DIRNAME} ${KDEINIT})
573       KDEDIR=$(${DIRNAME} ${KDEDIR})
574    fi
575    AC_SUBST([KDEDIR])
576 fi
577
578 AC_LANG_POP
579
580 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
581
582 if test "${PBX_MISDN}" = 1; then
583    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
584    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
585 fi
586
587 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
588
589 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
590
591 NETSNMP_CONFIG=No
592 if test "${USE_NETSNMP}" != "no"; then  
593    if test "x${NETSNMP_DIR}" != "x"; then
594       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
595       if test x"${NETSNMP_CONFIG}" = xNo; then
596          AC_MSG_NOTICE(***)
597          AC_MSG_NOTICE(*** net-snmp-config was not found in the path you specified:)
598          AC_MSG_NOTICE(*** ${NETSNMP_DIR}/bin)
599          AC_MSG_NOTICE(*** Either correct the installation, or run configure)
600          AC_MSG_NOTICE(*** including --without-netsnmp)
601          exit 1
602       fi
603    else
604       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
605    fi
606 fi
607 if test x"${NETSNMP_CONFIG}" != xNo; then
608    NETSNMP_libs=`net-snmp-config --agent-libs`
609    
610    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
611    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
612
613    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
614       NETSNMP_LIB="${NETSNMP_libs}"
615       PBX_NETSNMP=1
616    elif test ! -z "${NETSNMP_MANDATORY}";
617    then
618       AC_MSG_NOTICE(***)
619       AC_MSG_NOTICE(*** The Net-SNMP installation on this system appears to be broken.)
620       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
621       AC_MSG_NOTICE(*** including --without-netsnmp)
622       exit 1
623    fi
624 elif test ! -z "${NETSNMP_MANDATORY}";
625 then
626    AC_MSG_NOTICE(***)
627    AC_MSG_NOTICE(*** The Net-SNMP installation on this system appears to be broken.)
628    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
629    AC_MSG_NOTICE(*** including --without-netsnmp)
630    exit 1
631 fi
632
633 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
634
635 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [-lltdl])
636
637 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
638
639 AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
640
641 PBX_OSS=0
642 AC_CHECK_HEADER([linux/soundcard.h],
643                 [
644                 PBX_OSS=1
645                 AC_DEFINE_UNQUOTED([HAVE_OSS], 1, [Define to indicate the Open Sound System library])
646                 ])
647 if test "$PBX_OSS" = "0"; then
648    AC_CHECK_HEADER([sys/soundcard.h],
649                    [
650                    PBX_OSS=1
651                    AC_DEFINE_UNQUOTED([HAVE_OSS], 1, [Define to indicate the Open Sound System library])
652                    ])
653 fi
654 if test "$PBX_OSS" = "0"; then
655    AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
656 fi
657
658 PG_CONFIG=No
659 if test "${USE_PGSQL}" != "no"; then    
660    if test "x${PGSQL_DIR}" != "x"; then
661       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
662       if test x"${PG_CONFIG}" = xNo; then
663          AC_MSG_NOTICE(***)
664          AC_MSG_NOTICE(*** pg_config was not found in the path you specified:)
665          AC_MSG_NOTICE(*** ${PGSQL_DIR}/bin)
666          AC_MSG_NOTICE(*** Either correct the installation, or run configure)
667          AC_MSG_NOTICE(*** including --without-postgres)
668          exit 1
669       fi
670    else
671       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
672    fi
673 fi
674 if test "${PG_CONFIG}" != No; then
675    PGSQL_libdir=`pg_config --libdir`
676    PGSQL_includedir=`pg_config --includedir`
677    
678    AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
679    [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
680
681    if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
682       PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz -lcrypt"
683       PGSQL_INCLUDE="-I${PGSQL_includedir}"
684       PBX_PGSQL=1
685    elif test ! -z "${PGSQL_MANDATORY}";
686    then
687       AC_MSG_NOTICE(***)
688       AC_MSG_NOTICE(*** The PostgreSQL installation on this system appears to be broken.)
689       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
690       AC_MSG_NOTICE(*** including --without-postgres)
691       exit 1
692    fi
693 elif test ! -z "${PGSQL_MANDATORY}";
694 then
695    AC_MSG_NOTICE(***)
696    AC_MSG_NOTICE(*** The PostgreSQL installation on this system appears to be broken.)
697    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
698    AC_MSG_NOTICE(*** including --without-postgres)
699    exit 1
700 fi
701
702 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
703
704 AST_EXT_LIB_CHECK([PRI], [pri], [pri_call], [libpri.h])
705
706 AST_EXT_LIB_CHECK([SS7], [ss7], [ss7_new], [libss7.h])
707
708 if test "${USE_PWLIB}" != "no"; then
709         if test ! -z "${PWLIB_DIR}"; then
710                 PWLIBDIR="${PWLIB_DIR}"
711         fi
712         AST_CHECK_PWLIB()
713         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
714                 
715         if test "${HAS_PWLIB:-unset}" != "unset"; then
716                 AST_CHECK_OPENH323_PLATFORM()
717
718                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
719
720                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
721                         [Define if your system has the PWLib libraries.],
722                         [#include "ptlib.h"],
723                         [BOOL q = PTime::IsDaylightSavings();])
724         fi
725 fi
726
727 if test "${USE_PWLIB}" != "no" -a "x${ac_cv_lib_PWLIB}" != "xyes" -a ! -z "${PWLIB_MANDATORY}"; then
728    AC_MSG_NOTICE(***)
729    AC_MSG_NOTICE(*** The PWLIB installation on this system appears to be broken.)
730    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
731    AC_MSG_NOTICE(*** including --without-pwlib)
732    exit 1
733 fi
734
735 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
736         if test ! -z "${OPENH323_DIR}"; then
737                 OPENH323DIR="${OPENH323_DIR}"
738         fi
739         AST_CHECK_OPENH323()
740         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
741         AST_CHECK_OPENH323_BUILD()
742         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
743         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
744                 [Define if your system has the OpenH323 libraries.],
745                 [#include "ptlib.h"
746                 #include "h323.h"
747                 #include "h323ep.h"],
748                 [H323EndPoint ep = H323EndPoint();],
749                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
750 fi
751 if test "${USE_OPENH323}" != "no" -a "x${ac_cv_lib_OPENH323}" != "xyes" -a ! -z "${OPENH323_MANDATORY}"; then
752    AC_MSG_NOTICE(***)
753    AC_MSG_NOTICE(*** The PWLIB installation on this system appears to be broken.)
754    AC_MSG_NOTICE(*** Either correct the installation, or run configure)
755    AC_MSG_NOTICE(*** including --without-pwlib)
756    exit 1
757 fi
758
759
760 AC_LANG_PUSH(C++)
761
762 if test "${USE_QT}" != "no"; then
763    AC_MSG_CHECKING(for QDate in -lqt)
764    saved_libs="${LIBS}"
765    saved_cppflags="${CPPFLAGS}"
766    if test "x${QT_DIR}" != "x"; then
767       LIBS="${LIBS} -L${QT_DIR}/lib"
768       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
769    fi
770    LIBS="${LIBS} -lqt"
771    qtlib="qt"
772    AC_LINK_IFELSE(
773         [
774                 AC_LANG_PROGRAM(
775                 [#include <qt3/qdatetime.h>],
776                 [QDate date();])
777         ],
778         [ac_cv_lib_qt_qt_date="yes"],
779         [ac_cv_lib_qt_qt_date="no"])
780    LIBS="${saved_libs}"
781    CPPFLAGS="${saved_cppflags}"
782         
783    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
784       saved_libs="${LIBS}"
785       saved_cppflags="${CPPFLAGS}"
786       if test "x${QT_DIR}" != "x"; then
787          LIBS="${LIBS} -L${QT_DIR}/lib"
788          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
789       fi
790       LIBS="${LIBS} -lqt-mt"
791       qtlib="qt-mt"     
792       AC_LINK_IFELSE(
793                 [
794                         AC_LANG_PROGRAM(
795                         [#include <qt3/qdatetime.h>],
796                         [QDate date();])
797                 ],
798                 [ac_cv_lib_qt_qt_date="yes"],
799                 [ac_cv_lib_qt_qt_date="no"])
800       LIBS="${saved_libs}"
801       CPPFLAGS="${saved_cppflags}"
802    fi   
803
804    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
805       AC_MSG_RESULT(yes) 
806    else
807       AC_MSG_RESULT(no) 
808    fi
809         
810    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
811       QT_LIB="-l${qtlib}"
812       if test "${QT_DIR}" != ""; then
813          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
814          QT_INCLUDE="-I${QT_DIR}/include"
815       fi
816       PBX_QT=1
817       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
818       AC_PATH_TOOL(QTMOC, moc, No)
819    elif test ! -z "${QT_MANDATORY}"; 
820    then
821       AC_MSG_NOTICE(***)
822       AC_MSG_NOTICE(*** The Qt installation on this system appears to be broken.)
823       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
824       AC_MSG_NOTICE(*** including --without-qt.)
825       exit 1
826    fi
827 fi
828
829 AC_LANG_POP
830
831 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
832
833 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
834
835 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
836
837 AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
838
839 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
840 if test "${PBX_FREETDS}" != "0";
841 then
842     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr/include}/tdsver.h` in
843         *0.64*)
844                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
845         ;;
846     *0.63*)
847         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
848         ;;
849     *0.62*)
850         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
851         ;;
852     *)
853         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
854         ;;
855     esac
856 fi
857
858 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
859
860 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
861
862 if test "${host_os}" != "linux-gnu" ; then
863   tonezone_extra="-lm"
864 fi
865
866 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}])
867
868 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
869
870 AC_LANG_PUSH(C++)
871
872 if test "${USE_VPB}" != "no"; then
873    AC_MSG_CHECKING(for vpb_open in -lvpb)
874    saved_libs="${LIBS}"
875    saved_cppflags="${CPPFLAGS}"
876    if test "x${VPB_DIR}" != "x"; then
877       if test -d ${VPB_DIR}/lib; then
878          vpblibdir=${VPB_DIR}/lib
879       else
880          vpblibdir=${VPB_DIR}
881       fi
882       LIBS="${LIBS} -L${vpblibdir}"
883       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
884    fi
885    LIBS="${LIBS} -lvpb -lpthread"
886    AC_LINK_IFELSE(
887         [
888         AC_LANG_PROGRAM(
889         [#include <vpbapi.h>],
890         [int q = vpb_open(0,0);])
891         ],
892         [       AC_MSG_RESULT(yes) 
893                 ac_cv_lib_vpb_vpb_open="yes" 
894         ],
895         [       AC_MSG_RESULT(no) 
896                 ac_cv_lib_vpb_vpb_open="no" 
897         ]
898         )
899    LIBS="${saved_libs}"
900    CPPFLAGS="${saved_cppflags}"
901    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
902         VPB_LIB="-lvpb"
903         if test "${VPB_DIR}" != ""; then
904            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
905            VPB_INCLUDE="-I${VPB_DIR}/include"
906         fi
907         PBX_VPB=1
908         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
909    elif test ! -z "${VPB_MANDATORY}"; then
910       AC_MSG_NOTICE(***)
911       AC_MSG_NOTICE(*** The VoiceTronix (vpb) installation on this system appears to be broken.)
912       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
913       AC_MSG_NOTICE(*** including --without-vpb.)
914       exit 1
915    fi
916 fi
917
918 AC_LANG_POP
919
920 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
921
922 if test "${USE_ZAPTEL}" != "no"; then
923    AC_MSG_CHECKING(for ZT_TONE_DTMF_BASE in zaptel.h)
924    saved_cppflags="${CPPFLAGS}"
925    if test "x${ZAPTEL_DIR}" != "x"; then
926       CPPFLAGS="${CPPFLAGS} -I${ZAPTEL_DIR}/include"
927    fi
928    AC_COMPILE_IFELSE(
929         [
930         AC_LANG_PROGRAM(
931         [#include <zaptel/zaptel.h>],
932         [int foo = ZT_TONE_DTMF_BASE;])
933         ],
934         [       AC_MSG_RESULT(yes) 
935                 ac_cv_zaptel_h="yes" 
936         ],
937         [       AC_MSG_RESULT(no) 
938                 ac_cv_zaptel_h="no" 
939         ]
940         )
941    CPPFLAGS="${saved_cppflags}"
942    if test "${ac_cv_zaptel_h}" = "yes"; then
943         if test "${ZAPTEL_DIR}" != ""; then
944            ZAPTEL_INCLUDE="-I${ZAPTEL_DIR}/include"
945         fi
946         PBX_ZAPTEL=1
947         AC_DEFINE([HAVE_ZAPTEL], 1, [Define if your system has the Zaptel headers.])
948    elif test ! -z "${ZAPTEL_MANDATORY}"; 
949    then
950       AC_MSG_NOTICE(***)
951       AC_MSG_NOTICE(*** The Zaptel installation on this system appears to be broken.)
952       AC_MSG_NOTICE(*** Either correct the installation, or run configure)
953       AC_MSG_NOTICE(*** including --without-zaptel.)
954       exit 1
955    fi
956 fi
957
958 EDITLINE_LIB=""
959 if test "x$TERMCAP_LIB" != "x" ; then
960   EDITLINE_LIB="$TERMCAP_LIB"
961 elif test "x$TINFO_LIB" != "x" ; then
962   EDITLINE_LIB="$TINFO_LIB"
963 elif test "x$CURSES_LIB" != "x" ; then
964   EDITLINE_LIB="$CURSES_LIB"
965 elif test "x$NCURSES_LIB" != "x" ; then
966   EDITLINE_LIB="$NCURSES_LIB"
967 else
968   AC_MSG_ERROR(*** termcap support not found)
969 fi
970 AC_SUBST(EDITLINE_LIB)
971
972 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
973 AC_SUBST(PBX_H323)
974
975 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
976                                    #include <linux/version.h>
977                                    #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,0)
978                                    #include <linux/compiler.h>
979                                    #endif
980                                    ])
981 AC_SUBST(PBX_IXJUSER)
982
983 PBX_GTK=0
984 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
985 if test ! "x${GTKCONFIG}" = xNo; then
986    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
987    GTK_LIB=$(${GTKCONFIG} --libs gthread)
988    PBX_GTK=1
989    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
990 fi
991 AC_SUBST(PBX_GTK)
992 AC_SUBST(GTK_INCLUDE)
993 AC_SUBST(GTK_LIB)
994
995 PBX_CURL=0
996 AC_PATH_TOOL([CURL], [curl-config], No)
997 if test ! x"${CURL}" = xNo; then
998 # check for version
999    if test "${host_os}" = "SunOS"; then
1000       if [[ 0x`curl-config --vernum` -ge 0x70907 ]]; then
1001          CURL_INCLUDE=$(${CURL} --cflags)
1002          CURL_LIB=$(${CURL} --libs)
1003          PBX_CURL=1
1004          AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1005       fi
1006    else
1007       if [[[ 0x`curl-config --vernum` -ge 0x70907 ]]]; then
1008          CURL_INCLUDE=$(${CURL} --cflags)
1009          CURL_LIB=$(${CURL} --libs)
1010          PBX_CURL=1
1011          AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1012       fi
1013    fi
1014 fi
1015 AC_SUBST(PBX_CURL)
1016 AC_SUBST(CURL_INCLUDE)
1017 AC_SUBST(CURL_LIB)
1018
1019 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1020 AC_OUTPUT
1021
1022 if test "x${silent}" != "xyes" ; then
1023 echo
1024 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1025 echo "            .\$7\$7..          .7\$\$7:.    "
1026 echo "          .\$\$:.                 ,\$7.7   "
1027 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1028 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1029 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1030 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1031 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1032 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1033 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1034 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1035 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1036 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1037 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1038 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1039 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1040 echo " \$\$\$\$\$                        \$\$\$       "
1041 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1042 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1043 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1044 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1045 echo
1046 fi
1047
1048 AC_MSG_NOTICE(Package configured for: )
1049 AC_MSG_NOTICE( OS type  : $host_os)
1050 AC_MSG_NOTICE( Host CPU : $host_cpu)
1051 if test "${cross_compiling}" = "yes"; then
1052    AC_MSG_NOTICE( Cross Compilation = YES)
1053 fi