configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # Make sure we use autoconf 2.60 to generate the "configure" script,
   4 # in case we want to commit it. Other than that, version 2.59 is
   5 # perfectly fine for our purposes, so people who want to modify
   6 # this file just have to remember to set the AC_PREREQ argument
   7 # to something that suits their needs.
   8
   9 AC_PREREQ(2.60)
  10
  11 m4_define([PBX_VERSION],
  12           m4_bpatsubst(m4_esyscmd([build_tools/make_version .]),
  13                        [\([0-9.]*\)\(\w\|\W\)*],
  14                        [\1]))
  15 AC_INIT(asterisk, PBX_VERSION, www.asterisk.org)
  16
  17 # cross-compile macros
  18 AC_CANONICAL_BUILD
  19 AC_CANONICAL_HOST
  20
  21 # check existence of the package
  22 AC_CONFIG_SRCDIR([main/asterisk.c])
  23
  24 # specify output header file
  25 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
  26
  27 AC_COPYRIGHT("Asterisk")
  28 AC_REVISION($Revision$)
  29
  30 AC_GNU_SOURCE
  31 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
  32
  33 case "${host_os}" in
  34      freebsd*)
  35      ac_default_prefix=/usr/local
  36      CPPFLAGS=-I/usr/local/include
  37      LDFLAGS=-L/usr/local/lib
  38      ;;
  39
  40      *)
  41      ac_default_prefix=/usr
  42      if test ${sysconfdir} = '${prefix}/etc'; then
  43         sysconfdir=/etc
  44      fi
  45      if test ${mandir} = '${prefix}/man'; then
  46         mandir=/usr/share/man
  47      fi
  48      ;;
  49 esac
  50
  51 if test ${localstatedir} = '${prefix}/var'; then
  52      localstatedir=/var
  53 fi
  54
  55 BUILD_PLATFORM=${build}
  56 BUILD_CPU=${build_cpu}
  57 BUILD_VENDOR=${build_vendor}
  58 BUILD_OS=${build_os}
  59
  60 AC_SUBST(BUILD_PLATFORM)
  61 AC_SUBST(BUILD_CPU)
  62 AC_SUBST(BUILD_VENDOR)
  63 AC_SUBST(BUILD_OS)
  64
  65 HOST_PLATFORM=${host}
  66 HOST_CPU=${host_cpu}
  67 HOST_VENDOR=${host_vendor}
  68 HOST_OS=${host_os}
  69
  70 AC_SUBST(HOST_PLATFORM)
  71 AC_SUBST(HOST_CPU)
  72 AC_SUBST(HOST_VENDOR)
  73 AC_SUBST(HOST_OS)
  74
  75 case "${host_os}" in
  76      freebsd*)
  77      OSARCH=FreeBSD
  78      ;;
  79      netbsd*)
  80      OSARCH=NetBSD
  81      ;;
  82      openbsd*)
  83      OSARCH=OpenBSD
  84      ;;
  85      solaris*)
  86      OSARCH=SunOS
  87      ;;
  88      *)
  89      OSARCH=${host_os}
  90      ;;
  91 esac
  92
  93 AC_SUBST(OSARCH)
  94
  95 #  check for uname
  96 AC_PATH_TOOL([UNAME], [uname], No)
  97 if test ! x"${UNAME}" = xNo; then
  98    PBX_OSREV=$(${UNAME} -r)
  99 fi
 100 AC_SUBST(PBX_OSREV)
 101
 102 AH_TOP(
 103 #ifndef ASTERISK_AUTOCONFIG_H
 104 #define ASTERISK_AUTOCONFIG_H
 105
 106 #include "asterisk/buildopts.h"
 107
 108 )
 109
 110 AH_BOTTOM(
 111 #endif
 112 )
 113
 114 # cross-compile checks
 115 if test "${cross_compiling}" = "yes";
 116 then
 117    AC_CHECK_TOOL(CC, gcc, :)
 118    AC_CHECK_TOOL(CXX, g++, :)
 119    AC_CHECK_TOOL(LD, ld, :)
 120    AC_CHECK_TOOL(RANLIB, ranlib, :)
 121 fi
 122
 123 # Checks for programs.
 124 AC_PROG_CC
 125 AC_PROG_CXX
 126 AC_PROG_CPP
 127 AC_PROG_CXXCPP
 128 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
 129 # the developers regenerating the configure script don't have to install libtool.
 130 AST_PROG_LD     # note, does not work on FreeBSD
 131 AC_PROG_AWK
 132 AC_PROG_INSTALL
 133 AC_PROG_LN_S
 134 AC_PROG_RANLIB
 135 AST_CHECK_GNU_MAKE
 136
 137 AC_PATH_TOOL([STRIP], [strip], :)
 138 AC_PATH_TOOL([AR], [ar], :)
 139
 140 GNU_LD=0
 141 if test "x$with_gnu_ld" = "xyes" ; then
 142    GNU_LD=1
 143 fi
 144 AC_SUBST(GNU_LD)
 145
 146 AC_PATH_PROG([GREP], [grep], :)
 147 AC_PATH_PROG([FIND], [find], :)
 148 AC_PATH_PROG([COMPRESS], [compress], :)
 149 AC_PATH_PROG([BASENAME], [basename], :)
 150 AC_PATH_PROG([ID], [id], :)
 151 AC_PATH_PROG([DIRNAME], [dirname], :)
 152 AC_PATH_PROG([SHELL], [sh], :)
 153 AC_PATH_PROG([LN], [ln], :)
 154 AC_PATH_PROG([DOT], [dot], :)
 155 AC_PATH_PROG([WGET], [wget], :)
 156 AC_PATH_PROG([RUBBER], [rubber], :)
 157 if test "${WGET}" != ":" ; then
 158   DOWNLOAD=${WGET}
 159 else
 160   AC_PATH_PROG([FETCH], [fetch], [:])
 161   DOWNLOAD=${FETCH}
 162 fi
 163 AC_SUBST(DOWNLOAD)
 164
 165 ACX_PTHREAD
 166
 167 AC_LANG(C)
 168
 169 AC_ARG_ENABLE(dev-mode,
 170         [  --enable-dev-mode    Turn on developer mode],
 171         [case "${enableval}" in
 172               y|ye|yes) AST_DEVMODE=yes ;;
 173               n|no)  AST_DEVMODE=no ;;
 174               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
 175         esac])
 176 AC_SUBST(AST_DEVMODE)
 177
 178 # package option names should be in alphabetical order
 179 # by the --with option name, to make things easier for the users :-)
 180
 181 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
 182
 183 # BKTR is used for backtrace support on platforms that do not
 184 # have it natively.
 185 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
 186 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
 187 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
 188 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
 189 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
 190 AST_EXT_LIB_SETUP([GSM], [GSM], [gsm], [, or 'internal'])
 191 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
 192 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
 193 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
 194 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
 195 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
 196 AST_EXT_LIB_SETUP([LUA], [Lua], [lua])
 197 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
 198 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
 199 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
 200 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
 201 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
 202 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
 203 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
 204 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
 205 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
 206 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
 207 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
 208 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
 209 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
 210 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
 211 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
 212 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
 213 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
 214 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
 215 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
 216 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
 217 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
 218 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
 219 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
 220 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
 221 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
 222 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
 223 AST_EXT_LIB_SETUP([USB], [usb], [usb])
 224 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
 225 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
 226 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
 227 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
 228 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
 229 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
 230
 231 AST_EXT_LIB_SETUP([SDL], [Sdl], [sdl])
 232 AST_EXT_LIB_SETUP([SDL_IMAGE], [Sdl Image library], [SDL_image])
 233 AST_EXT_LIB_SETUP([FFMPEG], [Ffmpeg and avcodec library], [avcodec])
 234
 235 # check for basic system features and functionality before
 236 # checking for package libraries
 237
 238 AC_FUNC_ALLOCA
 239 AC_HEADER_DIRENT
 240 AC_HEADER_STDC
 241 AC_HEADER_SYS_WAIT
 242 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
 243
 244 AC_CHECK_HEADERS([winsock.h winsock2.h])
 245
 246 AC_SYS_LARGEFILE
 247
 248 # Checks for typedefs, structures, and compiler characteristics.
 249 AC_HEADER_STDBOOL
 250 AC_C_CONST
 251 AC_TYPE_UID_T
 252 AC_C_INLINE
 253 AC_TYPE_MODE_T
 254 AC_TYPE_OFF_T
 255 AC_TYPE_PID_T
 256 AC_TYPE_SIZE_T
 257 AC_CHECK_MEMBERS([struct stat.st_blksize])
 258 AC_HEADER_TIME
 259 AC_STRUCT_TM
 260 AC_C_VOLATILE
 261 AC_CHECK_TYPES([ptrdiff_t])
 262
 263 # Checks for library functions.
 264 AC_FUNC_CHOWN
 265 AC_FUNC_CLOSEDIR_VOID
 266 AC_FUNC_ERROR_AT_LINE
 267 AST_FUNC_FORK
 268 AC_FUNC_FSEEKO
 269 AC_PROG_GCC_TRADITIONAL
 270 # XXX: these are commented out until we determine whether it matters if our malloc()
 271 # acts exactly like glibc's or not
 272 # AC_FUNC_MALLOC
 273 # AC_FUNC_REALLOC
 274 AC_FUNC_MEMCMP
 275 AC_FUNC_MKTIME
 276 AC_FUNC_MMAP
 277 AC_FUNC_SELECT_ARGTYPES
 278 AC_FUNC_SETVBUF_REVERSED
 279 AC_TYPE_SIGNAL
 280 AC_FUNC_STAT
 281 AC_FUNC_STRCOLL
 282 AC_FUNC_STRFTIME
 283 AC_FUNC_STRNLEN
 284 AC_FUNC_STRTOD
 285 AC_FUNC_UTIME_NULL
 286 AC_FUNC_VPRINTF
 287 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap putenv re_comp regcomp select setenv socket strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
 288
 289 AC_CHECK_FUNCS([glob])
 290
 291 AC_MSG_CHECKING(for timersub in time.h)
 292 AC_LINK_IFELSE(
 293         AC_LANG_PROGRAM([#include <sys/time.h>],
 294                 [struct timeval *a; timersub(a, a, a);]),
 295         AC_MSG_RESULT(yes)
 296                 AC_DEFINE([HAVE_TIMERSUB], 1, [Define to 1 if your system defines timersub.]),
 297         AC_MSG_RESULT(no)
 298 )
 299
 300 AC_CHECK_HEADER([sys/poll.h],
 301    [HAS_POLL=1]
 302    AC_DEFINE([HAVE_SYS_POLL_H], 1, [Define to 1 if your system has working sys/poll.h]),
 303    )
 304 AC_SUBST(HAS_POLL)
 305
 306 # https support (in main/http.c) uses funopen on BSD systems,
 307 # fopencookie on linux
 308 AC_CHECK_FUNCS([funopen fopencookie])
 309
 310 AC_CHECK_FUNCS([inet_aton])
 311
 312 # check if we have IP_PKTINFO constant defined
 313 AC_MSG_CHECKING(for IP_PKTINFO)
 314 AC_LINK_IFELSE(
 315                 AC_LANG_PROGRAM([#include <netinet/in.h>],
 316                                                 [int pi = IP_PKTINFO;]),
 317                 AC_MSG_RESULT(yes)
 318                 AC_DEFINE([HAVE_PKTINFO], 1, [Define to 1 if your system defines IP_PKTINFO.]),
 319                 AC_MSG_RESULT(no)
 320 )
 321
 322 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
 323 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
 324
 325 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
 326 AC_LINK_IFELSE(
 327         AC_LANG_PROGRAM([#include <stdlib.h>
 328                          #include <netdb.h>],
 329                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
 330         AC_MSG_RESULT(yes)
 331         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
 332         AC_MSG_RESULT(no)
 333 )
 334
 335 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
 336 AC_LINK_IFELSE(
 337         AC_LANG_PROGRAM([#include <stdlib.h>
 338                          #include <netdb.h>],
 339                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
 340         AC_MSG_RESULT(yes)
 341         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
 342         AC_MSG_RESULT(no)
 343 )
 344
 345 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
 346
 347 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
 348 AC_LINK_IFELSE(
 349 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
 350 AC_MSG_RESULT(yes)
 351 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
 352 AC_MSG_RESULT(no)
 353 )
 354
 355 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
 356 AC_LINK_IFELSE(
 357 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
 358 AC_MSG_RESULT(yes)
 359 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
 360 AC_MSG_RESULT(no)
 361 )
 362
 363 if test "${cross_compiling}" = "no";
 364 then
 365   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
 366 fi
 367
 368 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
 369 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
 370 AST_C_DEFINE_CHECK([PTHREAD_MUTEX_RECURSIVE_NP], [PTHREAD_MUTEX_RECURSIVE_NP], [pthread.h])
 371 AST_C_DEFINE_CHECK([PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [pthread.h])
 372
 373 if test "${cross_compiling}" = "no";
 374 then
 375 AC_MSG_CHECKING(for working epoll support)
 376 AC_LINK_IFELSE(
 377 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
 378                                           if (res < 0)
 379                                              return 1;
 380                                           close (res);
 381                                           return 0;]),
 382 AC_MSG_RESULT(yes)
 383 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
 384 AC_MSG_RESULT(no)
 385 )
 386 fi
 387
 388 AC_MSG_CHECKING(for compiler atomic operations)
 389 AC_LINK_IFELSE(
 390 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
 391 AC_MSG_RESULT(yes)
 392 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
 393 AC_MSG_RESULT(no)
 394 )
 395
 396 AST_GCC_ATTRIBUTE(pure)
 397 AST_GCC_ATTRIBUTE(malloc)
 398 AST_GCC_ATTRIBUTE(const)
 399 AST_GCC_ATTRIBUTE(unused)
 400 AST_GCC_ATTRIBUTE(always_inline)
 401 AST_GCC_ATTRIBUTE(deprecated)
 402
 403 AC_MSG_CHECKING(for -ffunction-sections support)
 404 saved_CFLAGS="${CFLAGS}"
 405 CFLAGS="${CFLAGS} -ffunction-sections"
 406 AC_COMPILE_IFELSE(
 407         AC_LANG_PROGRAM([], [int x = 1;]),
 408         AC_MSG_RESULT(yes)
 409         [saved_LDFLAGS="${LDFLAGS}"]
 410         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
 411         AC_MSG_CHECKING(for --gc-sections support)
 412         AC_LINK_IFELSE(
 413                 AC_LANG_PROGRAM([], [int x = 1;]),
 414                 AC_MSG_RESULT(yes)
 415                 [GC_CFLAGS="-ffunction-sections"]
 416                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
 417                 AC_MSG_RESULT(no)
 418         )
 419         [LDFLAGS="${saved_LDFLAGS}"],
 420         AC_MSG_RESULT(no)
 421 )
 422 CFLAGS="${saved_CFLAGS}"
 423 AC_SUBST(GC_CFLAGS)
 424 AC_SUBST(GC_LDFLAGS)
 425
 426 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
 427 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
 428         AC_MSG_RESULT(yes)
 429         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
 430 else
 431         AC_MSG_RESULT(no)
 432         AST_DECLARATION_AFTER_STATEMENT=
 433 fi
 434 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
 435
 436
 437 AC_MSG_CHECKING(for sysinfo)
 438 AC_LINK_IFELSE(
 439         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
 440                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
 441         AC_MSG_RESULT(yes)
 442         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
 443         AC_MSG_RESULT(no)
 444 )
 445
 446 AC_MSG_CHECKING(for res_ninit)
 447 AC_LINK_IFELSE(
 448         AC_LANG_PROGRAM([#include <resolv.h>],
 449                         [int foo = res_ninit(NULL);]),
 450         AC_MSG_RESULT(yes)
 451         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
 452         AC_MSG_CHECKING(for res_ndestroy)
 453         AC_LINK_IFELSE(
 454                 AC_LANG_PROGRAM([#include <resolv.h>],
 455                                 [int foo = res_ndestroy(NULL);]),
 456                 AC_MSG_RESULT(yes)
 457                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
 458                 AC_MSG_RESULT(no)
 459         ),
 460         AC_MSG_RESULT(no)
 461 )
 462
 463 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
 464
 465 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
 466
 467 AC_CHECK_HEADER([libkern/OSAtomic.h],
 468                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
 469
 470 AC_CHECK_SIZEOF(int)
 471
 472 # do the package library checks now
 473
 474 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
 475
 476 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
 477
 478 if test "x${host_os}" = "xlinux-gnu" ; then
 479   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
 480 fi
 481
 482 # BSD might not have exp2, and/or log2
 483 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
 484 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
 485 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
 486 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
 487 AST_EXT_LIB_CHECK([SINL], [m], [sinl])
 488 AST_EXT_LIB_CHECK([COSL], [m], [cosl])
 489 AST_EXT_LIB_CHECK([TANL], [m], [tanl])
 490 AST_EXT_LIB_CHECK([ASINL], [m], [asinl])
 491 AST_EXT_LIB_CHECK([ACOSL], [m], [acosl])
 492 AST_EXT_LIB_CHECK([ATANL], [m], [atanl])
 493 AST_EXT_LIB_CHECK([ATAN2L], [m], [atan2l])
 494 AST_EXT_LIB_CHECK([POWL], [m], [powl])
 495 AST_EXT_LIB_CHECK([SQRTL], [m], [sqrtl])
 496 AST_EXT_LIB_CHECK([RINTL], [m], [rintl])
 497 AST_EXT_LIB_CHECK([EXPL], [m], [expl])
 498 AST_EXT_LIB_CHECK([LOGL], [m], [logl])
 499 AST_EXT_LIB_CHECK([REMAINDERL], [m], [remainderl])
 500 AST_EXT_LIB_CHECK([FMODL], [m], [fmodl])
 501 AST_EXT_LIB_CHECK([ROUNDL], [m], [roundl])
 502 AST_EXT_LIB_CHECK([TRUNCL], [m], [truncl])
 503 AST_EXT_LIB_CHECK([STRTOLD], [c], [strtold], [stdlib.h])
 504 AST_EXT_LIB_CHECK([FLOORL], [m], [floorl])
 505 AST_EXT_LIB_CHECK([CEILL], [m], [ceill])
 506 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
 507 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
 508 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
 509 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
 510 AST_EXT_LIB_CHECK([SIN], [m], [sin])
 511 AST_EXT_LIB_CHECK([COS], [m], [cos])
 512 AST_EXT_LIB_CHECK([TAN], [m], [tan])
 513 AST_EXT_LIB_CHECK([ASIN], [m], [asin])
 514 AST_EXT_LIB_CHECK([ACOS], [m], [acos])
 515 AST_EXT_LIB_CHECK([ATAN], [m], [atan])
 516 AST_EXT_LIB_CHECK([ATAN2], [m], [atan2])
 517 AST_EXT_LIB_CHECK([POW], [m], [pow])
 518 AST_EXT_LIB_CHECK([SQRT], [m], [sqrt])
 519 AST_EXT_LIB_CHECK([RINT], [m], [rint])
 520 AST_EXT_LIB_CHECK([EXP], [m], [exp])
 521 AST_EXT_LIB_CHECK([LOG], [m], [log])
 522 AST_EXT_LIB_CHECK([REMAINDER], [m], [remainder])
 523 AST_EXT_LIB_CHECK([FMOD], [m], [fmod])
 524 AST_EXT_LIB_CHECK([ROUND], [m], [round])
 525 AST_EXT_LIB_CHECK([TRUNC], [m], [trunc])
 526 AST_EXT_LIB_CHECK([STRTOD], [c], [strtod], [stdlib.h])
 527 AST_EXT_LIB_CHECK([FLOOR], [m], [floor])
 528 AST_EXT_LIB_CHECK([CEIL], [m], [ceil])
 529
 530 GSM_INTERNAL="yes"
 531 AC_SUBST(GSM_INTERNAL)
 532 GSM_SYSTEM="yes"
 533 if test "${USE_GSM}" != "no"; then
 534    if test "${GSM_DIR}" = "internal"; then
 535       GSM_SYSTEM="no"
 536    elif test "${GSM_DIR}" != ""; then
 537       GSM_INTERNAL="no"
 538    fi
 539    if test "${GSM_SYSTEM}" = "yes"; then
 540       gsmlibdir=""
 541       if test "x${GSM_DIR}" != "x"; then
 542          if test -d ${GSM_DIR}/lib; then
 543             gsmlibdir="-L${GSM_DIR}/lib"
 544          else
 545             gsmlibdir="-L${GSM_DIR}"
 546          fi
 547       fi
 548       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
 549       [Define to indicate the GSM library]), [], ${gsmlibdir})
 550       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
 551          if test "x${GSM_DIR}" != "x" ; then
 552             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
 553             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
 554          else
 555             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
 556             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
 557          fi
 558          if test "${GSM_HEADER_FOUND}" = "0" ; then
 559             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
 560                if test "x${GSM_MANDATORY}" = "xyes" ; then
 561                   AC_MSG_NOTICE([***])
 562                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
 563                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
 564                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
 565                   exit 1
 566                fi
 567             fi
 568          fi
 569          GSM_OK=0
 570          if test "${GSM_HEADER_FOUND}" = "1" ; then
 571             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
 572             GSM_OK=1
 573          else
 574             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
 575                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
 576                GSM_OK=1
 577             fi
 578          fi
 579          if test "${GSM_OK}" = "1" ; then
 580             GSM_LIB="-lgsm"
 581             if test "x${GSM_DIR}" != "x"; then
 582                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
 583                GSM_INCLUDE="-I${GSM_DIR}/include"
 584             fi
 585             PBX_GSM=1
 586             GSM_INTERNAL="no"
 587          fi
 588       fi
 589    fi
 590    if test "${GSM_INTERNAL}" = "yes"; then
 591       PBX_GSM=1
 592       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
 593    fi
 594 fi
 595
 596 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
 597
 598 if test "${USE_IMAP_TK}" != "no"; then
 599    if test "${IMAP_TK_DIR}" = "system" ; then
 600       AC_MSG_NOTICE([Checking for system c-client library...])
 601    elif test "${IMAP_TK_DIR}" = ""; then
 602       IMAP_TK_DIR=`pwd`"/../imap-2004g"
 603       if test  -n "${IMAP_TK_MANDATORY}"; then
 604          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
 605          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
 606          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
 607          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
 608       fi
 609    fi
 610    if test "${IMAP_TK_DIR}" != "system" ; then
 611       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
 612    fi
 613    saved_cppflags="${CPPFLAGS}"
 614    saved_libs="${LIBS}"
 615    if test "${IMAP_TK_DIR}" = "system" ; then
 616       imap_ldflags=""
 617       imap_libs="-lc-client"
 618       imap_include="-DUSE_SYSTEM_IMAP"
 619    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
 620       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
 621       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
 622       imap_include="-I${IMAP_TK_DIR}/c-client"
 623    fi
 624    CPPFLAGS="${CPPFLAGS} ${imap_include}"
 625    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
 626    AC_LINK_IFELSE(
 627         AC_LANG_PROGRAM(
 628                 [#ifdef USE_SYSTEM_IMAP
 629                 #include <imap/c-client.h>
 630                 #else
 631                 #include "c-client.h"
 632                 #endif
 633                 void mm_searched (MAILSTREAM *stream,unsigned long number)
 634                 {
 635                 }
 636                 void mm_exists (MAILSTREAM *stream,unsigned long number)
 637                 {
 638                 }
 639                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
 640                 {
 641                 }
 642                 void mm_flags (MAILSTREAM *stream,unsigned long number)
 643                 {
 644                 }
 645                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
 646                 {
 647                 }
 648                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
 649                 {
 650                 }
 651                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
 652                 {
 653                 }
 654                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
 655                 {
 656                 }
 657                 void mm_log (char *string,long errflg)
 658                 {
 659                 }
 660                 void mm_dlog (char *string)
 661                 {
 662                 }
 663                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
 664                 {
 665                 }
 666                 void mm_critical (MAILSTREAM *stream)
 667                 {
 668                 }
 669                 void mm_nocritical (MAILSTREAM *stream)
 670                 {
 671                 }
 672                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
 673                 {
 674                 }
 675                 void mm_fatal (char *string)
 676                 {
 677                 }],
 678                 [
 679                 MAILSTREAM *foo = mail_open(NULL, "", 0);
 680                 ]
 681         ),
 682         [ac_cv_imap_tk="yes"],
 683         [ac_cv_imap_tk="no"]
 684    )
 685    if test "${ac_cv_imap_tk}" = "yes"; then
 686    AC_LINK_IFELSE(
 687       AC_LANG_PROGRAM(
 688          [#ifdef USE_SYSTEM_IMAP
 689          #include <imap/c-client.h>
 690          #else
 691          #include "c-client.h"
 692          #endif
 693          void mm_searched (MAILSTREAM *stream,unsigned long number)
 694          {
 695          }
 696          void mm_exists (MAILSTREAM *stream,unsigned long number)
 697          {
 698          }
 699          void mm_expunged (MAILSTREAM *stream,unsigned long number)
 700          {
 701          }
 702          void mm_flags (MAILSTREAM *stream,unsigned long number)
 703          {
 704          }
 705          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
 706          {
 707          }
 708          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
 709          {
 710          }
 711          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
 712          {
 713          }
 714          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
 715          {
 716          }
 717          void mm_log (char *string,long errflg)
 718          {
 719          }
 720          void mm_dlog (char *string)
 721          {
 722          }
 723          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
 724          {
 725          }
 726          void mm_critical (MAILSTREAM *stream)
 727          {
 728          }
 729          void mm_nocritical (MAILSTREAM *stream)
 730          {
 731          }
 732          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
 733          {
 734          }
 735          void mm_fatal (char *string)
 736          {
 737          }],
 738          [
 739          long check = mail_expunge_full(NULL, "", 0);
 740          ]
 741       ),
 742       [ac_cv_imap_tk2006="yes"],
 743       [ac_cv_imap_tk2006="no"]
 744   )
 745   fi
 746    CPPFLAGS="${saved_cppflags}"
 747    LIBS="${saved_libs}"
 748    if test "${ac_cv_imap_tk}" = "yes"; then
 749       AC_MSG_RESULT(yes)
 750       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
 751       IMAP_TK_INCLUDE="${imap_include}"
 752       PBX_IMAP_TK=1
 753       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
 754       if test "${ac_cv_imap_tk2006}" = "yes"; then
 755          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
 756       fi
 757    else
 758       AC_MSG_RESULT(no)
 759    fi
 760 fi
 761
 762 # Needed by unixodbc
 763 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
 764
 765 AC_LANG_PUSH(C++)
 766
 767 if test "${USE_KDE}" != "no"; then
 768    AC_MSG_CHECKING(for crashHandler in -lkdecore)
 769    saved_libs="${LIBS}"
 770    saved_cppflags="${CPPFLAGS}"
 771    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
 772    if test -d ${KDE_DIR}/lib; then
 773       kdelibdir="${KDE_DIR}/lib"
 774    else
 775       kdelibdir="${KDE_DIR}"
 776    fi
 777    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
 778
 779    AC_LINK_IFELSE(
 780         [AC_LANG_PROGRAM(
 781                         [#include "kcrash.h"],
 782                         [KCrash::defaultCrashHandler(1);])
 783         ],
 784         [ac_cv_lib_kde_crash="yes"],
 785         [ac_cv_lib_kde_crash="no"])
 786
 787    LIBS="${saved_libs}"
 788    CPPFLAGS="${saved_cppflags}"
 789
 790    if test "${ac_cv_lib_kde_crash}" = "yes"; then
 791       AC_MSG_RESULT(yes)
 792       KDE_LIB="-lkdecore -lkdeui"
 793       if test "${KDE_DIR}" != ""; then
 794          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
 795          KDE_INCLUDE="-I${KDE_DIR}/include"
 796       fi
 797       PBX_KDE=1
 798       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
 799    else
 800       AC_MSG_RESULT(no)
 801    fi
 802 fi
 803 if test "${PBX_KDE}" = 1; then
 804    AC_PATH_TOOL(KDEINIT, kdeinit, No)
 805    if test ! x"${KDEINIT}" = xNo; then
 806       KDEDIR=$(${DIRNAME} ${KDEINIT})
 807       KDEDIR=$(${DIRNAME} ${KDEDIR})
 808    fi
 809    AC_SUBST([KDEDIR])
 810 fi
 811
 812 AC_LANG_POP
 813
 814 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
 815
 816 if test "${PBX_MISDN}" = 1; then
 817    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
 818    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
 819    AST_C_DEFINE_CHECK([MISDN_FAC_RESULT], [Fac_RESULT], [mISDNuser/suppserv.h])
 820    AST_C_DEFINE_CHECK([MISDN_FAC_ERROR], [Fac_ERROR], [mISDNuser/suppserv.h])
 821    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
 822 fi
 823
 824 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
 825
 826 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
 827
 828 NETSNMP_CONFIG=No
 829 if test "${USE_NETSNMP}" != "no"; then
 830    if test "x${NETSNMP_DIR}" != "x"; then
 831       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
 832       if test x"${NETSNMP_CONFIG}" = xNo; then
 833          AC_MSG_NOTICE([***])
 834          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
 835          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
 836          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
 837          AC_MSG_NOTICE([*** including --without-netsnmp])
 838          exit 1
 839       fi
 840    else
 841       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
 842    fi
 843 fi
 844 if test x"${NETSNMP_CONFIG}" != xNo; then
 845    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
 846
 847    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
 848    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
 849
 850    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
 851       NETSNMP_LIB="${NETSNMP_libs}"
 852       PBX_NETSNMP=1
 853    fi
 854 fi
 855
 856 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
 857
 858 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
 859
 860 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
 861
 862 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h], [-lexecinfo])
 863
 864 # possible places for oss definitions
 865 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
 866 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
 867 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
 868
 869 PG_CONFIG=No
 870 if test "${USE_PGSQL}" != "no"; then
 871    if test "x${PGSQL_DIR}" != "x"; then
 872       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
 873       if test x"${PG_CONFIG}" = xNo; then
 874          AC_MSG_NOTICE([***])
 875          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
 876          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
 877          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
 878          AC_MSG_NOTICE([*** including --without-postgres])
 879          exit 1
 880       fi
 881    else
 882       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
 883    fi
 884 fi
 885 if test "${PG_CONFIG}" != No; then
 886    PGSQL_libdir=`${PG_CONFIG} --libdir`
 887    PGSQL_includedir=`${PG_CONFIG} --includedir`
 888    if test "x$?" != "x0" ; then
 889       if test -n "${PGSQL_MANDATORY}" ; then
 890          AC_MSG_NOTICE([***])
 891          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
 892          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
 893          AC_MSG_NOTICE([*** including --without-postgres])
 894          exit 1
 895           fi
 896    else
 897       AC_CHECK_LIB([pq], [PQexec], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
 898       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
 899
 900       if test "${ac_cv_lib_pq_PQexec}" = "yes"; then
 901          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
 902          PGSQL_INCLUDE="-I${PGSQL_includedir}"
 903          PBX_PGSQL=1
 904       elif test -n "${PGSQL_MANDATORY}";
 905       then
 906          AC_MSG_NOTICE([***])
 907          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
 908          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
 909          AC_MSG_NOTICE([*** including --without-postgres])
 910          exit 1
 911       fi
 912    fi
 913 fi
 914
 915 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
 916
 917 AST_EXT_LIB_CHECK([PRI], [pri], [pri_keypad_facility], [libpri.h])
 918
 919 AST_EXT_LIB_CHECK([SS7], [ss7], [isup_cqr], [libss7.h])
 920
 921 if test "${USE_PWLIB}" != "no"; then
 922         if test -n "${PWLIB_DIR}"; then
 923                 PWLIBDIR="${PWLIB_DIR}"
 924         fi
 925         AST_CHECK_PWLIB()
 926         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
 927
 928         if test "${HAS_PWLIB:-unset}" != "unset"; then
 929                 AST_CHECK_OPENH323_PLATFORM()
 930
 931                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
 932
 933                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
 934                         [Define if your system has the PWLib libraries.],
 935                         [#include "ptlib.h"],
 936                         [BOOL q = PTime::IsDaylightSavings();])
 937         fi
 938 fi
 939
 940 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
 941         if test -n "${OPENH323_DIR}"; then
 942                 OPENH323DIR="${OPENH323_DIR}"
 943         fi
 944         AST_CHECK_OPENH323()
 945         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
 946         AST_CHECK_OPENH323_BUILD()
 947         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
 948         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
 949                 [Define if your system has the OpenH323 libraries.],
 950                 [#include "ptlib.h"
 951                 #include "h323.h"
 952                 #include "h323ep.h"],
 953                 [H323EndPoint ep = H323EndPoint();],
 954                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
 955 fi
 956
 957 AC_LANG_PUSH(C++)
 958
 959 if test "${USE_QT}" != "no"; then
 960    AC_MSG_CHECKING(for QDate in -lqt)
 961    saved_libs="${LIBS}"
 962    saved_cppflags="${CPPFLAGS}"
 963    if test "x${QT_DIR}" != "x"; then
 964       LIBS="${LIBS} -L${QT_DIR}/lib"
 965       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
 966    fi
 967    LIBS="${LIBS} -lqt"
 968    qtlib="qt"
 969    AC_LINK_IFELSE(
 970         [
 971                 AC_LANG_PROGRAM(
 972                 [#include <qt3/qdatetime.h>],
 973                 [QDate date();])
 974         ],
 975         [ac_cv_lib_qt_qt_date="yes"],
 976         [ac_cv_lib_qt_qt_date="no"])
 977    LIBS="${saved_libs}"
 978    CPPFLAGS="${saved_cppflags}"
 979
 980    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
 981       saved_libs="${LIBS}"
 982       saved_cppflags="${CPPFLAGS}"
 983       if test "x${QT_DIR}" != "x"; then
 984          LIBS="${LIBS} -L${QT_DIR}/lib"
 985          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
 986       fi
 987       LIBS="${LIBS} -lqt-mt"
 988       qtlib="qt-mt"
 989       AC_LINK_IFELSE(
 990                 [
 991                         AC_LANG_PROGRAM(
 992                         [#include <qt3/qdatetime.h>],
 993                         [QDate date();])
 994                 ],
 995                 [ac_cv_lib_qt_qt_date="yes"],
 996                 [ac_cv_lib_qt_qt_date="no"])
 997       LIBS="${saved_libs}"
 998       CPPFLAGS="${saved_cppflags}"
 999    fi
1000
1001    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
1002       AC_MSG_RESULT(yes)
1003    else
1004       AC_MSG_RESULT(no)
1005    fi
1006
1007    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
1008       QT_LIB="-l${qtlib}"
1009       if test "${QT_DIR}" != ""; then
1010          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
1011          QT_INCLUDE="-I${QT_DIR}/include"
1012       fi
1013       PBX_QT=1
1014       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
1015       AC_PATH_TOOL(QTMOC, moc, No)
1016    fi
1017 fi
1018
1019 AC_LANG_POP
1020
1021 LUA_INCLUDE="-I/usr/include/lua5.1"
1022 LUA_LIB="-llua5.1"
1023 AST_EXT_LIB_CHECK([LUA], [lua5.1], [luaL_newstate], [lua5.1/lua.h])
1024
1025 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
1026
1027 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
1028
1029 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
1030
1031 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
1032
1033 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
1034
1035 if test "$PBX_CRYPTO" = "1";
1036 then
1037     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
1038 fi
1039
1040 if test "$PBX_OPENSSL" = "1";
1041 then
1042     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
1043 fi
1044
1045 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
1046 if test "${PBX_FREETDS}" != "0";
1047 then
1048     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
1049         *0.64*)
1050                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
1051         ;;
1052     *0.63*)
1053         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
1054         ;;
1055     *0.62*)
1056         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
1057         ;;
1058     *)
1059         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
1060         ;;
1061     esac
1062 fi
1063
1064 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
1065
1066 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
1067
1068 if test "${host_os}" != "linux-gnu" ; then
1069   tonezone_extra="-lm"
1070 fi
1071
1072 # new tonezone, version 1.4.0
1073 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [140])
1074 # other case, old tonezone (0.80)
1075 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [80])
1076
1077 AST_EXT_LIB_CHECK([USB], [usb], [usb_init], [usb.h], [])
1078
1079 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1080
1081 AC_LANG_PUSH(C++)
1082
1083 if test "${USE_VPB}" != "no"; then
1084    AC_MSG_CHECKING(for vpb_open in -lvpb)
1085    saved_libs="${LIBS}"
1086    saved_cppflags="${CPPFLAGS}"
1087    if test "x${VPB_DIR}" != "x"; then
1088       if test -d ${VPB_DIR}/lib; then
1089          vpblibdir=${VPB_DIR}/lib
1090       else
1091          vpblibdir=${VPB_DIR}
1092       fi
1093       LIBS="${LIBS} -L${vpblibdir}"
1094       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1095    fi
1096    LIBS="${LIBS} -lvpb -lpthread"
1097    AC_LINK_IFELSE(
1098         [
1099         AC_LANG_PROGRAM(
1100         [#include <vpbapi.h>],
1101         [int q = vpb_open(0,0);])
1102         ],
1103         [       AC_MSG_RESULT(yes)
1104                 ac_cv_lib_vpb_vpb_open="yes"
1105         ],
1106         [       AC_MSG_RESULT(no)
1107                 ac_cv_lib_vpb_vpb_open="no"
1108         ]
1109         )
1110    LIBS="${saved_libs}"
1111    CPPFLAGS="${saved_cppflags}"
1112    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1113         VPB_LIB="-lvpb"
1114         if test "${VPB_DIR}" != ""; then
1115            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1116            VPB_INCLUDE="-I${VPB_DIR}/include"
1117         fi
1118         PBX_VPB=1
1119         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1120    fi
1121 fi
1122
1123 AC_LANG_POP
1124
1125 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1126
1127 # Check for various zaptel features and locations.
1128 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1129 # will be used in the system headers to determine the location
1130 # of the zaptel.h header.
1131
1132 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1133 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1134
1135 # Check for VLDTMF support
1136 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1137
1138 # Check for transcode support
1139 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1140
1141 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1142 case "${host_os}" in
1143     freebsd*)
1144         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],, [80])
1145         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],, [90])
1146         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],, [80])
1147
1148         # other case, old tonezone (0.80)
1149         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}], [80])
1150         ;;
1151 esac
1152
1153 EDITLINE_LIB=""
1154 if test "x$TERMCAP_LIB" != "x" ; then
1155   EDITLINE_LIB="$TERMCAP_LIB"
1156 elif test "x$TINFO_LIB" != "x" ; then
1157   EDITLINE_LIB="$TINFO_LIB"
1158 elif test "x$CURSES_LIB" != "x" ; then
1159   EDITLINE_LIB="$CURSES_LIB"
1160 elif test "x$NCURSES_LIB" != "x" ; then
1161   EDITLINE_LIB="$NCURSES_LIB"
1162 else
1163   AC_MSG_ERROR(*** termcap support not found)
1164 fi
1165 AC_SUBST(EDITLINE_LIB)
1166
1167 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1168 AC_SUBST(PBX_H323)
1169
1170 AC_CHECK_HEADER([linux/compiler.h],
1171                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1172
1173 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1174                                    #include <linux/version.h>
1175                                    #ifdef HAVE_LINUX_COMPILER_H
1176                                    #include <linux/compiler.h>
1177                                    #endif
1178                                    ])
1179 AC_SUBST(PBX_IXJUSER)
1180
1181 AST_EXT_TOOL_CHECK([SDL], [sdl])
1182 AST_EXT_LIB_CHECK([SDL_IMAGE], [SDL_image], [IMG_Load], [SDL/SDL_image.h], [${SDL_LIB}])
1183 AST_EXT_LIB_CHECK([FFMPEG], [avcodec], [sws_getContext], [ffmpeg/avcodec.h], [-lpthread -lz -lm])
1184
1185 PBX_GTK=0
1186 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1187 if test ! "x${GTKCONFIG}" = xNo; then
1188    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1189    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1190    PBX_GTK=1
1191    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1192 fi
1193 AC_SUBST(PBX_GTK)
1194 AC_SUBST(GTK_INCLUDE)
1195 AC_SUBST(GTK_LIB)
1196
1197 PBX_GTK2=0
1198 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1199 if test ! "x${PKGCONFIG}" = xNo; then
1200    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1201    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1202    PBX_GTK2=1
1203    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1204 fi
1205 AC_SUBST(PBX_GTK2)
1206 AC_SUBST(GTK2_INCLUDE)
1207 AC_SUBST(GTK2_LIB)
1208
1209 if test "${USE_CURL}" != "no"; then
1210    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1211    if test ! x"${CURL_CONFIG}" = xNo; then
1212    # check for version
1213       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1214          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1215          CURL_LIB=$(${CURL_CONFIG} --libs)
1216
1217          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1218          saved_cppflags="${CPPFLAGS}"
1219          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1220          AC_COMPILE_IFELSE(
1221             [AC_LANG_PROGRAM(
1222                 [#include <curl/curl.h>],
1223                     [curl_version();])
1224             ],[
1225                 AC_MSG_RESULT(yes)
1226                 ac_cv_curl_h="yes"
1227             ],[
1228                 AC_MSG_RESULT(no)
1229                 ac_cv_curl_h="no"
1230             ]
1231          )
1232          CPPFLAGS="${saved_cppflags}"
1233          if test "${ac_cv_curl_h}" = "yes"; then
1234              PBX_CURL=1
1235              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1236          fi
1237       fi
1238    fi
1239 fi
1240
1241 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1242 AST_CHECK_MANDATORY
1243
1244 AC_OUTPUT
1245
1246 if test "x${silent}" != "xyes" ; then
1247 echo
1248 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1249 echo "            .\$7\$7..          .7\$\$7:.    "
1250 echo "          .\$\$:.                 ,\$7.7   "
1251 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1252 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1253 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1254 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1255 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1256 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1257 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1258 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1259 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1260 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1261 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1262 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1263 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1264 echo " \$\$\$\$\$                        \$\$\$       "
1265 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1266 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1267 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1268 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1269 echo
1270 fi
1271
1272 AC_MSG_NOTICE(Package configured for: )
1273 AC_MSG_NOTICE( OS type  : $host_os)
1274 AC_MSG_NOTICE( Host CPU : $host_cpu)
1275 AC_MSG_NOTICE( build-cpu:vendor:os: $build_cpu : $build_vendor : $build_os :)
1276 AC_MSG_NOTICE( host-cpu:vendor:os: $host_cpu : $host_vendor : $host_os :)
1277 if test "${cross_compiling}" = "yes"; then
1278    AC_MSG_NOTICE( Cross Compilation = YES)
1279 fi