Change AST_EXT_TOOL_CHECK to attempt to build against <package>_LIB, per recommendati...
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.60)
10
11 AC_INIT(asterisk, 1.4, www.asterisk.org)
12
13 # cross-compile macros
14 AC_CANONICAL_BUILD
15 AC_CANONICAL_HOST
16
17 # check existence of the package
18 AC_CONFIG_SRCDIR([main/asterisk.c])
19
20 # specify output header file
21 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
22
23 AC_COPYRIGHT("Asterisk")
24 AC_REVISION($Revision$)
25
26 AC_GNU_SOURCE
27 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
28
29 case "${host_os}" in
30      freebsd*)
31      ac_default_prefix=/usr/local
32      CPPFLAGS=-I/usr/local/include
33      LDFLAGS=-L/usr/local/lib
34      ;;
35
36      *)
37      ac_default_prefix=/usr
38      if test ${sysconfdir} = '${prefix}/etc'; then
39         sysconfdir=/etc
40      fi
41      if test ${mandir} = '${prefix}/man'; then
42         mandir=/usr/share/man
43      fi
44      ;;
45 esac
46
47 if test ${localstatedir} = '${prefix}/var'; then
48      localstatedir=/var
49 fi
50
51 BUILD_PLATFORM=${build}
52 BUILD_CPU=${build_cpu}
53 BUILD_VENDOR=${build_vendor}
54 BUILD_OS=${build_os}
55
56 AC_SUBST(BUILD_PLATFORM)
57 AC_SUBST(BUILD_CPU)
58 AC_SUBST(BUILD_VENDOR)
59 AC_SUBST(BUILD_OS)
60
61 HOST_PLATFORM=${host}
62 HOST_CPU=${host_cpu}
63 HOST_VENDOR=${host_vendor}
64 HOST_OS=${host_os}
65
66 AC_SUBST(HOST_PLATFORM)
67 AC_SUBST(HOST_CPU)
68 AC_SUBST(HOST_VENDOR)
69 AC_SUBST(HOST_OS)
70
71 WINARCH=0
72
73 case "${host_os}" in
74      freebsd*)
75      OSARCH=FreeBSD
76      ;;
77      netbsd*)
78      OSARCH=NetBSD
79      ;;
80      openbsd*)
81      OSARCH=OpenBSD
82      ;;
83      solaris*)
84      OSARCH=SunOS
85      ;;
86      mingw32)
87      OSARCH=mingw32
88      WINARCH=1
89      ;;
90      cygwin)
91      OSARCH=cygwin
92      WINARCH=1
93      ;;
94      *)
95      OSARCH=${host_os}
96      ;;
97 esac
98
99 AC_SUBST(OSARCH)
100 AC_SUBST(WINARCH)
101
102 #  check for uname
103 AC_PATH_TOOL([UNAME], [uname], No)
104 if test ! x"${UNAME}" = xNo; then
105    PBX_OSREV=$(${UNAME} -r)
106 fi
107 AC_SUBST(PBX_OSREV)
108
109 AH_TOP(
110 #ifndef ASTERISK_AUTOCONFIG_H
111 #define ASTERISK_AUTOCONFIG_H
112
113 #include "asterisk/buildopts.h"
114
115 )
116
117 AH_BOTTOM(
118 #endif
119 )
120
121 # cross-compile checks
122 if test "${cross_compiling}" = "yes"; 
123 then
124    AC_CHECK_TOOL(CC, gcc, :)
125    AC_CHECK_TOOL(CXX, g++, :)
126    AC_CHECK_TOOL(LD, ld, :)
127    AC_CHECK_TOOL(RANLIB, ranlib, :)
128 fi
129
130 # Checks for programs.
131 AC_PROG_CC
132 AC_PROG_CXX
133 AC_PROG_CPP
134 AC_PROG_CXXCPP
135 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
136 # the developers regenerating the configure script don't have to install libtool.
137 AST_PROG_LD     # note, does not work on FreeBSD
138 AC_PROG_AWK
139 AC_PROG_INSTALL
140 AC_PROG_LN_S
141 AC_PROG_RANLIB
142 AST_CHECK_GNU_MAKE
143
144 AC_PATH_TOOL([STRIP], [strip], :)
145 AC_PATH_TOOL([AR], [ar], :)
146
147 GNU_LD=0
148 if test "x$with_gnu_ld" = "xyes" ; then
149    GNU_LD=1
150 fi
151 AC_SUBST(GNU_LD)
152
153 AC_PATH_PROG([AWK], [awk], :)
154 AC_PATH_PROG([GREP], [grep], :)
155 AC_PATH_PROG([FIND], [find], :)
156 AC_PATH_PROG([COMPRESS], [compress], :)
157 AC_PATH_PROG([BASENAME], [basename], :)
158 AC_PATH_PROG([ID], [id], :)
159 AC_PATH_PROG([DIRNAME], [dirname], :)
160 AC_PATH_PROG([SHELL], [sh], :)
161 AC_PATH_PROG([LN], [ln], :)
162 AC_PATH_PROG([DOT], [dot], :)
163 AC_PATH_PROG([WGET], [wget], :)
164 AC_PATH_PROG([RUBBER], [rubber], :)
165 AC_PATH_PROG([KPATHSEA], [kpsewhich], :)
166 if test "${WGET}" != ":" ; then
167   DOWNLOAD=${WGET}
168 else
169   AC_PATH_PROG([FETCH], [fetch], [:])
170   DOWNLOAD=${FETCH}
171 fi
172 AC_SUBST(DOWNLOAD)
173
174 AC_CHECK_TOOL([SOXMIX], [soxmix], [:])
175 if test "${SOXMIX}" != ":" ; then
176         AC_DEFINE([HAVE_SOXMIX], 1, [Define to 1 if your system has soxmix application.])
177 fi
178
179 ACX_PTHREAD
180
181 AC_LANG(C)
182
183 AC_ARG_ENABLE(dev-mode,
184         [  --enable-dev-mode    Turn on developer mode],
185         [case "${enableval}" in
186               y|ye|yes) AST_DEVMODE=yes ;;
187               n|no)  AST_DEVMODE=no ;;
188               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
189         esac])
190 AC_SUBST(AST_DEVMODE)
191
192 # AST_EXT_LIB_SETUP is used to tell configure to handle variables for
193 # various packages.
194 # $1 is the prefix for the variables in makeopts and autoconfig.h
195 # $2 is the short comment, $4 is the long comment
196 # $3 is the name used in --with- or --without- flags for configure.
197 #
198 # Package option names should be in alphabetical order
199 # by the --with option name (the third field),
200 # to make things easier for the users.
201
202 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
203
204 # BKTR is used for backtrace support on platforms that do not
205 # have it natively.
206 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
207 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
208 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
209 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
210 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
211 AST_EXT_LIB_SETUP([GSM], [External GSM library], [gsm], [, use 'internal' GSM otherwise])
212 AST_EXT_LIB_SETUP([GTK], [gtk libraries], [gtk])
213 AST_EXT_LIB_SETUP([GTK2], [gtk2 libraries], [gtk2])
214 AST_EXT_LIB_SETUP([ICONV], [Iconv Library], [iconv])
215 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
216 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
217 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
218 AST_EXT_LIB_SETUP([JACK], [Jack Audio Connection Kit], [jack])
219 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
220 AST_EXT_LIB_SETUP([LUA], [Lua], [lua])
221 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
222 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
223 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
224 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
225 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
226 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
227 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
228 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
229 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
230 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
231 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
232 AST_EXT_LIB_SETUP([PORTAUDIO], [PortAudio], [portaudio])
233 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
234 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
235 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
236 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
237 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
238 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
239 AST_EXT_LIB_SETUP([SPEEXDSP], [Speexdsp], [speexdsp])
240 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
241 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
242 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
243 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
244 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
245 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
246 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
247 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
248 AST_EXT_LIB_SETUP([USB], [usb], [usb])
249 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
250 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
251 AST_EXT_LIB_SETUP([X11], [X11 support], [x11])
252 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
253 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
254 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel Transcoder Support], [zaptel_transcode])
255 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel VLDTMF Support], [zaptel_vldtmf])
256 AST_EXT_LIB_SETUP([ZAPTEL_HWGAIN], [Zaptel Hardware Gain Support], [zaptel_hwgain])
257 AST_EXT_LIB_SETUP([ZAPTEL_ECHOCANPARAMS], [Zaptel Echo Canceler Parameter Support], [zaptel_echocanparams])
258 AST_EXT_LIB_SETUP([ZAPTEL_CHANALARMS], [Zaptel Channel Alarm Support], [zaptel_chanalarms])
259
260 AST_EXT_LIB_SETUP([SDL], [Sdl], [sdl])
261 AST_EXT_LIB_SETUP([SDL_IMAGE], [Sdl Image library], [SDL_image])
262 AST_EXT_LIB_SETUP([FFMPEG], [Ffmpeg and avcodec library], [avcodec])
263
264 # check for basic system features and functionality before
265 # checking for package libraries
266
267 AC_FUNC_ALLOCA
268 AC_HEADER_DIRENT
269 AC_HEADER_STDC
270 AC_HEADER_SYS_WAIT
271 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
272
273 AC_CHECK_HEADERS([winsock.h winsock2.h])
274
275 AC_SYS_LARGEFILE
276
277 # Checks for typedefs, structures, and compiler characteristics.
278 AC_HEADER_STDBOOL
279 AC_C_CONST
280 AC_TYPE_UID_T
281 AC_C_INLINE
282 AC_TYPE_MODE_T
283 AC_TYPE_OFF_T
284 AC_TYPE_PID_T
285 AC_TYPE_SIZE_T
286 AC_CHECK_MEMBERS([struct stat.st_blksize])
287 AC_HEADER_TIME
288 AC_STRUCT_TM
289 AC_C_VOLATILE
290 AC_CHECK_TYPES([ptrdiff_t])
291
292 # Checks for library functions.
293 AC_FUNC_CHOWN
294 AC_FUNC_CLOSEDIR_VOID
295 AC_FUNC_ERROR_AT_LINE
296 AST_FUNC_FORK
297 AC_FUNC_FSEEKO
298 AC_PROG_GCC_TRADITIONAL
299 # XXX: these are commented out until we determine whether it matters if our malloc()
300 # acts exactly like glibc's or not
301 # AC_FUNC_MALLOC
302 # AC_FUNC_REALLOC
303 AC_FUNC_MEMCMP
304 AC_FUNC_MKTIME
305 AC_FUNC_MMAP
306 AC_FUNC_SELECT_ARGTYPES
307 AC_FUNC_SETVBUF_REVERSED
308 AC_TYPE_SIGNAL
309 AC_FUNC_STAT
310 AC_FUNC_STRCOLL
311 AC_FUNC_STRFTIME
312 AC_FUNC_STRNLEN
313 AC_FUNC_STRTOD
314 AC_FUNC_UTIME_NULL
315 AC_FUNC_VPRINTF
316 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap putenv re_comp regcomp select setenv socket strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
317
318 AC_CHECK_FUNCS([glob])
319
320 AC_MSG_CHECKING(for timersub in time.h)
321 AC_LINK_IFELSE(
322         AC_LANG_PROGRAM([#include <sys/time.h>],
323                 [struct timeval *a; timersub(a, a, a);]),
324         AC_MSG_RESULT(yes)
325                 AC_DEFINE([HAVE_TIMERSUB], 1, [Define to 1 if your system defines timersub.]),
326         AC_MSG_RESULT(no)
327 )
328
329 AC_CHECK_HEADER([sys/poll.h], 
330    [HAS_POLL=1]
331    AC_DEFINE([HAVE_SYS_POLL_H], 1, [Define to 1 if your system has working sys/poll.h]),
332    )
333 AC_SUBST(HAS_POLL)
334
335 # https support (in main/http.c) uses funopen on BSD systems,
336 # fopencookie on linux
337 AC_CHECK_FUNCS([funopen fopencookie])
338
339 AC_CHECK_FUNCS([inet_aton])
340
341 # check if we have IP_PKTINFO constant defined
342 AC_MSG_CHECKING(for IP_PKTINFO)
343 AC_LINK_IFELSE(
344                 AC_LANG_PROGRAM([#include <netinet/in.h>],
345                                                 [int pi = IP_PKTINFO;]),
346                 AC_MSG_RESULT(yes)
347                 AC_DEFINE([HAVE_PKTINFO], 1, [Define to 1 if your system defines IP_PKTINFO.]),
348                 AC_MSG_RESULT(no)
349 )
350
351 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
352 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
353
354 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
355 AC_LINK_IFELSE(
356         AC_LANG_PROGRAM([#include <stdlib.h>
357                          #include <netdb.h>],
358                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
359         AC_MSG_RESULT(yes)
360         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
361         AC_MSG_RESULT(no)
362 )
363
364 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
365 AC_LINK_IFELSE(
366         AC_LANG_PROGRAM([#include <stdlib.h>
367                          #include <netdb.h>],
368                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
369         AC_MSG_RESULT(yes)
370         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
371         AC_MSG_RESULT(no)
372 )
373
374 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
375
376 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
377 AC_LINK_IFELSE(
378 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
379 AC_MSG_RESULT(yes)
380 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
381 AC_MSG_RESULT(no)
382 )
383
384 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
385 AC_LINK_IFELSE(
386 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
387 AC_MSG_RESULT(yes)
388 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
389 AC_MSG_RESULT(no)
390 )
391
392 if test "${cross_compiling}" = "no";
393 then
394   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
395 fi
396
397 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
398
399 AC_MSG_CHECKING(for PTHREAD_RWLOCK_PREFER_WRITER_NP in pthread.h)
400 AC_LINK_IFELSE(
401 AC_LANG_PROGRAM([#include <pthread.h>], [int a = PTHREAD_RWLOCK_PREFER_WRITER_NP;]),
402 AC_MSG_RESULT(yes)
403 AC_DEFINE([HAVE_PTHREAD_RWLOCK_PREFER_WRITER_NP], 1, [Define to 1 if your system defines PTHREAD_RWLOCK_PREFER_WRITER_NP in pthread.h]),
404 AC_MSG_RESULT(no)
405 )
406
407 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE_NP in pthread.h)
408 AC_LINK_IFELSE(
409 AC_LANG_PROGRAM([#include <pthread.h>], [int a = PTHREAD_MUTEX_RECURSIVE_NP;]),
410 AC_MSG_RESULT(yes)
411 AC_DEFINE([HAVE_PTHREAD_MUTEX_RECURSIVE_NP], 1, [Define to 1 if your system defines PTHREAD_MUTEX_RECURSIVE_NP in pthread.h]),
412 AC_MSG_RESULT(no)
413 )
414
415 AST_C_DEFINE_CHECK([PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [pthread.h])
416
417 if test "${cross_compiling}" = "no";
418 then
419 AC_MSG_CHECKING(for working epoll support)
420 AC_LINK_IFELSE(
421 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
422                                           if (res < 0)
423                                              return 1;
424                                           close (res);
425                                           return 0;]),
426 AC_MSG_RESULT(yes)
427 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
428 AC_MSG_RESULT(no)
429 )
430 fi
431
432 AC_MSG_CHECKING(for compiler atomic operations)
433 AC_LINK_IFELSE(
434 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
435 AC_MSG_RESULT(yes)
436 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
437 AC_MSG_RESULT(no)
438 )
439
440 AST_GCC_ATTRIBUTE(pure)
441 AST_GCC_ATTRIBUTE(malloc)
442 AST_GCC_ATTRIBUTE(const)
443 AST_GCC_ATTRIBUTE(unused)
444 AST_GCC_ATTRIBUTE(always_inline)
445 AST_GCC_ATTRIBUTE(deprecated)
446
447 AC_MSG_CHECKING(for -ffunction-sections support)
448 saved_CFLAGS="${CFLAGS}"
449 CFLAGS="${CFLAGS} -ffunction-sections"
450 AC_COMPILE_IFELSE(
451         AC_LANG_PROGRAM([], [int x = 1;]),
452         AC_MSG_RESULT(yes)
453         [saved_LDFLAGS="${LDFLAGS}"]
454         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
455         AC_MSG_CHECKING(for --gc-sections support)
456         AC_LINK_IFELSE(
457                 AC_LANG_PROGRAM([], [int x = 1;]),
458                 AC_MSG_RESULT(yes)
459                 [GC_CFLAGS="-ffunction-sections"]
460                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
461                 AC_MSG_RESULT(no)
462         )
463         [LDFLAGS="${saved_LDFLAGS}"],
464         AC_MSG_RESULT(no)
465 )
466 CFLAGS="${saved_CFLAGS}"
467 AC_SUBST(GC_CFLAGS)
468 AC_SUBST(GC_LDFLAGS)
469
470 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
471 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
472         AC_MSG_RESULT(yes)
473         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
474 else
475         AC_MSG_RESULT(no)
476         AST_DECLARATION_AFTER_STATEMENT=
477 fi
478 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
479
480
481 AC_MSG_CHECKING(for sysinfo)
482 AC_LINK_IFELSE(
483         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
484                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
485         AC_MSG_RESULT(yes)
486         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
487         AC_MSG_RESULT(no)
488 )
489
490 AC_MSG_CHECKING(for res_ninit)
491 AC_LINK_IFELSE(
492         AC_LANG_PROGRAM([#include <resolv.h>],
493                         [int foo = res_ninit(NULL);]),
494         AC_MSG_RESULT(yes)
495         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
496         AC_MSG_CHECKING(for res_ndestroy)
497         AC_LINK_IFELSE(
498                 AC_LANG_PROGRAM([#include <resolv.h>],
499                                 [int foo = res_ndestroy(NULL);]),
500                 AC_MSG_RESULT(yes)
501                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
502                 AC_MSG_RESULT(no)
503         ),
504         AC_MSG_RESULT(no)
505 )
506
507 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
508
509 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
510
511 AC_CHECK_HEADER([libkern/OSAtomic.h],
512                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
513
514 AC_CHECK_SIZEOF(int)
515
516 # do the package library checks now
517
518 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
519
520 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
521
522 if test "x${host_os}" = "xlinux-gnu" ; then
523   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
524 fi
525
526 # BSD might not have exp2, and/or log2
527 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
528 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
529 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
530 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
531 AST_EXT_LIB_CHECK([SINL], [m], [sinl])
532 AST_EXT_LIB_CHECK([COSL], [m], [cosl])
533 AST_EXT_LIB_CHECK([TANL], [m], [tanl])
534 AST_EXT_LIB_CHECK([ASINL], [m], [asinl])
535 AST_EXT_LIB_CHECK([ACOSL], [m], [acosl])
536 AST_EXT_LIB_CHECK([ATANL], [m], [atanl])
537 AST_EXT_LIB_CHECK([ATAN2L], [m], [atan2l])
538 AST_EXT_LIB_CHECK([POWL], [m], [powl])
539 AST_EXT_LIB_CHECK([SQRTL], [m], [sqrtl])
540 AST_EXT_LIB_CHECK([RINTL], [m], [rintl])
541 AST_EXT_LIB_CHECK([EXPL], [m], [expl])
542 AST_EXT_LIB_CHECK([LOGL], [m], [logl])
543 AST_EXT_LIB_CHECK([REMAINDERL], [m], [remainderl])
544 AST_EXT_LIB_CHECK([FMODL], [m], [fmodl])
545 AST_EXT_LIB_CHECK([ROUNDL], [m], [roundl])
546 AST_EXT_LIB_CHECK([TRUNCL], [m], [truncl])
547 AST_EXT_LIB_CHECK([STRTOLD], [c], [strtold], [stdlib.h])
548 AST_EXT_LIB_CHECK([FLOORL], [m], [floorl])
549 AST_EXT_LIB_CHECK([CEILL], [m], [ceill])
550 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
551 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
552 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
553 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
554 AST_EXT_LIB_CHECK([SIN], [m], [sin])
555 AST_EXT_LIB_CHECK([COS], [m], [cos])
556 AST_EXT_LIB_CHECK([TAN], [m], [tan])
557 AST_EXT_LIB_CHECK([ASIN], [m], [asin])
558 AST_EXT_LIB_CHECK([ACOS], [m], [acos])
559 AST_EXT_LIB_CHECK([ATAN], [m], [atan])
560 AST_EXT_LIB_CHECK([ATAN2], [m], [atan2])
561 AST_EXT_LIB_CHECK([POW], [m], [pow])
562 AST_EXT_LIB_CHECK([SQRT], [m], [sqrt])
563 AST_EXT_LIB_CHECK([RINT], [m], [rint])
564 AST_EXT_LIB_CHECK([EXP], [m], [exp])
565 AST_EXT_LIB_CHECK([LOG], [m], [log])
566 AST_EXT_LIB_CHECK([REMAINDER], [m], [remainder])
567 AST_EXT_LIB_CHECK([FMOD], [m], [fmod])
568 AST_EXT_LIB_CHECK([ROUND], [m], [round])
569 AST_EXT_LIB_CHECK([TRUNC], [m], [trunc])
570 AST_EXT_LIB_CHECK([STRTOD], [c], [strtod], [stdlib.h])
571 AST_EXT_LIB_CHECK([FLOOR], [m], [floor])
572 AST_EXT_LIB_CHECK([CEIL], [m], [ceil])
573
574 GSM_INTERNAL="yes"
575 AC_SUBST(GSM_INTERNAL)
576 GSM_SYSTEM="yes"
577 if test "${USE_GSM}" != "no"; then
578    if test "${GSM_DIR}" = "internal"; then
579       GSM_SYSTEM="no"
580    elif test "${GSM_DIR}" != ""; then
581       GSM_INTERNAL="no"
582    fi
583    if test "${GSM_SYSTEM}" = "yes"; then
584       gsmlibdir=""
585       if test "x${GSM_DIR}" != "x"; then
586          if test -d ${GSM_DIR}/lib; then
587             gsmlibdir="-L${GSM_DIR}/lib"
588          else
589             gsmlibdir="-L${GSM_DIR}"
590          fi
591       fi
592       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
593       [Define to indicate the GSM library]), [], ${gsmlibdir})
594       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
595          if test "x${GSM_DIR}" != "x" ; then
596             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
597             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
598          else
599             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
600             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
601          fi
602          if test "${GSM_HEADER_FOUND}" = "0" ; then
603             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
604                if test "x${GSM_MANDATORY}" = "xyes" ; then
605                   AC_MSG_NOTICE([***])
606                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
607                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
608                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
609                   exit 1
610                fi
611             fi
612          fi
613          GSM_OK=0
614          if test "${GSM_HEADER_FOUND}" = "1" ; then
615             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
616             GSM_OK=1
617          else
618             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
619                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
620                GSM_OK=1
621             fi
622          fi
623          if test "${GSM_OK}" = "1" ; then
624             GSM_LIB="-lgsm"
625             if test "x${GSM_DIR}" != "x"; then
626                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
627                GSM_INCLUDE="-I${GSM_DIR}/include"
628             fi
629             PBX_GSM=1
630             GSM_INTERNAL="no"
631          fi
632       fi
633    fi
634    if test "${GSM_INTERNAL}" = "yes"; then
635       PBX_GSM=1
636       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
637    fi
638 fi
639
640 if test "${host_os}" != "linux-gnu" ; then
641   AST_EXT_LIB_CHECK([ICONV], [iconv], [iconv_open], [iconv.h])
642 else
643   PBX_ICONV=1
644 fi
645
646 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
647
648 if test "${USE_IMAP_TK}" != "no"; then
649    if test "${IMAP_TK_DIR}" = "system" ; then
650       AC_MSG_NOTICE([Checking for system c-client library...])
651    elif test "${IMAP_TK_DIR}" = ""; then
652       IMAP_TK_DIR=`pwd`"/../imap-2004g"
653       if test  -n "${IMAP_TK_MANDATORY}"; then
654          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
655          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
656          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
657          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
658       fi
659    fi
660    if test "${IMAP_TK_DIR}" != "system" ; then
661       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
662    fi
663    saved_cppflags="${CPPFLAGS}"
664    saved_libs="${LIBS}"
665    if test "${IMAP_TK_DIR}" = "system" ; then
666       imap_ldflags=""
667       imap_libs="-lc-client"
668       imap_include="-DUSE_SYSTEM_IMAP"
669    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
670       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
671       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
672       imap_include="-I${IMAP_TK_DIR}/c-client"
673    fi
674    CPPFLAGS="${CPPFLAGS} ${imap_include}"
675    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
676    AC_LINK_IFELSE(
677         AC_LANG_PROGRAM(
678                 [#ifdef USE_SYSTEM_IMAP
679                 #include <imap/c-client.h>
680                 #else
681                 #include "c-client.h"
682                 #endif
683                 void mm_searched (MAILSTREAM *stream,unsigned long number)
684                 {
685                 }
686                 void mm_exists (MAILSTREAM *stream,unsigned long number)
687                 {
688                 }
689                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
690                 {
691                 }
692                 void mm_flags (MAILSTREAM *stream,unsigned long number)
693                 {
694                 }
695                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
696                 {
697                 }
698                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
699                 {
700                 }
701                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
702                 {
703                 }
704                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
705                 {
706                 }
707                 void mm_log (char *string,long errflg)
708                 {
709                 }
710                 void mm_dlog (char *string)
711                 {
712                 }
713                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
714                 {
715                 }
716                 void mm_critical (MAILSTREAM *stream)
717                 {
718                 }
719                 void mm_nocritical (MAILSTREAM *stream)
720                 {
721                 }
722                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
723                 {
724                 }
725                 void mm_fatal (char *string)
726                 {
727                 }],
728                 [
729                 MAILSTREAM *foo = mail_open(NULL, "", 0);
730                 ]
731         ),
732         [ac_cv_imap_tk="yes"],
733         [ac_cv_imap_tk="no"]
734    )
735    if test "${ac_cv_imap_tk}" = "yes"; then
736    AC_LINK_IFELSE(
737       AC_LANG_PROGRAM(
738          [#ifdef USE_SYSTEM_IMAP
739          #include <imap/c-client.h>
740          #else
741          #include "c-client.h"
742          #endif
743          void mm_searched (MAILSTREAM *stream,unsigned long number)
744          {
745          }
746          void mm_exists (MAILSTREAM *stream,unsigned long number)
747          {
748          }
749          void mm_expunged (MAILSTREAM *stream,unsigned long number)
750          {
751          }
752          void mm_flags (MAILSTREAM *stream,unsigned long number)
753          {
754          }
755          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
756          {
757          }
758          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
759          {
760          }
761          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
762          {
763          }
764          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
765          {
766          }
767          void mm_log (char *string,long errflg)
768          {
769          }
770          void mm_dlog (char *string)
771          {
772          }
773          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
774          {
775          }
776          void mm_critical (MAILSTREAM *stream)
777          {
778          }
779          void mm_nocritical (MAILSTREAM *stream)
780          {
781          }
782          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
783          {
784          }
785          void mm_fatal (char *string)
786          {
787          }],
788          [
789          long check = mail_expunge_full(NULL, "", 0);
790          ]
791       ),
792       [ac_cv_imap_tk2006="yes"],
793       [ac_cv_imap_tk2006="no"]
794   )
795   fi
796    CPPFLAGS="${saved_cppflags}"
797    LIBS="${saved_libs}"
798    if test "${ac_cv_imap_tk}" = "yes"; then
799       AC_MSG_RESULT(yes) 
800       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
801       IMAP_TK_INCLUDE="${imap_include}"
802       PBX_IMAP_TK=1
803       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
804       if test "${ac_cv_imap_tk2006}" = "yes"; then
805          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
806       fi
807    else
808       AC_MSG_RESULT(no) 
809    fi
810 fi
811
812 AST_EXT_LIB_CHECK([JACK], [jack], [jack_activate], [jack/jack.h])
813
814 # Needed by unixodbc
815 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
816
817 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
818
819 if test "${PBX_MISDN}" = 1; then
820    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
821    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
822    AST_C_DEFINE_CHECK([MISDN_FAC_RESULT], [Fac_RESULT], [mISDNuser/suppserv.h])
823    AST_C_DEFINE_CHECK([MISDN_FAC_ERROR], [Fac_ERROR], [mISDNuser/suppserv.h])
824    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
825 fi
826
827 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
828
829 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
830
831 AST_EXT_TOOL_CHECK([NETSNMP], [net-snmp], , [--agent-libs],
832 [#include <net-snmp/net-snmp-config.h>
833 #include <net-snmp/net-snmp-includes.h>
834 #include <net-snmp/agent/net-snmp-agent-includes.h>],
835 [int callback = snmp_register_callback(0, 0, NULL, NULL)])
836
837 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
838
839 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
840
841 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
842
843 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h])
844
845 # possible places for oss definitions
846 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
847 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
848 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
849
850 PG_CONFIG=No
851 if test "${USE_PGSQL}" != "no"; then    
852    if test "x${PGSQL_DIR}" != "x"; then
853       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
854       if test x"${PG_CONFIG}" = xNo; then
855          AC_MSG_NOTICE([***])
856          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
857          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
858          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
859          AC_MSG_NOTICE([*** including --without-postgres])
860          exit 1
861       fi
862    else
863       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
864    fi
865 fi
866 if test "${PG_CONFIG}" != No; then
867    PGSQL_libdir=`${PG_CONFIG} --libdir`
868    PGSQL_includedir=`${PG_CONFIG} --includedir`
869    if test "x$?" != "x0" ; then
870       if test -n "${PGSQL_MANDATORY}" ; then
871          AC_MSG_NOTICE([***])
872          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
873          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
874          AC_MSG_NOTICE([*** including --without-postgres])
875          exit 1
876           fi
877    else 
878       AC_CHECK_LIB([pq], [PQescapeStringConn], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
879       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
880
881       if test "${ac_cv_lib_pq_PQescapeStringConn}" = "yes"; then
882          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
883          PGSQL_INCLUDE="-I${PGSQL_includedir}"
884          PBX_PGSQL=1
885       elif test -n "${PGSQL_MANDATORY}";
886       then
887          AC_MSG_NOTICE([***])
888          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
889          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
890          AC_MSG_NOTICE([*** including --without-postgres])
891          exit 1
892       fi
893    fi
894 fi
895
896 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
897
898 AST_EXT_LIB_CHECK([PORTAUDIO], [portaudio], [Pa_GetDeviceCount], [portaudio.h])
899
900 AST_EXT_LIB_CHECK([PRI], [pri], [pri_new_bri], [libpri.h])
901
902 AST_EXT_LIB_CHECK([SS7], [ss7], [isup_cqr], [libss7.h])
903
904 if test "${USE_PWLIB}" != "no"; then
905         if test -n "${PWLIB_DIR}"; then
906                 PWLIBDIR="${PWLIB_DIR}"
907         fi
908         AST_CHECK_PWLIB()
909         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
910                 
911         if test "${HAS_PWLIB:-unset}" != "unset"; then
912                 AST_CHECK_OPENH323_PLATFORM()
913
914                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
915
916                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
917                         [Define if your system has the PWLib libraries.],
918                         [#include "ptlib.h"],
919                         [BOOL q = PTime::IsDaylightSavings();])
920         fi
921 fi
922
923 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
924         if test -n "${OPENH323_DIR}"; then
925                 OPENH323DIR="${OPENH323_DIR}"
926         fi
927         AST_CHECK_OPENH323()
928         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
929         AST_CHECK_OPENH323_BUILD()
930         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
931         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
932                 [Define if your system has the OpenH323 libraries.],
933                 [#include "ptlib.h"
934                 #include "h323.h"
935                 #include "h323ep.h"],
936                 [H323EndPoint ep = H323EndPoint();],
937                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
938 fi
939
940 LUA_INCLUDE="-I/usr/include/lua5.1"
941 LUA_LIB="-llua5.1"
942 AST_EXT_LIB_CHECK([LUA], [lua5.1], [luaL_newstate], [lua5.1/lua.h]) 
943
944 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
945
946 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
947
948 AST_EXT_LIB_CHECK([SPEEXDSP], [speexdsp], [speex_preprocess_ctl], [speex/speex.h], [-lm])
949
950 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
951
952 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
953
954 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
955
956 if test "$PBX_CRYPTO" = "1";
957 then
958     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
959 fi
960
961 if test "$PBX_OPENSSL" = "1";
962 then
963     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
964 fi
965
966 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
967 if test "${PBX_FREETDS}" != "0";
968 then
969     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
970         *0.64*)
971                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
972         ;;
973     *0.63*)
974         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
975         ;;
976     *0.62*)
977         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
978         ;;
979     *)
980         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
981         ;;
982     esac
983 fi
984
985 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
986
987 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
988
989 if test "${host_os}" != "linux-gnu" ; then
990   tonezone_extra="-lm"
991 fi
992
993 # new tonezone, version 1.4.0
994 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [], [140])
995 # other case, old tonezone (0.80)
996 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [], [80])
997
998 AST_EXT_LIB_CHECK([USB], [usb], [usb_init], [usb.h], [])
999
1000 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1001
1002 AC_LANG_PUSH(C++)
1003
1004 if test "${USE_VPB}" != "no"; then
1005    AC_MSG_CHECKING(for vpb_open in -lvpb)
1006    saved_libs="${LIBS}"
1007    saved_cppflags="${CPPFLAGS}"
1008    if test "x${VPB_DIR}" != "x"; then
1009       if test -d ${VPB_DIR}/lib; then
1010          vpblibdir=${VPB_DIR}/lib
1011       else
1012          vpblibdir=${VPB_DIR}
1013       fi
1014       LIBS="${LIBS} -L${vpblibdir}"
1015       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1016    fi
1017    LIBS="${LIBS} -lvpb -lpthread"
1018    AC_LINK_IFELSE(
1019         [
1020         AC_LANG_PROGRAM(
1021         [#include <vpbapi.h>],
1022         [int q = vpb_open(0,0);])
1023         ],
1024         [       AC_MSG_RESULT(yes) 
1025                 ac_cv_lib_vpb_vpb_open="yes" 
1026         ],
1027         [       AC_MSG_RESULT(no) 
1028                 ac_cv_lib_vpb_vpb_open="no" 
1029         ]
1030         )
1031    LIBS="${saved_libs}"
1032    CPPFLAGS="${saved_cppflags}"
1033    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1034         VPB_LIB="-lvpb"
1035         if test "${VPB_DIR}" != ""; then
1036            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1037            VPB_INCLUDE="-I${VPB_DIR}/include"
1038         fi
1039         PBX_VPB=1
1040         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1041    fi
1042 fi
1043
1044 AC_LANG_POP
1045
1046 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1047
1048 # Check for various zaptel features and locations.
1049 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1050 # will be used in the system headers to determine the location
1051 # of the zaptel.h header.
1052
1053 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1054 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1055
1056 # Check for VLDTMF support
1057 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1058
1059 # Check for echo canceler parameters support
1060 AST_C_DEFINE_CHECK([ZAPTEL_ECHOCANPARAMS], [ZT_ECHOCANCEL_PARAMS], [zaptel/zaptel.h])
1061
1062 # Check for transcoder support
1063 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1064
1065 # Check for hwgain support
1066 AST_C_DEFINE_CHECK([ZAPTEL_HWGAIN], [ZT_SET_HWGAIN], [zaptel/zaptel.h])
1067
1068 # Check for channel alarm support
1069 AST_C_COMPILE_CHECK([ZAPTEL_CHANALARMS], [size_t foo = sizeof(struct zt_params_v1)], [zaptel/zaptel.h])
1070
1071 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1072 case "${host_os}" in
1073     freebsd*)
1074         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],,, [80])
1075         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],,, [90])
1076         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],,, [80])
1077
1078         # other case, old tonezone (0.80)
1079         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}],, [80])
1080         ;;
1081 esac
1082
1083 EDITLINE_LIB=""
1084 if test "x$TERMCAP_LIB" != "x" ; then
1085   EDITLINE_LIB="$TERMCAP_LIB"
1086 elif test "x$TINFO_LIB" != "x" ; then
1087   EDITLINE_LIB="$TINFO_LIB"
1088 elif test "x$CURSES_LIB" != "x" ; then
1089   EDITLINE_LIB="$CURSES_LIB"
1090 elif test "x$NCURSES_LIB" != "x" ; then
1091   EDITLINE_LIB="$NCURSES_LIB"
1092 else
1093   AC_MSG_ERROR(*** termcap support not found)
1094 fi
1095 AC_SUBST(EDITLINE_LIB)
1096
1097 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1098 AC_SUBST(PBX_H323)
1099
1100 AC_CHECK_HEADER([linux/compiler.h],
1101                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1102
1103 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1104                                    #include <linux/version.h>
1105                                    #ifdef HAVE_LINUX_COMPILER_H
1106                                    #include <linux/compiler.h>
1107                                    #endif
1108                                    ])
1109 AC_SUBST(PBX_IXJUSER)
1110
1111 AST_EXT_TOOL_CHECK([SDL], [sdl])
1112 AST_EXT_LIB_CHECK([SDL_IMAGE], [SDL_image], [IMG_Load], [SDL_image.h], [${SDL_LIB}], [${SDL_INCLUDE}])
1113 AST_EXT_LIB_CHECK([FFMPEG], [avcodec], [sws_getContext], [ffmpeg/avcodec.h], [-lpthread -lz -lm])
1114
1115 # possible places for video4linux version 1
1116 AC_CHECK_HEADER([linux/videodev.h],
1117         [AC_DEFINE_UNQUOTED([HAVE_VIDEODEV_H], 1, [Define to 1 if your system has linux/videodev.h.])])
1118
1119 # possible places for X11
1120 AST_EXT_LIB_CHECK([X11], [X11], [XOpenDisplay], [X11/Xlib.h],,, [standard_path])
1121 AST_EXT_LIB_CHECK([X11], [X11], [XOpenDisplay], [X11/Xlib.h],, [-I/usr/X11R6/include], [X11R6])
1122
1123 PBX_GTK=0
1124 AST_EXT_TOOL_CHECK([GTK], [gtk], [--cflags gthread], [--libs gthread])
1125
1126 PBX_GTK2=0
1127 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1128 if test ! "x${PKGCONFIG}" = xNo; then
1129    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1130    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1131    PBX_GTK2=1
1132    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1133 fi
1134 AC_SUBST(PBX_GTK2)
1135 AC_SUBST(GTK2_INCLUDE)
1136 AC_SUBST(GTK2_LIB)
1137
1138 if test "${USE_CURL}" != "no"; then
1139    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1140    if test ! x"${CURL_CONFIG}" = xNo; then
1141    # check for version
1142       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1143          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1144          CURL_LIB=$(${CURL_CONFIG} --libs)
1145
1146          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1147          saved_cppflags="${CPPFLAGS}"
1148          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1149          AC_COMPILE_IFELSE(
1150             [AC_LANG_PROGRAM(
1151                 [#include <curl/curl.h>],
1152                     [curl_version();])
1153             ],[
1154                 AC_MSG_RESULT(yes)
1155                 ac_cv_curl_h="yes"
1156             ],[
1157                 AC_MSG_RESULT(no)
1158                 ac_cv_curl_h="no"
1159             ]
1160          )
1161          CPPFLAGS="${saved_cppflags}"
1162          if test "${ac_cv_curl_h}" = "yes"; then
1163              PBX_CURL=1
1164              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1165          fi
1166       fi
1167    fi
1168 fi
1169
1170 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1171 AST_CHECK_MANDATORY
1172
1173 AC_OUTPUT
1174
1175 if test "x${silent}" != "xyes" ; then
1176 echo
1177 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1178 echo "            .\$7\$7..          .7\$\$7:.    "
1179 echo "          .\$\$:.                 ,\$7.7   "
1180 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1181 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1182 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1183 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1184 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1185 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1186 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1187 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1188 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1189 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1190 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1191 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1192 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1193 echo " \$\$\$\$\$                        \$\$\$       "
1194 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1195 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1196 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1197 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1198 echo
1199 fi
1200
1201 AC_MSG_NOTICE(Package configured for: )
1202 AC_MSG_NOTICE( OS type  : $host_os)
1203 AC_MSG_NOTICE( Host CPU : $host_cpu)
1204 AC_MSG_NOTICE( build-cpu:vendor:os: $build_cpu : $build_vendor : $build_os :) 
1205 AC_MSG_NOTICE( host-cpu:vendor:os: $host_cpu : $host_vendor : $host_os :) 
1206 if test "${cross_compiling}" = "yes"; then
1207    AC_MSG_NOTICE( Cross Compilation = YES)
1208 fi