Merged revisions 87168 via svnmerge from
[asterisk/asterisk.git] / res / ael / ael.y
1 %{
2 /*
3  * Asterisk -- An open source telephony toolkit.
4  *
5  * Copyright (C) 2006, Digium, Inc.
6  *
7  * Steve Murphy <murf@parsetree.com>
8  *
9  * See http://www.asterisk.org for more information about
10  * the Asterisk project. Please do not directly contact
11  * any of the maintainers of this project for assistance;
12  * the project provides a web site, mailing lists and IRC
13  * channels for your use.
14  *
15  * This program is free software, distributed under the terms of
16  * the GNU General Public License Version 2. See the LICENSE file
17  * at the top of the source tree.
18  */
19 /*! \file
20  *
21  * \brief Bison Grammar description of AEL2.
22  *
23  */
24
25 #include "asterisk.h"
26
27 ASTERISK_FILE_VERSION(__FILE__, "$Revision$")
28
29 #include <stdio.h>
30 #include <stdlib.h>
31 #include <string.h>
32
33 #include "asterisk/logger.h"
34 #include "asterisk/ael_structs.h"
35
36 pval * linku1(pval *head, pval *tail);
37 static void set_dads(pval *dad, pval *child_list);
38 void reset_parencount(yyscan_t yyscanner);
39 void reset_semicount(yyscan_t yyscanner);
40 void reset_argcount(yyscan_t yyscanner );
41  
42 #define YYLEX_PARAM ((struct parse_io *)parseio)->scanner
43 #define YYERROR_VERBOSE 1
44
45 extern char *my_file;
46 #ifdef AAL_ARGCHECK
47 int ael_is_funcname(char *name);
48 #endif
49 static char *ael_token_subst(const char *mess);
50
51 %}
52
53
54 %union {
55         int     intval;         /* integer value, typically flags */
56         char    *str;           /* strings */
57         struct pval *pval;      /* full objects */
58 }
59
60 %{
61         /* declaring these AFTER the union makes things a lot simpler! */
62 void yyerror(YYLTYPE *locp, struct parse_io *parseio, char const *s);
63 int ael_yylex (YYSTYPE * yylval_param, YYLTYPE * yylloc_param , void * yyscanner);
64
65 /* create a new object with start-end marker */
66 pval *npval(pvaltype type, int first_line, int last_line,
67         int first_column, int last_column);
68
69 /* create a new object with start-end marker, simplified interface.
70  * Must be declared here because YYLTYPE is not known before
71  */
72 static pval *npval2(pvaltype type, YYLTYPE *first, YYLTYPE *last);
73
74 /* another frontend for npval, this time for a string */
75 static pval *nword(char *string, YYLTYPE *pos);
76
77 /* update end position of an object, return the object */
78 static pval *update_last(pval *, YYLTYPE *);
79 %}
80
81
82 %token KW_CONTEXT LC RC LP RP SEMI EQ COMMA COLON AMPER BAR AT
83 %token KW_MACRO KW_GLOBALS KW_IGNOREPAT KW_SWITCH KW_IF KW_IFTIME KW_ELSE KW_RANDOM KW_ABSTRACT KW_EXTEND
84 %token EXTENMARK KW_GOTO KW_JUMP KW_RETURN KW_BREAK KW_CONTINUE KW_REGEXTEN KW_HINT
85 %token KW_FOR KW_WHILE KW_CASE KW_PATTERN KW_DEFAULT KW_CATCH KW_SWITCHES KW_ESWITCHES
86 %token KW_INCLUDES KW_LOCAL
87
88 %right BAR COMMA
89
90 %token <str> word
91
92 %type <pval>includes
93 %type <pval>includeslist
94 %type <pval>switchlist
95 %type <pval>eswitches
96 %type <pval>switches
97 %type <pval>macro_statement
98 %type <pval>macro_statements
99 %type <pval>case_statement
100 %type <pval>case_statements
101 %type <pval>eval_arglist
102 %type <pval>application_call
103 %type <pval>application_call_head
104 %type <pval>macro_call
105 %type <pval>target jumptarget
106 %type <pval>statement
107 %type <pval>switch_statement
108
109 %type <pval>if_like_head
110 %type <pval>statements
111 %type <pval>extension
112 %type <pval>ignorepat
113 %type <pval>element
114 %type <pval>elements
115 %type <pval>arglist
116 %type <pval>assignment
117 %type <pval>local_assignment
118 %type <pval>global_statements
119 %type <pval>globals
120 %type <pval>macro
121 %type <pval>context
122 %type <pval>object
123 %type <pval>objects
124 %type <pval>file
125 /* XXX lr changes */
126 %type <pval>opt_else
127 %type <pval>timespec
128 %type <pval>included_entry
129
130 %type <str>opt_word
131 %type <str>context_name
132 %type <str>timerange
133
134 %type <str>goto_word
135 %type <str>word_list
136 %type <str>word3_list hint_word
137 %type <str>test_expr
138 %type <str>opt_pri
139
140 %type <intval>opt_abstract
141
142 /*
143  * OPTIONS
144  */
145
146 %locations      /* track source location using @n variables (yylloc in flex) */
147 %pure-parser    /* pass yylval and yylloc as arguments to yylex(). */
148 %name-prefix="ael_yy"
149 /*
150  * add an additional argument, parseio, to yyparse(),
151  * which is then accessible in the grammar actions
152  */
153 %parse-param {struct parse_io *parseio}
154
155 /* there will be two shift/reduce conflicts, they involve the if statement, where a single statement occurs not wrapped in curlies in the "true" section
156    the default action to shift will attach the else to the preceeding if. */
157 %expect 3
158 %error-verbose
159
160 /*
161  * declare destructors for objects.
162  * The former is for pval, the latter for strings.
163  * NOTE: we must not have a destructor for a 'file' object.
164  */
165 %destructor {
166                 destroy_pval($$);
167                 prev_word=0;
168         }       includes includeslist switchlist eswitches switches
169                 macro_statement macro_statements case_statement case_statements
170                 eval_arglist application_call application_call_head
171                 macro_call target jumptarget statement switch_statement
172                 if_like_head statements extension
173                 ignorepat element elements arglist assignment local_assignment
174                 global_statements globals macro context object objects
175                 opt_else
176                 timespec included_entry
177
178 %destructor { free($$);}  word word_list goto_word word3_list opt_word context_name
179                 timerange
180                 test_expr
181                 opt_pri
182
183
184 %%
185
186 file : objects  { $$ = parseio->pval = $1; }
187         ;
188
189 objects : object {$$=$1;}
190         | objects object { $$ = linku1($1, $2); }
191         | objects error {$$=$1;}
192         ;
193
194 object : context {$$=$1;}
195         | macro {$$=$1;}
196         | globals {$$=$1;}
197         | SEMI  {$$=0;/* allow older docs to be read */}
198         ;
199
200 context_name : word { $$ = $1; }
201         | KW_DEFAULT { $$ = strdup("default"); }
202         ;
203
204 context : opt_abstract KW_CONTEXT context_name LC elements RC {
205                 $$ = npval2(PV_CONTEXT, &@1, &@6);
206                 $$->u1.str = $3;
207                 $$->u2.statements = $5;
208                 set_dads($$,$5);
209                 $$->u3.abstract = $1;} 
210         ;
211
212 /* optional "abstract" keyword  XXX there is no regression test for this */
213 opt_abstract: KW_ABSTRACT { $$ = 1; }
214         | /* nothing */ { $$ = 0; }
215         | KW_EXTEND { $$ = 2; }
216         | KW_EXTEND KW_ABSTRACT { $$=3; }
217         | KW_ABSTRACT KW_EXTEND { $$=3; }
218         ;
219
220 macro : KW_MACRO word LP arglist RP LC macro_statements RC {
221                 $$ = npval2(PV_MACRO, &@1, &@8);
222                 $$->u1.str = $2; $$->u2.arglist = $4; $$->u3.macro_statements = $7;
223         set_dads($$,$7);}
224         ;
225
226 globals : KW_GLOBALS LC global_statements RC {
227                 $$ = npval2(PV_GLOBALS, &@1, &@4);
228                 $$->u1.statements = $3;
229         set_dads($$,$3);}
230         ;
231
232 global_statements : { $$ = NULL; }
233         | assignment global_statements {$$ = linku1($1, $2); }
234         | error global_statements {$$=$2;}
235         ;
236
237 assignment : word EQ { reset_semicount(parseio->scanner); }  word SEMI {
238                 $$ = npval2(PV_VARDEC, &@1, &@5);
239                 $$->u1.str = $1;
240                 $$->u2.val = $4; }
241         ;
242
243 local_assignment : KW_LOCAL word EQ { reset_semicount(parseio->scanner); }  word SEMI {
244                 $$ = npval2(PV_LOCALVARDEC, &@1, &@6);
245                 $$->u1.str = $2;
246                 $$->u2.val = $5; }
247         ;
248
249 /* XXX this matches missing arguments, is this desired ? */
250 arglist : /* empty */ { $$ = NULL; }
251         | word { $$ = nword($1, &@1); }
252         | arglist COMMA word { $$ = linku1($1, nword($3, &@3)); }
253         | arglist error {$$=$1;}
254         ;
255
256 elements : {$$=0;}
257         | element elements { $$ = linku1($1, $2); }
258         | error elements  { $$=$2;}
259         ;
260
261 element : extension {$$=$1;}
262         | includes {$$=$1;}
263         | switches {$$=$1;}
264         | eswitches {$$=$1;}
265         | ignorepat {$$=$1;}
266         | assignment {$$=$1;}
267     | local_assignment {$$=$1;}
268         | word error {free($1); $$=0;}
269         | SEMI  {$$=0;/* allow older docs to be read */}
270         ;
271
272 ignorepat : KW_IGNOREPAT EXTENMARK word SEMI {
273                 $$ = npval2(PV_IGNOREPAT, &@1, &@4);
274                 $$->u1.str = $3;}
275         ;
276
277 extension : word EXTENMARK statement {
278                 $$ = npval2(PV_EXTENSION, &@1, &@3);
279                 $$->u1.str = $1;
280                 $$->u2.statements = $3; set_dads($$,$3);}
281         | KW_REGEXTEN word EXTENMARK statement {
282                 $$ = npval2(PV_EXTENSION, &@1, &@4);
283                 $$->u1.str = $2;
284                 $$->u2.statements = $4; set_dads($$,$4);
285                 $$->u4.regexten=1;}
286         | KW_HINT LP hint_word RP word EXTENMARK statement {
287                 $$ = npval2(PV_EXTENSION, &@1, &@7);
288                 $$->u1.str = $5;
289                 $$->u2.statements = $7; set_dads($$,$7);
290                 $$->u3.hints = $3;}
291         | KW_REGEXTEN KW_HINT LP hint_word RP word EXTENMARK statement {
292                 $$ = npval2(PV_EXTENSION, &@1, &@8);
293                 $$->u1.str = $6;
294                 $$->u2.statements = $8; set_dads($$,$8);
295                 $$->u4.regexten=1;
296                 $$->u3.hints = $4;}
297
298         ;
299
300 /* list of statements in a block or after a case label - can be empty */
301 statements : /* empty */ { $$ = NULL; }
302         | statement statements { $$ = linku1($1, $2); }
303         | error statements {$$=$2;}
304         ;
305
306 /* hh:mm-hh:mm, due to the way the parser works we do not
307  * detect the '-' but only the ':' as separator
308  */
309 timerange: word3_list COLON word3_list COLON word3_list {
310                 asprintf(&$$, "%s:%s:%s", $1, $3, $5);
311                 free($1);
312                 free($3);
313                 free($5); }
314         | word { $$ = $1; }
315         ;
316
317 /* full time specification range|dow|*|* */
318 timespec : timerange BAR word3_list BAR word3_list BAR word3_list {
319                 $$ = nword($1, &@1);
320                 $$->next = nword($3, &@3);
321                 $$->next->next = nword($5, &@5);
322                 $$->next->next->next = nword($7, &@7); }
323         ;
324
325 /* expression used in if, random, while, switch */
326 test_expr : LP { reset_parencount(parseio->scanner); }  word_list RP { $$ = $3; }
327         ;
328
329 /* 'if' like statements: if, iftime, random */
330 if_like_head : KW_IF test_expr {
331                 $$= npval2(PV_IF, &@1, &@2);
332                 $$->u1.str = $2; }
333         |  KW_RANDOM test_expr {
334                 $$ = npval2(PV_RANDOM, &@1, &@2);
335                 $$->u1.str=$2;}
336         | KW_IFTIME LP timespec RP {
337                 $$ = npval2(PV_IFTIME, &@1, &@4);
338                 $$->u1.list = $3;
339                 prev_word = 0; }
340         ;
341
342 /* word_list is a hack to fix a problem with context switching between bison and flex;
343    by the time you register a new context with flex, you've already got a look-ahead token
344    from the old context, with no way to put it back and start afresh. So, we kludge this
345    and merge the words back together. */
346
347 word_list : word { $$ = $1;}
348         | word word {
349                 asprintf(&($$), "%s%s", $1, $2);
350                 free($1);
351                 free($2);
352                 prev_word = $$;}
353         ;
354
355 hint_word : word { $$ = $1; }
356         | hint_word word {
357                 asprintf(&($$), "%s %s", $1, $2);
358                 free($1);
359                 free($2); }
360         | hint_word COLON word {
361                 asprintf(&($$), "%s:%s", $1, $3);
362                 free($1);
363                 free($3); }
364         | hint_word AMPER word {  /* there are often '&' in hints */
365                 asprintf(&($$), "%s&%s", $1, $3);
366                 free($1);
367                 free($3);}
368
369
370 word3_list : word { $$ = $1;}
371         | word word {
372                 asprintf(&($$), "%s%s", $1, $2);
373                 free($1);
374                 free($2);
375                 prev_word = $$;}
376         | word word word {
377                 asprintf(&($$), "%s%s%s", $1, $2, $3);
378                 free($1);
379                 free($2);
380                 free($3);
381                 prev_word=$$;}
382         ;
383
384 goto_word : word { $$ = $1;}
385         | word word {
386                 asprintf(&($$), "%s%s", $1, $2);
387                 free($1);
388                 free($2);}
389         | goto_word COLON word {
390                 asprintf(&($$), "%s:%s", $1, $3);
391                 free($1);
392                 free($3);}
393         ;
394
395 switch_statement : KW_SWITCH test_expr LC case_statements RC {
396                 $$ = npval2(PV_SWITCH, &@1, &@5);
397                 $$->u1.str = $2;
398                 $$->u2.statements = $4; set_dads($$,$4);}
399         ;
400
401 /*
402  * Definition of a statememt in our language
403  */
404 statement : LC statements RC {
405                 $$ = npval2(PV_STATEMENTBLOCK, &@1, &@3);
406                 $$->u1.list = $2; set_dads($$,$2);}
407         | assignment { $$ = $1; }
408         | local_assignment { $$ = $1; }
409         | KW_GOTO target SEMI {
410                 $$ = npval2(PV_GOTO, &@1, &@3);
411                 $$->u1.list = $2;}
412         | KW_JUMP jumptarget SEMI {
413                 $$ = npval2(PV_GOTO, &@1, &@3);
414                 $$->u1.list = $2;}
415         | word COLON {
416                 $$ = npval2(PV_LABEL, &@1, &@2);
417                 $$->u1.str = $1; }
418         | KW_FOR LP {reset_semicount(parseio->scanner);} word SEMI
419                         {reset_semicount(parseio->scanner);} word SEMI
420                         {reset_parencount(parseio->scanner);} word RP statement { /* XXX word_list maybe ? */
421                 $$ = npval2(PV_FOR, &@1, &@12);
422                 $$->u1.for_init = $4;
423                 $$->u2.for_test=$7;
424                 $$->u3.for_inc = $10;
425                 $$->u4.for_statements = $12; set_dads($$,$12);}
426         | KW_WHILE test_expr statement {
427                 $$ = npval2(PV_WHILE, &@1, &@3);
428                 $$->u1.str = $2;
429                 $$->u2.statements = $3; set_dads($$,$3);}
430         | switch_statement { $$ = $1; }
431         | AMPER macro_call SEMI { $$ = update_last($2, &@2); }
432         | application_call SEMI { $$ = update_last($1, &@2); }
433         | word SEMI {
434                 $$= npval2(PV_APPLICATION_CALL, &@1, &@2);
435                 $$->u1.str = $1;}
436         | application_call EQ {reset_semicount(parseio->scanner);} word SEMI {
437                 char *bufx;
438                 int tot=0;
439                 pval *pptr;
440                 $$ = npval2(PV_VARDEC, &@1, &@5);
441                 $$->u2.val=$4;
442                 /* rebuild the original string-- this is not an app call, it's an unwrapped vardec, with a func call on the LHS */
443                 /* string to big to fit in the buffer? */
444                 tot+=strlen($1->u1.str);
445                 for(pptr=$1->u2.arglist;pptr;pptr=pptr->next) {
446                         tot+=strlen(pptr->u1.str);
447                         tot++; /* for a sep like a comma */
448                 }
449                 tot+=4; /* for safety */
450                 bufx = calloc(1, tot);
451                 strcpy(bufx,$1->u1.str);
452                 strcat(bufx,"(");
453                 /* XXX need to advance the pointer or the loop is very inefficient */
454                 for (pptr=$1->u2.arglist;pptr;pptr=pptr->next) {
455                         if ( pptr != $1->u2.arglist )
456                                 strcat(bufx,",");
457                         strcat(bufx,pptr->u1.str);
458                 }
459                 strcat(bufx,")");
460 #ifdef AAL_ARGCHECK
461                 if ( !ael_is_funcname($1->u1.str) )
462                         ast_log(LOG_WARNING, "==== File: %s, Line %d, Cols: %d-%d: Function call? The name %s is not in my internal list of function names\n",
463                                 my_file, @1.first_line, @1.first_column, @1.last_column, $1->u1.str);
464 #endif
465                 $$->u1.str = bufx;
466                 destroy_pval($1); /* the app call it is not, get rid of that chain */
467                 prev_word = 0;
468         }
469         | KW_BREAK SEMI { $$ = npval2(PV_BREAK, &@1, &@2); }
470         | KW_RETURN SEMI { $$ = npval2(PV_RETURN, &@1, &@2); }
471         | KW_CONTINUE SEMI { $$ = npval2(PV_CONTINUE, &@1, &@2); }
472         | if_like_head statement opt_else {
473                 $$ = update_last($1, &@2);
474                 $$->u2.statements = $2; set_dads($$,$2);
475                 $$->u3.else_statements = $3;set_dads($$,$3);}
476         | SEMI { $$=0; }
477         ;
478
479 opt_else : KW_ELSE statement { $$ = $2; }
480         | { $$ = NULL ; }
481
482  
483 target : goto_word { $$ = nword($1, &@1); }
484         | goto_word BAR goto_word {
485                 $$ = nword($1, &@1);
486                 $$->next = nword($3, &@3); }
487         | goto_word COMMA goto_word {
488                 $$ = nword($1, &@1);
489                 $$->next = nword($3, &@3); }
490         | goto_word BAR goto_word BAR goto_word {
491                 $$ = nword($1, &@1);
492                 $$->next = nword($3, &@3);
493                 $$->next->next = nword($5, &@5); }
494         | goto_word COMMA goto_word COMMA goto_word {
495                 $$ = nword($1, &@1);
496                 $$->next = nword($3, &@3);
497                 $$->next->next = nword($5, &@5); }
498         | KW_DEFAULT BAR goto_word BAR goto_word {
499                 $$ = nword(strdup("default"), &@1);
500                 $$->next = nword($3, &@3);
501                 $$->next->next = nword($5, &@5); }
502         | KW_DEFAULT COMMA goto_word COMMA goto_word {
503                 $$ = nword(strdup("default"), &@1);
504                 $$->next = nword($3, &@3);
505                 $$->next->next = nword($5, &@5); }
506         ;
507
508 opt_pri : /* empty */ { $$ = strdup("1"); }
509         | COMMA word { $$ = $2; }
510         ;
511
512 /* XXX please document the form of jumptarget */
513 jumptarget : goto_word opt_pri {                        /* ext[, pri] default 1 */
514                 $$ = nword($1, &@1);
515                 $$->next = nword($2, &@2); }  /*  jump extension[,priority][@context] */
516         | goto_word opt_pri AT context_name {   /* context, ext, pri */
517                 $$ = nword($4, &@4);
518                 $$->next = nword($1, &@1);
519                 $$->next->next = nword($2, &@2); }
520         ;
521
522 macro_call : word LP {reset_argcount(parseio->scanner);} eval_arglist RP {
523                 /* XXX original code had @2 but i think we need @5 */
524                 $$ = npval2(PV_MACRO_CALL, &@1, &@5);
525                 $$->u1.str = $1;
526                 $$->u2.arglist = $4;}
527         | word LP RP {
528                 $$= npval2(PV_MACRO_CALL, &@1, &@3);
529                 $$->u1.str = $1; }
530         ;
531
532 /* XXX application_call_head must be revised. Having 'word LP { ...'
533  * just as above should work fine, however it gives a different result.
534  */
535 application_call_head: word LP {reset_argcount(parseio->scanner);} {
536                 if (strcasecmp($1,"goto") == 0) {
537                         $$ = npval2(PV_GOTO, &@1, &@2);
538                         free($1); /* won't be using this */
539                         ast_log(LOG_WARNING, "==== File: %s, Line %d, Cols: %d-%d: Suggestion: Use the goto statement instead of the Goto() application call in AEL.\n", my_file, @1.first_line, @1.first_column, @1.last_column );
540                 } else {
541                         $$= npval2(PV_APPLICATION_CALL, &@1, &@2);
542                         $$->u1.str = $1;
543                 } }
544         ;
545
546 application_call : application_call_head eval_arglist RP {
547                 $$ = update_last($1, &@3);
548                 if( $$->type == PV_GOTO )
549                         $$->u1.list = $2;
550                 else
551                         $$->u2.arglist = $2;
552         }
553         | application_call_head RP { $$ = update_last($1, &@2); }
554         ;
555
556 opt_word : word { $$ = $1 }
557         | { $$ = strdup(""); }
558         ;
559
560 eval_arglist :  word_list { $$ = nword($1, &@1); }
561         | /*nothing! */   {
562                 $$= npval(PV_WORD,0/*@1.first_line*/,0/*@1.last_line*/,0/* @1.first_column*/, 0/*@1.last_column*/);
563                 $$->u1.str = strdup(""); }
564         | eval_arglist COMMA  opt_word { $$ = linku1($1, nword($3, &@3)); }
565         ;
566
567 case_statements: /* empty */ { $$ = NULL; }
568         | case_statement case_statements { $$ = linku1($1, $2); }
569         ;
570
571 case_statement: KW_CASE word COLON statements {
572                 $$ = npval2(PV_CASE, &@1, &@3); /* XXX 3 or 4 ? */
573                 $$->u1.str = $2;
574                 $$->u2.statements = $4; set_dads($$,$4);}
575         | KW_DEFAULT COLON statements {
576                 $$ = npval2(PV_DEFAULT, &@1, &@3);
577                 $$->u1.str = NULL;
578                 $$->u2.statements = $3;set_dads($$,$3);}
579         | KW_PATTERN word COLON statements {
580                 $$ = npval2(PV_PATTERN, &@1, &@4); /* XXX@3 or @4 ? */
581                 $$->u1.str = $2;
582                 $$->u2.statements = $4;set_dads($$,$4);}
583         ;
584
585 macro_statements: /* empty */ { $$ = NULL; }
586         | macro_statement macro_statements { $$ = linku1($1, $2); }
587         ;
588
589 macro_statement : statement {$$=$1;}
590         | includes { $$=$1;}
591         | KW_CATCH word LC statements RC {
592                 $$ = npval2(PV_CATCH, &@1, &@5);
593                 $$->u1.str = $2;
594                 $$->u2.statements = $4; set_dads($$,$4);}
595         ;
596
597 switches : KW_SWITCHES LC switchlist RC {
598                 $$ = npval2(PV_SWITCHES, &@1, &@2);
599                 $$->u1.list = $3; set_dads($$,$3);}
600         ;
601
602 eswitches : KW_ESWITCHES LC switchlist RC {
603                 $$ = npval2(PV_ESWITCHES, &@1, &@2);
604                 $$->u1.list = $3; set_dads($$,$3);}
605         ;
606
607 switchlist : /* empty */ { $$ = NULL; }
608         | word SEMI switchlist { $$ = linku1(nword($1, &@1), $3); }
609         | word AT word SEMI switchlist { char *x; asprintf(&x,"%s@%s", $1,$3); free($1); free($3);
610                                                                           $$ = linku1(nword(x, &@1), $5);}
611         | error switchlist {$$=$2;}
612         ;
613
614 included_entry : context_name { $$ = nword($1, &@1); }
615         | context_name BAR timespec {
616                 $$ = nword($1, &@1);
617                 $$->u2.arglist = $3;
618                 prev_word=0; /* XXX sure ? */ }
619         ;
620
621 /* list of ';' separated context names followed by optional timespec */
622 includeslist : included_entry SEMI { $$ = $1; }
623         | includeslist included_entry SEMI { $$ = linku1($1, $2); }
624         | includeslist error {$$=$1;}
625         ;
626
627 includes : KW_INCLUDES LC includeslist RC {
628                 $$ = npval2(PV_INCLUDES, &@1, &@4);
629                 $$->u1.list = $3;set_dads($$,$3);}
630         | KW_INCLUDES LC RC {
631                 $$ = npval2(PV_INCLUDES, &@1, &@3);}
632         ;
633
634
635 %%
636
637 static char *token_equivs1[] =
638 {
639         "AMPER",
640         "AT",
641         "BAR",
642         "COLON",
643         "COMMA",
644         "EQ",
645         "EXTENMARK",
646         "KW_BREAK",
647         "KW_CASE",
648         "KW_CATCH",
649         "KW_CONTEXT",
650         "KW_CONTINUE",
651         "KW_DEFAULT",
652         "KW_ELSE",
653         "KW_ESWITCHES",
654         "KW_FOR",
655         "KW_GLOBALS",
656         "KW_GOTO",
657         "KW_HINT",
658         "KW_IFTIME",
659         "KW_IF",
660         "KW_IGNOREPAT",
661         "KW_INCLUDES"
662         "KW_JUMP",
663         "KW_MACRO",
664         "KW_PATTERN",
665         "KW_REGEXTEN",
666         "KW_RETURN",
667         "KW_SWITCHES",
668         "KW_SWITCH",
669         "KW_WHILE",
670         "LC",
671         "LP",
672         "RC",
673         "RP",
674         "SEMI",
675 };
676
677 static char *token_equivs2[] =
678 {
679         "&",
680         "@",
681         "|",
682         ":",
683         ",",
684         "=",
685         "=>",
686         "break",
687         "case",
688         "catch",
689         "context",
690         "continue",
691         "default",
692         "else",
693         "eswitches",
694         "for",
695         "globals",
696         "goto",
697         "hint",
698         "ifTime",
699         "if",
700         "ignorepat",
701         "includes"
702         "jump",
703         "macro",
704         "pattern",
705         "regexten",
706         "return",
707         "switches",
708         "switch",
709         "while",
710         "{",
711         "(",
712         "}",
713         ")",
714         ";",
715 };
716
717
718 static char *ael_token_subst(const char *mess)
719 {
720         /* calc a length, malloc, fill, and return; yyerror had better free it! */
721         int len=0,i;
722         const char *p;
723         char *res, *s,*t;
724         int token_equivs_entries = sizeof(token_equivs1)/sizeof(char*);
725
726         for (p=mess; *p; p++) {
727                 for (i=0; i<token_equivs_entries; i++) {
728                         if ( strncmp(p,token_equivs1[i],strlen(token_equivs1[i])) == 0 )
729                         {
730                                 len+=strlen(token_equivs2[i])+2;
731                                 p += strlen(token_equivs1[i])-1;
732                                 break;
733                         }
734                 }
735                 len++;
736         }
737         res = calloc(1, len+1);
738         res[0] = 0;
739         s = res;
740         for (p=mess; *p;) {
741                 int found = 0;
742                 for (i=0; i<token_equivs_entries; i++) {
743                         if ( strncmp(p,token_equivs1[i],strlen(token_equivs1[i])) == 0 ) {
744                                 *s++ = '\'';
745                                 for (t=token_equivs2[i]; *t;) {
746                                         *s++ = *t++;
747                                 }
748                                 *s++ = '\'';
749                                 p += strlen(token_equivs1[i]);
750                                 found = 1;
751                                 break;
752                         }
753                 }
754                 if( !found )
755                         *s++ = *p++;
756         }
757         *s++ = 0;
758         return res;
759 }
760
761 void yyerror(YYLTYPE *locp, struct parse_io *parseio,  char const *s)
762 {
763         char *s2 = ael_token_subst((char *)s);
764         if (locp->first_line == locp->last_line) {
765                 ast_log(LOG_ERROR, "==== File: %s, Line %d, Cols: %d-%d: Error: %s\n", my_file, locp->first_line, locp->first_column, locp->last_column, s2);
766         } else {
767                 ast_log(LOG_ERROR, "==== File: %s, Line %d Col %d  to Line %d Col %d: Error: %s\n", my_file, locp->first_line, locp->first_column, locp->last_line, locp->last_column, s2);
768         }
769         free(s2);
770         parseio->syntax_error_count++;
771 }
772
773 struct pval *npval(pvaltype type, int first_line, int last_line,
774         int first_column, int last_column)
775 {
776         pval *z = calloc(1, sizeof(struct pval));
777         z->type = type;
778         z->startline = first_line;
779         z->endline = last_line;
780         z->startcol = first_column;
781         z->endcol = last_column;
782         z->filename = strdup(my_file);
783         return z;
784 }
785
786 static struct pval *npval2(pvaltype type, YYLTYPE *first, YYLTYPE *last)
787 {
788         return npval(type, first->first_line, last->last_line,
789                         first->first_column, last->last_column);
790 }
791
792 static struct pval *update_last(pval *obj, YYLTYPE *last)
793 {
794         obj->endline = last->last_line;
795         obj->endcol = last->last_column;
796         return obj;
797 }
798
799 /* frontend for npval to create a PV_WORD string from the given token */
800 static pval *nword(char *string, YYLTYPE *pos)
801 {
802         pval *p = npval2(PV_WORD, pos, pos);
803         if (p)
804                 p->u1.str = string;
805         return p;
806 }
807
808 /* this routine adds a dad ptr to each element in the list */
809 static void set_dads(struct pval *dad, struct pval *child_list)
810 {
811         struct pval *t;
812         
813         for(t=child_list;t;t=t->next)  /* simple stuff */
814                 t->dad = dad;
815 }
816