go back to including libresample in the main Asterisk binary, but this time including...
[asterisk/asterisk.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # Make sure we use autoconf 2.60 to generate the "configure" script,
4 # in case we want to commit it. Other than that, version 2.59 is
5 # perfectly fine for our purposes, so people who want to modify
6 # this file just have to remember to set the AC_PREREQ argument
7 # to something that suits their needs.
8
9 AC_PREREQ(2.60)
10
11 AC_INIT(asterisk, 1.4, www.asterisk.org)
12
13 # cross-compile macros
14 AC_CANONICAL_BUILD
15 AC_CANONICAL_HOST
16
17 # check existence of the package
18 AC_CONFIG_SRCDIR([main/asterisk.c])
19
20 # specify output header file
21 AC_CONFIG_HEADER(include/asterisk/autoconfig.h)
22
23 AC_COPYRIGHT("Asterisk")
24 AC_REVISION($Revision$)
25
26 AC_GNU_SOURCE
27 AC_USE_SYSTEM_EXTENSIONS        # note- does not work on FreeBSD
28
29 case "${host_os}" in
30      freebsd*)
31      ac_default_prefix=/usr/local
32      CPPFLAGS=-I/usr/local/include
33      LDFLAGS=-L/usr/local/lib
34      ;;
35
36      *)
37      ac_default_prefix=/usr
38      if test ${sysconfdir} = '${prefix}/etc'; then
39         sysconfdir=/etc
40      fi
41      if test ${mandir} = '${prefix}/man'; then
42         mandir=/usr/share/man
43      fi
44      ;;
45 esac
46
47 if test ${localstatedir} = '${prefix}/var'; then
48      localstatedir=/var
49 fi
50
51 BUILD_PLATFORM=${build}
52 BUILD_CPU=${build_cpu}
53 BUILD_VENDOR=${build_vendor}
54 BUILD_OS=${build_os}
55
56 AC_SUBST(BUILD_PLATFORM)
57 AC_SUBST(BUILD_CPU)
58 AC_SUBST(BUILD_VENDOR)
59 AC_SUBST(BUILD_OS)
60
61 HOST_PLATFORM=${host}
62 HOST_CPU=${host_cpu}
63 HOST_VENDOR=${host_vendor}
64 HOST_OS=${host_os}
65
66 AC_SUBST(HOST_PLATFORM)
67 AC_SUBST(HOST_CPU)
68 AC_SUBST(HOST_VENDOR)
69 AC_SUBST(HOST_OS)
70
71 WINARCH=0
72
73 case "${host_os}" in
74      freebsd*)
75      OSARCH=FreeBSD
76      ;;
77      netbsd*)
78      OSARCH=NetBSD
79      ;;
80      openbsd*)
81      OSARCH=OpenBSD
82      ;;
83      solaris*)
84      OSARCH=SunOS
85      ;;
86      mingw32)
87      OSARCH=mingw32
88      WINARCH=1
89      ;;
90      cygwin)
91      OSARCH=cygwin
92      WINARCH=1
93      ;;
94      *)
95      OSARCH=${host_os}
96      ;;
97 esac
98
99 AC_SUBST(OSARCH)
100 AC_SUBST(WINARCH)
101
102 #  check for uname
103 AC_PATH_TOOL([UNAME], [uname], No)
104 if test ! x"${UNAME}" = xNo; then
105    PBX_OSREV=$(${UNAME} -r)
106 fi
107 AC_SUBST(PBX_OSREV)
108
109 AH_TOP(
110 #ifndef ASTERISK_AUTOCONFIG_H
111 #define ASTERISK_AUTOCONFIG_H
112
113 #include "asterisk/buildopts.h"
114
115 )
116
117 AH_BOTTOM(
118 #endif
119 )
120
121 # cross-compile checks
122 if test "${cross_compiling}" = "yes"; 
123 then
124    AC_CHECK_TOOL(CC, gcc, :)
125    AC_CHECK_TOOL(CXX, g++, :)
126    AC_CHECK_TOOL(LD, ld, :)
127    AC_CHECK_TOOL(RANLIB, ranlib, :)
128 fi
129
130 # Checks for programs.
131 AC_PROG_CC
132 AC_PROG_CXX
133 AC_PROG_CPP
134 AC_PROG_CXXCPP
135 # This macro is just copied into our local acinclude.m4 from libtool.m4 so that
136 # the developers regenerating the configure script don't have to install libtool.
137 AST_PROG_LD     # note, does not work on FreeBSD
138 AC_PROG_AWK
139 AC_PROG_INSTALL
140 AC_PROG_LN_S
141 AC_PROG_RANLIB
142 AST_CHECK_GNU_MAKE
143
144 AC_PATH_TOOL([STRIP], [strip], :)
145 AC_PATH_TOOL([AR], [ar], :)
146
147 GNU_LD=0
148 if test "x$with_gnu_ld" = "xyes" ; then
149    GNU_LD=1
150 fi
151 AC_SUBST(GNU_LD)
152
153 AC_PATH_PROG([AWK], [awk], :)
154 AC_PATH_PROG([GREP], [grep], :)
155 AC_PATH_PROG([FIND], [find], :)
156 AC_PATH_PROG([COMPRESS], [compress], :)
157 AC_PATH_PROG([BASENAME], [basename], :)
158 AC_PATH_PROG([ID], [id], :)
159 AC_PATH_PROG([DIRNAME], [dirname], :)
160 AC_PATH_PROG([SHELL], [sh], :)
161 AC_PATH_PROG([LN], [ln], :)
162 AC_PATH_PROG([DOT], [dot], :)
163 AC_PATH_PROG([WGET], [wget], :)
164 AC_PATH_PROG([RUBBER], [rubber], :)
165 if test "${WGET}" != ":" ; then
166   DOWNLOAD=${WGET}
167 else
168   AC_PATH_PROG([FETCH], [fetch], [:])
169   DOWNLOAD=${FETCH}
170 fi
171 AC_SUBST(DOWNLOAD)
172
173 AC_CHECK_TOOL([SOXMIX], [soxmix], [:])
174 if test "${SOXMIX}" != ":" ; then
175         AC_DEFINE([HAVE_SOXMIX], 1, [Define to 1 if your system has soxmix application.])
176 fi
177
178 ACX_PTHREAD
179
180 AC_LANG(C)
181
182 AC_ARG_ENABLE(dev-mode,
183         [  --enable-dev-mode    Turn on developer mode],
184         [case "${enableval}" in
185               y|ye|yes) AST_DEVMODE=yes ;;
186               n|no)  AST_DEVMODE=no ;;
187               *) AC_MSG_ERROR(bad value ${enableval} for --enable-dev-mode)  ;;
188         esac])
189 AC_SUBST(AST_DEVMODE)
190
191 # AST_EXT_LIB_SETUP is used to tell configure to handle variables for
192 # various packages.
193 # $1 is the prefix for the variables in makeopts and autoconfig.h
194 # $2 is the short comment, $4 is the long comment
195 # $3 is the name used in --with- or --without- flags for configure.
196 #
197 # Package option names should be in alphabetical order
198 # by the --with option name (the third field),
199 # to make things easier for the users.
200
201 AST_EXT_LIB_SETUP([ALSA], [Advanced Linux Sound Architecture], [asound])
202
203 # BKTR is used for backtrace support on platforms that do not
204 # have it natively.
205 AST_EXT_LIB_SETUP([BKTR], [Stack Backtrace support], [execinfo])
206 AST_EXT_LIB_SETUP([CAP], [POSIX 1.e capabilities], [cap])
207 AST_EXT_LIB_SETUP([CURL], [cURL], [curl])
208 AST_EXT_LIB_SETUP([CURSES], [curses], [curses])
209 AST_EXT_LIB_SETUP([CRYPTO], [OpenSSL Cryptography support], [crypto])
210 AST_EXT_LIB_SETUP([GSM], [External GSM library], [gsm], [, use 'internal' GSM otherwise])
211 AST_EXT_LIB_SETUP([GTK], [gtk libraries], [gtk])
212 AST_EXT_LIB_SETUP([GTK2], [gtk2 libraries], [gtk2])
213 AST_EXT_LIB_SETUP([ICONV], [Iconv Library], [iconv])
214 AST_EXT_LIB_SETUP([IKSEMEL], [Iksemel Jabber Library], [iksemel])
215 AST_EXT_LIB_SETUP([IMAP_TK], [UW IMAP Toolkit], [imap])
216 AST_EXT_LIB_SETUP([ISDNNET], [ISDN4Linux Library], [isdnnet])
217 AST_EXT_LIB_SETUP([KDE], [KDE], [kde])
218 AST_EXT_LIB_SETUP([LTDL], [libtool], [ltdl])
219 AST_EXT_LIB_SETUP([LUA], [Lua], [lua])
220 AST_EXT_LIB_SETUP([MISDN], [mISDN User Library], [misdn])
221 AST_EXT_LIB_SETUP([NBS], [Network Broadcast Sound], [nbs])
222 AST_EXT_LIB_SETUP([NCURSES], [ncurses], [ncurses])
223 AST_EXT_LIB_SETUP([NETSNMP], [Net-SNMP], [netsnmp])
224 AST_EXT_LIB_SETUP([NEWT], [newt], [newt])
225 AST_EXT_LIB_SETUP([UNIXODBC], [unixODBC], [odbc])
226 AST_EXT_LIB_SETUP([OGG], [OGG], [ogg])
227 AST_EXT_LIB_SETUP([OSPTK], [OSP Toolkit], [osptk])
228 AST_EXT_LIB_SETUP([OSS], [Open Sound System], [oss])
229 AST_EXT_LIB_SETUP([PGSQL], [PostgreSQL], [postgres])
230 AST_EXT_LIB_SETUP([POPT], [popt], [popt])
231 AST_EXT_LIB_SETUP([PORTAUDIO], [PortAudio], [portaudio])
232 AST_EXT_LIB_SETUP([PRI], [ISDN PRI], [pri])
233 AST_EXT_LIB_SETUP([SS7], [ISDN SS7], [ss7])
234 AST_EXT_LIB_SETUP([PWLIB], [PWlib], [pwlib])
235 AST_EXT_LIB_SETUP([OPENH323], [OpenH323], [h323])
236 AST_EXT_LIB_SETUP([QT], [Qt], [qt])
237 AST_EXT_LIB_SETUP([RADIUS], [Radius Client], [radius])
238 AST_EXT_LIB_SETUP([SPEEX], [Speex], [speex])
239 AST_EXT_LIB_SETUP([SQLITE], [SQLite], [sqlite])
240 AST_EXT_LIB_SETUP([SQLITE3], [SQLite], [sqlite3])
241 AST_EXT_LIB_SETUP([SUPPSERV], [mISDN Supplemental Services], [suppserv])
242 AST_EXT_LIB_SETUP([OPENSSL], [OpenSSL Secure Sockets Layer support], [ssl])
243 AST_EXT_LIB_SETUP([FREETDS], [FreeTDS], [tds])
244 AST_EXT_LIB_SETUP([TERMCAP], [Termcap], [termcap])
245 AST_EXT_LIB_SETUP([TINFO], [Term Info], [tinfo])
246 AST_EXT_LIB_SETUP([TONEZONE], [tonezone], [tonezone])
247 AST_EXT_LIB_SETUP([USB], [usb], [usb])
248 AST_EXT_LIB_SETUP([VORBIS], [Vorbis], [vorbis])
249 AST_EXT_LIB_SETUP([VPB], [Voicetronix API], [vpb])
250 AST_EXT_LIB_SETUP([X11], [X11 support], [x11])
251 AST_EXT_LIB_SETUP([ZLIB], [zlib], [z])
252 AST_EXT_LIB_SETUP([ZAPTEL], [Zaptel], [zaptel])
253 AST_EXT_LIB_SETUP([ZAPTEL_TRANSCODE], [Zaptel_transcode], [zaptel_transcode])
254 AST_EXT_LIB_SETUP([ZAPTEL_VLDTMF], [Zaptel_vldtmf], [zaptel_vldtmf])
255
256 AST_EXT_LIB_SETUP([SDL], [Sdl], [sdl])
257 AST_EXT_LIB_SETUP([SDL_IMAGE], [Sdl Image library], [SDL_image])
258 AST_EXT_LIB_SETUP([FFMPEG], [Ffmpeg and avcodec library], [avcodec])
259
260 # check for basic system features and functionality before
261 # checking for package libraries
262
263 AC_FUNC_ALLOCA
264 AC_HEADER_DIRENT
265 AC_HEADER_STDC
266 AC_HEADER_SYS_WAIT
267 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h libintl.h limits.h locale.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h syslog.h termios.h unistd.h utime.h])
268
269 AC_CHECK_HEADERS([winsock.h winsock2.h])
270
271 AC_SYS_LARGEFILE
272
273 # Checks for typedefs, structures, and compiler characteristics.
274 AC_HEADER_STDBOOL
275 AC_C_CONST
276 AC_TYPE_UID_T
277 AC_C_INLINE
278 AC_TYPE_MODE_T
279 AC_TYPE_OFF_T
280 AC_TYPE_PID_T
281 AC_TYPE_SIZE_T
282 AC_CHECK_MEMBERS([struct stat.st_blksize])
283 AC_HEADER_TIME
284 AC_STRUCT_TM
285 AC_C_VOLATILE
286 AC_CHECK_TYPES([ptrdiff_t])
287
288 # Checks for library functions.
289 AC_FUNC_CHOWN
290 AC_FUNC_CLOSEDIR_VOID
291 AC_FUNC_ERROR_AT_LINE
292 AST_FUNC_FORK
293 AC_FUNC_FSEEKO
294 AC_PROG_GCC_TRADITIONAL
295 # XXX: these are commented out until we determine whether it matters if our malloc()
296 # acts exactly like glibc's or not
297 # AC_FUNC_MALLOC
298 # AC_FUNC_REALLOC
299 AC_FUNC_MEMCMP
300 AC_FUNC_MKTIME
301 AC_FUNC_MMAP
302 AC_FUNC_SELECT_ARGTYPES
303 AC_FUNC_SETVBUF_REVERSED
304 AC_TYPE_SIGNAL
305 AC_FUNC_STAT
306 AC_FUNC_STRCOLL
307 AC_FUNC_STRFTIME
308 AC_FUNC_STRNLEN
309 AC_FUNC_STRTOD
310 AC_FUNC_UTIME_NULL
311 AC_FUNC_VPRINTF
312 AC_CHECK_FUNCS([asprintf atexit bzero dup2 endpwent ftruncate getcwd gethostbyname gethostname getloadavg gettimeofday inet_ntoa isascii localtime_r memchr memmove memset mkdir munmap putenv re_comp regcomp select setenv socket strcasecmp strcasestr strchr strcspn strdup strerror strlcat strlcpy strncasecmp strndup strnlen strrchr strsep strspn strstr strtol strtoq unsetenv utime vasprintf])
313
314 AC_CHECK_FUNCS([glob])
315
316 AC_MSG_CHECKING(for timersub in time.h)
317 AC_LINK_IFELSE(
318         AC_LANG_PROGRAM([#include <sys/time.h>],
319                 [struct timeval *a; timersub(a, a, a);]),
320         AC_MSG_RESULT(yes)
321                 AC_DEFINE([HAVE_TIMERSUB], 1, [Define to 1 if your system defines timersub.]),
322         AC_MSG_RESULT(no)
323 )
324
325 AC_CHECK_HEADER([sys/poll.h], 
326    [HAS_POLL=1]
327    AC_DEFINE([HAVE_SYS_POLL_H], 1, [Define to 1 if your system has working sys/poll.h]),
328    )
329 AC_SUBST(HAS_POLL)
330
331 # https support (in main/http.c) uses funopen on BSD systems,
332 # fopencookie on linux
333 AC_CHECK_FUNCS([funopen fopencookie])
334
335 AC_CHECK_FUNCS([inet_aton])
336
337 # check if we have IP_PKTINFO constant defined
338 AC_MSG_CHECKING(for IP_PKTINFO)
339 AC_LINK_IFELSE(
340                 AC_LANG_PROGRAM([#include <netinet/in.h>],
341                                                 [int pi = IP_PKTINFO;]),
342                 AC_MSG_RESULT(yes)
343                 AC_DEFINE([HAVE_PKTINFO], 1, [Define to 1 if your system defines IP_PKTINFO.]),
344                 AC_MSG_RESULT(no)
345 )
346
347 # some systems already have gethostbyname_r so we don't need to build ours in main/utils.c
348 AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
349
350 AC_MSG_CHECKING(for gethostbyname_r with 6 arguments)
351 AC_LINK_IFELSE(
352         AC_LANG_PROGRAM([#include <stdlib.h>
353                          #include <netdb.h>],
354                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);]),
355         AC_MSG_RESULT(yes)
356         AC_DEFINE([HAVE_GETHOSTBYNAME_R_6], 1, [Define to 1 if your system has gethostbyname_r with 6 arguments.]),
357         AC_MSG_RESULT(no)
358 )
359
360 AC_MSG_CHECKING(for gethostbyname_r with 5 arguments)
361 AC_LINK_IFELSE(
362         AC_LANG_PROGRAM([#include <stdlib.h>
363                          #include <netdb.h>],
364                         [struct hostent *he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);]),
365         AC_MSG_RESULT(yes)
366         AC_DEFINE([HAVE_GETHOSTBYNAME_R_5], 1, [Define to 1 if your system has gethostbyname_r with 5 arguments.]),
367         AC_MSG_RESULT(no)
368 )
369
370 AC_CHECK_HEADER([byteswap.h], [AC_DEFINE_UNQUOTED([HAVE_BYTESWAP_H], 1, [Define to 1 if byteswap.h macros are available.])])
371
372 AC_MSG_CHECKING(for __swap16 variant of <sys/endian.h> byteswapping macros)
373 AC_LINK_IFELSE(
374 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = __swap16(a);]),
375 AC_MSG_RESULT(yes)
376 AC_DEFINE([HAVE_SYS_ENDIAN_SWAP16], 1, [Define to 1 if your sys/endian.h header file provides the __swap16 macro.]),
377 AC_MSG_RESULT(no)
378 )
379
380 AC_MSG_CHECKING(for bswap16 variant of <sys/endian.h> byteswapping macros)
381 AC_LINK_IFELSE(
382 AC_LANG_PROGRAM([#include <sys/endian.h>], [int a = 1; int b = bswap16(a);]),
383 AC_MSG_RESULT(yes)
384 AC_DEFINE([HAVE_SYS_ENDIAN_BSWAP16], 1, [Define to 1 if your sys/endian.h header file provides the bswap16 macro.]),
385 AC_MSG_RESULT(no)
386 )
387
388 if test "${cross_compiling}" = "no";
389 then
390   AC_CHECK_FILE(/dev/urandom, AC_DEFINE([HAVE_DEV_URANDOM], 1, [Define to 1 if your system has /dev/urandom.]))
391 fi
392
393 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_INITIALIZER], [PTHREAD_RWLOCK_INITIALIZER], [pthread.h])
394 AST_C_DEFINE_CHECK([PTHREAD_RWLOCK_PREFER_WRITER_NP], [PTHREAD_RWLOCK_PREFER_WRITER_NP], [pthread.h])
395 AST_C_DEFINE_CHECK([PTHREAD_MUTEX_RECURSIVE_NP], [PTHREAD_MUTEX_RECURSIVE_NP], [pthread.h])
396 AST_C_DEFINE_CHECK([PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP], [pthread.h])
397
398 if test "${cross_compiling}" = "no";
399 then
400 AC_MSG_CHECKING(for working epoll support)
401 AC_LINK_IFELSE(
402 AC_LANG_PROGRAM([#include <sys/epoll.h>], [int res = epoll_create(10);
403                                           if (res < 0)
404                                              return 1;
405                                           close (res);
406                                           return 0;]),
407 AC_MSG_RESULT(yes)
408 AC_DEFINE([HAVE_EPOLL], 1, [Define to 1 if your system has working epoll support.]),
409 AC_MSG_RESULT(no)
410 )
411 fi
412
413 AC_MSG_CHECKING(for compiler atomic operations)
414 AC_LINK_IFELSE(
415 AC_LANG_PROGRAM([], [int foo1; int foo2 = __sync_fetch_and_add(&foo1, 1);]),
416 AC_MSG_RESULT(yes)
417 AC_DEFINE([HAVE_GCC_ATOMICS], 1, [Define to 1 if your GCC C compiler provides atomic operations.]),
418 AC_MSG_RESULT(no)
419 )
420
421 AST_GCC_ATTRIBUTE(pure)
422 AST_GCC_ATTRIBUTE(malloc)
423 AST_GCC_ATTRIBUTE(const)
424 AST_GCC_ATTRIBUTE(unused)
425 AST_GCC_ATTRIBUTE(always_inline)
426 AST_GCC_ATTRIBUTE(deprecated)
427
428 AC_MSG_CHECKING(for -ffunction-sections support)
429 saved_CFLAGS="${CFLAGS}"
430 CFLAGS="${CFLAGS} -ffunction-sections"
431 AC_COMPILE_IFELSE(
432         AC_LANG_PROGRAM([], [int x = 1;]),
433         AC_MSG_RESULT(yes)
434         [saved_LDFLAGS="${LDFLAGS}"]
435         [LDFLAGS="${LDFLAGS} -Wl,--gc-sections"]
436         AC_MSG_CHECKING(for --gc-sections support)
437         AC_LINK_IFELSE(
438                 AC_LANG_PROGRAM([], [int x = 1;]),
439                 AC_MSG_RESULT(yes)
440                 [GC_CFLAGS="-ffunction-sections"]
441                 [[GC_LDFLAGS="-Wl,--gc-sections"]],
442                 AC_MSG_RESULT(no)
443         )
444         [LDFLAGS="${saved_LDFLAGS}"],
445         AC_MSG_RESULT(no)
446 )
447 CFLAGS="${saved_CFLAGS}"
448 AC_SUBST(GC_CFLAGS)
449 AC_SUBST(GC_LDFLAGS)
450
451 AC_MSG_CHECKING(for -Wdeclaration-after-statement support)
452 if $(${CC} -Wdeclaration-after-statement -S -o /dev/null -xc /dev/null > /dev/null 2>&1); then
453         AC_MSG_RESULT(yes)
454         AST_DECLARATION_AFTER_STATEMENT=-Wdeclaration-after-statement
455 else
456         AC_MSG_RESULT(no)
457         AST_DECLARATION_AFTER_STATEMENT=
458 fi
459 AC_SUBST(AST_DECLARATION_AFTER_STATEMENT)
460
461
462 AC_MSG_CHECKING(for sysinfo)
463 AC_LINK_IFELSE(
464         AC_LANG_PROGRAM([#include <sys/sysinfo.h>],
465                         [struct sysinfo sys_info; int uptime = sys_info.uptime]),
466         AC_MSG_RESULT(yes)
467         AC_DEFINE([HAVE_SYSINFO], 1, [Define to 1 if your system has sysinfo support]),
468         AC_MSG_RESULT(no)
469 )
470
471 AC_MSG_CHECKING(for res_ninit)
472 AC_LINK_IFELSE(
473         AC_LANG_PROGRAM([#include <resolv.h>],
474                         [int foo = res_ninit(NULL);]),
475         AC_MSG_RESULT(yes)
476         AC_DEFINE([HAVE_RES_NINIT], 1, [Define to 1 if your system has the re-entrant resolver functions.])
477         AC_MSG_CHECKING(for res_ndestroy)
478         AC_LINK_IFELSE(
479                 AC_LANG_PROGRAM([#include <resolv.h>],
480                                 [int foo = res_ndestroy(NULL);]),
481                 AC_MSG_RESULT(yes)
482                 AC_DEFINE([HAVE_RES_NDESTROY], 1, [Define to 1 if your system has the ndestroy resolver function.]),
483                 AC_MSG_RESULT(no)
484         ),
485         AC_MSG_RESULT(no)
486 )
487
488 AST_C_DEFINE_CHECK([RTLD_NOLOAD], [RTLD_NOLOAD], [dlfcn.h])
489
490 AST_C_DEFINE_CHECK([IP_MTU_DISCOVER], [IP_MTU_DISCOVER], [netinet/in.h])
491
492 AC_CHECK_HEADER([libkern/OSAtomic.h],
493                 [AC_DEFINE_UNQUOTED([HAVE_OSX_ATOMICS], 1, [Define to 1 if OSX atomic operations are supported.])])
494
495 AC_CHECK_SIZEOF(int)
496
497 # do the package library checks now
498
499 AST_EXT_LIB_CHECK([ALSA], [asound], [snd_spcm_init], [alsa/asoundlib.h], [-lm -ldl])
500
501 AST_EXT_LIB_CHECK([CURSES], [curses], [initscr], [curses.h])
502
503 if test "x${host_os}" = "xlinux-gnu" ; then
504   AST_EXT_LIB_CHECK([CAP], [cap], [cap_from_text], [sys/capability.h])
505 fi
506
507 # BSD might not have exp2, and/or log2
508 AST_EXT_LIB_CHECK([EXP2L], [m], [exp2l])
509 AST_EXT_LIB_CHECK([LOG2L], [m], [log2l])
510 AST_EXT_LIB_CHECK([EXP10L], [m], [exp10l])
511 AST_EXT_LIB_CHECK([LOG10L], [m], [log10l])
512 AST_EXT_LIB_CHECK([SINL], [m], [sinl])
513 AST_EXT_LIB_CHECK([COSL], [m], [cosl])
514 AST_EXT_LIB_CHECK([TANL], [m], [tanl])
515 AST_EXT_LIB_CHECK([ASINL], [m], [asinl])
516 AST_EXT_LIB_CHECK([ACOSL], [m], [acosl])
517 AST_EXT_LIB_CHECK([ATANL], [m], [atanl])
518 AST_EXT_LIB_CHECK([ATAN2L], [m], [atan2l])
519 AST_EXT_LIB_CHECK([POWL], [m], [powl])
520 AST_EXT_LIB_CHECK([SQRTL], [m], [sqrtl])
521 AST_EXT_LIB_CHECK([RINTL], [m], [rintl])
522 AST_EXT_LIB_CHECK([EXPL], [m], [expl])
523 AST_EXT_LIB_CHECK([LOGL], [m], [logl])
524 AST_EXT_LIB_CHECK([REMAINDERL], [m], [remainderl])
525 AST_EXT_LIB_CHECK([FMODL], [m], [fmodl])
526 AST_EXT_LIB_CHECK([ROUNDL], [m], [roundl])
527 AST_EXT_LIB_CHECK([TRUNCL], [m], [truncl])
528 AST_EXT_LIB_CHECK([STRTOLD], [c], [strtold], [stdlib.h])
529 AST_EXT_LIB_CHECK([FLOORL], [m], [floorl])
530 AST_EXT_LIB_CHECK([CEILL], [m], [ceill])
531 AST_EXT_LIB_CHECK([EXP2], [m], [exp2])
532 AST_EXT_LIB_CHECK([LOG2], [m], [log2])
533 AST_EXT_LIB_CHECK([EXP10], [m], [exp10])
534 AST_EXT_LIB_CHECK([LOG10], [m], [log10])
535 AST_EXT_LIB_CHECK([SIN], [m], [sin])
536 AST_EXT_LIB_CHECK([COS], [m], [cos])
537 AST_EXT_LIB_CHECK([TAN], [m], [tan])
538 AST_EXT_LIB_CHECK([ASIN], [m], [asin])
539 AST_EXT_LIB_CHECK([ACOS], [m], [acos])
540 AST_EXT_LIB_CHECK([ATAN], [m], [atan])
541 AST_EXT_LIB_CHECK([ATAN2], [m], [atan2])
542 AST_EXT_LIB_CHECK([POW], [m], [pow])
543 AST_EXT_LIB_CHECK([SQRT], [m], [sqrt])
544 AST_EXT_LIB_CHECK([RINT], [m], [rint])
545 AST_EXT_LIB_CHECK([EXP], [m], [exp])
546 AST_EXT_LIB_CHECK([LOG], [m], [log])
547 AST_EXT_LIB_CHECK([REMAINDER], [m], [remainder])
548 AST_EXT_LIB_CHECK([FMOD], [m], [fmod])
549 AST_EXT_LIB_CHECK([ROUND], [m], [round])
550 AST_EXT_LIB_CHECK([TRUNC], [m], [trunc])
551 AST_EXT_LIB_CHECK([STRTOD], [c], [strtod], [stdlib.h])
552 AST_EXT_LIB_CHECK([FLOOR], [m], [floor])
553 AST_EXT_LIB_CHECK([CEIL], [m], [ceil])
554
555 GSM_INTERNAL="yes"
556 AC_SUBST(GSM_INTERNAL)
557 GSM_SYSTEM="yes"
558 if test "${USE_GSM}" != "no"; then
559    if test "${GSM_DIR}" = "internal"; then
560       GSM_SYSTEM="no"
561    elif test "${GSM_DIR}" != ""; then
562       GSM_INTERNAL="no"
563    fi
564    if test "${GSM_SYSTEM}" = "yes"; then
565       gsmlibdir=""
566       if test "x${GSM_DIR}" != "x"; then
567          if test -d ${GSM_DIR}/lib; then
568             gsmlibdir="-L${GSM_DIR}/lib"
569          else
570             gsmlibdir="-L${GSM_DIR}"
571          fi
572       fi
573       AC_CHECK_LIB([gsm], [gsm_create], AC_DEFINE_UNQUOTED([HAVE_GSM], 1,
574       [Define to indicate the GSM library]), [], ${gsmlibdir})
575       if test "${ac_cv_lib_gsm_gsm_create}" = "yes"; then
576          if test "x${GSM_DIR}" != "x" ; then
577             AC_CHECK_HEADER([${GSM_DIR}/include/gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
578             AC_CHECK_HEADER([${GSM_DIR}/include/gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
579          else
580             AC_CHECK_HEADER([gsm.h], [GSM_HEADER_FOUND=1], [GSM_HEADER_FOUND=0])
581             AC_CHECK_HEADER([gsm/gsm.h], [GSM_GSM_HEADER_FOUND=1], [GSM_GSM_HEADER_FOUND=0])
582          fi
583          if test "${GSM_HEADER_FOUND}" = "0" ; then
584             if test "{GSM_GSM_HEADER_FOUND}" = "0" ; then
585                if test "x${GSM_MANDATORY}" = "xyes" ; then
586                   AC_MSG_NOTICE([***])
587                   AC_MSG_NOTICE([*** It appears that you do not have the gsm development package installed.])
588                   AC_MSG_NOTICE([*** Please install it to include ${GSM_DESCRIP} support, or re-run configure])
589                   AC_MSG_NOTICE([*** without explicitly specifying --with-${GSM_OPTION}])
590                   exit 1
591                fi
592             fi
593          fi
594          GSM_OK=0
595          if test "${GSM_HEADER_FOUND}" = "1" ; then
596             AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
597             GSM_OK=1
598          else
599             if test "${GSM_GSM_HEADER_FOUND}" = "1" ; then
600                AC_DEFINE_UNQUOTED([HAVE_GSM_GSM_HEADER], 1, [Define to indicate that gsm.h is in gsm/gsm.h])
601                GSM_OK=1
602             fi
603          fi
604          if test "${GSM_OK}" = "1" ; then
605             GSM_LIB="-lgsm"
606             if test "x${GSM_DIR}" != "x"; then
607                GSM_LIB="${gsmlibdir} ${GSM_LIB}"
608                GSM_INCLUDE="-I${GSM_DIR}/include"
609             fi
610             PBX_GSM=1
611             GSM_INTERNAL="no"
612          fi
613       fi
614    fi
615    if test "${GSM_INTERNAL}" = "yes"; then
616       PBX_GSM=1
617       AC_DEFINE_UNQUOTED([HAVE_GSM_HEADER], 1, [Define to indicate that gsm.h has no prefix for its location])
618    fi
619 fi
620
621 AST_EXT_LIB_CHECK([ICONV], [iconv], [libiconv], [iconv.h])
622
623 AST_EXT_LIB_CHECK([IKSEMEL], [iksemel], [iks_start_sasl], [iksemel.h])
624
625 if test "${USE_IMAP_TK}" != "no"; then
626    if test "${IMAP_TK_DIR}" = "system" ; then
627       AC_MSG_NOTICE([Checking for system c-client library...])
628    elif test "${IMAP_TK_DIR}" = ""; then
629       IMAP_TK_DIR=`pwd`"/../imap-2004g"
630       if test  -n "${IMAP_TK_MANDATORY}"; then
631          AC_MSG_NOTICE([The --with-imap option does not search your system for installed])
632          AC_MSG_NOTICE([c-client library/header files. Since you did not provide a path])
633          AC_MSG_NOTICE([the configure script will assume you have placed built the c-client])
634          AC_MSG_NOTICE([files at ${IMAP_TK_DIR}, as outlined in the doc/imapstorage.txt file.])
635       fi
636    fi
637    if test "${IMAP_TK_DIR}" != "system" ; then
638       AC_MSG_CHECKING(for UW IMAP Toolkit c-client library)
639    fi
640    saved_cppflags="${CPPFLAGS}"
641    saved_libs="${LIBS}"
642    if test "${IMAP_TK_DIR}" = "system" ; then
643       imap_ldflags=""
644       imap_libs="-lc-client"
645       imap_include="-DUSE_SYSTEM_IMAP"
646    elif test -f ${IMAP_TK_DIR}/c-client/LDFLAGS ; then
647       imap_ldflags=`cat ${IMAP_TK_DIR}/c-client/LDFLAGS`
648       imap_libs="${IMAP_TK_DIR}/c-client/c-client.a"
649       imap_include="-I${IMAP_TK_DIR}/c-client"
650    fi
651    CPPFLAGS="${CPPFLAGS} ${imap_include}"
652    LIBS="${LIBS} ${imap_libs} "`echo ${imap_ldflags}`
653    AC_LINK_IFELSE(
654         AC_LANG_PROGRAM(
655                 [#ifdef USE_SYSTEM_IMAP
656                 #include <imap/c-client.h>
657                 #else
658                 #include "c-client.h"
659                 #endif
660                 void mm_searched (MAILSTREAM *stream,unsigned long number)
661                 {
662                 }
663                 void mm_exists (MAILSTREAM *stream,unsigned long number)
664                 {
665                 }
666                 void mm_expunged (MAILSTREAM *stream,unsigned long number)
667                 {
668                 }
669                 void mm_flags (MAILSTREAM *stream,unsigned long number)
670                 {
671                 }
672                 void mm_notify (MAILSTREAM *stream,char *string,long errflg)
673                 {
674                 }
675                 void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
676                 {
677                 }
678                 void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
679                 {
680                 }
681                 void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
682                 {
683                 }
684                 void mm_log (char *string,long errflg)
685                 {
686                 }
687                 void mm_dlog (char *string)
688                 {
689                 }
690                 void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
691                 {
692                 }
693                 void mm_critical (MAILSTREAM *stream)
694                 {
695                 }
696                 void mm_nocritical (MAILSTREAM *stream)
697                 {
698                 }
699                 long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
700                 {
701                 }
702                 void mm_fatal (char *string)
703                 {
704                 }],
705                 [
706                 MAILSTREAM *foo = mail_open(NULL, "", 0);
707                 ]
708         ),
709         [ac_cv_imap_tk="yes"],
710         [ac_cv_imap_tk="no"]
711    )
712    if test "${ac_cv_imap_tk}" = "yes"; then
713    AC_LINK_IFELSE(
714       AC_LANG_PROGRAM(
715          [#ifdef USE_SYSTEM_IMAP
716          #include <imap/c-client.h>
717          #else
718          #include "c-client.h"
719          #endif
720          void mm_searched (MAILSTREAM *stream,unsigned long number)
721          {
722          }
723          void mm_exists (MAILSTREAM *stream,unsigned long number)
724          {
725          }
726          void mm_expunged (MAILSTREAM *stream,unsigned long number)
727          {
728          }
729          void mm_flags (MAILSTREAM *stream,unsigned long number)
730          {
731          }
732          void mm_notify (MAILSTREAM *stream,char *string,long errflg)
733          {
734          }
735          void mm_list (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
736          {
737          }
738          void mm_lsub (MAILSTREAM *stream,int delimiter,char *mailbox,long attributes)
739          {
740          }
741          void mm_status (MAILSTREAM *stream,char *mailbox,MAILSTATUS *status)
742          {
743          }
744          void mm_log (char *string,long errflg)
745          {
746          }
747          void mm_dlog (char *string)
748          {
749          }
750          void mm_login (NETMBX *mb,char *user,char *pwd,long trial)
751          {
752          }
753          void mm_critical (MAILSTREAM *stream)
754          {
755          }
756          void mm_nocritical (MAILSTREAM *stream)
757          {
758          }
759          long mm_diskerror (MAILSTREAM *stream,long errcode,long serious)
760          {
761          }
762          void mm_fatal (char *string)
763          {
764          }],
765          [
766          long check = mail_expunge_full(NULL, "", 0);
767          ]
768       ),
769       [ac_cv_imap_tk2006="yes"],
770       [ac_cv_imap_tk2006="no"]
771   )
772   fi
773    CPPFLAGS="${saved_cppflags}"
774    LIBS="${saved_libs}"
775    if test "${ac_cv_imap_tk}" = "yes"; then
776       AC_MSG_RESULT(yes) 
777       IMAP_TK_LIB="${imap_libs} "`echo ${imap_ldflags}`
778       IMAP_TK_INCLUDE="${imap_include}"
779       PBX_IMAP_TK=1
780       AC_DEFINE([HAVE_IMAP_TK], 1, [Define if your system has the UW IMAP Toolkit c-client library.])
781       if test "${ac_cv_imap_tk2006}" = "yes"; then
782          AC_DEFINE([HAVE_IMAP_TK2006], 1, [Define if your system has the UW IMAP Toolkit c-client library version 2006 or greater.])
783       fi
784    else
785       AC_MSG_RESULT(no) 
786    fi
787 fi
788
789 # Needed by unixodbc
790 AST_EXT_LIB_CHECK([LTDL], [ltdl], [lt_dlinit], [ltdl.h], [])
791
792 AC_LANG_PUSH(C++)
793
794 if test "${USE_KDE}" != "no"; then
795    AC_MSG_CHECKING(for crashHandler in -lkdecore)
796    saved_libs="${LIBS}"
797    saved_cppflags="${CPPFLAGS}"
798    CPPFLAGS="${CPPFLAGS} -I${KDE_DIR}/include"
799    if test -d ${KDE_DIR}/lib; then
800       kdelibdir="${KDE_DIR}/lib"
801    else
802       kdelibdir="${KDE_DIR}"
803    fi
804    LIBS="${LIBS} -L${kdelibdir} -lkdecore"
805
806    AC_LINK_IFELSE(
807         [AC_LANG_PROGRAM(
808                         [#include "kcrash.h"],
809                         [KCrash::defaultCrashHandler(1);])
810         ],
811         [ac_cv_lib_kde_crash="yes"],
812         [ac_cv_lib_kde_crash="no"])
813                 
814    LIBS="${saved_libs}"
815    CPPFLAGS="${saved_cppflags}"
816         
817    if test "${ac_cv_lib_kde_crash}" = "yes"; then
818       AC_MSG_RESULT(yes) 
819       KDE_LIB="-lkdecore -lkdeui"
820       if test "${KDE_DIR}" != ""; then
821          KDE_LIB="-L${kdelibdir} ${KDE_LIB}"
822          KDE_INCLUDE="-I${KDE_DIR}/include"
823       fi
824       PBX_KDE=1
825       AC_DEFINE([HAVE_LIBKDE], 1, [Define if your system has the KDE libraries.])
826    else
827       AC_MSG_RESULT(no) 
828    fi
829 fi
830 if test "${PBX_KDE}" = 1; then
831    AC_PATH_TOOL(KDEINIT, kdeinit, No)
832    if test ! x"${KDEINIT}" = xNo; then
833       KDEDIR=$(${DIRNAME} ${KDEINIT})
834       KDEDIR=$(${DIRNAME} ${KDEDIR})
835    fi
836    AC_SUBST([KDEDIR])
837 fi
838
839 AC_LANG_POP
840
841 AST_EXT_LIB_CHECK([MISDN], [mISDN], [mISDN_open], [mISDNuser/mISDNlib.h])
842
843 if test "${PBX_MISDN}" = 1; then
844    AST_EXT_LIB_CHECK([ISDNNET], [isdnnet], [init_manager], [mISDNuser/isdn_net.h], [-lmISDN -lpthread])
845    AST_EXT_LIB_CHECK([SUPPSERV], [suppserv], [encodeFac], [mISDNuser/suppserv.h])
846    AST_C_DEFINE_CHECK([MISDN_FAC_RESULT], [Fac_RESULT], [mISDNuser/suppserv.h])
847    AST_C_DEFINE_CHECK([MISDN_FAC_ERROR], [Fac_ERROR], [mISDNuser/suppserv.h])
848    AC_CHECK_HEADER([linux/mISDNdsp.h], [AC_DEFINE_UNQUOTED([MISDN_1_2], 1, [Build chan_misdn for mISDN 1.2 or later.])])
849 fi
850
851 AST_EXT_LIB_CHECK([NBS], [nbs], [nbs_connect], [nbs.h])
852
853 AST_EXT_LIB_CHECK([NCURSES], [ncurses], [initscr], [curses.h])
854
855 # XXX do we need to check for snmp_register_callback ?
856 AST_EXT_TOOL_CHECK([NETSNMP], [net-snmp], , [--agent-libs])
857
858 AST_EXT_LIB_CHECK([NEWT], [newt], [newtBell], [newt.h])
859
860 AST_EXT_LIB_CHECK([UNIXODBC], [odbc], [SQLConnect], [sql.h], [])
861
862 AST_EXT_LIB_CHECK([OGG], [ogg], [ogg_sync_init], [])
863
864 AST_EXT_LIB_CHECK([BKTR], [execinfo], [backtrace], [execinfo.h])
865
866 # possible places for oss definitions
867 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [linux/soundcard.h])
868 AST_EXT_LIB_CHECK([OSS], [ossaudio], [], [sys/soundcard.h])
869 AST_EXT_LIB_CHECK([OSS], [ossaudio], [oss_ioctl_mixer], [soundcard.h])
870
871 PG_CONFIG=No
872 if test "${USE_PGSQL}" != "no"; then    
873    if test "x${PGSQL_DIR}" != "x"; then
874       AC_PATH_TOOL([PG_CONFIG], [pg_config], No, [${PGSQL_DIR}/bin])
875       if test x"${PG_CONFIG}" = xNo; then
876          AC_MSG_NOTICE([***])
877          AC_MSG_NOTICE([*** pg_config was not found in the path you specified:])
878          AC_MSG_NOTICE([*** ${PGSQL_DIR}/bin])
879          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
880          AC_MSG_NOTICE([*** including --without-postgres])
881          exit 1
882       fi
883    else
884       AC_PATH_TOOL([PG_CONFIG], [pg_config], No)
885    fi
886 fi
887 if test "${PG_CONFIG}" != No; then
888    PGSQL_libdir=`${PG_CONFIG} --libdir`
889    PGSQL_includedir=`${PG_CONFIG} --includedir`
890    if test "x$?" != "x0" ; then
891       if test -n "${PGSQL_MANDATORY}" ; then
892          AC_MSG_NOTICE([***])
893          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
894          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
895          AC_MSG_NOTICE([*** including --without-postgres])
896          exit 1
897           fi
898    else 
899       AC_CHECK_LIB([pq], [PQescapeStringConn], AC_DEFINE_UNQUOTED([HAVE_PGSQL], 1,
900       [Define to indicate the PostgreSQL library]), [], -L${PGSQL_libdir} -lz)
901
902       if test "${ac_cv_lib_pq_PQescapeStringConn}" = "yes"; then
903          PGSQL_LIB="-L${PGSQL_libdir} -lpq -lz"
904          PGSQL_INCLUDE="-I${PGSQL_includedir}"
905          PBX_PGSQL=1
906       elif test -n "${PGSQL_MANDATORY}";
907       then
908          AC_MSG_NOTICE([***])
909          AC_MSG_NOTICE([*** The PostgreSQL installation on this system appears to be broken.])
910          AC_MSG_NOTICE([*** Either correct the installation, or run configure])
911          AC_MSG_NOTICE([*** including --without-postgres])
912          exit 1
913       fi
914    fi
915 fi
916
917 AST_EXT_LIB_CHECK([POPT], [popt], [poptStrerror], [popt.h])
918
919 AST_EXT_LIB_CHECK([PORTAUDIO], [portaudio], [Pa_GetDeviceCount], [portaudio.h])
920
921 AST_EXT_LIB_CHECK([PRI], [pri], [pri_new_bri], [libpri.h])
922
923 AST_EXT_LIB_CHECK([SS7], [ss7], [isup_cqr], [libss7.h])
924
925 if test "${USE_PWLIB}" != "no"; then
926         if test -n "${PWLIB_DIR}"; then
927                 PWLIBDIR="${PWLIB_DIR}"
928         fi
929         AST_CHECK_PWLIB()
930         AST_CHECK_PWLIB_VERSION([PWLib], [PWLIB], [ptbuildopts.h], [1], [9], [2])
931                 
932         if test "${HAS_PWLIB:-unset}" != "unset"; then
933                 AST_CHECK_OPENH323_PLATFORM()
934
935                 PLATFORM_PWLIB="pt_${PWLIB_PLATFORM}_r"
936
937                 AST_CHECK_PWLIB_BUILD([PWLib], [PWLIB],
938                         [Define if your system has the PWLib libraries.],
939                         [#include "ptlib.h"],
940                         [BOOL q = PTime::IsDaylightSavings();])
941         fi
942 fi
943
944 if test "${PBX_PWLIB}" = "1" -a "${USE_OPENH323}" != "no" ; then
945         if test -n "${OPENH323_DIR}"; then
946                 OPENH323DIR="${OPENH323_DIR}"
947         fi
948         AST_CHECK_OPENH323()
949         AST_CHECK_PWLIB_VERSION([OpenH323], [OPENH323], [openh323buildopts.h], [1], [17], [3])
950         AST_CHECK_OPENH323_BUILD()
951         PLATFORM_OPENH323="h323_${PWLIB_PLATFORM}_${OPENH323_SUFFIX}"
952         AST_CHECK_PWLIB_BUILD([OpenH323], [OPENH323],
953                 [Define if your system has the OpenH323 libraries.],
954                 [#include "ptlib.h"
955                 #include "h323.h"
956                 #include "h323ep.h"],
957                 [H323EndPoint ep = H323EndPoint();],
958                 [${PWLIB_INCLUDE}], [${PWLIB_LIB}])
959 fi
960
961 AC_LANG_PUSH(C++)
962
963 if test "${USE_QT}" != "no"; then
964    AC_MSG_CHECKING(for QDate in -lqt)
965    saved_libs="${LIBS}"
966    saved_cppflags="${CPPFLAGS}"
967    if test "x${QT_DIR}" != "x"; then
968       LIBS="${LIBS} -L${QT_DIR}/lib"
969       CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
970    fi
971    LIBS="${LIBS} -lqt"
972    qtlib="qt"
973    AC_LINK_IFELSE(
974         [
975                 AC_LANG_PROGRAM(
976                 [#include <qt3/qdatetime.h>],
977                 [QDate date();])
978         ],
979         [ac_cv_lib_qt_qt_date="yes"],
980         [ac_cv_lib_qt_qt_date="no"])
981    LIBS="${saved_libs}"
982    CPPFLAGS="${saved_cppflags}"
983         
984    if test "${ac_cv_lib_qt_qt_date}" = "no"; then
985       saved_libs="${LIBS}"
986       saved_cppflags="${CPPFLAGS}"
987       if test "x${QT_DIR}" != "x"; then
988          LIBS="${LIBS} -L${QT_DIR}/lib"
989          CPPFLAGS="${CPPFLAGS} -I${QT_DIR}/include"
990       fi
991       LIBS="${LIBS} -lqt-mt"
992       qtlib="qt-mt"     
993       AC_LINK_IFELSE(
994                 [
995                         AC_LANG_PROGRAM(
996                         [#include <qt3/qdatetime.h>],
997                         [QDate date();])
998                 ],
999                 [ac_cv_lib_qt_qt_date="yes"],
1000                 [ac_cv_lib_qt_qt_date="no"])
1001       LIBS="${saved_libs}"
1002       CPPFLAGS="${saved_cppflags}"
1003    fi   
1004
1005    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
1006       AC_MSG_RESULT(yes) 
1007    else
1008       AC_MSG_RESULT(no) 
1009    fi
1010         
1011    if test "${ac_cv_lib_qt_qt_date}" = "yes"; then
1012       QT_LIB="-l${qtlib}"
1013       if test "${QT_DIR}" != ""; then
1014          QT_LIB="-L${QT_DIR}/lib ${QT_LIB}"
1015          QT_INCLUDE="-I${QT_DIR}/include"
1016       fi
1017       PBX_QT=1
1018       AC_DEFINE([HAVE_QT], 1, [Define if your system has the Qt library])
1019       AC_PATH_TOOL(QTMOC, moc, No)
1020    fi
1021 fi
1022
1023 AC_LANG_POP
1024
1025 LUA_INCLUDE="-I/usr/include/lua5.1"
1026 LUA_LIB="-llua5.1"
1027 AST_EXT_LIB_CHECK([LUA], [lua5.1], [luaL_newstate], [lua5.1/lua.h]) 
1028
1029 AST_EXT_LIB_CHECK([RADIUS], [radiusclient-ng], [rc_read_config], [radiusclient-ng.h])
1030
1031 AST_EXT_LIB_CHECK([SPEEX], [speex], [speex_encode], [speex/speex.h], [-lm])
1032
1033 AST_EXT_LIB_CHECK([SQLITE], [sqlite], [sqlite_exec], [sqlite.h])
1034
1035 AST_EXT_LIB_CHECK([SQLITE3], [sqlite3], [sqlite3_open], [sqlite3.h])
1036
1037 AST_EXT_LIB_CHECK([CRYPTO], [crypto], [AES_encrypt], [openssl/aes.h])
1038
1039 if test "$PBX_CRYPTO" = "1";
1040 then
1041     AST_EXT_LIB_CHECK([OPENSSL], [ssl], [ssl2_connect], [openssl/ssl.h], [-lcrypto])
1042 fi
1043
1044 if test "$PBX_OPENSSL" = "1";
1045 then
1046     AST_EXT_LIB_CHECK([OSPTK], [osptk], [OSPPCryptoDecrypt], [osp/osp.h], [-lcrypto -lssl])
1047 fi
1048
1049 AST_EXT_LIB_CHECK([FREETDS], [tds], [tds_version], [tds.h])
1050 if test "${PBX_FREETDS}" != "0";
1051 then
1052     case `grep TDS_VERSION_NO ${FREETDS_DIR:-/usr}/include/tdsver.h` in
1053         *0.64*)
1054                 FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_64"
1055         ;;
1056     *0.63*)
1057         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_63"
1058         ;;
1059     *0.62*)
1060         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_0_62"
1061         ;;
1062     *)
1063         FREETDS_INCLUDE="${FREETDS_INCLUDE} -DFREETDS_PRE_0_62"
1064         ;;
1065     esac
1066 fi
1067
1068 AST_EXT_LIB_CHECK([TERMCAP], [termcap], [tgetent], [])
1069
1070 AST_EXT_LIB_CHECK([TINFO], [tinfo], [tgetent], [])
1071
1072 if test "${host_os}" != "linux-gnu" ; then
1073   tonezone_extra="-lm"
1074 fi
1075
1076 # new tonezone, version 1.4.0
1077 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/tonezone.h], [${tonezone_extra}], [], [140])
1078 # other case, old tonezone (0.80)
1079 AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel/zaptel.h], [${tonezone_extra}], [], [80])
1080
1081 AST_EXT_LIB_CHECK([USB], [usb], [usb_init], [usb.h], [])
1082
1083 AST_EXT_LIB_CHECK([VORBIS], [vorbis], [vorbis_info_init], [vorbis/codec.h], [-lm -lvorbisenc])
1084
1085 AC_LANG_PUSH(C++)
1086
1087 if test "${USE_VPB}" != "no"; then
1088    AC_MSG_CHECKING(for vpb_open in -lvpb)
1089    saved_libs="${LIBS}"
1090    saved_cppflags="${CPPFLAGS}"
1091    if test "x${VPB_DIR}" != "x"; then
1092       if test -d ${VPB_DIR}/lib; then
1093          vpblibdir=${VPB_DIR}/lib
1094       else
1095          vpblibdir=${VPB_DIR}
1096       fi
1097       LIBS="${LIBS} -L${vpblibdir}"
1098       CPPFLAGS="${CPPFLAGS} -I${VPB_DIR}/include"
1099    fi
1100    LIBS="${LIBS} -lvpb -lpthread"
1101    AC_LINK_IFELSE(
1102         [
1103         AC_LANG_PROGRAM(
1104         [#include <vpbapi.h>],
1105         [int q = vpb_open(0,0);])
1106         ],
1107         [       AC_MSG_RESULT(yes) 
1108                 ac_cv_lib_vpb_vpb_open="yes" 
1109         ],
1110         [       AC_MSG_RESULT(no) 
1111                 ac_cv_lib_vpb_vpb_open="no" 
1112         ]
1113         )
1114    LIBS="${saved_libs}"
1115    CPPFLAGS="${saved_cppflags}"
1116    if test "${ac_cv_lib_vpb_vpb_open}" = "yes"; then
1117         VPB_LIB="-lvpb"
1118         if test "${VPB_DIR}" != ""; then
1119            VPB_LIB="-L${vpblibdir}  ${VPB_LIB}"
1120            VPB_INCLUDE="-I${VPB_DIR}/include"
1121         fi
1122         PBX_VPB=1
1123         AC_DEFINE([HAVE_VPB], 1, [Define if your system has the VoiceTronix API libraries.])
1124    fi
1125 fi
1126
1127 AC_LANG_POP
1128
1129 AST_EXT_LIB_CHECK([ZLIB], [z], [compress], [zlib.h])
1130
1131 # Check for various zaptel features and locations.
1132 # The version number, which goes into HAVE_ZAPTEL_VERSION,
1133 # will be used in the system headers to determine the location
1134 # of the zaptel.h header.
1135
1136 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_TONE_DTMF_BASE], [zaptel/zaptel.h], [140])
1137 AST_C_DEFINE_CHECK([ZAPTEL], [ZT_DIAL_OP_CANCEL], [zaptel/zaptel.h], [90])
1138
1139 # Check for VLDTMF support
1140 AST_C_DEFINE_CHECK([ZAPTEL_VLDTMF], [ZT_EVENT_REMOVED], [zaptel/zaptel.h])
1141
1142 # Check for transcode support
1143 AST_C_DEFINE_CHECK([ZAPTEL_TRANSCODE], [ZT_TCOP_ALLOCATE], [zaptel/zaptel.h])
1144
1145 # Check for Zaptel hwgain support
1146 AST_C_DEFINE_CHECK([ZAPTEL_HWGAIN], [ZT_SET_HWGAIN], [zaptel/zaptel.h])
1147
1148 # On FreeBSD, try old zaptel (0.80 or so) and pretend we have vldtmf
1149 case "${host_os}" in
1150     freebsd*)
1151         AST_EXT_LIB_CHECK([ZAPTEL], [zaptel],, [zaptel.h],,, [80])
1152         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel/zaptel.h],,, [90])
1153         AST_EXT_LIB_CHECK([ZAPTEL_VLDTMF], [zaptel],, [zaptel.h],,, [80])
1154
1155         # other case, old tonezone (0.80)
1156         AST_EXT_LIB_CHECK([TONEZONE], [tonezone], [tone_zone_find], [zaptel.h], [${tonezone_extra}],, [80])
1157         ;;
1158 esac
1159
1160 EDITLINE_LIB=""
1161 if test "x$TERMCAP_LIB" != "x" ; then
1162   EDITLINE_LIB="$TERMCAP_LIB"
1163 elif test "x$TINFO_LIB" != "x" ; then
1164   EDITLINE_LIB="$TINFO_LIB"
1165 elif test "x$CURSES_LIB" != "x" ; then
1166   EDITLINE_LIB="$CURSES_LIB"
1167 elif test "x$NCURSES_LIB" != "x" ; then
1168   EDITLINE_LIB="$NCURSES_LIB"
1169 else
1170   AC_MSG_ERROR(*** termcap support not found)
1171 fi
1172 AC_SUBST(EDITLINE_LIB)
1173
1174 AC_CHECK_HEADER([h323.h], [PBX_H323=1], [PBX_H323=0])
1175 AC_SUBST(PBX_H323)
1176
1177 AC_CHECK_HEADER([linux/compiler.h],
1178                 [AC_DEFINE_UNQUOTED([HAVE_LINUX_COMPILER_H], 1, [Define to 1 if your system has linux/compiler.h.])])
1179
1180 AC_CHECK_HEADER([linux/ixjuser.h], [PBX_IXJUSER=1], [PBX_IXJUSER=0], [
1181                                    #include <linux/version.h>
1182                                    #ifdef HAVE_LINUX_COMPILER_H
1183                                    #include <linux/compiler.h>
1184                                    #endif
1185                                    ])
1186 AC_SUBST(PBX_IXJUSER)
1187
1188 AST_EXT_TOOL_CHECK([SDL], [sdl])
1189 AST_EXT_LIB_CHECK([SDL_IMAGE], [SDL_image], [IMG_Load], [SDL_image.h], [${SDL_LIB}], [${SDL_INCLUDE}])
1190 AST_EXT_LIB_CHECK([FFMPEG], [avcodec], [sws_getContext], [ffmpeg/avcodec.h], [-lpthread -lz -lm])
1191
1192 # possible places for video4linux version 1
1193 AC_CHECK_HEADER([linux/videodev.h],
1194         [AC_DEFINE_UNQUOTED([HAVE_VIDEODEV_H], 1, [Define to 1 if your system has linux/videodev.h.])])
1195
1196 # possible places for X11
1197 AST_EXT_LIB_CHECK([X11], [X11], [XOpenDisplay], [X11/Xlib.h],,, [standard_path])
1198 AST_EXT_LIB_CHECK([X11], [X11], [XOpenDisplay], [X11/Xlib.h],, [-I/usr/X11R6/include], [X11R6])
1199
1200 # we don't use gtk right now...
1201 AST_EXT_TOOL_CHECK([GTK], [gtk])
1202
1203 PBX_GTK2=0
1204 AC_CHECK_TOOL(PKGCONFIG, pkg-config, No)
1205 if test ! "x${PKGCONFIG}" = xNo; then
1206    GTK2_INCLUDE=$(${PKGCONFIG} gtk+-2.0 --cflags 2>/dev/null)
1207    GTK2_LIB=$(${PKGCONFIG} gtk+-2.0 --libs)
1208    PBX_GTK2=1
1209    AC_DEFINE([HAVE_GTK2], 1, [Define if your system has the GTK2 libraries.])
1210 fi
1211 AC_SUBST(PBX_GTK2)
1212 AC_SUBST(GTK2_INCLUDE)
1213 AC_SUBST(GTK2_LIB)
1214
1215 if test "${USE_CURL}" != "no"; then
1216    AC_PATH_TOOL([CURL_CONFIG], [curl-config], No)
1217    if test ! x"${CURL_CONFIG}" = xNo; then
1218    # check for version
1219       if test $(printf "%d" 0x$(${CURL_CONFIG} --vernum)) -ge $(printf "%d" 0x070907); then
1220          CURL_INCLUDE=$(${CURL_CONFIG} --cflags)
1221          CURL_LIB=$(${CURL_CONFIG} --libs)
1222
1223          AC_MSG_CHECKING(for curl_version() in curl/curl.h)
1224          saved_cppflags="${CPPFLAGS}"
1225          CPPFLAGS="${CPPFLAGS} ${CURL_INCLUDE}"
1226          AC_COMPILE_IFELSE(
1227             [AC_LANG_PROGRAM(
1228                 [#include <curl/curl.h>],
1229                     [curl_version();])
1230             ],[
1231                 AC_MSG_RESULT(yes)
1232                 ac_cv_curl_h="yes"
1233             ],[
1234                 AC_MSG_RESULT(no)
1235                 ac_cv_curl_h="no"
1236             ]
1237          )
1238          CPPFLAGS="${saved_cppflags}"
1239          if test "${ac_cv_curl_h}" = "yes"; then
1240              PBX_CURL=1
1241              AC_DEFINE([HAVE_CURL], 1, [Define if your system has the curl libraries.])
1242          fi
1243       fi
1244    fi
1245 fi
1246
1247 AC_CONFIG_FILES([build_tools/menuselect-deps makeopts channels/h323/Makefile])
1248 AST_CHECK_MANDATORY
1249
1250 AC_OUTPUT
1251
1252 if test "x${silent}" != "xyes" ; then
1253 echo
1254 echo "               .\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$=..      "
1255 echo "            .\$7\$7..          .7\$\$7:.    "
1256 echo "          .\$\$:.                 ,\$7.7   "
1257 echo "        .\$7.     7\$\$\$\$           .\$\$77  "
1258 echo "     ..\$\$.       \$\$\$\$\$            .\$\$\$7 "
1259 echo "    ..7\$   .?.   \$\$\$\$\$   .?.       7\$\$\$."
1260 echo "   \$.\$.   .\$\$\$7. \$\$\$\$7 .7\$\$\$.      .\$\$\$."
1261 echo " .777.   .\$\$\$\$\$\$77\$\$\$77\$\$\$\$\$7.      \$\$\$,"
1262 echo " \$\$\$~      .7\$\$\$\$\$\$\$\$\$\$\$\$\$7.       .\$\$\$."
1263 echo ".\$\$7          .7\$\$\$\$\$\$\$7:          ?\$\$\$."
1264 echo "\$\$\$          ?7\$\$\$\$\$\$\$\$\$\$I        .\$\$\$7 "
1265 echo "\$\$\$       .7\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$      :\$\$\$. "
1266 echo "\$\$\$       \$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$\$\$\$    .\$\$\$.  "
1267 echo "\$\$\$        \$\$\$   7\$\$\$7  .\$\$\$    .\$\$\$.   "
1268 echo "\$\$\$\$             \$\$\$\$7         .\$\$\$.    "
1269 echo "7\$\$\$7            7\$\$\$\$        7\$\$\$      "
1270 echo " \$\$\$\$\$                        \$\$\$       "
1271 echo "  \$\$\$\$7.                       \$\$  (TM)     "
1272 echo "   \$\$\$\$\$\$\$.           .7\$\$\$\$\$\$  \$\$      "
1273 echo "     \$\$\$\$\$\$\$\$\$\$\$\$7\$\$\$\$\$\$\$\$\$.\$\$\$\$\$\$      "
1274 echo "       \$\$\$\$\$\$\$\$\$\$\$\$\$\$\$\$.                "
1275 echo
1276 fi
1277
1278 AC_MSG_NOTICE(Package configured for: )
1279 AC_MSG_NOTICE( OS type  : $host_os)
1280 AC_MSG_NOTICE( Host CPU : $host_cpu)
1281 AC_MSG_NOTICE( build-cpu:vendor:os: $build_cpu : $build_vendor : $build_os :) 
1282 AC_MSG_NOTICE( host-cpu:vendor:os: $host_cpu : $host_vendor : $host_os :) 
1283 if test "${cross_compiling}" = "yes"; then
1284    AC_MSG_NOTICE( Cross Compilation = YES)
1285 fi