dc5309005d4fc376f1f0b854f220e593f1360a6e
[asterisk/asterisk.git] / res / ael / ael.y
1 %{
2 /*
3  * Asterisk -- An open source telephony toolkit.
4  *
5  * Copyright (C) 2006, Digium, Inc.
6  *
7  * Steve Murphy <murf@parsetree.com>
8  *
9  * See http://www.asterisk.org for more information about
10  * the Asterisk project. Please do not directly contact
11  * any of the maintainers of this project for assistance;
12  * the project provides a web site, mailing lists and IRC
13  * channels for your use.
14  *
15  * This program is free software, distributed under the terms of
16  * the GNU General Public License Version 2. See the LICENSE file
17  * at the top of the source tree.
18  */
19 /*! \file
20  *
21  * \brief Bison Grammar description of AEL2.
22  *
23  */
24
25 #include "asterisk.h"
26
27 ASTERISK_FILE_VERSION(__FILE__, "$Revision$")
28
29 #include <stdio.h>
30 #include <stdlib.h>
31 #include <string.h>
32
33 #include "asterisk/logger.h"
34 #include "asterisk/ael_structs.h"
35
36 pval * linku1(pval *head, pval *tail);
37 static void set_dads(pval *dad, pval *child_list);
38 void reset_parencount(yyscan_t yyscanner);
39 void reset_semicount(yyscan_t yyscanner);
40 void reset_argcount(yyscan_t yyscanner );
41  
42 #define YYLEX_PARAM ((struct parse_io *)parseio)->scanner
43 #define YYERROR_VERBOSE 1
44
45 extern char *my_file;
46 #ifdef AAL_ARGCHECK
47 int ael_is_funcname(char *name);
48 #endif
49 static char *ael_token_subst(const char *mess);
50
51 %}
52
53
54 %union {
55         int     intval;         /* integer value, typically flags */
56         char    *str;           /* strings */
57         struct pval *pval;      /* full objects */
58 }
59
60 %{
61         /* declaring these AFTER the union makes things a lot simpler! */
62 void yyerror(YYLTYPE *locp, struct parse_io *parseio, char const *s);
63 int ael_yylex (YYSTYPE * yylval_param, YYLTYPE * yylloc_param , void * yyscanner);
64
65 /* create a new object with start-end marker */
66 pval *npval(pvaltype type, int first_line, int last_line,
67         int first_column, int last_column);
68
69 /* create a new object with start-end marker, simplified interface.
70  * Must be declared here because YYLTYPE is not known before
71  */
72 static pval *npval2(pvaltype type, YYLTYPE *first, YYLTYPE *last);
73
74 /* another frontend for npval, this time for a string */
75 static pval *nword(char *string, YYLTYPE *pos);
76
77 /* update end position of an object, return the object */
78 static pval *update_last(pval *, YYLTYPE *);
79 %}
80
81
82 %token KW_CONTEXT LC RC LP RP SEMI EQ COMMA COLON AMPER BAR AT
83 %token KW_MACRO KW_GLOBALS KW_IGNOREPAT KW_SWITCH KW_IF KW_IFTIME KW_ELSE KW_RANDOM KW_ABSTRACT
84 %token EXTENMARK KW_GOTO KW_JUMP KW_RETURN KW_BREAK KW_CONTINUE KW_REGEXTEN KW_HINT
85 %token KW_FOR KW_WHILE KW_CASE KW_PATTERN KW_DEFAULT KW_CATCH KW_SWITCHES KW_ESWITCHES
86 %token KW_INCLUDES KW_LOCAL
87
88 %right BAR COMMA
89
90 %token <str> word
91
92 %type <pval>includes
93 %type <pval>includeslist
94 %type <pval>switchlist
95 %type <pval>eswitches
96 %type <pval>switches
97 %type <pval>macro_statement
98 %type <pval>macro_statements
99 %type <pval>case_statement
100 %type <pval>case_statements
101 %type <pval>eval_arglist
102 %type <pval>application_call
103 %type <pval>application_call_head
104 %type <pval>macro_call
105 %type <pval>target jumptarget
106 %type <pval>statement
107 %type <pval>switch_statement
108
109 %type <pval>if_like_head
110 %type <pval>statements
111 %type <pval>extension
112 %type <pval>ignorepat
113 %type <pval>element
114 %type <pval>elements
115 %type <pval>arglist
116 %type <pval>assignment
117 %type <pval>local_assignment
118 %type <pval>global_statements
119 %type <pval>globals
120 %type <pval>macro
121 %type <pval>context
122 %type <pval>object
123 %type <pval>objects
124 %type <pval>file
125 /* XXX lr changes */
126 %type <pval>opt_else
127 %type <pval>timespec
128 %type <pval>included_entry
129
130 %type <str>opt_word
131 %type <str>context_name
132 %type <str>timerange
133
134 %type <str>goto_word
135 %type <str>word_list
136 %type <str>word3_list hint_word
137 %type <str>test_expr
138 %type <str>opt_pri
139
140 %type <intval>opt_abstract
141
142 /*
143  * OPTIONS
144  */
145
146 %locations      /* track source location using @n variables (yylloc in flex) */
147 %pure-parser    /* pass yylval and yylloc as arguments to yylex(). */
148 %name-prefix="ael_yy"
149 /*
150  * add an additional argument, parseio, to yyparse(),
151  * which is then accessible in the grammar actions
152  */
153 %parse-param {struct parse_io *parseio}
154
155 /* there will be two shift/reduce conflicts, they involve the if statement, where a single statement occurs not wrapped in curlies in the "true" section
156    the default action to shift will attach the else to the preceeding if. */
157 %expect 3
158 %error-verbose
159
160 /*
161  * declare destructors for objects.
162  * The former is for pval, the latter for strings.
163  * NOTE: we must not have a destructor for a 'file' object.
164  */
165 %destructor {
166                 destroy_pval($$);
167                 prev_word=0;
168         }       includes includeslist switchlist eswitches switches
169                 macro_statement macro_statements case_statement case_statements
170                 eval_arglist application_call application_call_head
171                 macro_call target jumptarget statement switch_statement
172                 if_like_head statements extension
173                 ignorepat element elements arglist assignment local_assignment
174                 global_statements globals macro context object objects
175                 opt_else
176                 timespec included_entry
177
178 %destructor { free($$);}  word word_list goto_word word3_list opt_word context_name
179                 timerange
180                 test_expr
181                 opt_pri
182
183
184 %%
185
186 file : objects  { $$ = parseio->pval = $1; }
187         ;
188
189 objects : object {$$=$1;}
190         | objects object { $$ = linku1($1, $2); }
191         | objects error {$$=$1;}
192         ;
193
194 object : context {$$=$1;}
195         | macro {$$=$1;}
196         | globals {$$=$1;}
197         | SEMI  {$$=0;/* allow older docs to be read */}
198         ;
199
200 context_name : word { $$ = $1; }
201         | KW_DEFAULT { $$ = strdup("default"); }
202         ;
203
204 context : opt_abstract KW_CONTEXT context_name LC elements RC {
205                 if (!$5) {
206                         ast_log(LOG_WARNING, "==== File: %s, Line %d, Cols: %d-%d: Warning! The empty context %s will be IGNORED!\n", 
207                                 my_file, @4.first_line, @4.first_column, @4.last_column, $3 );
208                         $$ = 0;
209                         free($3);
210                 } else {
211                         $$ = npval2(PV_CONTEXT, &@1, &@6);
212                         $$->u1.str = $3;
213                         $$->u2.statements = $5;
214                         set_dads($$,$5);
215                         $$->u3.abstract = $1;} }
216         ;
217
218 /* optional "abstract" keyword  XXX there is no regression test for this */
219 opt_abstract: KW_ABSTRACT { $$ = 1; }
220         | /* nothing */ { $$ = 0; }
221         ;
222
223 macro : KW_MACRO word LP arglist RP LC macro_statements RC {
224                 $$ = npval2(PV_MACRO, &@1, &@8);
225                 $$->u1.str = $2; $$->u2.arglist = $4; $$->u3.macro_statements = $7;
226         set_dads($$,$7);}
227         ;
228
229 globals : KW_GLOBALS LC global_statements RC {
230                 $$ = npval2(PV_GLOBALS, &@1, &@4);
231                 $$->u1.statements = $3;
232         set_dads($$,$3);}
233         ;
234
235 global_statements : { $$ = NULL; }
236         | assignment global_statements {$$ = linku1($1, $2); }
237         | error global_statements {$$=$2;}
238         ;
239
240 assignment : word EQ { reset_semicount(parseio->scanner); }  word SEMI {
241                 $$ = npval2(PV_VARDEC, &@1, &@5);
242                 $$->u1.str = $1;
243                 $$->u2.val = $4; }
244         ;
245
246 local_assignment : KW_LOCAL word EQ { reset_semicount(parseio->scanner); }  word SEMI {
247                 $$ = npval2(PV_LOCALVARDEC, &@1, &@6);
248                 $$->u1.str = $2;
249                 $$->u2.val = $5; }
250         ;
251
252 /* XXX this matches missing arguments, is this desired ? */
253 arglist : /* empty */ { $$ = NULL; }
254         | word { $$ = nword($1, &@1); }
255         | arglist COMMA word { $$ = linku1($1, nword($3, &@3)); }
256         | arglist error {$$=$1;}
257         ;
258
259 elements : {$$=0;}
260         | element elements { $$ = linku1($1, $2); }
261         | error elements  { $$=$2;}
262         ;
263
264 element : extension {$$=$1;}
265         | includes {$$=$1;}
266         | switches {$$=$1;}
267         | eswitches {$$=$1;}
268         | ignorepat {$$=$1;}
269         | assignment {$$=$1;}
270     | local_assignment {$$=$1;}
271         | word error {free($1); $$=0;}
272         | SEMI  {$$=0;/* allow older docs to be read */}
273         ;
274
275 ignorepat : KW_IGNOREPAT EXTENMARK word SEMI {
276                 $$ = npval2(PV_IGNOREPAT, &@1, &@4);
277                 $$->u1.str = $3;}
278         ;
279
280 extension : word EXTENMARK statement {
281                 $$ = npval2(PV_EXTENSION, &@1, &@3);
282                 $$->u1.str = $1;
283                 $$->u2.statements = $3; set_dads($$,$3);}
284         | KW_REGEXTEN word EXTENMARK statement {
285                 $$ = npval2(PV_EXTENSION, &@1, &@4);
286                 $$->u1.str = $2;
287                 $$->u2.statements = $4; set_dads($$,$4);
288                 $$->u4.regexten=1;}
289         | KW_HINT LP hint_word RP word EXTENMARK statement {
290                 $$ = npval2(PV_EXTENSION, &@1, &@7);
291                 $$->u1.str = $5;
292                 $$->u2.statements = $7; set_dads($$,$7);
293                 $$->u3.hints = $3;}
294         | KW_REGEXTEN KW_HINT LP hint_word RP word EXTENMARK statement {
295                 $$ = npval2(PV_EXTENSION, &@1, &@8);
296                 $$->u1.str = $6;
297                 $$->u2.statements = $8; set_dads($$,$8);
298                 $$->u4.regexten=1;
299                 $$->u3.hints = $4;}
300
301         ;
302
303 /* list of statements in a block or after a case label - can be empty */
304 statements : /* empty */ { $$ = NULL; }
305         | statement statements { $$ = linku1($1, $2); }
306         | error statements {$$=$2;}
307         ;
308
309 /* hh:mm-hh:mm, due to the way the parser works we do not
310  * detect the '-' but only the ':' as separator
311  */
312 timerange: word3_list COLON word3_list COLON word3_list {
313                 asprintf(&$$, "%s:%s:%s", $1, $3, $5);
314                 free($1);
315                 free($3);
316                 free($5); }
317         | word { $$ = $1; }
318         ;
319
320 /* full time specification range|dow|*|* */
321 timespec : timerange BAR word3_list BAR word3_list BAR word3_list {
322                 $$ = nword($1, &@1);
323                 $$->next = nword($3, &@3);
324                 $$->next->next = nword($5, &@5);
325                 $$->next->next->next = nword($7, &@7); }
326         ;
327
328 /* expression used in if, random, while, switch */
329 test_expr : LP { reset_parencount(parseio->scanner); }  word_list RP { $$ = $3; }
330         ;
331
332 /* 'if' like statements: if, iftime, random */
333 if_like_head : KW_IF test_expr {
334                 $$= npval2(PV_IF, &@1, &@2);
335                 $$->u1.str = $2; }
336         |  KW_RANDOM test_expr {
337                 $$ = npval2(PV_RANDOM, &@1, &@2);
338                 $$->u1.str=$2;}
339         | KW_IFTIME LP timespec RP {
340                 $$ = npval2(PV_IFTIME, &@1, &@4);
341                 $$->u1.list = $3;
342                 prev_word = 0; }
343         ;
344
345 /* word_list is a hack to fix a problem with context switching between bison and flex;
346    by the time you register a new context with flex, you've already got a look-ahead token
347    from the old context, with no way to put it back and start afresh. So, we kludge this
348    and merge the words back together. */
349
350 word_list : word { $$ = $1;}
351         | word word {
352                 asprintf(&($$), "%s%s", $1, $2);
353                 free($1);
354                 free($2);
355                 prev_word = $$;}
356         ;
357
358 hint_word : word { $$ = $1; }
359         | hint_word word {
360                 asprintf(&($$), "%s %s", $1, $2);
361                 free($1);
362                 free($2); }
363         | hint_word COLON word {
364                 asprintf(&($$), "%s:%s", $1, $3);
365                 free($1);
366                 free($3); }
367         | hint_word AMPER word {  /* there are often '&' in hints */
368                 asprintf(&($$), "%s&%s", $1, $3);
369                 free($1);
370                 free($3);}
371
372
373 word3_list : word { $$ = $1;}
374         | word word {
375                 asprintf(&($$), "%s%s", $1, $2);
376                 free($1);
377                 free($2);
378                 prev_word = $$;}
379         | word word word {
380                 asprintf(&($$), "%s%s%s", $1, $2, $3);
381                 free($1);
382                 free($2);
383                 free($3);
384                 prev_word=$$;}
385         ;
386
387 goto_word : word { $$ = $1;}
388         | word word {
389                 asprintf(&($$), "%s%s", $1, $2);
390                 free($1);
391                 free($2);}
392         | goto_word COLON word {
393                 asprintf(&($$), "%s:%s", $1, $3);
394                 free($1);
395                 free($3);}
396         ;
397
398 switch_statement : KW_SWITCH test_expr LC case_statements RC {
399                 $$ = npval2(PV_SWITCH, &@1, &@5);
400                 $$->u1.str = $2;
401                 $$->u2.statements = $4; set_dads($$,$4);}
402         ;
403
404 /*
405  * Definition of a statememt in our language
406  */
407 statement : LC statements RC {
408                 $$ = npval2(PV_STATEMENTBLOCK, &@1, &@3);
409                 $$->u1.list = $2; set_dads($$,$2);}
410         | assignment { $$ = $1; }
411         | local_assignment { $$ = $1; }
412         | KW_GOTO target SEMI {
413                 $$ = npval2(PV_GOTO, &@1, &@3);
414                 $$->u1.list = $2;}
415         | KW_JUMP jumptarget SEMI {
416                 $$ = npval2(PV_GOTO, &@1, &@3);
417                 $$->u1.list = $2;}
418         | word COLON {
419                 $$ = npval2(PV_LABEL, &@1, &@2);
420                 $$->u1.str = $1; }
421         | KW_FOR LP {reset_semicount(parseio->scanner);} word SEMI
422                         {reset_semicount(parseio->scanner);} word SEMI
423                         {reset_parencount(parseio->scanner);} word RP statement { /* XXX word_list maybe ? */
424                 $$ = npval2(PV_FOR, &@1, &@12);
425                 $$->u1.for_init = $4;
426                 $$->u2.for_test=$7;
427                 $$->u3.for_inc = $10;
428                 $$->u4.for_statements = $12; set_dads($$,$12);}
429         | KW_WHILE test_expr statement {
430                 $$ = npval2(PV_WHILE, &@1, &@3);
431                 $$->u1.str = $2;
432                 $$->u2.statements = $3; set_dads($$,$3);}
433         | switch_statement { $$ = $1; }
434         | AMPER macro_call SEMI { $$ = update_last($2, &@2); }
435         | application_call SEMI { $$ = update_last($1, &@2); }
436         | word SEMI {
437                 $$= npval2(PV_APPLICATION_CALL, &@1, &@2);
438                 $$->u1.str = $1;}
439         | application_call EQ {reset_semicount(parseio->scanner);} word SEMI {
440                 char *bufx;
441                 int tot=0;
442                 pval *pptr;
443                 $$ = npval2(PV_VARDEC, &@1, &@5);
444                 $$->u2.val=$4;
445                 /* rebuild the original string-- this is not an app call, it's an unwrapped vardec, with a func call on the LHS */
446                 /* string to big to fit in the buffer? */
447                 tot+=strlen($1->u1.str);
448                 for(pptr=$1->u2.arglist;pptr;pptr=pptr->next) {
449                         tot+=strlen(pptr->u1.str);
450                         tot++; /* for a sep like a comma */
451                 }
452                 tot+=4; /* for safety */
453                 bufx = calloc(1, tot);
454                 strcpy(bufx,$1->u1.str);
455                 strcat(bufx,"(");
456                 /* XXX need to advance the pointer or the loop is very inefficient */
457                 for (pptr=$1->u2.arglist;pptr;pptr=pptr->next) {
458                         if ( pptr != $1->u2.arglist )
459                                 strcat(bufx,",");
460                         strcat(bufx,pptr->u1.str);
461                 }
462                 strcat(bufx,")");
463 #ifdef AAL_ARGCHECK
464                 if ( !ael_is_funcname($1->u1.str) )
465                         ast_log(LOG_WARNING, "==== File: %s, Line %d, Cols: %d-%d: Function call? The name %s is not in my internal list of function names\n",
466                                 my_file, @1.first_line, @1.first_column, @1.last_column, $1->u1.str);
467 #endif
468                 $$->u1.str = bufx;
469                 destroy_pval($1); /* the app call it is not, get rid of that chain */
470                 prev_word = 0;
471         }
472         | KW_BREAK SEMI { $$ = npval2(PV_BREAK, &@1, &@2); }
473         | KW_RETURN SEMI { $$ = npval2(PV_RETURN, &@1, &@2); }
474         | KW_CONTINUE SEMI { $$ = npval2(PV_CONTINUE, &@1, &@2); }
475         | if_like_head statement opt_else {
476                 $$ = update_last($1, &@2);
477                 $$->u2.statements = $2; set_dads($$,$2);
478                 $$->u3.else_statements = $3;set_dads($$,$3);}
479         | SEMI { $$=0; }
480         ;
481
482 opt_else : KW_ELSE statement { $$ = $2; }
483         | { $$ = NULL ; }
484
485  
486 target : goto_word { $$ = nword($1, &@1); }
487         | goto_word BAR goto_word {
488                 $$ = nword($1, &@1);
489                 $$->next = nword($3, &@3); }
490         | goto_word COMMA goto_word {
491                 $$ = nword($1, &@1);
492                 $$->next = nword($3, &@3); }
493         | goto_word BAR goto_word BAR goto_word {
494                 $$ = nword($1, &@1);
495                 $$->next = nword($3, &@3);
496                 $$->next->next = nword($5, &@5); }
497         | goto_word COMMA goto_word COMMA goto_word {
498                 $$ = nword($1, &@1);
499                 $$->next = nword($3, &@3);
500                 $$->next->next = nword($5, &@5); }
501         | KW_DEFAULT BAR goto_word BAR goto_word {
502                 $$ = nword(strdup("default"), &@1);
503                 $$->next = nword($3, &@3);
504                 $$->next->next = nword($5, &@5); }
505         | KW_DEFAULT COMMA goto_word COMMA goto_word {
506                 $$ = nword(strdup("default"), &@1);
507                 $$->next = nword($3, &@3);
508                 $$->next->next = nword($5, &@5); }
509         ;
510
511 opt_pri : /* empty */ { $$ = strdup("1"); }
512         | COMMA word { $$ = $2; }
513         ;
514
515 /* XXX please document the form of jumptarget */
516 jumptarget : goto_word opt_pri {                        /* ext[, pri] default 1 */
517                 $$ = nword($1, &@1);
518                 $$->next = nword($2, &@2); }  /*  jump extension[,priority][@context] */
519         | goto_word opt_pri AT context_name {   /* context, ext, pri */
520                 $$ = nword($4, &@4);
521                 $$->next = nword($1, &@1);
522                 $$->next->next = nword($2, &@2); }
523         ;
524
525 macro_call : word LP {reset_argcount(parseio->scanner);} eval_arglist RP {
526                 /* XXX original code had @2 but i think we need @5 */
527                 $$ = npval2(PV_MACRO_CALL, &@1, &@5);
528                 $$->u1.str = $1;
529                 $$->u2.arglist = $4;}
530         | word LP RP {
531                 $$= npval2(PV_MACRO_CALL, &@1, &@3);
532                 $$->u1.str = $1; }
533         ;
534
535 /* XXX application_call_head must be revised. Having 'word LP { ...'
536  * just as above should work fine, however it gives a different result.
537  */
538 application_call_head: word LP {reset_argcount(parseio->scanner);} {
539                 if (strcasecmp($1,"goto") == 0) {
540                         $$ = npval2(PV_GOTO, &@1, &@2);
541                         free($1); /* won't be using this */
542                         ast_log(LOG_WARNING, "==== File: %s, Line %d, Cols: %d-%d: Suggestion: Use the goto statement instead of the Goto() application call in AEL.\n", my_file, @1.first_line, @1.first_column, @1.last_column );
543                 } else {
544                         $$= npval2(PV_APPLICATION_CALL, &@1, &@2);
545                         $$->u1.str = $1;
546                 } }
547         ;
548
549 application_call : application_call_head eval_arglist RP {
550                 $$ = update_last($1, &@3);
551                 if( $$->type == PV_GOTO )
552                         $$->u1.list = $2;
553                 else
554                         $$->u2.arglist = $2;
555         }
556         | application_call_head RP { $$ = update_last($1, &@2); }
557         ;
558
559 opt_word : word { $$ = $1 }
560         | { $$ = strdup(""); }
561         ;
562
563 eval_arglist :  word_list { $$ = nword($1, &@1); }
564         | /*nothing! */   {
565                 $$= npval(PV_WORD,0/*@1.first_line*/,0/*@1.last_line*/,0/* @1.first_column*/, 0/*@1.last_column*/);
566                 $$->u1.str = strdup(""); }
567         | eval_arglist COMMA  opt_word { $$ = linku1($1, nword($3, &@3)); }
568         ;
569
570 case_statements: /* empty */ { $$ = NULL; }
571         | case_statement case_statements { $$ = linku1($1, $2); }
572         ;
573
574 case_statement: KW_CASE word COLON statements {
575                 $$ = npval2(PV_CASE, &@1, &@3); /* XXX 3 or 4 ? */
576                 $$->u1.str = $2;
577                 $$->u2.statements = $4; set_dads($$,$4);}
578         | KW_DEFAULT COLON statements {
579                 $$ = npval2(PV_DEFAULT, &@1, &@3);
580                 $$->u1.str = NULL;
581                 $$->u2.statements = $3;set_dads($$,$3);}
582         | KW_PATTERN word COLON statements {
583                 $$ = npval2(PV_PATTERN, &@1, &@4); /* XXX@3 or @4 ? */
584                 $$->u1.str = $2;
585                 $$->u2.statements = $4;set_dads($$,$4);}
586         ;
587
588 macro_statements: /* empty */ { $$ = NULL; }
589         | macro_statement macro_statements { $$ = linku1($1, $2); }
590         ;
591
592 macro_statement : statement {$$=$1;}
593         | includes { $$=$1;}
594         | KW_CATCH word LC statements RC {
595                 $$ = npval2(PV_CATCH, &@1, &@5);
596                 $$->u1.str = $2;
597                 $$->u2.statements = $4; set_dads($$,$4);}
598         ;
599
600 switches : KW_SWITCHES LC switchlist RC {
601                 $$ = npval2(PV_SWITCHES, &@1, &@2);
602                 $$->u1.list = $3; set_dads($$,$3);}
603         ;
604
605 eswitches : KW_ESWITCHES LC switchlist RC {
606                 $$ = npval2(PV_ESWITCHES, &@1, &@2);
607                 $$->u1.list = $3; set_dads($$,$3);}
608         ;
609
610 switchlist : /* empty */ { $$ = NULL; }
611         | word SEMI switchlist { $$ = linku1(nword($1, &@1), $3); }
612         | word AT word SEMI switchlist { char *x; asprintf(&x,"%s@%s", $1,$3); free($1); free($3);
613                                                                           $$ = linku1(nword(x, &@1), $5);}
614         | error switchlist {$$=$2;}
615         ;
616
617 included_entry : context_name { $$ = nword($1, &@1); }
618         | context_name BAR timespec {
619                 $$ = nword($1, &@1);
620                 $$->u2.arglist = $3;
621                 prev_word=0; /* XXX sure ? */ }
622         ;
623
624 /* list of ';' separated context names followed by optional timespec */
625 includeslist : included_entry SEMI { $$ = $1; }
626         | includeslist included_entry SEMI { $$ = linku1($1, $2); }
627         | includeslist error {$$=$1;}
628         ;
629
630 includes : KW_INCLUDES LC includeslist RC {
631                 $$ = npval2(PV_INCLUDES, &@1, &@4);
632                 $$->u1.list = $3;set_dads($$,$3);}
633         | KW_INCLUDES LC RC {
634                 $$ = npval2(PV_INCLUDES, &@1, &@3);}
635         ;
636
637
638 %%
639
640 static char *token_equivs1[] =
641 {
642         "AMPER",
643         "AT",
644         "BAR",
645         "COLON",
646         "COMMA",
647         "EQ",
648         "EXTENMARK",
649         "KW_BREAK",
650         "KW_CASE",
651         "KW_CATCH",
652         "KW_CONTEXT",
653         "KW_CONTINUE",
654         "KW_DEFAULT",
655         "KW_ELSE",
656         "KW_ESWITCHES",
657         "KW_FOR",
658         "KW_GLOBALS",
659         "KW_GOTO",
660         "KW_HINT",
661         "KW_IFTIME",
662         "KW_IF",
663         "KW_IGNOREPAT",
664         "KW_INCLUDES"
665         "KW_JUMP",
666         "KW_MACRO",
667         "KW_PATTERN",
668         "KW_REGEXTEN",
669         "KW_RETURN",
670         "KW_SWITCHES",
671         "KW_SWITCH",
672         "KW_WHILE",
673         "LC",
674         "LP",
675         "RC",
676         "RP",
677         "SEMI",
678 };
679
680 static char *token_equivs2[] =
681 {
682         "&",
683         "@",
684         "|",
685         ":",
686         ",",
687         "=",
688         "=>",
689         "break",
690         "case",
691         "catch",
692         "context",
693         "continue",
694         "default",
695         "else",
696         "eswitches",
697         "for",
698         "globals",
699         "goto",
700         "hint",
701         "ifTime",
702         "if",
703         "ignorepat",
704         "includes"
705         "jump",
706         "macro",
707         "pattern",
708         "regexten",
709         "return",
710         "switches",
711         "switch",
712         "while",
713         "{",
714         "(",
715         "}",
716         ")",
717         ";",
718 };
719
720
721 static char *ael_token_subst(const char *mess)
722 {
723         /* calc a length, malloc, fill, and return; yyerror had better free it! */
724         int len=0,i;
725         const char *p;
726         char *res, *s,*t;
727         int token_equivs_entries = sizeof(token_equivs1)/sizeof(char*);
728
729         for (p=mess; *p; p++) {
730                 for (i=0; i<token_equivs_entries; i++) {
731                         if ( strncmp(p,token_equivs1[i],strlen(token_equivs1[i])) == 0 )
732                         {
733                                 len+=strlen(token_equivs2[i])+2;
734                                 p += strlen(token_equivs1[i])-1;
735                                 break;
736                         }
737                 }
738                 len++;
739         }
740         res = calloc(1, len+1);
741         res[0] = 0;
742         s = res;
743         for (p=mess; *p;) {
744                 int found = 0;
745                 for (i=0; i<token_equivs_entries; i++) {
746                         if ( strncmp(p,token_equivs1[i],strlen(token_equivs1[i])) == 0 ) {
747                                 *s++ = '\'';
748                                 for (t=token_equivs2[i]; *t;) {
749                                         *s++ = *t++;
750                                 }
751                                 *s++ = '\'';
752                                 p += strlen(token_equivs1[i]);
753                                 found = 1;
754                                 break;
755                         }
756                 }
757                 if( !found )
758                         *s++ = *p++;
759         }
760         *s++ = 0;
761         return res;
762 }
763
764 void yyerror(YYLTYPE *locp, struct parse_io *parseio,  char const *s)
765 {
766         char *s2 = ael_token_subst((char *)s);
767         if (locp->first_line == locp->last_line) {
768                 ast_log(LOG_ERROR, "==== File: %s, Line %d, Cols: %d-%d: Error: %s\n", my_file, locp->first_line, locp->first_column, locp->last_column, s2);
769         } else {
770                 ast_log(LOG_ERROR, "==== File: %s, Line %d Col %d  to Line %d Col %d: Error: %s\n", my_file, locp->first_line, locp->first_column, locp->last_line, locp->last_column, s2);
771         }
772         free(s2);
773         parseio->syntax_error_count++;
774 }
775
776 struct pval *npval(pvaltype type, int first_line, int last_line,
777         int first_column, int last_column)
778 {
779         pval *z = calloc(1, sizeof(struct pval));
780         z->type = type;
781         z->startline = first_line;
782         z->endline = last_line;
783         z->startcol = first_column;
784         z->endcol = last_column;
785         z->filename = strdup(my_file);
786         return z;
787 }
788
789 static struct pval *npval2(pvaltype type, YYLTYPE *first, YYLTYPE *last)
790 {
791         return npval(type, first->first_line, last->last_line,
792                         first->first_column, last->last_column);
793 }
794
795 static struct pval *update_last(pval *obj, YYLTYPE *last)
796 {
797         obj->endline = last->last_line;
798         obj->endcol = last->last_column;
799         return obj;
800 }
801
802 /* frontend for npval to create a PV_WORD string from the given token */
803 static pval *nword(char *string, YYLTYPE *pos)
804 {
805         pval *p = npval2(PV_WORD, pos, pos);
806         if (p)
807                 p->u1.str = string;
808         return p;
809 }
810
811 /* this routine adds a dad ptr to each element in the list */
812 static void set_dads(struct pval *dad, struct pval *child_list)
813 {
814         struct pval *t;
815         
816         for(t=child_list;t;t=t->next)  /* simple stuff */
817                 t->dad = dad;
818 }
819