8b41545b4a91a0c2508994bff4514d964481247e
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.60)
10
11 AC_INIT(asterisk, 1.4, www.asterisk.org)
12
13 # cross-compile macros
14 AC_CANONICAL_BUILD
15 AC_CANONICAL_HOST
16
17 # check existence of the package
18 AC_CONFIG_SRCDIR([main/asterisk.c])
19
20 # specify output header file
21 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
22
23 AC_COPYRIGHT("Asterisk")
24 AC_REVISION($Revision$)
25
26 AC_GNU_SOURCE
27 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
28
29 case "${host_os}" in
30      freebsd*)
31      ac_default_prefix=/usr/local
32      CPPFLAGS=-I/usr/local/include
33      LDFLAGS=-L/usr/local/lib
34      ;;
35
36      *)
37      ac_default_prefix=/usr
38      if test ${sysconfdir} = '${prefix}/etc'; then
39         sysconfdir=/etc
40      fi
41      if test ${mandir} = '${prefix}/man'; then
42         mandir=/usr/share/man
43      fi
44      ;;
45 esac
46
47 if test ${localstatedir} = '${prefix}/var'; then
48      localstatedir=/var
49 fi
50
51 BUILD_PLATFORM=${build}
52 BUILD_CPU=${build_cpu}
53 BUILD_VENDOR=${build_vendor}
54 BUILD_OS=${build_os}
55
56 AC_SUBST(BUILD_PLATFORM)
57 AC_SUBST(BUILD_CPU)
58 AC_SUBST(BUILD_VENDOR)
59 AC_SUBST(BUILD_OS)
60
61 HOST_PLATFORM=${host}
62 HOST_CPU=${host_cpu}
63 HOST_VENDOR=${host_vendor}
64 HOST_OS=${host_os}
65
66 AC_SUBST(HOST_PLATFORM)
67 AC_SUBST(HOST_CPU)
68 AC_SUBST(HOST_VENDOR)
69 AC_SUBST(HOST_OS)
70
71 WINARCH=0
72
73 case "${host_os}" in
74      freebsd*)
75      OSARCH=FreeBSD
76      ;;
77      netbsd*)
78      OSARCH=NetBSD
79      ;;
80      openbsd*)
81      OSARCH=OpenBSD
82      ;;
83      solaris*)
84      OSARCH=SunOS
85      ;;
86      mingw32)
87      OSARCH=mingw32
88      WINARCH=1
89      ;;
90      cygwin)
91      OSARCH=cygwin
92      WINARCH=1
93      ;;
94      *)
95      OSARCH=${host_os}
96      ;;
97 esac
98
99 AC_SUBST(OSARCH)
100 AC_SUBST(WINARCH)
101
102 #  check for uname
103 AC_PATH_TOOL([UNAME], [uname], No)
104 if test ! x"${UNAME}" = xNo; then
105    PBX_OSREV=$(${UNAME} -r)
106 fi
107 AC_SUBST(PBX_OSREV)
108
109 AH_TOP(
110 #ifndef ASTERISK_AUTOCONFIG_H
111 #define ASTERISK_AUTOCONFIG_H
112
113 #include "asterisk/buildopts.h"
114
115 )
116
117 AH_BOTTOM(
118 #endif
119 )
120
121 # cross-compile checks
122 if test "${cross_compiling}" = "yes"; 
123 then
124    AC_CHECK_TOOL(CC, gcc, :)
125    AC_CHECK_TOOL(CXX, g++, :)
126    AC_CHECK_TOOL(LD, ld, :)
127    AC_CHECK_TOOL(RANLIB, ranlib, :)
128 fi
129
130 # Checks for programs.
131 AC_PROG_CC
132 AC_PROG_CXX
133 AC_PROG_CPP
134 AC_PROG_CXXCPP
135 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
136 # the developers regenerating the configure script don't have to install libtool.
137 AST_PROG_LD     # note, does not work on FreeBSD
138 AC_PROG_AWK
139 AC_PROG_INSTALL
140 AC_PROG_LN_S
141 AC_PROG_RANLIB
142 AST_CHECK_GNU_MAKE
143
144 AC_PATH_TOOL([STRIP], [strip], :)
145 AC_PATH_TOOL([AR], [ar], :)
146
147 GNU_LD=0
148 if test "x$with_gnu_ld" = "xyes" ; then
149    GNU_LD=1
150 fi
151 AC_SUBST(GNU_LD)
152
153 AC_PATH_PROG([AWK], [awk], :)
154 AC_PATH_PROG([GREP], [grep], :)
155 AC_PATH_PROG([FIND], [find], :)
156 AC_PATH_PROG([COMPRESS], [compress], :)
157 AC_PATH_PROG([BASENAME], [basename], :)
158 AC_PATH_PROG([ID], [id], :)
159 AC_PATH_PROG([DIRNAME], [dirname], :)
160 AC_PATH_PROG([SHELL], [sh], :)
161 AC_PATH_PROG([LN], [ln], :)
162 AC_PATH_PROG([DOT], [dot], :)
163 AC_PATH_PROG([WGET], [wget], :)
164 AC_PATH_PROG([RUBBER], [rubber], :)
165 if test "${WGET}" != ":" ; then
166   DOWNLOAD=${WGET}
167 else
168   AC_PATH_PROG([FETCH], [fetch], [:])
169   DOWNLOAD=${FETCH}
170 fi
171 AC_SUBST(DOWNLOAD)
172
173 ACX_PTHREAD
174
175 AC_LANG(C)
176
177 AC_ARG_ENABLE(dev-mode,
178         [  --enable-dev-mode    Turn on developer mode],
179         [case "${enableval}" in
180               y|ye|yes) AST_DEVMODE=yes ;;
181               n|no)  AST_DEVMODE=no ;;
182               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
183         esac])
184 AC_SUBST(AST_DEVMODE)
185
186 # package option names should be in alphabetical order
187 # by the --with option name (the third field),
188 # to make things easier for the users.
189
190 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
191
192 # BKTR is used for backtrace support on platforms that do not
193 # have it natively.
194 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
195 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
196 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
197 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
198 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
199 AST_EXT_LIB_SETUP([GSM], [External GSM library], [gsm], [, use 'internal' GSM otherwise])
200 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
201 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
202 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
203 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
204 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
205 AST_EXT_LIB_SETUP([LUA], [Lua], [lua])
206 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
207 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
208 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
209 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
210 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
211 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
212 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
213 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
214 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
215 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
216 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
217 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
218 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
219 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
220 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
221 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
222 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
223 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
224 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
225 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
226 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
227 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
228 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
229 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
230 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
231 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
232 AST_EXT_LIB_SETUP([USB], [usb], [usb])
233 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
234 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
235 AST_EXT_LIB_SETUP([X11], [X11 support], [x11])
236 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
237 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
238 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
239 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
240
241 AST_EXT_LIB_SETUP([SDL], [Sdl], [sdl])
242 AST_EXT_LIB_SETUP([SDL_IMAGE], [Sdl Image library], [SDL_image])
243 AST_EXT_LIB_SETUP([FFMPEG], [Ffmpeg and avcodec library], [avcodec])
244
245 # check for basic system features and functionality before
246 # checking for package libraries
247
248 AC_FUNC_ALLOCA
249 AC_HEADER_DIRENT
250 AC_HEADER_STDC
251 AC_HEADER_SYS_WAIT
252 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
253
254 AC_CHECK_HEADERS([winsock.h winsock2.h])
255
256 AC_SYS_LARGEFILE
257
258 # Checks for typedefs, structures, and compiler characteristics.
259 AC_HEADER_STDBOOL
260 AC_C_CONST
261 AC_TYPE_UID_T
262 AC_C_INLINE
263 AC_TYPE_MODE_T
264 AC_TYPE_OFF_T
265 AC_TYPE_PID_T
266 AC_TYPE_SIZE_T
267 AC_CHECK_MEMBERS([struct stat.st_blksize])
268 AC_HEADER_TIME
269 AC_STRUCT_TM
270 AC_C_VOLATILE
271 AC_CHECK_TYPES([ptrdiff_t])
272
273 # Checks for library functions.
274 AC_FUNC_CHOWN
275 AC_FUNC_CLOSEDIR_VOID
276 AC_FUNC_ERROR_AT_LINE
277 AST_FUNC_FORK
278 AC_FUNC_FSEEKO
279 AC_PROG_GCC_TRADITIONAL
280 # XXX: these are commented out until we determine whether it matters if our malloc()
281 # acts exactly like glibc's or not
282 # AC_FUNC_MALLOC
283 # AC_FUNC_REALLOC
284 AC_FUNC_MEMCMP
285 AC_FUNC_MKTIME
286 AC_FUNC_MMAP
287 AC_FUNC_SELECT_ARGTYPES
288 AC_FUNC_SETVBUF_REVERSED
289 AC_TYPE_SIGNAL
290 AC_FUNC_STAT
291 AC_FUNC_STRCOLL
292 AC_FUNC_STRFTIME
293 AC_FUNC_STRNLEN
294 AC_FUNC_STRTOD
295 AC_FUNC_UTIME_NULL
296 AC_FUNC_VPRINTF
297 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap putenv re_comp regcomp select setenv socket strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
298
299 AC_CHECK_FUNCS([glob])
300
301 AC_MSG_CHECKING(for timersub in time.h)
302 AC_LINK_IFELSE(
303         AC_LANG_PROGRAM([#include <sys/time.h>],
304                 [struct timeval *a; timersub(a, a, a);]),
305         AC_MSG_RESULT(yes)
306                 AC_DEFINE([HAVE_TIMERSUB], 1, [Define to 1 if your system defines timersub.]),
307         AC_MSG_RESULT(no)
308 )
309
310 AC_CHECK_HEADER([sys/poll.h], 
311    [HAS_POLL=1]
312    AC_DEFINE([HAVE_SYS_POLL_H], 1, [Define to 1 if your system has working sys/poll.h]),
313    )
314 AC_SUBST(HAS_POLL)
315
316 # https support (in main/http.c) uses funopen on BSD systems,
317 # fopencookie on linux
318 AC_CHECK_FUNCS([funopen fopencookie])
319
320 AC_CHECK_FUNCS([inet_aton])
321
322 # check if we have IP_PKTINFO constant defined
323 AC_MSG_CHECKING(for IP_PKTINFO)
324 AC_LINK_IFELSE(
325                 AC_LANG_PROGRAM([#include <netinet/in.h>],
326                                                 [int pi = IP_PKTINFO;]),
327                 AC_MSG_RESULT(yes)
328                 AC_DEFINE([HAVE_PKTINFO], 1, [Define to 1 if your system defines IP_PKTINFO.]),
329                 AC_MSG_RESULT(no)
330 )
331
332 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
333 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
334
335 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
336 AC_LINK_IFELSE(
337         AC_LANG_PROGRAM([#include <stdlib.h>
338                          #include <netdb.h>],
339                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
340         AC_MSG_RESULT(yes)
341         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
342         AC_MSG_RESULT(no)
343 )
344
345 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
346 AC_LINK_IFELSE(
347         AC_LANG_PROGRAM([#include <stdlib.h>
348                          #include <netdb.h>],
349                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
350         AC_MSG_RESULT(yes)
351         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
352         AC_MSG_RESULT(no)
353 )
354
355 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
356
357 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
358 AC_LINK_IFELSE(
359 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
360 AC_MSG_RESULT(yes)
361 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
362 AC_MSG_RESULT(no)
363 )
364
365 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
366 AC_LINK_IFELSE(
367 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
368 AC_MSG_RESULT(yes)
369 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
370 AC_MSG_RESULT(no)
371 )
372
373 if test "${cross_compiling}" = "no";
374 then
375   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
376 fi
377
378 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
379 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
380 AST_C_DEFINE_CHECK([PTHREAD_MUTEX_RECURSIVE_NP], [PTHREAD_MUTEX_RECURSIVE_NP], [pthread.h])
381 AST_C_DEFINE_CHECK([PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [pthread.h])
382
383 if test "${cross_compiling}" = "no";
384 then
385 AC_MSG_CHECKING(for working epoll support)
386 AC_LINK_IFELSE(
387 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
388                                           if (res < 0)
389                                              return 1;
390                                           close (res);
391                                           return 0;]),
392 AC_MSG_RESULT(yes)
393 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
394 AC_MSG_RESULT(no)
395 )
396 fi
397
398 AC_MSG_CHECKING(for compiler atomic operations)
399 AC_LINK_IFELSE(
400 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
401 AC_MSG_RESULT(yes)
402 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
403 AC_MSG_RESULT(no)
404 )
405
406 AST_GCC_ATTRIBUTE(pure)
407 AST_GCC_ATTRIBUTE(malloc)
408 AST_GCC_ATTRIBUTE(const)
409 AST_GCC_ATTRIBUTE(unused)
410 AST_GCC_ATTRIBUTE(always_inline)
411 AST_GCC_ATTRIBUTE(deprecated)
412
413 AC_MSG_CHECKING(for -ffunction-sections support)
414 saved_CFLAGS="${CFLAGS}"
415 CFLAGS="${CFLAGS} -ffunction-sections"
416 AC_COMPILE_IFELSE(
417         AC_LANG_PROGRAM([], [int x = 1;]),
418         AC_MSG_RESULT(yes)
419         [saved_LDFLAGS="${LDFLAGS}"]
420         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
421         AC_MSG_CHECKING(for --gc-sections support)
422         AC_LINK_IFELSE(
423                 AC_LANG_PROGRAM([], [int x = 1;]),
424                 AC_MSG_RESULT(yes)
425                 [GC_CFLAGS="-ffunction-sections"]
426                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
427                 AC_MSG_RESULT(no)
428         )
429         [LDFLAGS="${saved_LDFLAGS}"],
430         AC_MSG_RESULT(no)
431 )
432 CFLAGS="${saved_CFLAGS}"
433 AC_SUBST(GC_CFLAGS)
434 AC_SUBST(GC_LDFLAGS)
435
436 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
437 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
438         AC_MSG_RESULT(yes)
439         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
440 else
441         AC_MSG_RESULT(no)
442         AST_DECLARATION_AFTER_STATEMENT=
443 fi
444 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
445
446
447 AC_MSG_CHECKING(for sysinfo)
448 AC_LINK_IFELSE(
449         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
450                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
451         AC_MSG_RESULT(yes)
452         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
453         AC_MSG_RESULT(no)
454 )
455
456 AC_MSG_CHECKING(for res_ninit)
457 AC_LINK_IFELSE(
458         AC_LANG_PROGRAM([#include <resolv.h>],
459                         [int foo = res_ninit(NULL);]),
460         AC_MSG_RESULT(yes)
461         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
462         AC_MSG_CHECKING(for res_ndestroy)
463         AC_LINK_IFELSE(
464                 AC_LANG_PROGRAM([#include <resolv.h>],
465                                 [int foo = res_ndestroy(NULL);]),
466                 AC_MSG_RESULT(yes)
467                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
468                 AC_MSG_RESULT(no)
469         ),
470         AC_MSG_RESULT(no)
471 )
472
473 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
474
475 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
476
477 AC_CHECK_HEADER([libkern/OSAtomic.h],
478                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
479
480 AC_CHECK_SIZEOF(int)
481
482 # do the package library checks now
483
484 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
485
486 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
487
488 if test "x${host_os}" = "xlinux-gnu" ; then
489   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
490 fi
491
492 # BSD might not have exp2, and/or log2
493 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
494 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
495 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
496 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
497 AST_EXT_LIB_CHECK([SINL], [m], [sinl])
498 AST_EXT_LIB_CHECK([COSL], [m], [cosl])
499 AST_EXT_LIB_CHECK([TANL], [m], [tanl])
500 AST_EXT_LIB_CHECK([ASINL], [m], [asinl])
501 AST_EXT_LIB_CHECK([ACOSL], [m], [acosl])
502 AST_EXT_LIB_CHECK([ATANL], [m], [atanl])
503 AST_EXT_LIB_CHECK([ATAN2L], [m], [atan2l])
504 AST_EXT_LIB_CHECK([POWL], [m], [powl])
505 AST_EXT_LIB_CHECK([SQRTL], [m], [sqrtl])
506 AST_EXT_LIB_CHECK([RINTL], [m], [rintl])
507 AST_EXT_LIB_CHECK([EXPL], [m], [expl])
508 AST_EXT_LIB_CHECK([LOGL], [m], [logl])
509 AST_EXT_LIB_CHECK([REMAINDERL], [m], [remainderl])
510 AST_EXT_LIB_CHECK([FMODL], [m], [fmodl])
511 AST_EXT_LIB_CHECK([ROUNDL], [m], [roundl])
512 AST_EXT_LIB_CHECK([TRUNCL], [m], [truncl])
513 AST_EXT_LIB_CHECK([STRTOLD], [c], [strtold], [stdlib.h])
514 AST_EXT_LIB_CHECK([FLOORL], [m], [floorl])
515 AST_EXT_LIB_CHECK([CEILL], [m], [ceill])
516 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
517 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
518 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
519 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
520 AST_EXT_LIB_CHECK([SIN], [m], [sin])
521 AST_EXT_LIB_CHECK([COS], [m], [cos])
522 AST_EXT_LIB_CHECK([TAN], [m], [tan])
523 AST_EXT_LIB_CHECK([ASIN], [m], [asin])
524 AST_EXT_LIB_CHECK([ACOS], [m], [acos])
525 AST_EXT_LIB_CHECK([ATAN], [m], [atan])
526 AST_EXT_LIB_CHECK([ATAN2], [m], [atan2])
527 AST_EXT_LIB_CHECK([POW], [m], [pow])
528 AST_EXT_LIB_CHECK([SQRT], [m], [sqrt])
529 AST_EXT_LIB_CHECK([RINT], [m], [rint])
530 AST_EXT_LIB_CHECK([EXP], [m], [exp])
531 AST_EXT_LIB_CHECK([LOG], [m], [log])
532 AST_EXT_LIB_CHECK([REMAINDER], [m], [remainder])
533 AST_EXT_LIB_CHECK([FMOD], [m], [fmod])
534 AST_EXT_LIB_CHECK([ROUND], [m], [round])
535 AST_EXT_LIB_CHECK([TRUNC], [m], [trunc])
536 AST_EXT_LIB_CHECK([STRTOD], [c], [strtod], [stdlib.h])
537 AST_EXT_LIB_CHECK([FLOOR], [m], [floor])
538 AST_EXT_LIB_CHECK([CEIL], [m], [ceil])
539
540 GSM_INTERNAL="yes"
541 AC_SUBST(GSM_INTERNAL)
542 GSM_SYSTEM="yes"
543 if test "${USE_GSM}" != "no"; then
544    if test "${GSM_DIR}" = "internal"; then
545       GSM_SYSTEM="no"
546    elif test "${GSM_DIR}" != ""; then
547       GSM_INTERNAL="no"
548    fi
549    if test "${GSM_SYSTEM}" = "yes"; then
550       gsmlibdir=""
551       if test "x${GSM_DIR}" != "x"; then
552          if test -d ${GSM_DIR}/lib; then
553             gsmlibdir="-L${GSM_DIR}/lib"
554          else
555             gsmlibdir="-L${GSM_DIR}"
556          fi
557       fi
558       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
559       [Define to indicate the GSM library]), [], ${gsmlibdir})
560       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
561          if test "x${GSM_DIR}" != "x" ; then
562             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
563             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
564          else
565             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
566             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
567          fi
568          if test "${GSM_HEADER_FOUND}" = "0" ; then
569             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
570                if test "x${GSM_MANDATORY}" = "xyes" ; then
571                   AC_MSG_NOTICE([***])
572                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
573                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
574                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
575                   exit 1
576                fi
577             fi
578          fi
579          GSM_OK=0
580          if test "${GSM_HEADER_FOUND}" = "1" ; then
581             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
582             GSM_OK=1
583          else
584             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
585                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
586                GSM_OK=1
587             fi
588          fi
589          if test "${GSM_OK}" = "1" ; then
590             GSM_LIB="-lgsm"
591             if test "x${GSM_DIR}" != "x"; then
592                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
593                GSM_INCLUDE="-I${GSM_DIR}/include"
594             fi
595             PBX_GSM=1
596             GSM_INTERNAL="no"
597          fi
598       fi
599    fi
600    if test "${GSM_INTERNAL}" = "yes"; then
601       PBX_GSM=1
602       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
603    fi
604 fi
605
606 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
607
608 if test "${USE_IMAP_TK}" != "no"; then
609    if test "${IMAP_TK_DIR}" = "system" ; then
610       AC_MSG_NOTICE([Checking for system c-client library...])
611    elif test "${IMAP_TK_DIR}" = ""; then
612       IMAP_TK_DIR=`pwd`"/../imap-2004g"
613       if test  -n "${IMAP_TK_MANDATORY}"; then
614          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
615          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
616          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
617          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
618       fi
619    fi
620    if test "${IMAP_TK_DIR}" != "system" ; then
621       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
622    fi
623    saved_cppflags="${CPPFLAGS}"
624    saved_libs="${LIBS}"
625    if test "${IMAP_TK_DIR}" = "system" ; then
626       imap_ldflags=""
627       imap_libs="-lc-client"
628       imap_include="-DUSE_SYSTEM_IMAP"
629    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
630       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
631       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
632       imap_include="-I${IMAP_TK_DIR}/c-client"
633    fi
634    CPPFLAGS="${CPPFLAGS} ${imap_include}"
635    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
636    AC_LINK_IFELSE(
637         AC_LANG_PROGRAM(
638                 [#ifdef USE_SYSTEM_IMAP
639                 #include <imap/c-client.h>
640                 #else
641                 #include "c-client.h"
642                 #endif
643                 void mm_searched (MAILSTREAM *stream,unsigned long number)
644                 {
645                 }
646                 void mm_exists (MAILSTREAM *stream,unsigned long number)
647                 {
648                 }
649                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
650                 {
651                 }
652                 void mm_flags (MAILSTREAM *stream,unsigned long number)
653                 {
654                 }
655                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
656                 {
657                 }
658                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
659                 {
660                 }
661                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
662                 {
663                 }
664                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
665                 {
666                 }
667                 void mm_log (char *string,long errflg)
668                 {
669                 }
670                 void mm_dlog (char *string)
671                 {
672                 }
673                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
674                 {
675                 }
676                 void mm_critical (MAILSTREAM *stream)
677                 {
678                 }
679                 void mm_nocritical (MAILSTREAM *stream)
680                 {
681                 }
682                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
683                 {
684                 }
685                 void mm_fatal (char *string)
686                 {
687                 }],
688                 [
689                 MAILSTREAM *foo = mail_open(NULL, "", 0);
690                 ]
691         ),
692         [ac_cv_imap_tk="yes"],
693         [ac_cv_imap_tk="no"]
694    )
695    if test "${ac_cv_imap_tk}" = "yes"; then
696    AC_LINK_IFELSE(
697       AC_LANG_PROGRAM(
698          [#ifdef USE_SYSTEM_IMAP
699          #include <imap/c-client.h>
700          #else
701          #include "c-client.h"
702          #endif
703          void mm_searched (MAILSTREAM *stream,unsigned long number)
704          {
705          }
706          void mm_exists (MAILSTREAM *stream,unsigned long number)
707          {
708          }
709          void mm_expunged (MAILSTREAM *stream,unsigned long number)
710          {
711          }
712          void mm_flags (MAILSTREAM *stream,unsigned long number)
713          {
714          }
715          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
716          {
717          }
718          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
719          {
720          }
721          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
722          {
723          }
724          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
725          {
726          }
727          void mm_log (char *string,long errflg)
728          {
729          }
730          void mm_dlog (char *string)
731          {
732          }
733          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
734          {
735          }
736          void mm_critical (MAILSTREAM *stream)
737          {
738          }
739          void mm_nocritical (MAILSTREAM *stream)
740          {
741          }
742          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
743          {
744          }
745          void mm_fatal (char *string)
746          {
747          }],
748          [
749          long check = mail_expunge_full(NULL, "", 0);
750          ]
751       ),
752       [ac_cv_imap_tk2006="yes"],
753       [ac_cv_imap_tk2006="no"]
754   )
755   fi
756    CPPFLAGS="${saved_cppflags}"
757    LIBS="${saved_libs}"
758    if test "${ac_cv_imap_tk}" = "yes"; then
759       AC_MSG_RESULT(yes) 
760       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
761       IMAP_TK_INCLUDE="${imap_include}"
762       PBX_IMAP_TK=1
763       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
764       if test "${ac_cv_imap_tk2006}" = "yes"; then
765          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
766       fi
767    else
768       AC_MSG_RESULT(no) 
769    fi
770 fi
771
772 # Needed by unixodbc
773 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
774
775 AC_LANG_PUSH(C++)
776
777 if test "${USE_KDE}" != "no"; then
778    AC_MSG_CHECKING(for crashHandler in -lkdecore)
779    saved_libs="${LIBS}"
780    saved_cppflags="${CPPFLAGS}"
781    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
782    if test -d ${KDE_DIR}/lib; then
783       kdelibdir="${KDE_DIR}/lib"
784    else
785       kdelibdir="${KDE_DIR}"
786    fi
787    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
788
789    AC_LINK_IFELSE(
790         [AC_LANG_PROGRAM(
791                         [#include "kcrash.h"],
792                         [KCrash::defaultCrashHandler(1);])
793         ],
794         [ac_cv_lib_kde_crash="yes"],
795         [ac_cv_lib_kde_crash="no"])
796                 
797    LIBS="${saved_libs}"
798    CPPFLAGS="${saved_cppflags}"
799         
800    if test "${ac_cv_lib_kde_crash}" = "yes"; then
801       AC_MSG_RESULT(yes) 
802       KDE_LIB="-lkdecore -lkdeui"
803       if test "${KDE_DIR}" != ""; then
804          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
805          KDE_INCLUDE="-I${KDE_DIR}/include"
806       fi
807       PBX_KDE=1
808       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
809    else
810       AC_MSG_RESULT(no) 
811    fi
812 fi
813 if test "${PBX_KDE}" = 1; then
814    AC_PATH_TOOL(KDEINIT, kdeinit, No)
815    if test ! x"${KDEINIT}" = xNo; then
816       KDEDIR=$(${DIRNAME} ${KDEINIT})
817       KDEDIR=$(${DIRNAME} ${KDEDIR})
818    fi
819    AC_SUBST([KDEDIR])
820 fi
821
822 AC_LANG_POP
823
824 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
825
826 if test "${PBX_MISDN}" = 1; then
827    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
828    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
829    AST_C_DEFINE_CHECK([MISDN_FAC_RESULT], [Fac_RESULT], [mISDNuser/suppserv.h])
830    AST_C_DEFINE_CHECK([MISDN_FAC_ERROR], [Fac_ERROR], [mISDNuser/suppserv.h])
831    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
832 fi
833
834 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
835
836 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
837
838 NETSNMP_CONFIG=No
839 if test "${USE_NETSNMP}" != "no"; then  
840    if test "x${NETSNMP_DIR}" != "x"; then
841       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No, [${NETSNMP_DIR}/bin])
842       if test x"${NETSNMP_CONFIG}" = xNo; then
843          AC_MSG_NOTICE([***])
844          AC_MSG_NOTICE([*** net-snmp-config was not found in the path you specified:])
845          AC_MSG_NOTICE([*** ${NETSNMP_DIR}/bin])
846          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
847          AC_MSG_NOTICE([*** including --without-netsnmp])
848          exit 1
849       fi
850    else
851       AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], No)
852    fi
853 fi
854 if test x"${NETSNMP_CONFIG}" != xNo; then
855    NETSNMP_libs=`${NETSNMP_CONFIG} --agent-libs`
856    
857    AC_CHECK_LIB([netsnmp], [snmp_register_callback], AC_DEFINE_UNQUOTED([HAVE_NETSNMP], 1,
858    [Define to indicate the Net-SNMP library]), [], ${NETSNMP_libs})
859
860    if test "${ac_cv_lib_netsnmp_snmp_register_callback}" = "yes"; then
861       NETSNMP_LIB="${NETSNMP_libs}"
862       PBX_NETSNMP=1
863    fi
864 fi
865
866 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
867
868 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
869
870 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
871
872 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h])
873
874 # possible places for oss definitions
875 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
876 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
877 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
878
879 PG_CONFIG=No
880 if test "${USE_PGSQL}" != "no"; then    
881    if test "x${PGSQL_DIR}" != "x"; then
882       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
883       if test x"${PG_CONFIG}" = xNo; then
884          AC_MSG_NOTICE([***])
885          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
886          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
887          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
888          AC_MSG_NOTICE([*** including --without-postgres])
889          exit 1
890       fi
891    else
892       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
893    fi
894 fi
895 if test "${PG_CONFIG}" != No; then
896    PGSQL_libdir=`${PG_CONFIG} --libdir`
897    PGSQL_includedir=`${PG_CONFIG} --includedir`
898    if test "x$?" != "x0" ; then
899       if test -n "${PGSQL_MANDATORY}" ; then
900          AC_MSG_NOTICE([***])
901          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
902          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
903          AC_MSG_NOTICE([*** including --without-postgres])
904          exit 1
905           fi
906    else 
907       AC_CHECK_LIB([pq], [PQescapeStringConn], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
908       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
909
910       if test "${ac_cv_lib_pq_PQescapeStringConn}" = "yes"; then
911          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
912          PGSQL_INCLUDE="-I${PGSQL_includedir}"
913          PBX_PGSQL=1
914       elif test -n "${PGSQL_MANDATORY}";
915       then
916          AC_MSG_NOTICE([***])
917          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
918          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
919          AC_MSG_NOTICE([*** including --without-postgres])
920          exit 1
921       fi
922    fi
923 fi
924
925 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
926
927 AST_EXT_LIB_CHECK([PRI], [pri], [pri_new_bri], [libpri.h])
928
929 AST_EXT_LIB_CHECK([SS7], [ss7], [isup_cqr], [libss7.h])
930
931 if test "${USE_PWLIB}" != "no"; then
932         if test -n "${PWLIB_DIR}"; then
933                 PWLIBDIR="${PWLIB_DIR}"
934         fi
935         AST_CHECK_PWLIB()
936         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
937                 
938         if test "${HAS_PWLIB:-unset}" != "unset"; then
939                 AST_CHECK_OPENH323_PLATFORM()
940
941                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
942
943                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
944                         [Define if your system has the PWLib libraries.],
945                         [#include "ptlib.h"],
946                         [BOOL q = PTime::IsDaylightSavings();])
947         fi
948 fi
949
950 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
951         if test -n "${OPENH323_DIR}"; then
952                 OPENH323DIR="${OPENH323_DIR}"
953         fi
954         AST_CHECK_OPENH323()
955         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
956         AST_CHECK_OPENH323_BUILD()
957         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
958         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
959                 [Define if your system has the OpenH323 libraries.],
960                 [#include "ptlib.h"
961                 #include "h323.h"
962                 #include "h323ep.h"],
963                 [H323EndPoint ep = H323EndPoint();],
964                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
965 fi
966
967 AC_LANG_PUSH(C++)
968
969 if test "${USE_QT}" != "no"; then
970    AC_MSG_CHECKING(for QDate in -lqt)
971    saved_libs="${LIBS}"
972    saved_cppflags="${CPPFLAGS}"
973    if test "x${QT_DIR}" != "x"; then
974       LIBS="${LIBS} -L${QT_DIR}/lib"
975       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
976    fi
977    LIBS="${LIBS} -lqt"
978    qtlib="qt"
979    AC_LINK_IFELSE(
980         [
981                 AC_LANG_PROGRAM(
982                 [#include <qt3/qdatetime.h>],
983                 [QDate date();])
984         ],
985         [ac_cv_lib_qt_qt_date="yes"],
986         [ac_cv_lib_qt_qt_date="no"])
987    LIBS="${saved_libs}"
988    CPPFLAGS="${saved_cppflags}"
989         
990    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
991       saved_libs="${LIBS}"
992       saved_cppflags="${CPPFLAGS}"
993       if test "x${QT_DIR}" != "x"; then
994          LIBS="${LIBS} -L${QT_DIR}/lib"
995          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
996       fi
997       LIBS="${LIBS} -lqt-mt"
998       qtlib="qt-mt"     
999       AC_LINK_IFELSE(
1000                 [
1001                         AC_LANG_PROGRAM(
1002                         [#include <qt3/qdatetime.h>],
1003                         [QDate date();])
1004                 ],
1005                 [ac_cv_lib_qt_qt_date="yes"],
1006                 [ac_cv_lib_qt_qt_date="no"])
1007       LIBS="${saved_libs}"
1008       CPPFLAGS="${saved_cppflags}"
1009    fi   
1010
1011    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
1012       AC_MSG_RESULT(yes) 
1013    else
1014       AC_MSG_RESULT(no) 
1015    fi
1016         
1017    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
1018       QT_LIB="-l${qtlib}"
1019       if test "${QT_DIR}" != ""; then
1020          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
1021          QT_INCLUDE="-I${QT_DIR}/include"
1022       fi
1023       PBX_QT=1
1024       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
1025       AC_PATH_TOOL(QTMOC, moc, No)
1026    fi
1027 fi
1028
1029 AC_LANG_POP
1030
1031 LUA_INCLUDE="-I/usr/include/lua5.1"
1032 LUA_LIB="-llua5.1"
1033 AST_EXT_LIB_CHECK([LUA], [lua5.1], [luaL_newstate], [lua5.1/lua.h]) 
1034
1035 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
1036
1037 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
1038
1039 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
1040
1041 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
1042
1043 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
1044
1045 if test "$PBX_CRYPTO" = "1";
1046 then
1047     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
1048 fi
1049
1050 if test "$PBX_OPENSSL" = "1";
1051 then
1052     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
1053 fi
1054
1055 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
1056 if test "${PBX_FREETDS}" != "0";
1057 then
1058     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
1059         *0.64*)
1060                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
1061         ;;
1062     *0.63*)
1063         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
1064         ;;
1065     *0.62*)
1066         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
1067         ;;
1068     *)
1069         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
1070         ;;
1071     esac
1072 fi
1073
1074 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
1075
1076 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
1077
1078 if test "${host_os}" != "linux-gnu" ; then
1079   tonezone_extra="-lm"
1080 fi
1081
1082 # new tonezone, version 1.4.0
1083 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [], [140])
1084 # other case, old tonezone (0.80)
1085 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [], [80])
1086
1087 AST_EXT_LIB_CHECK([USB], [usb], [usb_init], [usb.h], [])
1088
1089 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1090
1091 AC_LANG_PUSH(C++)
1092
1093 if test "${USE_VPB}" != "no"; then
1094    AC_MSG_CHECKING(for vpb_open in -lvpb)
1095    saved_libs="${LIBS}"
1096    saved_cppflags="${CPPFLAGS}"
1097    if test "x${VPB_DIR}" != "x"; then
1098       if test -d ${VPB_DIR}/lib; then
1099          vpblibdir=${VPB_DIR}/lib
1100       else
1101          vpblibdir=${VPB_DIR}
1102       fi
1103       LIBS="${LIBS} -L${vpblibdir}"
1104       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1105    fi
1106    LIBS="${LIBS} -lvpb -lpthread"
1107    AC_LINK_IFELSE(
1108         [
1109         AC_LANG_PROGRAM(
1110         [#include <vpbapi.h>],
1111         [int q = vpb_open(0,0);])
1112         ],
1113         [       AC_MSG_RESULT(yes) 
1114                 ac_cv_lib_vpb_vpb_open="yes" 
1115         ],
1116         [       AC_MSG_RESULT(no) 
1117                 ac_cv_lib_vpb_vpb_open="no" 
1118         ]
1119         )
1120    LIBS="${saved_libs}"
1121    CPPFLAGS="${saved_cppflags}"
1122    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1123         VPB_LIB="-lvpb"
1124         if test "${VPB_DIR}" != ""; then
1125            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1126            VPB_INCLUDE="-I${VPB_DIR}/include"
1127         fi
1128         PBX_VPB=1
1129         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1130    fi
1131 fi
1132
1133 AC_LANG_POP
1134
1135 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1136
1137 # Check for various zaptel features and locations.
1138 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1139 # will be used in the system headers to determine the location
1140 # of the zaptel.h header.
1141
1142 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1143 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1144
1145 # Check for VLDTMF support
1146 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1147
1148 # Check for transcode support
1149 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1150
1151 # Check for Zaptel hwgain support
1152 AST_C_DEFINE_CHECK([ZAPTEL_HWGAIN], [ZT_SET_HWGAIN], [zaptel/zaptel.h])
1153
1154 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1155 case "${host_os}" in
1156     freebsd*)
1157         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],,, [80])
1158         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],,, [90])
1159         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],,, [80])
1160
1161         # other case, old tonezone (0.80)
1162         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}],, [80])
1163         ;;
1164 esac
1165
1166 EDITLINE_LIB=""
1167 if test "x$TERMCAP_LIB" != "x" ; then
1168   EDITLINE_LIB="$TERMCAP_LIB"
1169 elif test "x$TINFO_LIB" != "x" ; then
1170   EDITLINE_LIB="$TINFO_LIB"
1171 elif test "x$CURSES_LIB" != "x" ; then
1172   EDITLINE_LIB="$CURSES_LIB"
1173 elif test "x$NCURSES_LIB" != "x" ; then
1174   EDITLINE_LIB="$NCURSES_LIB"
1175 else
1176   AC_MSG_ERROR(*** termcap support not found)
1177 fi
1178 AC_SUBST(EDITLINE_LIB)
1179
1180 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1181 AC_SUBST(PBX_H323)
1182
1183 AC_CHECK_HEADER([linux/compiler.h],
1184                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1185
1186 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1187                                    #include <linux/version.h>
1188                                    #ifdef HAVE_LINUX_COMPILER_H
1189                                    #include <linux/compiler.h>
1190                                    #endif
1191                                    ])
1192 AC_SUBST(PBX_IXJUSER)
1193
1194 AST_EXT_TOOL_CHECK([SDL], [sdl])
1195 AST_EXT_LIB_CHECK([SDL_IMAGE], [SDL_image], [IMG_Load], [SDL_image.h], [${SDL_LIB}], [${SDL_INCLUDE}])
1196 AST_EXT_LIB_CHECK([FFMPEG], [avcodec], [sws_getContext], [ffmpeg/avcodec.h], [-lpthread -lz -lm])
1197
1198 # possible places for video4linux version 1
1199 AC_CHECK_HEADER([linux/videodev.h],
1200         [AC_DEFINE_UNQUOTED([HAVE_VIDEODEV_H], 1, [Define to 1 if your system has linux/videodev.h.])])
1201
1202 # possible places for X11
1203 AST_EXT_LIB_CHECK([X11], [X11], [XOpenDisplay], [X11/Xlib.h],,, [standard_path])
1204 AST_EXT_LIB_CHECK([X11], [X11], [XOpenDisplay], [X11/Xlib.h],, [-I/usr/X11R6/include], [X11R6])
1205
1206 PBX_GTK=0
1207 AC_CHECK_TOOL(GTKCONFIG, gtk-config, No)
1208 if test ! "x${GTKCONFIG}" = xNo; then
1209    GTK_INCLUDE=$(${GTKCONFIG} --cflags gthread)
1210    GTK_LIB=$(${GTKCONFIG} --libs gthread)
1211    PBX_GTK=1
1212    AC_DEFINE([HAVE_GTK], 1, [Define if your system has the GTK libraries.])
1213 fi
1214 AC_SUBST(PBX_GTK)
1215 AC_SUBST(GTK_INCLUDE)
1216 AC_SUBST(GTK_LIB)
1217
1218 PBX_GTK2=0
1219 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1220 if test ! "x${PKGCONFIG}" = xNo; then
1221    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1222    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1223    PBX_GTK2=1
1224    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1225 fi
1226 AC_SUBST(PBX_GTK2)
1227 AC_SUBST(GTK2_INCLUDE)
1228 AC_SUBST(GTK2_LIB)
1229
1230 if test "${USE_CURL}" != "no"; then
1231    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1232    if test ! x"${CURL_CONFIG}" = xNo; then
1233    # check for version
1234       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1235          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1236          CURL_LIB=$(${CURL_CONFIG} --libs)
1237
1238          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1239          saved_cppflags="${CPPFLAGS}"
1240          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1241          AC_COMPILE_IFELSE(
1242             [AC_LANG_PROGRAM(
1243                 [#include <curl/curl.h>],
1244                     [curl_version();])
1245             ],[
1246                 AC_MSG_RESULT(yes)
1247                 ac_cv_curl_h="yes"
1248             ],[
1249                 AC_MSG_RESULT(no)
1250                 ac_cv_curl_h="no"
1251             ]
1252          )
1253          CPPFLAGS="${saved_cppflags}"
1254          if test "${ac_cv_curl_h}" = "yes"; then
1255              PBX_CURL=1
1256              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1257          fi
1258       fi
1259    fi
1260 fi
1261
1262 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1263 AST_CHECK_MANDATORY
1264
1265 AC_OUTPUT
1266
1267 if test "x${silent}" != "xyes" ; then
1268 echo
1269 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1270 echo "            .\$7\$7..          .7\$\$7:.    "
1271 echo "          .\$\$:.                 ,\$7.7   "
1272 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1273 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1274 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1275 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1276 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1277 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1278 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1279 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1280 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1281 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1282 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1283 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1284 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1285 echo " \$\$\$\$\$                        \$\$\$       "
1286 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1287 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1288 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1289 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1290 echo
1291 fi
1292
1293 AC_MSG_NOTICE(Package configured for: )
1294 AC_MSG_NOTICE( OS type  : $host_os)
1295 AC_MSG_NOTICE( Host CPU : $host_cpu)
1296 AC_MSG_NOTICE( build-cpu:vendor:os: $build_cpu : $build_vendor : $build_os :) 
1297 AC_MSG_NOTICE( host-cpu:vendor:os: $host_cpu : $host_vendor : $host_os :) 
1298 if test "${cross_compiling}" = "yes"; then
1299    AC_MSG_NOTICE( Cross Compilation = YES)
1300 fi